plugins/iterm2/iterm2.zshrc

   1 # AX-ZSH: Alex' Modular ZSH Configuration
   2 # iterm2.zshrc: iTerm2 Shell Integration
   3
   4 [[ -z "$AXZSH_PLUGIN_CHECK" ]] || return 92
   5
   6 # Check prerequisites ...
   7 axzsh_is_modern_terminal || return 91
   8 [[ -o interactive ]] || return 91
   9 [[ -z "$ITERM_SHELL_INTEGRATION_INSTALLED" ]] || return 91
  10 [[ "${ITERM_ENABLE_SHELL_INTEGRATION_WITH_TMUX-}$TERM" =~ "^screen" ]] && return 91
  11
  12 # Add iTerm2 commands to PATH, when available.
  13 [[ -d ~/.iterm2 ]] && path+=(~/.iterm2)
  14
  15 # Try to source user-local shell integration installed by iTerm2 itself,
  16 # and only fall back to the implementation here when not found.
  17 [[ -e "$HOME/.iterm2_shell_integration.zsh" ]] && source "$HOME/.iterm2_shell_integration.zsh"
  18 [[ -z "$ITERM_SHELL_INTEGRATION_INSTALLED" ]] || return 0
  19
  20 ITERM_SHELL_INTEGRATION_INSTALLED="Yes"
  21 ITERM2_SHOULD_DECORATE_PROMPT="1"
  22
  23 # Indicates start of command output. Runs just before command executes.
  24 iterm2_before_cmd_executes() {
  25         printf "\033]133;C;\007"
  26 }
  27
  28 iterm2_set_user_var() {
  29         printf "\033]1337;SetUserVar=%s=%s\007" "$1" $(printf "%s" "$2" | base64 | tr -d '\n')
  30 }
  31
  32 # Users can write their own version of this method. It should call
  33 # iterm2_set_user_var but not produce any other output.
  34 # e.g., iterm2_set_user_var currentDirectory $PWD
  35 # Accessible in iTerm2 (in a badge now, elsewhere in the future) as
  36 # \(user.currentDirectory).
  37 whence -v iterm2_print_user_vars > /dev/null 2>&1
  38 if [ $? -ne 0 ]; then
  39         iterm2_print_user_vars() {
  40                 :
  41         }
  42 fi
  43
  44 iterm2_print_state_data() {
  45         printf "\033]1337;RemoteHost=%s@%s\007" "$USER" "$iterm2_hostname"
  46         printf "\033]1337;CurrentDir=%s\007" "$PWD"
  47         iterm2_print_user_vars
  48 }
  49
  50 # Report return code of command; runs after command finishes but before prompt
  51 iterm2_after_cmd_executes() {
  52         printf "\033]133;D;%s\007" "$STATUS"
  53         iterm2_print_state_data
  54 }
  55
  56 # Mark start of prompt
  57 iterm2_prompt_mark() {
  58         printf "\033]133;A\007"
  59 }
  60
  61 # Mark end of prompt
  62 iterm2_prompt_end() {
  63         printf "\033]133;B\007"
  64 }
  65
  66 # There are three possible paths in life.
  67 #
  68 # 1) A command is entered at the prompt and you press return.
  69 #    The following steps happen:
  70 #    * iterm2_preexec is invoked
  71 #      * PS1 is set to ITERM2_PRECMD_PS1
  72 #      * ITERM2_SHOULD_DECORATE_PROMPT is set to 1
  73 #    * The command executes (possibly reading or modifying PS1)
  74 #    * iterm2_precmd is invoked
  75 #      * ITERM2_PRECMD_PS1 is set to PS1 (as modified by command execution)
  76 #      * PS1 gets our escape sequences added to it
  77 #    * zsh displays your prompt
  78 #    * You start entering a command
  79 #
  80 # 2) You press ^C while entering a command at the prompt.
  81 #    The following steps happen:
  82 #    * (iterm2_preexec is NOT invoked)
  83 #    * iterm2_precmd is invoked
  84 #      * iterm2_before_cmd_executes is called since we detected that iterm2_preexec was not run
  85 #      * (ITERM2_PRECMD_PS1 and PS1 are not messed with, since PS1 already has our escape
  86 #        sequences and ITERM2_PRECMD_PS1 already has PS1's original value)
  87 #    * zsh displays your prompt
  88 #    * You start entering a command
  89 #
  90 # 3) A new shell is born.
  91 #    * PS1 has some initial value, either zsh's default or a value set before this script is sourced.
  92 #    * iterm2_precmd is invoked
  93 #      * ITERM2_SHOULD_DECORATE_PROMPT is initialized to 1
  94 #      * ITERM2_PRECMD_PS1 is set to the initial value of PS1
  95 #      * PS1 gets our escape sequences added to it
  96 #    * Your prompt is shown and you may begin entering a command.
  97 #
  98 # Invariants:
  99 # * ITERM2_SHOULD_DECORATE_PROMPT is 1 during and just after command execution, and "" while the prompt is
 100 #   shown and until you enter a command and press return.
 101 # * PS1 does not have our escape sequences during command execution
 102 # * After the command executes but before a new one begins, PS1 has escape sequences and
 103 #   ITERM2_PRECMD_PS1 has PS1's original value.
 104 iterm2_decorate_prompt() {
 105         # This should be a raw PS1 without iTerm2's stuff. It could be changed during command
 106         # execution.
 107         ITERM2_PRECMD_PS1="$PS1"
 108         ITERM2_SHOULD_DECORATE_PROMPT=""
 109
 110         # Add our escape sequences just before the prompt is shown.
 111         # Use ITERM2_SQUELCH_MARK for people who can't mdoify PS1 directly, like powerlevel9k users.
 112         # This is gross but I had a heck of a time writing a correct if statetment for zsh 5.0.2.
 113         local PREFIX=""
 114         if [[ $PS1 == *"$(iterm2_prompt_mark)"* ]]; then
 115                 PREFIX=""
 116         elif [[ "${ITERM2_SQUELCH_MARK-}" != "" ]]; then
 117                 PREFIX=""
 118         else
 119                 PREFIX="%{$(iterm2_prompt_mark)%}"
 120         fi
 121         PS1="$PREFIX$PS1%{$(iterm2_prompt_end)%}"
 122 }
 123
 124 iterm2_precmd() {
 125         local STATUS="$?"
 126         if [ -z "${ITERM2_SHOULD_DECORATE_PROMPT-}" ]; then
 127                 # You pressed ^C while entering a command (iterm2_preexec did not run)
 128                 iterm2_before_cmd_executes
 129         fi
 130
 131         iterm2_after_cmd_executes "$STATUS"
 132
 133         if [ -n "$ITERM2_SHOULD_DECORATE_PROMPT" ]; then
 134                 iterm2_decorate_prompt
 135         fi
 136 }
 137
 138 # This is not run if you press ^C while entering a command.
 139 iterm2_preexec() {
 140         # Set PS1 back to its raw value prior to executing the command.
 141         PS1="$ITERM2_PRECMD_PS1"
 142         ITERM2_SHOULD_DECORATE_PROMPT="1"
 143         iterm2_before_cmd_executes
 144 }
 145
 146 # If hostname -f is slow on your system, set iterm2_hostname prior to sourcing this script.
 147 [[ -z "$iterm2_hostname" ]] && iterm2_hostname=`hostname -f`
 148
 149 precmd_functions+=(iterm2_precmd)
 150 preexec_functions+=(iterm2_preexec)
 151
 152 iterm2_print_state_data
 153 printf "\033]1337;ShellIntegrationVersion=11;shell=zsh\007"
 154
 155 # Setup iTerm2 command aliases
 156 for cmd (~/.iterm2/*(N)); do
 157         [[ -x "$cmd" ]] && alias "$(basename "$cmd")=$cmd"
 158 done
 159 unset cmd