configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_rolling])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 # We do not use m4_esyscmd_s to support older autoconf.
  16 define([VERSION_STRING], m4_esyscmd(git describe 2>/dev/null | sed 's/^v//' | tr -d '\n'))
  17 m4_ifval(VERSION_STRING, [], [define([VERSION_STRING], VERSION_NUMBER)])
  18
  19 AC_INIT([netdata], VERSION_STRING[]VERSION_SUFFIX)
  20
  21 AM_MAINTAINER_MODE([disable])
  22 if test x"$USE_MAINTAINER_MODE" = xyes; then
  23 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  24 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  25 fi
  26
  27 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  28 AC_SUBST([PACKAGE_RPM_VERSION])
  29 AC_SUBST([PACKAGE_RPM_RELEASE])
  30
  31
  32 # -----------------------------------------------------------------------------
  33 # autoconf initialization
  34
  35 AC_CONFIG_AUX_DIR([.])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR([src/main.c])
  39 AM_INIT_AUTOMAKE
  40 AC_CANONICAL_HOST
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 PKG_PROG_PKG_CONFIG
  44 AC_USE_SYSTEM_EXTENSIONS
  45
  46
  47 # -----------------------------------------------------------------------------
  48 # configurable options
  49
  50 AC_ARG_ENABLE(
  51         [plugin-nfacct],
  52         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  53         ,
  54         [enable_plugin_nfacct="no"]
  55 )
  56 AC_ARG_ENABLE(
  57         [plugin-freeipmi],
  58         [AS_HELP_STRING([--enable-plugin-freeipmi], [freeipmi plugin, requires root])],
  59         ,
  60         [enable_plugin_freeipmi="detect"]
  61 )
  62 AC_ARG_ENABLE(
  63         [pedantic],
  64         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  65         ,
  66         [enable_pedantic="no"]
  67 )
  68 AC_ARG_WITH(
  69         [webdir],
  70         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  71         [webdir="${withval}"],
  72         [webdir="\$(pkgdatadir)/web"]
  73 )
  74 AC_ARG_WITH(
  75         [libcap],
  76         [AS_HELP_STRING([--with-libcap], [build with libcap])],
  77         ,
  78         [with_libcap="detect"]
  79 )
  80 AC_ARG_WITH(
  81         [zlib],
  82         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  83         ,
  84         [with_zlib="yes"]
  85 )
  86 AC_ARG_WITH(
  87         [math],
  88         [AS_HELP_STRING([--with-math], [build with math])],
  89         ,
  90         [with_math="yes"]
  91 )
  92 AC_ARG_WITH(
  93         [user],
  94         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  95         ,
  96         [with_user="nobody"]
  97 )
  98 AC_ARG_ENABLE(
  99         [x86-sse],
 100         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 101         ,
 102         [enable_x86_sse="yes"]
 103 )
 104
 105
 106 # -----------------------------------------------------------------------------
 107 # netdata required checks
 108
 109 # fails on centos6
 110 #AX_CHECK_ENABLE_DEBUG()
 111
 112 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 113 AX_GCC_FUNC_ATTRIBUTE([malloc])
 114 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 115 AX_GCC_FUNC_ATTRIBUTE([format])
 116 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 117
 118 AC_CHECK_FUNCS_ONCE(accept4)
 119 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
 120 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
 121 AC_CHECK_FUNCS([clock_gettime])
 122 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
 123
 124 AC_TYPE_INT8_T
 125 AC_TYPE_INT16_T
 126 AC_TYPE_INT32_T
 127 AC_TYPE_INT64_T
 128 AC_TYPE_UINT8_T
 129 AC_TYPE_UINT16_T
 130 AC_TYPE_UINT32_T
 131 AC_TYPE_UINT64_T
 132 AC_C_INLINE
 133 AC_FUNC_STRERROR_R
 134 AC_C__GENERIC
 135 AC_C___ATOMIC
 136 # AC_C_STMT_EXPR
 137 AC_CHECK_SIZEOF([void *])
 138 AC_CANONICAL_HOST
 139 AC_HEADER_MAJOR
 140 AC_HEADER_RESOLV
 141
 142 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 143
 144
 145 # -----------------------------------------------------------------------------
 146 # operating system detection
 147
 148 case "$host_os" in
 149 freebsd*)
 150         build_target=freebsd
 151         ;;
 152 darwin*)
 153         build_target=macos
 154         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
 155         ;;
 156 *)
 157         build_target=linux
 158         ;;
 159 esac
 160
 161 AM_CONDITIONAL([FREEBSD], [test "${build_target}" = "freebsd"])
 162 AM_CONDITIONAL([MACOS], [test "${build_target}" = "macos"])
 163 AM_CONDITIONAL([LINUX], [test "${build_target}" = "linux"])
 164
 165
 166 # -----------------------------------------------------------------------------
 167 # compiler options
 168
 169 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 170 AS_CASE([$host_cpu],
 171         [i?86], [SSE_CANDIDATE="yes"]
 172 )
 173 AC_SUBST([SSE_CANDIDATE])
 174 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 175         opt="-msse2 -mfpmath=sse"
 176         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 177 fi
 178
 179 if test "${GCC}" = "yes"; then
 180         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 181         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 182 else
 183         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 184         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 185 fi
 186
 187 if test "${enable_pedantic}" = "yes"; then
 188         enable_strict="yes"
 189         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 190 fi
 191
 192
 193 # -----------------------------------------------------------------------------
 194 # pthreads
 195
 196 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 197 LIBS="${PTHREAD_LIBS} ${LIBS}"
 198 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 199 CC="${PTHREAD_CC}"
 200
 201
 202 # -----------------------------------------------------------------------------
 203 # memory allocation library
 204
 205 TS_CHECK_JEMALLOC
 206 if test "$has_jemalloc" = "1"; then
 207         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 208 else
 209         TS_CHECK_TCMALLOC
 210         if test "$has_tcmalloc" = "1"; then
 211                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 212         else
 213                 AC_C_MALLOPT
 214                 AC_C_MALLINFO
 215         fi
 216 fi
 217
 218
 219 # -----------------------------------------------------------------------------
 220 # libm
 221
 222 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 223 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 224 if test -z "${MATH_LIBS}"; then
 225         AC_CHECK_LIB(
 226                 [m],
 227                 [sin],
 228                 [MATH_LIBS="-lm"]
 229         )
 230 fi
 231
 232 if test "${with_math}" = "yes"; then
 233         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 234         AC_DEFINE([STORAGE_WITH_MATH], [1], [math usability])
 235         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 236         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 237 fi
 238
 239
 240 # -----------------------------------------------------------------------------
 241 # zlib
 242
 243 PKG_CHECK_MODULES(
 244         [ZLIB],
 245         [zlib],
 246         [have_zlib=yes],
 247         [have_zlib=no]
 248 )
 249 test "${with_zlib}" = "yes" -a "${have_zlib}" != "yes" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 250 if test "${with_zlib}" = "yes"; then
 251         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib usability])
 252         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 253         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 254 fi
 255
 256
 257 # -----------------------------------------------------------------------------
 258 # libuuid
 259
 260 PKG_CHECK_MODULES(
 261         [UUID],
 262         [uuid],
 263         [have_uuid=yes],
 264         [AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])]
 265 )
 266 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid usability])
 267 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 268 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 269
 270
 271 # -----------------------------------------------------------------------------
 272 # libcap
 273
 274 PKG_CHECK_MODULES(
 275         [LIBCAP],
 276         [libcap],
 277         [have_libcap=yes],
 278         [have_libcap=no]
 279 )
 280 test "${with_libcap}" = "yes" -a "${have_libcap}" != "yes" && AC_MSG_ERROR([libcap required but not found.])
 281
 282 AC_MSG_CHECKING([if libcap should be used])
 283 if test "${with_libcap}" != "no"; then
 284         with_libcap="yes"
 285         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 286         OPTIONAL_LIBCAP_CLFAGS="${LIBCAP_CFLAGS}"
 287         OPTIONAL_LIBCAP_LIBS="${LIBCAP_LIBS}"
 288 else
 289         with_libcap="no"
 290 fi
 291 AC_MSG_RESULT([${with_libcap}])
 292 AM_CONDITIONAL([ENABLE_CAPABILITY], [test "${with_libcap}" = "yes"])
 293
 294
 295 # -----------------------------------------------------------------------------
 296 # apps.plugin
 297
 298 AC_MSG_CHECKING([if apps.plugin should be enabled])
 299 if test "${build_target}" != "macos"; then
 300     enable_plugin_apps="yes"
 301 else
 302     enable_plugin_apps="no"
 303 fi
 304 AC_MSG_RESULT([${enable_plugin_apps}])
 305 AM_CONDITIONAL([ENABLE_PLUGIN_APPS], [test "${enable_plugin_apps}" = "yes"])
 306
 307
 308 # -----------------------------------------------------------------------------
 309 # freeipmi.plugin - libipmimonitoring
 310
 311 PKG_CHECK_MODULES(
 312         [IPMIMONITORING],
 313         [libipmimonitoring],
 314         [have_ipmimonitoring=yes],
 315         [have_ipmimonitoring=no]
 316 )
 317 test "${enable_plugin_freeipmi}" = "yes" -a "${have_ipmimonitoring}" != "yes" && \
 318         AC_MSG_ERROR([ipmimonitoring required but not found. Try installing 'libipmimonitoring-dev' or 'libipmimonitoring-devel'])
 319
 320 AC_MSG_CHECKING([if freeipmi.plugin should be enabled])
 321 if test "${enable_plugin_freeipmi}" != "no" -a "${have_ipmimonitoring}" = "yes"; then
 322         enable_plugin_freeipmi="yes"
 323         AC_DEFINE([HAVE_FREEIPMI], [1], [ipmimonitoring usability])
 324         OPTIONAL_IPMIMONITORING_CLFAGS="${IPMIMONITORING_CFLAGS}"
 325         OPTIONAL_IPMIMONITORING_LIBS="${IPMIMONITORING_LIBS}"
 326 else
 327         enable_plugin_freeipmi="no"
 328 fi
 329 AC_MSG_RESULT([${enable_plugin_freeipmi}])
 330 AM_CONDITIONAL([ENABLE_PLUGIN_FREEIPMI], [test "${enable_plugin_freeipmi}" = "yes"])
 331
 332
 333 # -----------------------------------------------------------------------------
 334 # nfacct.plugin - libmnl, libnetfilter_acct
 335
 336 PKG_CHECK_MODULES(
 337         [NFACCT],
 338         [libnetfilter_acct],
 339         [have_libnetfilter_acct=yes],
 340         [have_libnetfilter_acct=no]
 341 )
 342 PKG_CHECK_MODULES(
 343         [LIBMNL],
 344         [libmnl],
 345         [have_libmnl=yes],
 346         [have_libmnl=no]
 347 )
 348
 349 test "${enable_plugin_nfacct}" = "yes" -a "${have_libnetfilter_acct}" != "yes" && \
 350         AC_MSG_ERROR([netfilter_acct required but not found])
 351
 352 test "${enable_plugin_nfacct}" = "yes" -a "${have_libmnl}" != "yes" && \
 353         AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 354
 355 AC_MSG_CHECKING([if nfacct.plugin should be enabled])
 356 if test "${enable_plugin_nfacct}" != "no" -a "${have_libnetfilter_acct}" = "yes" -a "${have_libmnl}" = "yes"; then
 357         enable_plugin_nfacct="yes"
 358         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin usability])
 359         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 360         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 361 else
 362         enable_plugin_nfacct="no"
 363 fi
 364 AC_MSG_RESULT([${enable_plugin_nfacct}])
 365 AM_CONDITIONAL([ENABLE_PLUGIN_NFACCT], [test "${enable_plugin_nfacct}" = "yes"])
 366
 367
 368 # -----------------------------------------------------------------------------
 369
 370 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 371
 372 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 373 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 374 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 375 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 376 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 377 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 378 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 379 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 380 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 381 AC_SUBST([webdir])
 382
 383 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 384 AC_SUBST([OPTIONAL_MATH_LIBS])
 385 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 386 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 387 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 388 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 389 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 390 AC_SUBST([OPTIONAL_UUID_LIBS])
 391 AC_SUBST([OPTIONAL_LIBCAP_CFLAGS])
 392 AC_SUBST([OPTIONAL_LIBCAP_LIBS])
 393 AC_SUBST([OPTIONAL_IPMIMONITORING_CFLAGS])
 394 AC_SUBST([OPTIONAL_IPMIMONITORING_LIBS])
 395
 396 AC_CONFIG_FILES([
 397         Makefile
 398         charts.d/Makefile
 399         conf.d/Makefile
 400         netdata.spec
 401         python.d/Makefile
 402         node.d/Makefile
 403         plugins.d/Makefile
 404         src/Makefile
 405         system/Makefile
 406         web/Makefile
 407         contrib/Makefile
 408 ])
 409 AC_OUTPUT
 410
 411 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 412 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to transfer a lot less data with web clients. It should be enabled.]) || :