configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [4])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  39 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  40 AC_CHECK_FUNCS([clock_gettime])
  41
  42 # Check system type
  43 case "$host_os" in
  44 freebsd*)
  45         build_target=freebsd
  46         ;;
  47 darwin*)
  48         build_target=macos
  49         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  50         ;;
  51 *)
  52         ;;
  53 esac
  54
  55 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  56 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  57
  58 AC_ARG_ENABLE(
  59         [plugin-nfacct],
  60         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  61         ,
  62         [enable_plugin_nfacct="no"]
  63 )
  64 AC_ARG_ENABLE(
  65         [pedantic],
  66         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  67         ,
  68         [enable_pedantic="no"]
  69 )
  70 AC_ARG_WITH(
  71         [webdir],
  72         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  73         [webdir="${withval}"],
  74         [webdir="\$(pkgdatadir)/web"]
  75 )
  76 AC_ARG_WITH(
  77         [zlib],
  78         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  79         ,
  80         [with_zlib="yes"]
  81 )
  82 AC_ARG_WITH(
  83         [math],
  84         [AS_HELP_STRING([--with-math], [build with math])],
  85         ,
  86         [with_math="yes"]
  87 )
  88 AC_ARG_WITH(
  89         [user],
  90         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  91         ,
  92         [with_user="nobody"]
  93 )
  94 AC_ARG_ENABLE(
  95         [x86-sse],
  96         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
  97         ,
  98         [enable_x86_sse="yes"]
  99 )
 100
 101 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 102 LIBS="${PTHREAD_LIBS} ${LIBS}"
 103 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 104 CC="${PTHREAD_CC}"
 105
 106 TS_CHECK_JEMALLOC
 107 if test "$has_jemalloc" = "1"; then
 108         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 109 else
 110         TS_CHECK_TCMALLOC
 111         if test "$has_tcmalloc" = "1"; then
 112                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 113         else
 114                 AC_C_MALLOPT
 115                 AC_C_MALLINFO
 116         fi
 117 fi
 118
 119 AC_TYPE_UINT8_T
 120 AC_TYPE_UINT16_T
 121 AC_TYPE_UINT32_T
 122 AC_C_INLINE
 123 AC_FUNC_STRERROR_R
 124 AC_C__GENERIC
 125 AC_C___ATOMIC
 126 AC_CHECK_SIZEOF([void *])
 127 AC_CANONICAL_HOST
 128 AC_HEADER_MAJOR
 129 AC_HEADER_RESOLV
 130
 131 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 132 AS_CASE([$host_cpu],
 133         [i?86], [SSE_CANDIDATE="yes"]
 134 )
 135 AC_SUBST([SSE_CANDIDATE])
 136 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 137         opt="-msse2 -mfpmath=sse"
 138         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 139 fi
 140
 141 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 142 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 143 if test -z "${MATH_LIBS}"; then
 144         AC_CHECK_LIB(
 145                 [m],
 146                 [sin],
 147                 [MATH_LIBS="-lm"]
 148         )
 149 fi
 150
 151 PKG_CHECK_MODULES(
 152         [UUID],
 153         [uuid],
 154 )
 155 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 156 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 157 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 158 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 159
 160 if test "${enable_plugin_nfacct}" = "yes"; then
 161         PKG_CHECK_MODULES(
 162                 [NFACCT],
 163                 [libnetfilter_acct],
 164         )
 165         PKG_CHECK_MODULES(
 166                 [LIBMNL],
 167                 [libmnl],
 168         )
 169         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 170         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 171         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 172         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 173         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 174 fi
 175 if test "${with_zlib}" = "yes"; then
 176         PKG_CHECK_MODULES(
 177                 [ZLIB],
 178                 [zlib],
 179         )
 180         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 181         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 182         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 183         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 184 fi
 185 if test "${with_math}" = "yes"; then
 186         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 187         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 188         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 189         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 190 fi
 191
 192 if test "${GCC}" = "yes"; then
 193         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 194         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 195 else
 196         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 197         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 198 fi
 199
 200 if test "${enable_pedantic}" = "yes"; then
 201         enable_strict="yes"
 202         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 203 fi
 204
 205 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 206
 207 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 208 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 209 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 210 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 211 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 212 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 213 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 214 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 215 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 216 AC_SUBST([webdir])
 217
 218 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 219 AC_SUBST([OPTIONAL_MATH_LIBS])
 220 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 221 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 222 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 223 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 224 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 225 AC_SUBST([OPTIONAL_UUID_LIBS])
 226
 227 AC_CONFIG_FILES([
 228         Makefile
 229         charts.d/Makefile
 230         conf.d/Makefile
 231         netdata.spec
 232         python.d/Makefile
 233         node.d/Makefile
 234         plugins.d/Makefile
 235         src/Makefile
 236         system/Makefile
 237         web/Makefile
 238         contrib/Makefile
 239 ])
 240 AC_OUTPUT
 241
 242 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 243 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :