core/30_path/30_path.zprofile

   1 # AX-ZSH: Alex' Modular ZSH Configuration
   2 # 30_path.zprofile: Setup PATH environment
   3
   4 # Set default PATH
   5 if [[ -x /usr/libexec/path_helper ]]; then
   6         eval "$(/usr/libexec/path_helper)"
   7 else
   8         PATH="/usr/sbin:/usr/bin:/sbin:/bin"
   9 fi
  10 typeset -Ux PATH
  11
  12 _axzsh_setup_path() {
  13         # Prepend additional search paths
  14         for d (
  15                 /Developer/usr/bin
  16                 /usr/ucb
  17                 /usr/pkg/bin
  18                 /usr/local/bin
  19                 /usr/local/sbin
  20                 /opt/*/bin(NOn)
  21                 /opt/*/sbin(NOn)
  22                 ~/.gem/ruby/*/bin(NOn)
  23                 ~/.go/bin
  24                 ~/.cargo/bin
  25                 ~/.local/bin
  26                 ~/bin
  27                 ~/sbin
  28                 ~/Applications
  29         ); do
  30                 [[ -d "$d" ]] && path=("$d" $path)
  31         done
  32
  33         # Append additional search paths
  34         for d (
  35                 /usr/X11/bin
  36                 /usr/local/games
  37                 /usr/games
  38         ); do
  39                 [[ -d "$d" ]] && path=($path "$d")
  40         done
  41 }
  42
  43 # Prepend and append search paths (in a special order!)
  44 _axzsh_setup_path
  45
  46 # Set default MANPATH
  47 MANPATH="$(manpath -q)" 2>/dev/null
  48 if [[ $? -ne 0 ]]; then
  49         for d (
  50                 ~/share/man
  51                 ~/man
  52                 /opt/*/share/man(NOn)
  53                 /opt/*/man(NOn)
  54                 /usr/share/man
  55                 /usr/local/share/man
  56         ); do
  57                 [[ -d "$d" ]] && manpath=($manpath "$d")
  58         done
  59 fi
  60 typeset -Ux MANPATH