configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_rolling])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 # We do not use m4_esyscmd_s to support older autoconf.
  16 define([VERSION_STRING], m4_esyscmd(git describe 2>/dev/null | sed 's/^v//' | tr -d '\n'))
  17 m4_ifval(VERSION_STRING, [], [define([VERSION_STRING], VERSION_NUMBER)])
  18
  19 AC_INIT([netdata], VERSION_STRING[]VERSION_SUFFIX)
  20
  21 AM_MAINTAINER_MODE([disable])
  22 if test x"$USE_MAINTAINER_MODE" = xyes; then
  23 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  24 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  25 fi
  26
  27 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  28 AC_SUBST([PACKAGE_RPM_VERSION])
  29 AC_SUBST([PACKAGE_RPM_RELEASE])
  30
  31 # fails on centos6
  32 #AX_CHECK_ENABLE_DEBUG()
  33
  34 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  35 AX_GCC_FUNC_ATTRIBUTE(malloc)
  36 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  37 AX_GCC_FUNC_ATTRIBUTE(format)
  38 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  39
  40 AC_CONFIG_AUX_DIR([.])
  41 AC_CONFIG_HEADERS([config.h])
  42 AC_CONFIG_MACRO_DIR([m4])
  43 AC_CONFIG_SRCDIR([src/main.c])
  44 AM_INIT_AUTOMAKE
  45 AC_CANONICAL_HOST
  46 AC_PROG_CC
  47 AC_PROG_INSTALL
  48 PKG_PROG_PKG_CONFIG
  49 AC_USE_SYSTEM_EXTENSIONS
  50 AC_CHECK_FUNCS_ONCE(accept4)
  51 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  52 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  53 AC_CHECK_FUNCS([clock_gettime])
  54 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
  55
  56 # Check system type
  57 case "$host_os" in
  58 freebsd*)
  59         build_target=freebsd
  60         ;;
  61 darwin*)
  62         build_target=macos
  63         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  64         ;;
  65 *)
  66         build_target=linux
  67         ;;
  68 esac
  69
  70 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  71 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  72 AM_CONDITIONAL([LINUX], [test x$build_target = xlinux])
  73
  74 AC_ARG_ENABLE(
  75         [plugin-nfacct],
  76         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  77         ,
  78         [enable_plugin_nfacct="no"]
  79 )
  80 AC_ARG_ENABLE(
  81         [plugin-freeipmi],
  82         [AS_HELP_STRING([--enable-plugin-freeipmi], [freeipmi plugin, requires root])],
  83         ,
  84         [enable_plugin_freeipmi="no"]
  85 )
  86 AC_ARG_ENABLE(
  87         [pedantic],
  88         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  89         ,
  90         [enable_pedantic="no"]
  91 )
  92 AC_ARG_WITH(
  93         [webdir],
  94         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  95         [webdir="${withval}"],
  96         [webdir="\$(pkgdatadir)/web"]
  97 )
  98 AC_ARG_WITH(
  99         [zlib],
 100         [AS_HELP_STRING([--with-zlib], [build with zlib])],
 101         ,
 102         [with_zlib="yes"]
 103 )
 104 AC_ARG_WITH(
 105         [math],
 106         [AS_HELP_STRING([--with-math], [build with math])],
 107         ,
 108         [with_math="yes"]
 109 )
 110 AC_ARG_WITH(
 111         [user],
 112         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
 113         ,
 114         [with_user="nobody"]
 115 )
 116 AC_ARG_ENABLE(
 117         [x86-sse],
 118         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 119         ,
 120         [enable_x86_sse="yes"]
 121 )
 122
 123 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 124 LIBS="${PTHREAD_LIBS} ${LIBS}"
 125 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 126 CC="${PTHREAD_CC}"
 127
 128 TS_CHECK_JEMALLOC
 129 if test "$has_jemalloc" = "1"; then
 130         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 131 else
 132         TS_CHECK_TCMALLOC
 133         if test "$has_tcmalloc" = "1"; then
 134                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 135         else
 136                 AC_C_MALLOPT
 137                 AC_C_MALLINFO
 138         fi
 139 fi
 140
 141 AC_TYPE_INT8_T
 142 AC_TYPE_INT16_T
 143 AC_TYPE_INT32_T
 144 AC_TYPE_INT64_T
 145 AC_TYPE_UINT8_T
 146 AC_TYPE_UINT16_T
 147 AC_TYPE_UINT32_T
 148 AC_TYPE_UINT64_T
 149 AC_C_INLINE
 150 AC_FUNC_STRERROR_R
 151 AC_C__GENERIC
 152 AC_C___ATOMIC
 153 # AC_C_STMT_EXPR
 154 AC_CHECK_SIZEOF([void *])
 155 AC_CANONICAL_HOST
 156 AC_HEADER_MAJOR
 157 AC_HEADER_RESOLV
 158 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 159
 160 AC_CHECK_LIB([cap], [cap_get_proc, cap_set_proc],
 161         [AC_CHECK_HEADER(
 162                 [sys/capability.h],
 163                 [
 164                         CAP_LIBS=-lcap
 165                         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 166                 ]
 167         )]
 168 )
 169 OPTIONAL_CAP_LIBS="${CAP_LIBS}"
 170
 171 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 172 AS_CASE([$host_cpu],
 173         [i?86], [SSE_CANDIDATE="yes"]
 174 )
 175 AC_SUBST([SSE_CANDIDATE])
 176 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 177         opt="-msse2 -mfpmath=sse"
 178         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 179 fi
 180
 181 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 182 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 183 if test -z "${MATH_LIBS}"; then
 184         AC_CHECK_LIB(
 185                 [m],
 186                 [sin],
 187                 [MATH_LIBS="-lm"]
 188         )
 189 fi
 190
 191 PKG_CHECK_MODULES(
 192         [UUID],
 193         [uuid],
 194 )
 195 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 196 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 197 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 198 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 199
 200 if test "${enable_plugin_freeipmi}" = "yes"; then
 201         PKG_CHECK_MODULES(
 202                 [IPMIMONITORING],
 203                 [libipmimonitoring],
 204         )
 205     test -z "${IPMIMONITORING_LIBS}" && AC_MSG_ERROR([ipmimonitoring required but not found. Try installing 'libipmimonitoring-dev' or 'libipmimonitoring-devel'])
 206     freeipmi=yes
 207     AC_DEFINE([HAVE_FREEIPMI], [1], [ipmimonitoring usability])
 208         OPTIONAL_IPMIMONITORING_CLFAGS="${IPMIMONITORING_CFLAGS}"
 209         OPTIONAL_IPMIMONITORING_LIBS="${IPMIMONITORING_LIBS}"
 210 fi
 211 AM_CONDITIONAL([FREEIPMI], [test x$freeipmi = xyes])
 212
 213 if test "${enable_plugin_nfacct}" = "yes"; then
 214         PKG_CHECK_MODULES(
 215                 [NFACCT],
 216                 [libnetfilter_acct],
 217         )
 218         PKG_CHECK_MODULES(
 219                 [LIBMNL],
 220                 [libmnl],
 221         )
 222         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 223         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 224         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 225         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 226         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 227 fi
 228
 229 if test "${with_zlib}" = "yes"; then
 230         PKG_CHECK_MODULES(
 231                 [ZLIB],
 232                 [zlib],
 233         )
 234         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 235         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 236         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 237         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 238 fi
 239
 240 if test "${with_math}" = "yes"; then
 241         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 242         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 243         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 244         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 245 fi
 246
 247 if test "${GCC}" = "yes"; then
 248         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 249         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 250 else
 251         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 252         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 253 fi
 254
 255 if test "${enable_pedantic}" = "yes"; then
 256         enable_strict="yes"
 257         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 258 fi
 259
 260 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 261
 262 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 263 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 264 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 265 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 266 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 267 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 268 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 269 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 270 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 271 AC_SUBST([webdir])
 272
 273 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 274 AC_SUBST([OPTIONAL_MATH_LIBS])
 275 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 276 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 277 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 278 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 279 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 280 AC_SUBST([OPTIONAL_UUID_LIBS])
 281 AC_SUBST([OPTIONAL_CAP_LIBS])
 282 AC_SUBST([OPTIONAL_IPMIMONITORING_CFLAGS])
 283 AC_SUBST([OPTIONAL_IPMIMONITORING_LIBS])
 284
 285 AC_CONFIG_FILES([
 286         Makefile
 287         charts.d/Makefile
 288         conf.d/Makefile
 289         netdata.spec
 290         python.d/Makefile
 291         node.d/Makefile
 292         plugins.d/Makefile
 293         src/Makefile
 294         system/Makefile
 295         web/Makefile
 296         contrib/Makefile
 297 ])
 298 AC_OUTPUT
 299
 300 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 301 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to transfer a lot less data with web clients. It should be enabled.]) || :