core/50_axzsh/functions/_axzsh

   1 #compdef axzshctl
   2
   3 _axzshctl() {
   4         _arguments \
   5                 '1: :((
   6                         enable\:"Enable AX-ZSH."
   7                         disable\:"Disable AX-ZSH."
   8                         enable-plugin\:"Enable plugin(s)."
   9                         disable-plugin\:"Disable plugin(s)."
  10                         list-enabled\:"List enabled plugin(s)."
  11                         reset-plugins\:"Reset active plugins to the default set."
  12                         enable-default-plugins\:"Enable all default plugins."
  13                         check-plugins\:"Check \"useful\" plugins."
  14                         set-theme\:"Set active theme."
  15                         upgrade\:"Upgrade AX-ZSH installation (requires Git)."
  16                         update-caches\:"Force rebuild of all cache files."
  17                 ))' \
  18                 '*: :->args'
  19 #
  20         case "$state" in
  21           'args')
  22                 case "$words[2]" in
  23                   "enable-plugin"|"disable-plugin")
  24                         compadd "$@" -- \
  25                                 "$AXZSH"/plugins/*(/:t) \
  26                                 "$AXZSH"/custom_plugins/*(N/:t) \
  27                                 "$AXZSH"/repos/*(/:t:s/#/\\/)
  28                         ;;
  29                   "set-theme")
  30                         compadd "$@" -- "-" \
  31                                 "$AXZSH"/themes/*.axzshtheme(:r:t) \
  32                                 "$AXZSH"/custom_themes/*.axzshtheme(N:r:t) \
  33                                 "$AXZSH"/custom_themes/*.zsh-theme(N:r:t) \
  34                                 "$AXZSH"/repos/*/*.axzshtheme(N:r:t) \
  35                                 "$AXZSH"/repos/*/*.zsh-theme(N:r:t)
  36                         ;;
  37                 esac
  38                 ;;
  39         esac
  40 }
  41
  42 _axzshctl "$@"