configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [4])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  39 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  40 AC_CHECK_FUNCS([clock_gettime])
  41
  42 # Check system type
  43 case "$host_os" in
  44 freebsd*)
  45         build_target=freebsd
  46         ;;
  47 *)
  48         ;;
  49 esac
  50
  51 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  52
  53 AC_ARG_ENABLE(
  54         [plugin-nfacct],
  55         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  56         ,
  57         [enable_plugin_nfacct="no"]
  58 )
  59 AC_ARG_ENABLE(
  60         [pedantic],
  61         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  62         ,
  63         [enable_pedantic="no"]
  64 )
  65 AC_ARG_WITH(
  66         [webdir],
  67         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  68         [webdir="${withval}"],
  69         [webdir="\$(pkgdatadir)/web"]
  70 )
  71 AC_ARG_WITH(
  72         [zlib],
  73         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  74         ,
  75         [with_zlib="yes"]
  76 )
  77 AC_ARG_WITH(
  78         [math],
  79         [AS_HELP_STRING([--with-math], [build with math])],
  80         ,
  81         [with_math="yes"]
  82 )
  83 AC_ARG_WITH(
  84         [user],
  85         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  86         ,
  87         [with_user="nobody"]
  88 )
  89 AC_ARG_ENABLE(
  90         [x86-sse],
  91         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
  92         ,
  93         [enable_x86_sse="yes"]
  94 )
  95
  96 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  97 LIBS="${PTHREAD_LIBS} ${LIBS}"
  98 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  99 CC="${PTHREAD_CC}"
 100
 101 TS_CHECK_JEMALLOC
 102 if test "$has_jemalloc" = "1"; then
 103         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 104 else
 105         TS_CHECK_TCMALLOC
 106         if test "$has_tcmalloc" = "1"; then
 107                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 108         else
 109                 AC_C_MALLOPT
 110                 AC_C_MALLINFO
 111         fi
 112 fi
 113
 114 AC_TYPE_UINT8_T
 115 AC_TYPE_UINT16_T
 116 AC_TYPE_UINT32_T
 117 AC_C_INLINE
 118 AC_FUNC_STRERROR_R
 119 AC_C__GENERIC
 120 AC_C___ATOMIC
 121 AC_CHECK_SIZEOF([void *])
 122 AC_CANONICAL_HOST
 123 AC_HEADER_MAJOR
 124 AC_HEADER_RESOLV
 125
 126 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 127 AS_CASE([$host_cpu],
 128         [i?86], [SSE_CANDIDATE="yes"]
 129 )
 130 AC_SUBST([SSE_CANDIDATE])
 131 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 132         opt="-msse2 -mfpmath=sse"
 133         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 134 fi
 135
 136 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 137 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 138 if test -z "${MATH_LIBS}"; then
 139         AC_CHECK_LIB(
 140                 [m],
 141                 [sin],
 142                 [MATH_LIBS="-lm"]
 143         )
 144 fi
 145
 146 PKG_CHECK_MODULES(
 147         [UUID],
 148         [uuid],
 149 )
 150 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 151 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 152 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 153 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 154
 155 if test "${enable_plugin_nfacct}" = "yes"; then
 156         PKG_CHECK_MODULES(
 157                 [NFACCT],
 158                 [libnetfilter_acct],
 159         )
 160         PKG_CHECK_MODULES(
 161                 [LIBMNL],
 162                 [libmnl],
 163         )
 164         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 165         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 166         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 167         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 168         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 169 fi
 170 if test "${with_zlib}" = "yes"; then
 171         PKG_CHECK_MODULES(
 172                 [ZLIB],
 173                 [zlib],
 174         )
 175         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 176         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 177         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 178         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 179 fi
 180 if test "${with_math}" = "yes"; then
 181         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 182         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 183         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 184         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 185 fi
 186
 187 if test "${GCC}" = "yes"; then
 188         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 189         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 190 else
 191         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 192         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 193 fi
 194
 195 if test "${enable_pedantic}" = "yes"; then
 196         enable_strict="yes"
 197         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 198 fi
 199
 200 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 201
 202 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 203 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 204 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 205 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 206 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 207 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 208 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 209 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 210 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 211 AC_SUBST([webdir])
 212
 213 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 214 AC_SUBST([OPTIONAL_MATH_LIBS])
 215 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 216 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 217 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 218 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 219 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 220 AC_SUBST([OPTIONAL_UUID_LIBS])
 221
 222 AC_CONFIG_FILES([
 223         Makefile
 224         charts.d/Makefile
 225         conf.d/Makefile
 226         netdata.spec
 227         python.d/Makefile
 228         node.d/Makefile
 229         plugins.d/Makefile
 230         src/Makefile
 231         system/Makefile
 232         web/Makefile
 233         contrib/Makefile
 234 ])
 235 AC_OUTPUT
 236
 237 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 238 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :