configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [4])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  28 AX_GCC_FUNC_ATTRIBUTE(malloc)
  29 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  30 AX_GCC_FUNC_ATTRIBUTE(format)
  31 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  32
  33 AC_CONFIG_AUX_DIR([.])
  34 AC_CONFIG_HEADERS([config.h])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR([src/main.c])
  37 AM_INIT_AUTOMAKE
  38 AC_CANONICAL_HOST
  39 AC_PROG_CC
  40 AC_PROG_INSTALL
  41 PKG_PROG_PKG_CONFIG
  42 AC_USE_SYSTEM_EXTENSIONS
  43 AC_CHECK_FUNCS_ONCE(accept4)
  44 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  45 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  46 AC_CHECK_FUNCS([clock_gettime])
  47
  48 # Check system type
  49 case "$host_os" in
  50 freebsd*)
  51         build_target=freebsd
  52         ;;
  53 darwin*)
  54         build_target=macos
  55         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  56         ;;
  57 *)
  58         ;;
  59 esac
  60
  61 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  62 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  63
  64 AC_ARG_ENABLE(
  65         [plugin-nfacct],
  66         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  67         ,
  68         [enable_plugin_nfacct="no"]
  69 )
  70 AC_ARG_ENABLE(
  71         [pedantic],
  72         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  73         ,
  74         [enable_pedantic="no"]
  75 )
  76 AC_ARG_WITH(
  77         [webdir],
  78         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  79         [webdir="${withval}"],
  80         [webdir="\$(pkgdatadir)/web"]
  81 )
  82 AC_ARG_WITH(
  83         [zlib],
  84         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  85         ,
  86         [with_zlib="yes"]
  87 )
  88 AC_ARG_WITH(
  89         [math],
  90         [AS_HELP_STRING([--with-math], [build with math])],
  91         ,
  92         [with_math="yes"]
  93 )
  94 AC_ARG_WITH(
  95         [user],
  96         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  97         ,
  98         [with_user="nobody"]
  99 )
 100 AC_ARG_ENABLE(
 101         [x86-sse],
 102         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 103         ,
 104         [enable_x86_sse="yes"]
 105 )
 106
 107 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 108 LIBS="${PTHREAD_LIBS} ${LIBS}"
 109 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 110 CC="${PTHREAD_CC}"
 111
 112 TS_CHECK_JEMALLOC
 113 if test "$has_jemalloc" = "1"; then
 114         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 115 else
 116         TS_CHECK_TCMALLOC
 117         if test "$has_tcmalloc" = "1"; then
 118                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 119         else
 120                 AC_C_MALLOPT
 121                 AC_C_MALLINFO
 122         fi
 123 fi
 124
 125 AC_TYPE_UINT8_T
 126 AC_TYPE_UINT16_T
 127 AC_TYPE_UINT32_T
 128 AC_C_INLINE
 129 AC_FUNC_STRERROR_R
 130 AC_C__GENERIC
 131 AC_C___ATOMIC
 132 AC_C_STMT_EXPR
 133 AC_CHECK_SIZEOF([void *])
 134 AC_CANONICAL_HOST
 135 AC_HEADER_MAJOR
 136 AC_HEADER_RESOLV
 137
 138 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 139 AS_CASE([$host_cpu],
 140         [i?86], [SSE_CANDIDATE="yes"]
 141 )
 142 AC_SUBST([SSE_CANDIDATE])
 143 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 144         opt="-msse2 -mfpmath=sse"
 145         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 146 fi
 147
 148 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 149 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 150 if test -z "${MATH_LIBS}"; then
 151         AC_CHECK_LIB(
 152                 [m],
 153                 [sin],
 154                 [MATH_LIBS="-lm"]
 155         )
 156 fi
 157
 158 PKG_CHECK_MODULES(
 159         [UUID],
 160         [uuid],
 161 )
 162 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 163 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 164 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 165 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 166
 167 if test "${enable_plugin_nfacct}" = "yes"; then
 168         PKG_CHECK_MODULES(
 169                 [NFACCT],
 170                 [libnetfilter_acct],
 171         )
 172         PKG_CHECK_MODULES(
 173                 [LIBMNL],
 174                 [libmnl],
 175         )
 176         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 177         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 178         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 179         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 180         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 181 fi
 182 if test "${with_zlib}" = "yes"; then
 183         PKG_CHECK_MODULES(
 184                 [ZLIB],
 185                 [zlib],
 186         )
 187         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 188         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 189         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 190         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 191 fi
 192 if test "${with_math}" = "yes"; then
 193         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 194         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 195         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 196         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 197 fi
 198
 199 if test "${GCC}" = "yes"; then
 200         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 201         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 202 else
 203         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 204         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 205 fi
 206
 207 if test "${enable_pedantic}" = "yes"; then
 208         enable_strict="yes"
 209         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 210 fi
 211
 212 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 213
 214 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 215 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 216 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 217 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 218 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 219 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 220 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 221 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 222 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 223 AC_SUBST([webdir])
 224
 225 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 226 AC_SUBST([OPTIONAL_MATH_LIBS])
 227 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 228 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 229 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 230 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 231 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 232 AC_SUBST([OPTIONAL_UUID_LIBS])
 233
 234 AC_CONFIG_FILES([
 235         Makefile
 236         charts.d/Makefile
 237         conf.d/Makefile
 238         netdata.spec
 239         python.d/Makefile
 240         node.d/Makefile
 241         plugins.d/Makefile
 242         src/Makefile
 243         system/Makefile
 244         web/Makefile
 245         contrib/Makefile
 246 ])
 247 AC_OUTPUT
 248
 249 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 250 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :