+# Handle "initialization stage", load all plugins of that stage, either from an
+# existing cache file or individually, optionally creating the cache.
+# - $1: Script name
+# - $2: Stage name (ax-io, zprofile, zshrc, zlogin, zlogout)
+function axzsh_handle_stage {
+ local name="$1"
+ local type="$2"
+
+ [[ -n "$AXZSH_DEBUG" ]] && echo "» $name ($type):"
+
+ # Look for some 3rd-party integrations ...
+
+ # --- Powerlevel10k ---
+ # Read in Powerlevel10k configuration file, if not already read:
+ [[ -z "$POWERLEVEL9K_CONFIG_FILE" && -r ~/.p10k.zsh ]] && source ~/.p10k.zsh
+ # Enable instant prompt. Should stay close to the top of ~/.zshrc.
+ # Initialization code that may require console input (password prompts,
+ # [y/n] confirmations, etc.) must be executed before this, so all ax-zsh
+ # plugings should do output in their "zprofile" stage!
+ if [[ "$type" == "zprofile" ]]; then
+ p10k_instant_prompt="${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh"
+ [[ -r "$p10k_instant_prompt" ]] && source "$p10k_instant_prompt"
+ fi
+
+ # Initialize cache
+ mkdir -p "$AXZSH/cache"
+ local cache_file="$AXZSH/cache/$type.cache"
+
+ local cat_cmd=${commands[cat]:-cat}
+
+ if [[ -r "$cache_file" ]]; then
+ # Cache file exists, use it!
+ # But when in the "zshrc" stage, make sure that the "zprofile" stage
+ # has already been handled (this uses the "01_zprofile" plugin which
+ # is used in the "zshrc.cache" as well, but can't be used successfully
+ # there because it becomes sourced inside of a ZSH function; so we have
+ # to source it here in the global context manually ...):
+ [[ -z "$AXZSH_ZPROFILE_READ" && "$type" = "zshrc" ]] \
+ && source "$AXZSH/core/01_zprofile/01_zprofile.zshrc"
+ [[ -n "$AXZSH_DEBUG" ]] \
+ && echo " - Reading cache file \"$cache_file\" ..."
+ source "$cache_file"
+ unfunction ax_plugin_init
+ else
+ # No cache file available.
+ # Setup list of plugins to load:
+ local plugin_list
+ typeset -U plugin_list
+ plugin_list=(
+ "$AXZSH/core/"[0-5]*
+ "$AXZSH/active_plugins/"*(N)
+ "$AXZSH/core/"[6-9]*
+ )
+
+ # Create new cache file:
+ if [[ -n "$cache_file" ]]; then
+ [[ -n "$AXZSH_DEBUG" ]] \
+ && echo " (Writing new cache file to \"$cache_file\" ...)"
+ printf "# %s\n\n" "$(LC_ALL=C date)" >"$cache_file"
+ fi
+
+ # Read in all the plugins for the current "type":
+ for plugin ($plugin_list); do
+ # Read the "theme file", if any and in "zshrc" stage.
+ # This must be done before 99_cleanup is run!
+ if [[ "$plugin:t" == "99_cleanup" && "$type" = "zshrc" ]]; then
+ if [[ -r "$AXZSH_THEME" ]]; then
+ source "$AXZSH_THEME"
+ if [[ -n "$cache_file" ]]; then
+ # Source the theme in the new cache file:
+ echo "# BEGIN Theme" >>"$cache_file"
+ echo 'source "$AXZSH_THEME"' >>"$cache_file"
+ echo "# END Theme" >>"$cache_file"
+ fi
+ fi
+ fi
+ axzsh_load_plugin "$plugin" "$type" "$cache_file"
+ done
+ fi
+}
+