configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 # fails on centos6
  28 #AX_CHECK_ENABLE_DEBUG()
  29
  30 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  31 AX_GCC_FUNC_ATTRIBUTE(malloc)
  32 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  33 AX_GCC_FUNC_ATTRIBUTE(format)
  34 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  35
  36 AC_CONFIG_AUX_DIR([.])
  37 AC_CONFIG_HEADERS([config.h])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([src/main.c])
  40 AM_INIT_AUTOMAKE
  41 AC_CANONICAL_HOST
  42 AC_PROG_CC
  43 AC_PROG_INSTALL
  44 PKG_PROG_PKG_CONFIG
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_CHECK_FUNCS_ONCE(accept4)
  47 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  48 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  49 AC_CHECK_FUNCS([clock_gettime])
  50
  51 # Check system type
  52 case "$host_os" in
  53 freebsd*)
  54         build_target=freebsd
  55         ;;
  56 darwin*)
  57         build_target=macos
  58         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  59         ;;
  60 *)
  61         ;;
  62 esac
  63
  64 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  65 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  66
  67 AC_ARG_ENABLE(
  68         [plugin-nfacct],
  69         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  70         ,
  71         [enable_plugin_nfacct="no"]
  72 )
  73 AC_ARG_ENABLE(
  74         [pedantic],
  75         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  76         ,
  77         [enable_pedantic="no"]
  78 )
  79 AC_ARG_WITH(
  80         [webdir],
  81         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  82         [webdir="${withval}"],
  83         [webdir="\$(pkgdatadir)/web"]
  84 )
  85 AC_ARG_WITH(
  86         [zlib],
  87         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  88         ,
  89         [with_zlib="yes"]
  90 )
  91 AC_ARG_WITH(
  92         [math],
  93         [AS_HELP_STRING([--with-math], [build with math])],
  94         ,
  95         [with_math="yes"]
  96 )
  97 AC_ARG_WITH(
  98         [user],
  99         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
 100         ,
 101         [with_user="nobody"]
 102 )
 103 AC_ARG_ENABLE(
 104         [x86-sse],
 105         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 106         ,
 107         [enable_x86_sse="yes"]
 108 )
 109
 110 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 111 LIBS="${PTHREAD_LIBS} ${LIBS}"
 112 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 113 CC="${PTHREAD_CC}"
 114
 115 TS_CHECK_JEMALLOC
 116 if test "$has_jemalloc" = "1"; then
 117         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 118 else
 119         TS_CHECK_TCMALLOC
 120         if test "$has_tcmalloc" = "1"; then
 121                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 122         else
 123                 AC_C_MALLOPT
 124                 AC_C_MALLINFO
 125         fi
 126 fi
 127
 128 AC_TYPE_INT8_T
 129 AC_TYPE_INT16_T
 130 AC_TYPE_INT32_T
 131 AC_TYPE_INT64_T
 132 AC_TYPE_UINT8_T
 133 AC_TYPE_UINT16_T
 134 AC_TYPE_UINT32_T
 135 AC_TYPE_UINT64_T
 136 AC_C_INLINE
 137 AC_FUNC_STRERROR_R
 138 AC_C__GENERIC
 139 AC_C___ATOMIC
 140 # AC_C_STMT_EXPR
 141 AC_CHECK_SIZEOF([void *])
 142 AC_CANONICAL_HOST
 143 AC_HEADER_MAJOR
 144 AC_HEADER_RESOLV
 145
 146 AC_CHECK_LIB([cap], [cap_get_proc, cap_set_proc],
 147         [AC_CHECK_HEADER(
 148                 [sys/capability.h],
 149                 [
 150                         CAP_LIBS=-lcap
 151                         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 152                 ]
 153         )]
 154 )
 155 OPTIONAL_CAP_LIBS="${CAP_LIBS}"
 156
 157 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 158 AS_CASE([$host_cpu],
 159         [i?86], [SSE_CANDIDATE="yes"]
 160 )
 161 AC_SUBST([SSE_CANDIDATE])
 162 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 163         opt="-msse2 -mfpmath=sse"
 164         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 165 fi
 166
 167 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 168 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 169 if test -z "${MATH_LIBS}"; then
 170         AC_CHECK_LIB(
 171                 [m],
 172                 [sin],
 173                 [MATH_LIBS="-lm"]
 174         )
 175 fi
 176
 177 PKG_CHECK_MODULES(
 178         [UUID],
 179         [uuid],
 180 )
 181 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 182 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 183 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 184 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 185
 186 if test "${enable_plugin_nfacct}" = "yes"; then
 187         PKG_CHECK_MODULES(
 188                 [NFACCT],
 189                 [libnetfilter_acct],
 190         )
 191         PKG_CHECK_MODULES(
 192                 [LIBMNL],
 193                 [libmnl],
 194         )
 195         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 196         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 197         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 198         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 199         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 200 fi
 201 if test "${with_zlib}" = "yes"; then
 202         PKG_CHECK_MODULES(
 203                 [ZLIB],
 204                 [zlib],
 205         )
 206         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 207         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 208         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 209         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 210 fi
 211 if test "${with_math}" = "yes"; then
 212         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 213         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 214         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 215         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 216 fi
 217
 218 if test "${GCC}" = "yes"; then
 219         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 220         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 221 else
 222         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 223         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 224 fi
 225
 226 if test "${enable_pedantic}" = "yes"; then
 227         enable_strict="yes"
 228         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 229 fi
 230
 231 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 232
 233 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 234 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 235 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 236 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 237 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 238 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 239 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 240 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 241 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 242 AC_SUBST([webdir])
 243
 244 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 245 AC_SUBST([OPTIONAL_MATH_LIBS])
 246 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 247 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 248 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 249 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 250 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 251 AC_SUBST([OPTIONAL_UUID_LIBS])
 252 AC_SUBST([OPTIONAL_CAP_LIBS])
 253
 254 AC_CONFIG_FILES([
 255         Makefile
 256         charts.d/Makefile
 257         conf.d/Makefile
 258         netdata.spec
 259         python.d/Makefile
 260         node.d/Makefile
 261         plugins.d/Makefile
 262         src/Makefile
 263         system/Makefile
 264         web/Makefile
 265         contrib/Makefile
 266 ])
 267 AC_OUTPUT
 268
 269 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 270 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :