configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [3])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38
  39 AC_ARG_ENABLE(
  40         [plugin-nfacct],
  41         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  42         ,
  43         [enable_plugin_nfacct="no"]
  44 )
  45 AC_ARG_ENABLE(
  46         [pedantic],
  47         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  48         ,
  49         [enable_pedantic="no"]
  50 )
  51 AC_ARG_WITH(
  52         [webdir],
  53         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  54         [webdir="${withval}"],
  55         [webdir="\$(pkgdatadir)/web"]
  56 )
  57 AC_ARG_WITH(
  58         [zlib],
  59         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  60         ,
  61         [with_zlib="yes"]
  62 )
  63 AC_ARG_WITH(
  64         [math],
  65         [AS_HELP_STRING([--with-math], [build with math])],
  66         ,
  67         [with_math="yes"]
  68 )
  69 AC_ARG_WITH(
  70         [user],
  71         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  72         ,
  73         [with_user="nobody"]
  74 )
  75
  76 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  77 LIBS="${PTHREAD_LIBS} ${LIBS}"
  78 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  79 CC="${PTHREAD_CC}"
  80
  81 AC_TYPE_UINT8_T
  82 AC_TYPE_UINT16_T
  83 AC_TYPE_UINT32_T
  84 AC_C_INLINE
  85 AC_FUNC_STRERROR_R
  86 AC_C__GENERIC
  87 AC_C___ATOMIC
  88 AC_CHECK_SIZEOF([void *])
  89 AC_CANONICAL_HOST
  90
  91 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
  92 AS_CASE([$host_cpu],
  93         [i?86], [SSE_CANDIDATE="yes"]
  94 )
  95 AC_SUBST([SSE_CANDIDATE])
  96 if test "${SSE_CANDIDATE}" = "yes"; then
  97         opt="-msse2 -mfpmath=sse"
  98         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
  99 fi
 100
 101 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 102 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 103 if test -z "${MATH_LIBS}"; then
 104         AC_CHECK_LIB(
 105                 [m],
 106                 [sin],
 107                 [MATH_LIBS="-lm"]
 108         )
 109 fi
 110
 111 PKG_CHECK_MODULES(
 112         [UUID],
 113         [uuid],
 114 )
 115 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 116 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 117 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 118 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 119
 120 if test "${enable_plugin_nfacct}" = "yes"; then
 121         PKG_CHECK_MODULES(
 122                 [NFACCT],
 123                 [libnetfilter_acct],
 124         )
 125         PKG_CHECK_MODULES(
 126                 [LIBMNL],
 127                 [libmnl],
 128         )
 129         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 130         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 131         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 132         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 133         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 134 fi
 135 if test "${with_zlib}" = "yes"; then
 136         PKG_CHECK_MODULES(
 137                 [ZLIB],
 138                 [zlib],
 139         )
 140         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 141         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 142         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 143         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 144 fi
 145 if test "${with_math}" = "yes"; then
 146         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 147         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 148         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 149         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 150 fi
 151
 152 if test "${GCC}" = "yes"; then
 153         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 154         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 155 else
 156         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 157         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 158 fi
 159
 160 if test "${enable_pedantic}" = "yes"; then
 161         enable_strict="yes"
 162         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 163 fi
 164
 165 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 166
 167 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 168 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 169 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 170 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 171 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 172 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 173 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 174 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 175 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 176 AC_SUBST([webdir])
 177
 178 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 179 AC_SUBST([OPTIONAL_MATH_LIBS])
 180 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 181 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 182 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 183 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 184 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 185 AC_SUBST([OPTIONAL_UUID_LIBS])
 186
 187 AC_CONFIG_FILES([
 188         Makefile
 189         charts.d/Makefile
 190         conf.d/Makefile
 191         netdata.spec
 192         python.d/Makefile
 193         node.d/Makefile
 194         plugins.d/Makefile
 195         src/Makefile
 196         system/Makefile
 197         web/Makefile
 198         contrib/Makefile
 199 ])
 200 AC_OUTPUT
 201
 202 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 203 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :