configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [4])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  39 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  40 AC_CHECK_FUNCS([clock_gettime])
  41
  42 # Check system type
  43 case "$host_os" in
  44 freebsd*)
  45         build_target=freebsd
  46         ;;
  47 darwin*)
  48         build_target=macos
  49         ;;
  50 *)
  51         ;;
  52 esac
  53
  54 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  55 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  56
  57 AC_ARG_ENABLE(
  58         [plugin-nfacct],
  59         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  60         ,
  61         [enable_plugin_nfacct="no"]
  62 )
  63 AC_ARG_ENABLE(
  64         [pedantic],
  65         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  66         ,
  67         [enable_pedantic="no"]
  68 )
  69 AC_ARG_WITH(
  70         [webdir],
  71         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  72         [webdir="${withval}"],
  73         [webdir="\$(pkgdatadir)/web"]
  74 )
  75 AC_ARG_WITH(
  76         [zlib],
  77         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  78         ,
  79         [with_zlib="yes"]
  80 )
  81 AC_ARG_WITH(
  82         [math],
  83         [AS_HELP_STRING([--with-math], [build with math])],
  84         ,
  85         [with_math="yes"]
  86 )
  87 AC_ARG_WITH(
  88         [user],
  89         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  90         ,
  91         [with_user="nobody"]
  92 )
  93 AC_ARG_ENABLE(
  94         [x86-sse],
  95         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
  96         ,
  97         [enable_x86_sse="yes"]
  98 )
  99
 100 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 101 LIBS="${PTHREAD_LIBS} ${LIBS}"
 102 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 103 CC="${PTHREAD_CC}"
 104
 105 TS_CHECK_JEMALLOC
 106 if test "$has_jemalloc" = "1"; then
 107         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 108 else
 109         TS_CHECK_TCMALLOC
 110         if test "$has_tcmalloc" = "1"; then
 111                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 112         else
 113                 AC_C_MALLOPT
 114                 AC_C_MALLINFO
 115         fi
 116 fi
 117
 118 AC_TYPE_UINT8_T
 119 AC_TYPE_UINT16_T
 120 AC_TYPE_UINT32_T
 121 AC_C_INLINE
 122 AC_FUNC_STRERROR_R
 123 AC_C__GENERIC
 124 AC_C___ATOMIC
 125 AC_CHECK_SIZEOF([void *])
 126 AC_CANONICAL_HOST
 127 AC_HEADER_MAJOR
 128 AC_HEADER_RESOLV
 129
 130 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 131 AS_CASE([$host_cpu],
 132         [i?86], [SSE_CANDIDATE="yes"]
 133 )
 134 AC_SUBST([SSE_CANDIDATE])
 135 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 136         opt="-msse2 -mfpmath=sse"
 137         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 138 fi
 139
 140 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 141 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 142 if test -z "${MATH_LIBS}"; then
 143         AC_CHECK_LIB(
 144                 [m],
 145                 [sin],
 146                 [MATH_LIBS="-lm"]
 147         )
 148 fi
 149
 150 PKG_CHECK_MODULES(
 151         [UUID],
 152         [uuid],
 153 )
 154 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 155 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 156 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 157 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 158
 159 if test "${enable_plugin_nfacct}" = "yes"; then
 160         PKG_CHECK_MODULES(
 161                 [NFACCT],
 162                 [libnetfilter_acct],
 163         )
 164         PKG_CHECK_MODULES(
 165                 [LIBMNL],
 166                 [libmnl],
 167         )
 168         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 169         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 170         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 171         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 172         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 173 fi
 174 if test "${with_zlib}" = "yes"; then
 175         PKG_CHECK_MODULES(
 176                 [ZLIB],
 177                 [zlib],
 178         )
 179         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 180         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 181         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 182         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 183 fi
 184 if test "${with_math}" = "yes"; then
 185         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 186         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 187         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 188         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 189 fi
 190
 191 if test "${GCC}" = "yes"; then
 192         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 193         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 194 else
 195         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 196         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 197 fi
 198
 199 if test "${enable_pedantic}" = "yes"; then
 200         enable_strict="yes"
 201         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 202 fi
 203
 204 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 205
 206 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 207 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 208 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 209 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 210 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 211 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 212 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 213 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 214 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 215 AC_SUBST([webdir])
 216
 217 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 218 AC_SUBST([OPTIONAL_MATH_LIBS])
 219 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 220 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 221 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 222 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 223 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 224 AC_SUBST([OPTIONAL_UUID_LIBS])
 225
 226 AC_CONFIG_FILES([
 227         Makefile
 228         charts.d/Makefile
 229         conf.d/Makefile
 230         netdata.spec
 231         python.d/Makefile
 232         node.d/Makefile
 233         plugins.d/Makefile
 234         src/Makefile
 235         system/Makefile
 236         web/Makefile
 237         contrib/Makefile
 238 ])
 239 AC_OUTPUT
 240
 241 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 242 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :