configure.in

   1 #
   2 # ngIRCd -- The Next Generation IRC Daemon
   3 # Copyright (c)2001-2008 Alexander Barton <alex@barton.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 # Please read the file COPYING, README and AUTHORS for more information.
  10 #
  11
  12 # -- Initialisation --
  13
  14 AC_PREREQ(2.50)
  15 AC_INIT(ngircd, 14.1)
  16 AC_CONFIG_SRCDIR(src/ngircd/ngircd.c)
  17 AC_CANONICAL_TARGET
  18 AM_INIT_AUTOMAKE(1.6)
  19 AM_CONFIG_HEADER(src/config.h)
  20
  21 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  22
  23 # -- Templates for config.h --
  24
  25 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
  26 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
  27 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
  28 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
  29 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
  30 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
  31 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
  32 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
  33 AH_TEMPLATE([WANT_IPV6], [Define if IPV6 protocol should be enabled])
  34 AH_TEMPLATE([ZEROCONF], [Define if support for Zeroconf should be included])
  35 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
  36
  37 AH_TEMPLATE([TARGET_OS], [Target operating system name])
  38 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
  39 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
  40
  41 # -- C Compiler --
  42
  43 AC_PROG_CC
  44
  45 # -- Helper programs --
  46
  47 AC_PROG_AWK
  48 AC_PROG_INSTALL
  49 AC_PROG_LN_S
  50 AC_PROG_MAKE_SET
  51 AC_PROG_RANLIB
  52
  53 # -- Compiler Features --
  54
  55 AM_C_PROTOTYPES
  56 AC_C_CONST
  57 AC_C_INLINE
  58
  59 # -- Hard coded system and compiler dependencies/features/options ... --
  60
  61 AC_DEFUN([GCC_STACK_PROTECT_CC],[
  62   ssp_cc=yes
  63   # we use -fstack-protector-all for the test to enfoce the use of the guard variable
  64   AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
  65   ssp_old_cflags="$CFLAGS"
  66   CFLAGS="$CFLAGS -fstack-protector-all"
  67   AC_TRY_LINK(,,, ssp_cc=no)
  68   echo $ssp_cc
  69   CFLAGS="$ssp_old_cflags"
  70   if test "X$ssp_cc" = "Xyes"; then
  71       CFLAGS="$CFLAGS -fstack-protector"
  72       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
  73   fi
  74 ])
  75
  76 if test "$GCC" = "yes"; then
  77         # We are using the GNU C compiler. Good!
  78         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
  79
  80         GCC_STACK_PROTECT_CC
  81 fi
  82
  83 case "$target_os" in
  84         hpux*)
  85                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
  86                 # (tested with HP/UX 11.11)
  87                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
  88                 ;;
  89 esac
  90
  91 # Add additional CFLAGS, eventually specified on the command line:
  92 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
  93
  94 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
  95
  96 # -- Headers --
  97
  98 AC_HEADER_STDC
  99 AC_HEADER_TIME
 100 AC_HEADER_SYS_WAIT
 101
 102 AC_CHECK_HEADERS([ \
 103         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
 104         strings.h sys/socket.h sys/time.h unistd.h \
 105         ],,AC_MSG_ERROR([required C header missing!]))
 106
 107 AC_CHECK_HEADERS([arpa/inet.h ctype.h malloc.h stdbool.h stddef.h varargs.h])
 108
 109 # -- Datatypes --
 110
 111 AC_MSG_CHECKING(whether socklen_t exists)
 112 AC_TRY_COMPILE([
 113 #include <sys/types.h>
 114 #include <sys/socket.h>
 115         ],[
 116         socklen_t a, b;
 117         a = 2; b = 4; a += b;
 118         ],[
 119         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
 120         ],[
 121         AC_MSG_RESULT(no)
 122 ])
 123
 124 AC_TYPE_SIGNAL
 125 AC_TYPE_SIZE_T
 126
 127 # -- Libraries --
 128
 129 AC_CHECK_LIB(UTIL,memmove)
 130 AC_CHECK_LIB(socket,bind)
 131 AC_CHECK_LIB(nsl,gethostent)
 132
 133 # -- Functions --
 134
 135 AC_FUNC_FORK
 136 AC_FUNC_STRFTIME
 137
 138 AC_CHECK_FUNCS([ \
 139         bind gethostbyaddr gethostbyname gethostname inet_ntoa \
 140         setsid setsockopt socket strcasecmp waitpid],,AC_MSG_ERROR([required function missing!]))
 141
 142 AC_CHECK_FUNCS(getaddrinfo getnameinfo inet_aton isdigit sigaction snprintf \
 143  vsnprintf strdup strlcpy strlcat strtok_r)
 144
 145 # -- Configuration options --
 146
 147 # use syslog?
 148
 149 x_syslog_on=no
 150 AC_ARG_WITH(syslog,
 151         [  --without-syslog        disable syslog (autodetected by default)],
 152         [       if test "$withval" != "no"; then
 153                         if test "$withval" != "yes"; then
 154                                 CFLAGS="-I$withval/include $CFLAGS"
 155                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 156                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 157                         fi
 158                         AC_CHECK_LIB(be, syslog)
 159                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
 160                                 AC_MSG_ERROR([Can't enable syslog!])
 161                         )
 162                 fi
 163         ],
 164         [
 165                 AC_CHECK_LIB(be, syslog)
 166                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
 167         ]
 168 )
 169 if test "$x_syslog_on" = "yes"; then
 170         AC_DEFINE(SYSLOG, 1)
 171         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
 172 fi
 173
 174 # use zlib compression?
 175
 176 x_zlib_on=no
 177 AC_ARG_WITH(zlib,
 178         [  --without-zlib          disable zlib compression (autodetected by default)],
 179         [       if test "$withval" != "no"; then
 180                         if test "$withval" != "yes"; then
 181                                 CFLAGS="-I$withval/include $CFLAGS"
 182                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 183                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 184                         fi
 185                         AC_CHECK_LIB(z, deflate)
 186                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
 187                                 AC_MSG_ERROR([Can't enable zlib!])
 188                         )
 189                 fi
 190         ],
 191         [       AC_CHECK_LIB(z, deflate)
 192                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
 193         ]
 194 )
 195 if test "$x_zlib_on" = "yes"; then
 196         AC_DEFINE(ZLIB, 1)
 197         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
 198 fi
 199
 200 # detect which IO API to use:
 201
 202 x_io_backend=none
 203
 204 AC_ARG_WITH(select,
 205         [  --without-select        disable select IO support (autodetected by default)],
 206         [       if test "$withval" != "no"; then
 207                         if test "$withval" != "yes"; then
 208                                 CFLAGS="-I$withval/include $CFLAGS"
 209                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 210                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 211                         fi
 212                         AC_CHECK_FUNCS(select, x_io_select=yes,
 213                                 AC_MSG_ERROR([Can't enable select IO support!])
 214                         )
 215                 fi
 216         ],
 217         [
 218                 AC_CHECK_FUNCS(select, x_io_select=yes)
 219         ]
 220 )
 221
 222 AC_ARG_WITH(poll,
 223         [  --without-poll          disable poll support (autodetected by default)],
 224         [       if test "$withval" != "no"; then
 225                         if test "$withval" != "yes"; then
 226                                 CFLAGS="-I$withval/include $CFLAGS"
 227                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 228                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 229                         fi
 230                         AC_CHECK_FUNCS(poll, x_io_backend=poll\(\),
 231                                 AC_MSG_ERROR([Can't enable poll IO support!])
 232                         )
 233                 fi
 234         ],
 235         [
 236                 AC_CHECK_FUNCS(poll, x_io_backend=poll\(\))
 237         ]
 238 )
 239
 240 AC_ARG_WITH(devpoll,
 241         [  --without-devpoll       disable /dev/poll IO support (autodetected by default)],
 242         [       if test "$withval" != "no"; then
 243                         if test "$withval" != "yes"; then
 244                                 CFLAGS="-I$withval/include $CFLAGS"
 245                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 246                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 247                         fi
 248
 249                                 AC_CHECK_HEADERS(sys/devpoll.h,,AC_MSG_ERROR([required C header missing!]))
 250                 fi
 251         ],
 252         [
 253                 AC_CHECK_HEADERS(sys/devpoll.h, x_io_backend=/dev/poll)
 254         ]
 255 )
 256
 257 AC_ARG_WITH(epoll,
 258         [  --without-epoll         disable epoll IO support (autodetected by default)],
 259         [       if test "$withval" != "no"; then
 260                         if test "$withval" != "yes"; then
 261                                 CFLAGS="-I$withval/include $CFLAGS"
 262                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 263                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 264                         fi
 265                         AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes,
 266                                 AC_MSG_ERROR([Can't enable epoll IO support!])
 267                         )
 268                 fi
 269         ],
 270         [
 271                 AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes)
 272         ]
 273 )
 274
 275 AC_ARG_WITH(kqueue,
 276         [  --without-kqueue        disable kqueue IO support (autodetected by default)],
 277         [       if test "$withval" != "no"; then
 278                         if test "$withval" != "yes"; then
 279                                 CFLAGS="-I$withval/include $CFLAGS"
 280                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 281                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 282                         fi
 283                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\),
 284                                 AC_MSG_ERROR([Can't enable kqueue IO support!])
 285                         )
 286                 fi
 287         ],
 288         [
 289                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\))
 290         ]
 291 )
 292
 293 if test "$x_io_epoll" = "yes" -a "$x_io_select" = "yes"; then
 294         # when epoll() and select() are available, we'll use both!
 295         x_io_backend="epoll(), select()"
 296 else
 297         if test "$x_io_epoll" = "yes"; then
 298                 # we prefere epoll() if it is available
 299                 x_io_backend="epoll()"
 300         else
 301                 if test "$x_io_select" = "yes" -a "$x_io_backend" = "none"; then
 302                         # we'll use select, when available and no "better"
 303                         # interface has been detected ...
 304                         x_io_backend="select()"
 305                 fi
 306         fi
 307 fi
 308
 309 if test "$x_io_backend" = "none"; then
 310         AC_MSG_ERROR([No useabe IO API activated/found!?])
 311 fi
 312
 313 # use SSL?
 314
 315 AC_ARG_WITH(openssl,
 316         [  --with-openssl          enable SSL support using OpenSSL],
 317         [       if test "$withval" != "no"; then
 318                         if test "$withval" != "yes"; then
 319                                 CFLAGS="-I$withval/include $CFLAGS"
 320                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 321                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 322                         fi
 323                         AC_CHECK_LIB(crypto, BIO_s_mem)
 324                         AC_CHECK_LIB(ssl, SSL_library_init)
 325                         AC_CHECK_FUNCS(SSL_library_init, x_ssl_openssl=yes,
 326                                 AC_MSG_ERROR([Can't enable openssl])
 327                         )
 328                 fi
 329         ]
 330 )
 331
 332 AC_ARG_WITH(gnutls,
 333         [  --with-gnutls           enable SSL support using gnutls],
 334         [       if test "$withval" != "no"; then
 335                         if test "$withval" != "yes"; then
 336                                 CFLAGS="-I$withval/include $CFLAGS"
 337                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 338                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 339                         fi
 340                         AC_CHECK_LIB(gnutls, gnutls_global_init)
 341                         AC_CHECK_FUNCS(gnutls_global_init, x_ssl_gnutls=yes,
 342                                 AC_MSG_ERROR([Can't enable gnutls])
 343                         )
 344                 fi
 345         ]
 346 )
 347
 348 x_ssl_lib="no"
 349 if test "$x_ssl_gnutls" = "yes"; then
 350         if test "$x_ssl_openssl" = "yes";then
 351                 AC_MSG_ERROR([Cannot enable both gnutls and openssl])
 352         fi
 353         x_ssl_lib=gnutls
 354 fi
 355 if test "$x_ssl_openssl" = "yes"; then
 356         x_ssl_lib=openssl
 357 fi
 358
 359 # use TCP wrappers?
 360
 361 x_tcpwrap_on=no
 362 AC_ARG_WITH(tcp-wrappers,
 363         [  --with-tcp-wrappers     enable TCP wrappers support],
 364         [       if test "$withval" != "no"; then
 365                         if test "$withval" != "yes"; then
 366                                 CFLAGS="-I$withval/include $CFLAGS"
 367                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 368                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 369                         fi
 370                         AC_MSG_CHECKING(for hosts_access)
 371                         LIBS="-lwrap $LIBS"
 372                         AC_TRY_LINK([
 373 #include <tcpd.h>
 374 int allow_severity = 0;
 375 int deny_severity = 0;
 376                                 ],[
 377                                 tcpd_warn("link test");
 378                                 ],[
 379                                 AC_MSG_RESULT(yes)
 380                                 AC_DEFINE(TCPWRAP, 1)
 381                                 x_tcpwrap_on=yes
 382                                 ],[
 383                                 AC_MSG_RESULT(no)
 384                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
 385                         ])
 386                 fi
 387         ]
 388 )
 389
 390 # include support for "zeroconf"?
 391
 392 x_zeroconf_on=no
 393 AC_ARG_WITH(zeroconf,
 394         [  --with-zeroconf         enable support for "Zeroconf"],
 395         [       if test "$withval" != "no"; then
 396                         if test "$withval" != "yes"; then
 397                                 CFLAGS="-I$withval/include $CFLAGS"
 398                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 399                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 400                         fi
 401                         AC_CHECK_FUNCS(DNSServiceRegistrationCreate, x_zeroconf_on=osx,
 402                         [
 403                                 AC_CHECK_LIB(pthread, pthread_mutexattr_init)
 404                                 AC_CHECK_LIB(howl, sw_discovery_init)
 405                                 AC_CHECK_FUNCS(sw_discovery_init, \
 406                                  x_zeroconf_on=howl, \
 407                                  AC_MSG_ERROR([Can't enable Zeroconf!]))
 408                         ])
 409                 fi
 410         ]
 411 )
 412 if test "$x_zeroconf_on" = "osx"; then
 413         AC_CHECK_HEADERS([DNSServiceDiscovery/DNSServiceDiscovery.h \
 414          mach/port.h],,AC_MSG_ERROR([required C header missing!]))
 415         AC_DEFINE(ZEROCONF, 1)
 416 fi
 417 if test "$x_zeroconf_on" = "howl"; then
 418         for dir in /usr/local/include /usr/local/include/howl* \
 419          /usr/include /usr/include/howl* \
 420          /usr/local/include/avahi* /usr/include/avahi*; do
 421                 test -d "$dir" || continue
 422                 AC_MSG_CHECKING([for Howl headers in $dir])
 423                 if test -f "$dir/rendezvous/rendezvous.h"; then
 424                         if test "$dir" != "/usr/local/include" -a \
 425                          "$dir" != "/usr/include"; then
 426                                 CFLAGS="-I$dir $CFLAGS"
 427                                 CPPFLAGS="-I$dir $CPPFLAGS"
 428                         fi
 429                         AC_MSG_RESULT(yes)
 430                         break
 431                 else
 432                         AC_MSG_RESULT(no)
 433                 fi
 434         done
 435         AC_CHECK_HEADERS([rendezvous/rendezvous.h],, \
 436          AC_MSG_ERROR([required C header missing!]))
 437         AC_DEFINE(ZEROCONF, 1)
 438 fi
 439
 440 # do IDENT requests using libident?
 441
 442 x_identauth_on=no
 443 AC_ARG_WITH(ident,
 444         [  --with-ident            enable "IDENT" ("AUTH") protocol support],
 445         [       if test "$withval" != "no"; then
 446                         if test "$withval" != "yes"; then
 447                                 CFLAGS="-I$withval/include $CFLAGS"
 448                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 449                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 450                         fi
 451                         AC_CHECK_LIB(ident, ident_id)
 452                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
 453                                 AC_MSG_ERROR([Can't enable IDENT support!])
 454                         )
 455                 fi
 456         ]
 457 )
 458 if test "$x_identauth_on" = "yes"; then
 459         AC_DEFINE(IDENTAUTH, 1)
 460         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
 461 fi
 462
 463 # compile in IRC+ protocol support?
 464
 465 x_ircplus_on=yes
 466 AC_ARG_ENABLE(ircplus,
 467         [  --disable-ircplus       disable IRC+ protocol],
 468         if test "$enableval" = "no"; then x_ircplus_on=no; fi
 469 )
 470 if test "$x_ircplus_on" = "yes"; then
 471         AC_DEFINE(IRCPLUS, 1)
 472 fi
 473
 474 # enable support for IPv6?
 475 x_ipv6_on=no
 476 AC_ARG_ENABLE(ipv6,
 477         [  --enable-ipv6           enable IPv6 protocol support],
 478         if test "$enableval" = "yes"; then x_ipv6_on=yes; fi
 479 )
 480 if test "$x_ipv6_on" = "yes"; then
 481         # getaddrinfo() and getnameinfo() are optional when not compiling
 482         # with IPv6 support, but are required for IPv6 to work!
 483         AC_CHECK_FUNCS([ \
 484                 getaddrinfo getnameinfo \
 485                 ],,AC_MSG_ERROR([required function missing for IPv6 support!]))
 486         AC_DEFINE(WANT_IPV6, 1)
 487 fi
 488
 489 # compile in IRC "sniffer"?
 490
 491 x_sniffer_on=no; x_debug_on=no
 492 AC_ARG_ENABLE(sniffer,
 493         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
 494         if test "$enableval" = "yes"; then
 495                 AC_DEFINE(SNIFFER, 1)
 496                 x_sniffer_on=yes; x_debug_on=yes
 497         fi
 498 )
 499
 500 # enable additional debugging code?
 501
 502 AC_ARG_ENABLE(debug,
 503         [  --enable-debug          show additional debug output],
 504         if test "$enableval" = "yes"; then x_debug_on=yes; fi
 505 )
 506 if test "$x_debug_on" = "yes"; then
 507         AC_DEFINE(DEBUG, 1)
 508         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
 509         AC_CHECK_FUNCS(mtrace)
 510 fi
 511
 512 # enable "strict RFC rules"?
 513
 514 x_strict_rfc_on=no
 515 AC_ARG_ENABLE(strict-rfc,
 516         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
 517         if test "$enableval" = "yes"; then
 518                 AC_DEFINE(STRICT_RFC, 1)
 519                 x_strict_rfc_on=yes
 520         fi
 521 )
 522
 523 # -- Definitions --
 524
 525 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
 526 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
 527 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
 528
 529 # Add additional CFLAGS, eventually specified on the command line, but after
 530 # running this configure script. Useful for "-Werror" for example.
 531 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
 532
 533 # -- Generate files --
 534
 535 AC_OUTPUT([ \
 536         Makefile \
 537         doc/Makefile \
 538         doc/src/Makefile \
 539         src/Makefile \
 540         src/portab/Makefile \
 541         src/ipaddr/Makefile \
 542         src/tool/Makefile \
 543         src/ngircd/Makefile \
 544         src/testsuite/Makefile \
 545         man/Makefile \
 546         contrib/Makefile \
 547         contrib/Debian/Makefile \
 548         contrib/MacOSX/Makefile \
 549         contrib/MacOSX/ngIRCd.xcodeproj/Makefile \
 550         contrib/MacOSX/ngIRCd.pmdoc/Makefile \
 551 ])
 552
 553 type dpkg >/dev/null 2>&1
 554 if test $? -eq 0; then
 555         # Generate debian/ link if the dpkg command exists
 556         # (read: if we are running on a debian compatible system)
 557         echo "creating Debian-specific links ..."
 558         test -f debian/rules || ln -s contrib/Debian debian
 559 fi
 560
 561 # -- Result --
 562
 563 echo
 564 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
 565 echo
 566
 567 # Someone please show me a better way :)  [borrowed by OpenSSH]
 568 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
 569 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
 570 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
 571 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
 572 D=`eval echo ${datadir}/doc/${PACKAGE}` ; D=`eval echo ${D}`
 573
 574 echo "             Target: ${target}"
 575 test "$target" != "$host" && echo "               Host: ${host}"
 576 echo "           Compiler: ${CC}"
 577 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
 578 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
 579 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
 580 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
 581 echo
 582 echo "    'ngircd' binary: $S"
 583 echo " Configuration file: $C"
 584 echo "       Manual pages: $M"
 585 echo "      Documentation: $D"
 586 echo
 587
 588 echo $ECHO_N "     Syslog support: $ECHO_C"
 589 test "$x_syslog_on" = "yes" \
 590         && echo $ECHO_N "yes   $ECHO_C" \
 591         || echo $ECHO_N "no    $ECHO_C"
 592 echo $ECHO_N "  Enable debug code: $ECHO_C"
 593 test "$x_debug_on" = "yes" \
 594         && echo "yes" \
 595         || echo "no"
 596
 597 echo $ECHO_N "   zlib compression: $ECHO_C"
 598 test "$x_zlib_on" = "yes" \
 599         && echo $ECHO_N "yes   $ECHO_C" \
 600         || echo $ECHO_N "no    $ECHO_C"
 601 echo $ECHO_N "        IRC sniffer: $ECHO_C"
 602 test "$x_sniffer_on" = "yes" \
 603         && echo "yes" \
 604         || echo "no"
 605
 606 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
 607 test "$x_tcpwrap_on" = "yes" \
 608         && echo $ECHO_N "yes   $ECHO_C" \
 609         || echo $ECHO_N "no    $ECHO_C"
 610 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
 611 test "$x_strict_rfc_on" = "yes" \
 612         && echo "yes" \
 613         || echo "no"
 614
 615 echo $ECHO_N "   Zeroconf support: $ECHO_C"
 616 case "$x_zeroconf_on" in
 617         osx)
 618                 echo $ECHO_N "Apple $ECHO_C"
 619                 ;;
 620         howl)
 621                 echo $ECHO_N "Howl  $ECHO_C"
 622                 ;;
 623         *)
 624                 echo $ECHO_N "no    $ECHO_C"
 625                 ;;
 626 esac
 627 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
 628 test "$x_ircplus_on" = "yes" \
 629         && echo "yes" \
 630         || echo "no"
 631
 632 echo $ECHO_N "      IDENT support: $ECHO_C"
 633 test "$x_identauth_on" = "yes" \
 634         && echo $ECHO_N "yes   $ECHO_C" \
 635         || echo $ECHO_N "no    $ECHO_C"
 636 echo $ECHO_N "        I/O backend: $ECHO_C"
 637         echo "\"$x_io_backend\""
 638
 639 echo $ECHO_N "      IPv6 protocol: $ECHO_C"
 640 echo $ECHO_N "$x_ipv6_on    $ECHO_C"
 641
 642 echo $ECHO_N "        SSL support: $ECHO_C"
 643 echo "$x_ssl_lib"
 644
 645 echo
 646
 647 # -eof-