configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_rolling])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 define([VERSION_STRING], m4_esyscmd_s(git describe 2>/dev/null | sed 's/^v//'))
  16 m4_ifval(VERSION_STRING, [], [define([VERSION_STRING], VERSION_NUMBER)])
  17
  18 AC_INIT([netdata], VERSION_STRING[]VERSION_SUFFIX)
  19
  20 AM_MAINTAINER_MODE([disable])
  21 if test x"$USE_MAINTAINER_MODE" = xyes; then
  22 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  23 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  24 fi
  25
  26 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  27 AC_SUBST([PACKAGE_RPM_VERSION])
  28 AC_SUBST([PACKAGE_RPM_RELEASE])
  29
  30 # fails on centos6
  31 #AX_CHECK_ENABLE_DEBUG()
  32
  33 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  34 AX_GCC_FUNC_ATTRIBUTE(malloc)
  35 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  36 AX_GCC_FUNC_ATTRIBUTE(format)
  37 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  38
  39 AC_CONFIG_AUX_DIR([.])
  40 AC_CONFIG_HEADERS([config.h])
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([src/main.c])
  43 AM_INIT_AUTOMAKE
  44 AC_CANONICAL_HOST
  45 AC_PROG_CC
  46 AC_PROG_INSTALL
  47 PKG_PROG_PKG_CONFIG
  48 AC_USE_SYSTEM_EXTENSIONS
  49 AC_CHECK_FUNCS_ONCE(accept4)
  50 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  51 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  52 AC_CHECK_FUNCS([clock_gettime])
  53 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
  54
  55 # Check system type
  56 case "$host_os" in
  57 freebsd*)
  58         build_target=freebsd
  59         ;;
  60 darwin*)
  61         build_target=macos
  62         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  63         ;;
  64 *)
  65         build_target=linux
  66         ;;
  67 esac
  68
  69 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  70 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  71 AM_CONDITIONAL([LINUX], [test x$build_target = xlinux])
  72
  73 AC_ARG_ENABLE(
  74         [plugin-nfacct],
  75         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  76         ,
  77         [enable_plugin_nfacct="no"]
  78 )
  79 AC_ARG_ENABLE(
  80         [pedantic],
  81         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  82         ,
  83         [enable_pedantic="no"]
  84 )
  85 AC_ARG_WITH(
  86         [webdir],
  87         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  88         [webdir="${withval}"],
  89         [webdir="\$(pkgdatadir)/web"]
  90 )
  91 AC_ARG_WITH(
  92         [zlib],
  93         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  94         ,
  95         [with_zlib="yes"]
  96 )
  97 AC_ARG_WITH(
  98         [math],
  99         [AS_HELP_STRING([--with-math], [build with math])],
 100         ,
 101         [with_math="yes"]
 102 )
 103 AC_ARG_WITH(
 104         [user],
 105         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
 106         ,
 107         [with_user="nobody"]
 108 )
 109 AC_ARG_ENABLE(
 110         [x86-sse],
 111         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 112         ,
 113         [enable_x86_sse="yes"]
 114 )
 115
 116 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 117 LIBS="${PTHREAD_LIBS} ${LIBS}"
 118 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 119 CC="${PTHREAD_CC}"
 120
 121 TS_CHECK_JEMALLOC
 122 if test "$has_jemalloc" = "1"; then
 123         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 124 else
 125         TS_CHECK_TCMALLOC
 126         if test "$has_tcmalloc" = "1"; then
 127                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 128         else
 129                 AC_C_MALLOPT
 130                 AC_C_MALLINFO
 131         fi
 132 fi
 133
 134 AC_TYPE_INT8_T
 135 AC_TYPE_INT16_T
 136 AC_TYPE_INT32_T
 137 AC_TYPE_INT64_T
 138 AC_TYPE_UINT8_T
 139 AC_TYPE_UINT16_T
 140 AC_TYPE_UINT32_T
 141 AC_TYPE_UINT64_T
 142 AC_C_INLINE
 143 AC_FUNC_STRERROR_R
 144 AC_C__GENERIC
 145 AC_C___ATOMIC
 146 # AC_C_STMT_EXPR
 147 AC_CHECK_SIZEOF([void *])
 148 AC_CANONICAL_HOST
 149 AC_HEADER_MAJOR
 150 AC_HEADER_RESOLV
 151 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 152
 153 AC_CHECK_LIB([cap], [cap_get_proc, cap_set_proc],
 154         [AC_CHECK_HEADER(
 155                 [sys/capability.h],
 156                 [
 157                         CAP_LIBS=-lcap
 158                         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 159                 ]
 160         )]
 161 )
 162 OPTIONAL_CAP_LIBS="${CAP_LIBS}"
 163
 164 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 165 AS_CASE([$host_cpu],
 166         [i?86], [SSE_CANDIDATE="yes"]
 167 )
 168 AC_SUBST([SSE_CANDIDATE])
 169 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 170         opt="-msse2 -mfpmath=sse"
 171         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 172 fi
 173
 174 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 175 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 176 if test -z "${MATH_LIBS}"; then
 177         AC_CHECK_LIB(
 178                 [m],
 179                 [sin],
 180                 [MATH_LIBS="-lm"]
 181         )
 182 fi
 183
 184 PKG_CHECK_MODULES(
 185         [UUID],
 186         [uuid],
 187 )
 188 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 189 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 190 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 191 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 192
 193 if test "${enable_plugin_nfacct}" = "yes"; then
 194         PKG_CHECK_MODULES(
 195                 [NFACCT],
 196                 [libnetfilter_acct],
 197         )
 198         PKG_CHECK_MODULES(
 199                 [LIBMNL],
 200                 [libmnl],
 201         )
 202         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 203         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 204         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 205         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 206         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 207 fi
 208 if test "${with_zlib}" = "yes"; then
 209         PKG_CHECK_MODULES(
 210                 [ZLIB],
 211                 [zlib],
 212         )
 213         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 214         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 215         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 216         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 217 fi
 218 if test "${with_math}" = "yes"; then
 219         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 220         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 221         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 222         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 223 fi
 224
 225 if test "${GCC}" = "yes"; then
 226         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 227         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 228 else
 229         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 230         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 231 fi
 232
 233 if test "${enable_pedantic}" = "yes"; then
 234         enable_strict="yes"
 235         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 236 fi
 237
 238 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 239
 240 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 241 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 242 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 243 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 244 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 245 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 246 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 247 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 248 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 249 AC_SUBST([webdir])
 250
 251 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 252 AC_SUBST([OPTIONAL_MATH_LIBS])
 253 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 254 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 255 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 256 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 257 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 258 AC_SUBST([OPTIONAL_UUID_LIBS])
 259 AC_SUBST([OPTIONAL_CAP_LIBS])
 260
 261 AC_CONFIG_FILES([
 262         Makefile
 263         charts.d/Makefile
 264         conf.d/Makefile
 265         netdata.spec
 266         python.d/Makefile
 267         node.d/Makefile
 268         plugins.d/Makefile
 269         src/Makefile
 270         system/Makefile
 271         web/Makefile
 272         contrib/Makefile
 273 ])
 274 AC_OUTPUT
 275
 276 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 277 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :