default_plugins/ssh/ssh.zshrc

   1 # AX-ZSH: Alex' Modular ZSH Configuration
   2 # ssh.zshrc: Setup (Open-) SSH
   3
   4 # Make sure that "ssh(1)" is installed
   5 (( $+commands[ssh] )) || return
   6
   7 # Load SSH keys into the SSH agent, when one is running and doesn't have
   8 # any keys already. Not having an SSH agent running at all is ok as well and
   9 # results in an "success" exit code (0) as well.
  10 ssh-autoadd() {
  11         [[ -z "$SSH_AUTH_SOCK" ]] && return 0
  12         ssh-add -l >/dev/null && return 0
  13         [[ $? -eq 2 ]] && return 2
  14         [[ "$1" = "-v" ]] && echo "SSH agent is running, but has no identities."
  15         ssh-add
  16 }
  17
  18 _ax_ssh_prompt() {
  19         [[ -n "$SSH_CLIENT" ]] || return 1
  20         return 0
  21 }
  22
  23 ax_logname_prompt_functions=($ax_logname_prompt_functions _ax_ssh_prompt)
  24 ax_hostname_prompt_functions=($ax_hostname_prompt_functions _ax_ssh_prompt)
  25
  26 # Validate SSH_AUTH_SOCK: Inside of screen(1) sessions for example, the socket
  27 # file becomes invalid when the session has been disconnected.
  28 [[ ! -r "$SSH_AUTH_SOCK" ]] && unset SSH_AUTH_SOCK
  29
  30 # Look for common socket locations ...
  31 if [[ -z "$SSH_AUTH_SOCK" ]]; then
  32         for s (
  33                 /mnt/c/Local/$LOGNAME/ssh-agent.sock
  34         ); do
  35                 if [[ -r "$s" ]]; then
  36                         export SSH_AUTH_SOCK=$s
  37                         break
  38                 fi
  39         done
  40         unset s
  41 fi
  42
  43 # Save SSH environment when available:
  44 if [[ -n "$SSH_AUTH_SOCK" && -d "$XDG_RUNTIME_DIR" ]]; then
  45         # Save current environment when no state exists or is invalid.
  46         if [[ -r "$XDG_RUNTIME_DIR/ssh-env.sh" ]]; then
  47                 (
  48                         source "$XDG_RUNTIME_DIR/ssh-env.sh"
  49                         if [[ -z "$SSH_AUTH_SOCK" || ! -r "$SSH_AUTH_SOCK" ]]; then
  50                                 # Content is invalid, remove state file!
  51                                 rm -f "$XDG_RUNTIME_DIR/ssh-env.sh"
  52                         fi
  53                 )
  54         fi
  55         if [[ ! -r "$XDG_RUNTIME_DIR/ssh-env.sh" ]]; then
  56                 # No state file exists, create a new one:
  57                 echo "SSH_AUTH_SOCK=\"$SSH_AUTH_SOCK\"" >"$XDG_RUNTIME_DIR/ssh-env.sh"
  58                 echo "export SSH_AUTH_SOCK" >>"$XDG_RUNTIME_DIR/ssh-env.sh"
  59         fi
  60 fi
  61
  62 # Restore SSH environment when not set but available:
  63 if [[ -z "$SSH_AUTH_SOCK" && -r "$XDG_RUNTIME_DIR/ssh-env.sh" ]]; then
  64         # Try to recover known good environment ...
  65         source "$XDG_RUNTIME_DIR/ssh-env.sh"
  66         if [[ ! -r "$SSH_AUTH_SOCK" ]]; then
  67                 # Clean up!
  68                 unset SSH_AUTH_SOCK
  69                 rm -f "$XDG_RUNTIME_DIR/ssh-env.sh"
  70         fi
  71 fi