configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 # fails on centos6
  28 #AX_CHECK_ENABLE_DEBUG()
  29
  30 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  31 AX_GCC_FUNC_ATTRIBUTE(malloc)
  32 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  33 AX_GCC_FUNC_ATTRIBUTE(format)
  34 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  35
  36 AC_CONFIG_AUX_DIR([.])
  37 AC_CONFIG_HEADERS([config.h])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([src/main.c])
  40 AM_INIT_AUTOMAKE
  41 AC_CANONICAL_HOST
  42 AC_PROG_CC
  43 AC_PROG_INSTALL
  44 PKG_PROG_PKG_CONFIG
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_CHECK_FUNCS_ONCE(accept4)
  47 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  48 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  49 AC_CHECK_FUNCS([clock_gettime])
  50 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
  51
  52 # Check system type
  53 case "$host_os" in
  54 freebsd*)
  55         build_target=freebsd
  56         ;;
  57 darwin*)
  58         build_target=macos
  59         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  60         ;;
  61 *)
  62         build_target=linux
  63         ;;
  64 esac
  65
  66 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  67 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  68 AM_CONDITIONAL([LINUX], [test x$build_target = xlinux])
  69
  70 AC_ARG_ENABLE(
  71         [plugin-nfacct],
  72         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  73         ,
  74         [enable_plugin_nfacct="no"]
  75 )
  76 AC_ARG_ENABLE(
  77         [pedantic],
  78         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  79         ,
  80         [enable_pedantic="no"]
  81 )
  82 AC_ARG_WITH(
  83         [webdir],
  84         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  85         [webdir="${withval}"],
  86         [webdir="\$(pkgdatadir)/web"]
  87 )
  88 AC_ARG_WITH(
  89         [zlib],
  90         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  91         ,
  92         [with_zlib="yes"]
  93 )
  94 AC_ARG_WITH(
  95         [math],
  96         [AS_HELP_STRING([--with-math], [build with math])],
  97         ,
  98         [with_math="yes"]
  99 )
 100 AC_ARG_WITH(
 101         [user],
 102         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
 103         ,
 104         [with_user="nobody"]
 105 )
 106 AC_ARG_ENABLE(
 107         [x86-sse],
 108         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 109         ,
 110         [enable_x86_sse="yes"]
 111 )
 112
 113 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 114 LIBS="${PTHREAD_LIBS} ${LIBS}"
 115 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 116 CC="${PTHREAD_CC}"
 117
 118 TS_CHECK_JEMALLOC
 119 if test "$has_jemalloc" = "1"; then
 120         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 121 else
 122         TS_CHECK_TCMALLOC
 123         if test "$has_tcmalloc" = "1"; then
 124                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 125         else
 126                 AC_C_MALLOPT
 127                 AC_C_MALLINFO
 128         fi
 129 fi
 130
 131 AC_TYPE_INT8_T
 132 AC_TYPE_INT16_T
 133 AC_TYPE_INT32_T
 134 AC_TYPE_INT64_T
 135 AC_TYPE_UINT8_T
 136 AC_TYPE_UINT16_T
 137 AC_TYPE_UINT32_T
 138 AC_TYPE_UINT64_T
 139 AC_C_INLINE
 140 AC_FUNC_STRERROR_R
 141 AC_C__GENERIC
 142 AC_C___ATOMIC
 143 # AC_C_STMT_EXPR
 144 AC_CHECK_SIZEOF([void *])
 145 AC_CANONICAL_HOST
 146 AC_HEADER_MAJOR
 147 AC_HEADER_RESOLV
 148
 149 AC_CHECK_LIB([cap], [cap_get_proc, cap_set_proc],
 150         [AC_CHECK_HEADER(
 151                 [sys/capability.h],
 152                 [
 153                         CAP_LIBS=-lcap
 154                         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 155                 ]
 156         )]
 157 )
 158 OPTIONAL_CAP_LIBS="${CAP_LIBS}"
 159
 160 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 161 AS_CASE([$host_cpu],
 162         [i?86], [SSE_CANDIDATE="yes"]
 163 )
 164 AC_SUBST([SSE_CANDIDATE])
 165 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 166         opt="-msse2 -mfpmath=sse"
 167         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 168 fi
 169
 170 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 171 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 172 if test -z "${MATH_LIBS}"; then
 173         AC_CHECK_LIB(
 174                 [m],
 175                 [sin],
 176                 [MATH_LIBS="-lm"]
 177         )
 178 fi
 179
 180 PKG_CHECK_MODULES(
 181         [UUID],
 182         [uuid],
 183 )
 184 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 185 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 186 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 187 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 188
 189 if test "${enable_plugin_nfacct}" = "yes"; then
 190         PKG_CHECK_MODULES(
 191                 [NFACCT],
 192                 [libnetfilter_acct],
 193         )
 194         PKG_CHECK_MODULES(
 195                 [LIBMNL],
 196                 [libmnl],
 197         )
 198         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 199         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 200         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 201         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 202         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 203 fi
 204 if test "${with_zlib}" = "yes"; then
 205         PKG_CHECK_MODULES(
 206                 [ZLIB],
 207                 [zlib],
 208         )
 209         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 210         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 211         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 212         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 213 fi
 214 if test "${with_math}" = "yes"; then
 215         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 216         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 217         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 218         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 219 fi
 220
 221 if test "${GCC}" = "yes"; then
 222         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 223         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 224 else
 225         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 226         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 227 fi
 228
 229 if test "${enable_pedantic}" = "yes"; then
 230         enable_strict="yes"
 231         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 232 fi
 233
 234 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 235
 236 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 237 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 238 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 239 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 240 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 241 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 242 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 243 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 244 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 245 AC_SUBST([webdir])
 246
 247 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 248 AC_SUBST([OPTIONAL_MATH_LIBS])
 249 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 250 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 251 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 252 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 253 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 254 AC_SUBST([OPTIONAL_UUID_LIBS])
 255 AC_SUBST([OPTIONAL_CAP_LIBS])
 256
 257 AC_CONFIG_FILES([
 258         Makefile
 259         charts.d/Makefile
 260         conf.d/Makefile
 261         netdata.spec
 262         python.d/Makefile
 263         node.d/Makefile
 264         plugins.d/Makefile
 265         src/Makefile
 266         system/Makefile
 267         web/Makefile
 268         contrib/Makefile
 269 ])
 270 AC_OUTPUT
 271
 272 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 273 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :