configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [4])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  39 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  40 AC_CHECK_FUNCS([clock_gettime])
  41
  42 # Check system type
  43 case "$host_os" in
  44 freebsd*)
  45         build_target=freebsd
  46         ;;
  47 darwin*)
  48         build_target=freebsd
  49         ;;
  50 *)
  51         ;;
  52 esac
  53
  54 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  55
  56 AC_ARG_ENABLE(
  57         [plugin-nfacct],
  58         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  59         ,
  60         [enable_plugin_nfacct="no"]
  61 )
  62 AC_ARG_ENABLE(
  63         [pedantic],
  64         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  65         ,
  66         [enable_pedantic="no"]
  67 )
  68 AC_ARG_WITH(
  69         [webdir],
  70         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  71         [webdir="${withval}"],
  72         [webdir="\$(pkgdatadir)/web"]
  73 )
  74 AC_ARG_WITH(
  75         [zlib],
  76         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  77         ,
  78         [with_zlib="yes"]
  79 )
  80 AC_ARG_WITH(
  81         [math],
  82         [AS_HELP_STRING([--with-math], [build with math])],
  83         ,
  84         [with_math="yes"]
  85 )
  86 AC_ARG_WITH(
  87         [user],
  88         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  89         ,
  90         [with_user="nobody"]
  91 )
  92 AC_ARG_ENABLE(
  93         [x86-sse],
  94         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
  95         ,
  96         [enable_x86_sse="yes"]
  97 )
  98
  99 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 100 LIBS="${PTHREAD_LIBS} ${LIBS}"
 101 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 102 CC="${PTHREAD_CC}"
 103
 104 TS_CHECK_JEMALLOC
 105 if test "$has_jemalloc" = "1"; then
 106         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 107 else
 108         TS_CHECK_TCMALLOC
 109         if test "$has_tcmalloc" = "1"; then
 110                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 111         else
 112                 AC_C_MALLOPT
 113                 AC_C_MALLINFO
 114         fi
 115 fi
 116
 117 AC_TYPE_UINT8_T
 118 AC_TYPE_UINT16_T
 119 AC_TYPE_UINT32_T
 120 AC_C_INLINE
 121 AC_FUNC_STRERROR_R
 122 AC_C__GENERIC
 123 AC_C___ATOMIC
 124 AC_CHECK_SIZEOF([void *])
 125 AC_CANONICAL_HOST
 126
 127 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 128 AS_CASE([$host_cpu],
 129         [i?86], [SSE_CANDIDATE="yes"]
 130 )
 131 AC_SUBST([SSE_CANDIDATE])
 132 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 133         opt="-msse2 -mfpmath=sse"
 134         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 135 fi
 136
 137 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 138 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 139 if test -z "${MATH_LIBS}"; then
 140         AC_CHECK_LIB(
 141                 [m],
 142                 [sin],
 143                 [MATH_LIBS="-lm"]
 144         )
 145 fi
 146
 147 PKG_CHECK_MODULES(
 148         [UUID],
 149         [uuid],
 150 )
 151 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 152 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 153 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 154 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 155
 156 if test "${enable_plugin_nfacct}" = "yes"; then
 157         PKG_CHECK_MODULES(
 158                 [NFACCT],
 159                 [libnetfilter_acct],
 160         )
 161         PKG_CHECK_MODULES(
 162                 [LIBMNL],
 163                 [libmnl],
 164         )
 165         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 166         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 167         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 168         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 169         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 170 fi
 171 if test "${with_zlib}" = "yes"; then
 172         PKG_CHECK_MODULES(
 173                 [ZLIB],
 174                 [zlib],
 175         )
 176         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 177         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 178         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 179         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 180 fi
 181 if test "${with_math}" = "yes"; then
 182         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 183         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 184         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 185         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 186 fi
 187
 188 if test "${GCC}" = "yes"; then
 189         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 190         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 191 else
 192         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 193         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 194 fi
 195
 196 if test "${enable_pedantic}" = "yes"; then
 197         enable_strict="yes"
 198         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 199 fi
 200
 201 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 202
 203 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 204 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 205 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 206 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 207 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 208 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 209 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 210 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 211 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 212 AC_SUBST([webdir])
 213
 214 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 215 AC_SUBST([OPTIONAL_MATH_LIBS])
 216 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 217 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 218 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 219 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 220 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 221 AC_SUBST([OPTIONAL_UUID_LIBS])
 222
 223 AC_CONFIG_FILES([
 224         Makefile
 225         charts.d/Makefile
 226         conf.d/Makefile
 227         netdata.spec
 228         python.d/Makefile
 229         node.d/Makefile
 230         plugins.d/Makefile
 231         src/Makefile
 232         system/Makefile
 233         web/Makefile
 234         contrib/Makefile
 235 ])
 236 AC_OUTPUT
 237
 238 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 239 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :