core/30_path/30_path.zprofile

   1 # AX-ZSH: Alex' Modular ZSH Configuration
   2 # 40_path.zprofile: Setup PATH environment
   3
   4 # Set default PATH
   5 if [[ -x /usr/libexec/path_helper ]]; then
   6         eval "$(/usr/libexec/path_helper)"
   7 else
   8         PATH="/usr/sbin:/usr/bin:/sbin:/bin"
   9 fi
  10 typeset -Ux PATH
  11 typeset -U path
  12
  13 _axzsh_setup_path() {
  14         # Prepend additional search paths
  15         for d (
  16                 /Developer/usr/bin
  17                 /usr/ucb
  18                 /usr/pkg/bin
  19                 /usr/local/bin
  20                 /usr/local/sbin
  21                 /opt/*/bin(NOn)
  22                 /opt/*/sbin(NOn)
  23                 /home/linuxbrew/.linuxbrew/bin
  24                 /home/linuxbrew/.linuxbrew/sbin
  25                 ~/.linuxbrew/bin
  26                 ~/.linuxbrew/sbin
  27                 ~/.gem/ruby/*/bin(NOn)
  28                 ~/.go/bin
  29                 ~/.cargo/bin
  30                 ~/.local/bin
  31                 ~/bin
  32                 ~/sbin
  33                 ~/Applications
  34         ); do
  35                 [[ -d "$d" ]] && path=("$d" $path)
  36         done
  37
  38         # Append additional search paths
  39         for d (
  40                 /usr/X11/bin
  41                 /usr/local/games
  42                 /usr/games
  43         ); do
  44                 [[ -d "$d" ]] && path=($path "$d")
  45         done
  46 }
  47
  48 # Prepend and append search paths (in a special order!)
  49 _axzsh_setup_path
  50
  51 # Set default MANPATH
  52 MANPATH="$(manpath -q)" 2>/dev/null
  53 if [[ $? -ne 0 ]]; then
  54         for d (
  55                 ~/share/man
  56                 ~/man
  57                 ~/.linuxbrew/share/man
  58                 /home/linuxbrew/.linuxbrew/share/man
  59                 /opt/*/share/man(NOn)
  60                 /opt/*/man(NOn)
  61                 /usr/share/man
  62                 /usr/local/share/man
  63         ); do
  64                 [[ -d "$d" ]] && manpath=($manpath "$d")
  65         done
  66 fi
  67 typeset -Ux MANPATH
  68 typeset -U manpath