core/50_prompt/50_prompt.zshrc

   1 # AX-ZSH: Alex' Modular ZSH Configuration
   2 # 50_prompt.zshrc: Setup default prompts
   3
   4 # Logname ("user name")
   5
   6 (( $UID == 0 )) \
   7         && ZSH_THEME_LOGNAME_PROMPT_PREFIX="%{$fg_no_bold[red]%}" \
   8         || ZSH_THEME_LOGNAME_PROMPT_PREFIX=""
   9 ZSH_THEME_LOGNAME_PROMPT_SUFFIX="%{$reset_color%}@"
  10
  11 function ax_logname_prompt_root() {
  12         (( $UID == 0 )) || return 1
  13         echo "$LOGNAME"
  14         return 0
  15 }
  16
  17 function ax_logname_prompt_yn() {
  18         local func
  19         for func ($ax_logname_prompt_functions); do
  20                 $func || continue
  21                 echo "${ZSH_THEME_LOGNAME_PROMPT_PREFIX}${1:-$LOGNAME}${ZSH_THEME_LOGNAME_PROMPT_SUFFIX}"
  22                 return
  23         done
  24 }
  25
  26 ax_logname_prompt_functions=()
  27
  28 # Hostname
  29
  30 ZSH_THEME_HOSTNAME_PROMPT_PREFIX=""
  31 ZSH_THEME_HOSTNAME_PROMPT_SUFFIX="%{$reset_color%}:"
  32
  33 function ax_hostname_prompt_root() {
  34         (( $UID == 0 )) || return 1
  35         return 0
  36 }
  37
  38 function ax_hostname_prompt_yn() {
  39         local func
  40         for func ($ax_hostname_prompt_functions); do
  41                 $func || continue
  42                 echo "${ZSH_THEME_HOSTNAME_PROMPT_PREFIX}${1:-$SHORT_HOST}${ZSH_THEME_HOSTNAME_PROMPT_SUFFIX}"
  43                 return
  44         done
  45 }
  46
  47 ax_hostname_prompt_functions=()
  48
  49 # VCS
  50
  51 ZSH_THEME_VCS_PROMPT_PREFIX="(%{$fg_no_bold[yellow]%}"
  52 ZSH_THEME_VCS_PROMPT_SUFFIX="%{$reset_color%}) "
  53
  54 ZSH_THEME_VCS_PROMPT_CLEAN="%{$fg_no_bold[green]%}✔"
  55 ZSH_THEME_VCS_PROMPT_DIRTY="%{$fg_no_bold[red]%}✘"
  56 ZSH_THEME_VCS_PROMPT_AHEAD="%{$fg_no_bold[cyan]%}→"
  57 ZSH_THEME_VCS_PROMPT_BEHIND="%{$fg_no_bold[blue]%}←"
  58
  59 function ax_vcs_prompt() {
  60         local func
  61         local p
  62         for func ($ax_vcs_prompt_functions); do
  63                 p=$( $func ) || continue
  64                 echo "${ZSH_THEME_VCS_PROMPT_PREFIX}${p}${ZSH_THEME_VCS_PROMPT_SUFFIX}"
  65                 return
  66         done
  67 }
  68
  69 ax_vcs_prompt_functions=()
  70
  71 # Options and defaults
  72
  73 setopt PROMPT_SUBST
  74
  75 export PS1 RPS1