configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_rolling])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 # We do not use m4_esyscmd_s to support older autoconf.
  16 define([VERSION_STRING], m4_esyscmd(git describe 2>/dev/null | sed 's/^v//' | tr -d '\n'))
  17 m4_ifval(VERSION_STRING, [], [define([VERSION_STRING], VERSION_NUMBER)])
  18
  19 AC_INIT([netdata], VERSION_STRING[]VERSION_SUFFIX)
  20
  21 AM_MAINTAINER_MODE([disable])
  22 if test x"$USE_MAINTAINER_MODE" = xyes; then
  23 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  24 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  25 fi
  26
  27 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  28 AC_SUBST([PACKAGE_RPM_VERSION])
  29 AC_SUBST([PACKAGE_RPM_RELEASE])
  30
  31
  32 # -----------------------------------------------------------------------------
  33 # autoconf initialization
  34
  35 AC_CONFIG_AUX_DIR([.])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR([src/main.c])
  39 AM_INIT_AUTOMAKE
  40 AC_CANONICAL_HOST
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 PKG_PROG_PKG_CONFIG
  44 AC_USE_SYSTEM_EXTENSIONS
  45
  46
  47 # -----------------------------------------------------------------------------
  48 # configurable options
  49
  50 AC_ARG_ENABLE(
  51         [plugin-nfacct],
  52         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  53         ,
  54         [enable_plugin_nfacct="no"]
  55 )
  56 AC_ARG_ENABLE(
  57         [plugin-freeipmi],
  58         [AS_HELP_STRING([--enable-plugin-freeipmi], [freeipmi plugin, requires root])],
  59         ,
  60         [enable_plugin_freeipmi="detect"]
  61 )
  62 AC_ARG_ENABLE(
  63         [pedantic],
  64         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  65         ,
  66         [enable_pedantic="no"]
  67 )
  68 AC_ARG_WITH(
  69         [webdir],
  70         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  71         [webdir="${withval}"],
  72         [webdir="\$(pkgdatadir)/web"]
  73 )
  74 AC_ARG_WITH(
  75         [cap],
  76         [AS_HELP_STRING([--with-cap], [build with libcap])],
  77         ,
  78         [with_cap="detect"]
  79 )
  80 AC_ARG_WITH(
  81         [zlib],
  82         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  83         ,
  84         [with_zlib="yes"]
  85 )
  86 AC_ARG_WITH(
  87         [math],
  88         [AS_HELP_STRING([--with-math], [build with math])],
  89         ,
  90         [with_math="yes"]
  91 )
  92 AC_ARG_WITH(
  93         [user],
  94         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  95         ,
  96         [with_user="nobody"]
  97 )
  98 AC_ARG_ENABLE(
  99         [x86-sse],
 100         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 101         ,
 102         [enable_x86_sse="yes"]
 103 )
 104
 105
 106 # -----------------------------------------------------------------------------
 107 # netdata required checks
 108
 109 # fails on centos6
 110 #AX_CHECK_ENABLE_DEBUG()
 111
 112 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
 113 AX_GCC_FUNC_ATTRIBUTE(malloc)
 114 AX_GCC_FUNC_ATTRIBUTE(noreturn)
 115 AX_GCC_FUNC_ATTRIBUTE(format)
 116 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
 117
 118 AC_CHECK_FUNCS_ONCE(accept4)
 119 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
 120 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
 121 AC_CHECK_FUNCS([clock_gettime])
 122 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
 123
 124 AC_TYPE_INT8_T
 125 AC_TYPE_INT16_T
 126 AC_TYPE_INT32_T
 127 AC_TYPE_INT64_T
 128 AC_TYPE_UINT8_T
 129 AC_TYPE_UINT16_T
 130 AC_TYPE_UINT32_T
 131 AC_TYPE_UINT64_T
 132 AC_C_INLINE
 133 AC_FUNC_STRERROR_R
 134 AC_C__GENERIC
 135 AC_C___ATOMIC
 136 # AC_C_STMT_EXPR
 137 AC_CHECK_SIZEOF([void *])
 138 AC_CANONICAL_HOST
 139 AC_HEADER_MAJOR
 140 AC_HEADER_RESOLV
 141
 142 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 143
 144
 145 # -----------------------------------------------------------------------------
 146 # operating system detection
 147
 148 case "$host_os" in
 149 freebsd*)
 150         build_target=freebsd
 151         ;;
 152 darwin*)
 153         build_target=macos
 154         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
 155         ;;
 156 *)
 157         build_target=linux
 158         ;;
 159 esac
 160
 161 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
 162 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
 163 AM_CONDITIONAL([LINUX], [test x$build_target = xlinux])
 164
 165
 166 # -----------------------------------------------------------------------------
 167 # compiler options
 168
 169 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 170 AS_CASE([$host_cpu],
 171         [i?86], [SSE_CANDIDATE="yes"]
 172 )
 173 AC_SUBST([SSE_CANDIDATE])
 174 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 175         opt="-msse2 -mfpmath=sse"
 176         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 177 fi
 178
 179 if test "${GCC}" = "yes"; then
 180         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 181         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 182 else
 183         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 184         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 185 fi
 186
 187 if test "${enable_pedantic}" = "yes"; then
 188         enable_strict="yes"
 189         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 190 fi
 191
 192
 193 # -----------------------------------------------------------------------------
 194 # pthreads
 195
 196 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 197 LIBS="${PTHREAD_LIBS} ${LIBS}"
 198 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 199 CC="${PTHREAD_CC}"
 200
 201
 202 # -----------------------------------------------------------------------------
 203 # memory allocation library
 204
 205 TS_CHECK_JEMALLOC
 206 if test "$has_jemalloc" = "1"; then
 207         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 208 else
 209         TS_CHECK_TCMALLOC
 210         if test "$has_tcmalloc" = "1"; then
 211                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 212         else
 213                 AC_C_MALLOPT
 214                 AC_C_MALLINFO
 215         fi
 216 fi
 217
 218
 219 # -----------------------------------------------------------------------------
 220 # libm
 221
 222 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 223 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 224 if test -z "${MATH_LIBS}"; then
 225         AC_CHECK_LIB(
 226                 [m],
 227                 [sin],
 228                 [MATH_LIBS="-lm"]
 229         )
 230 fi
 231
 232 if test "${with_math}" = "yes"; then
 233         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 234         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 235         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 236         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 237 fi
 238
 239
 240 # -----------------------------------------------------------------------------
 241 # zlib
 242
 243 if test "${with_zlib}" = "yes"; then
 244         PKG_CHECK_MODULES(
 245                 [ZLIB],
 246                 [zlib],
 247         )
 248         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 249         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 250         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 251         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 252 fi
 253
 254
 255 # -----------------------------------------------------------------------------
 256 # libuuid
 257
 258 PKG_CHECK_MODULES(
 259         [UUID],
 260         [uuid],
 261         [have_uuid=yes],
 262         [have_uuid=no]
 263 )
 264 test "${have_uuid}" = "no" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 265 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid usability])
 266 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 267 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 268
 269
 270 # -----------------------------------------------------------------------------
 271 # libcap
 272
 273 if test "${with_cap}" != "no"; then
 274         PKG_CHECK_MODULES(
 275                 [CAP],
 276                 [libcap],
 277                 [have_cap=yes],
 278                 [have_cap=no]
 279         )
 280 fi
 281 test "${have_cap}" = "no" -a "${with_cap}" = "yes" && AC_MSG_ERROR([libcap required but not found.])
 282 if test "${have_cap}" = "yes"; then
 283         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 284         OPTIONAL_CAP_CLFAGS="${CAP_CFLAGS}"
 285         OPTIONAL_CAP_LIBS="${CAP_LIBS}"
 286 fi
 287 AM_CONDITIONAL([ENABLE_CAPABILITY], [test "${have_cap}" = "yes"])
 288
 289
 290 # -----------------------------------------------------------------------------
 291 # apps.plugin
 292
 293 AM_CONDITIONAL([ENABLE_PLUGIN_APPS], [test "${build_target}" != "macos"])
 294
 295
 296 # -----------------------------------------------------------------------------
 297 # freeipmi.plugin - libipmimonitoring
 298
 299 if test "${enable_plugin_freeipmi}" != "no"; then
 300         PKG_CHECK_MODULES(
 301                 [IPMIMONITORING],
 302                 [libipmimonitoring],
 303                 [have_ipmimonitoring=yes],
 304                 [have_ipmimonitoring=no]
 305         )
 306 fi
 307 test "${have_ipmimonitoring}" = "no" -a "${enable_plugin_freeipmi}" = "yes" && \
 308         AC_MSG_ERROR([ipmimonitoring required but not found. Try installing 'libipmimonitoring-dev' or 'libipmimonitoring-devel'])
 309 if test "${have_ipmimonitoring}" = "yes"; then
 310         AC_DEFINE([HAVE_FREEIPMI], [1], [ipmimonitoring usability])
 311         OPTIONAL_IPMIMONITORING_CLFAGS="${IPMIMONITORING_CFLAGS}"
 312         OPTIONAL_IPMIMONITORING_LIBS="${IPMIMONITORING_LIBS}"
 313 fi
 314 AM_CONDITIONAL([ENABLE_PLUGIN_FREEIPMI], [test "${have_ipmimonitoring}" = "yes"])
 315
 316
 317 # -----------------------------------------------------------------------------
 318 # nfacct.plugin - libmnl, libnetfilter_acct
 319
 320 if test "${enable_plugin_nfacct}" = "yes"; then
 321         PKG_CHECK_MODULES(
 322                 [NFACCT],
 323                 [libnetfilter_acct],
 324         )
 325         PKG_CHECK_MODULES(
 326                 [LIBMNL],
 327                 [libmnl],
 328         )
 329         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 330         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 331         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 332         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 333         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 334 fi
 335
 336
 337 # -----------------------------------------------------------------------------
 338
 339 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 340
 341 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 342 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 343 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 344 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 345 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 346 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 347 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 348 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 349 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 350 AC_SUBST([webdir])
 351
 352 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 353 AC_SUBST([OPTIONAL_MATH_LIBS])
 354 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 355 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 356 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 357 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 358 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 359 AC_SUBST([OPTIONAL_UUID_LIBS])
 360 AC_SUBST([OPTIONAL_CAP_CFLAGS])
 361 AC_SUBST([OPTIONAL_CAP_LIBS])
 362 AC_SUBST([OPTIONAL_IPMIMONITORING_CFLAGS])
 363 AC_SUBST([OPTIONAL_IPMIMONITORING_LIBS])
 364
 365 AC_CONFIG_FILES([
 366         Makefile
 367         charts.d/Makefile
 368         conf.d/Makefile
 369         netdata.spec
 370         python.d/Makefile
 371         node.d/Makefile
 372         plugins.d/Makefile
 373         src/Makefile
 374         system/Makefile
 375         web/Makefile
 376         contrib/Makefile
 377 ])
 378 AC_OUTPUT
 379
 380 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 381 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to transfer a lot less data with web clients. It should be enabled.]) || :