configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [4])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AX_CHECK_ENABLE_DEBUG()
  28
  29 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  30 AX_GCC_FUNC_ATTRIBUTE(malloc)
  31 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  32 AX_GCC_FUNC_ATTRIBUTE(format)
  33 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  34
  35 AC_CONFIG_AUX_DIR([.])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR([src/main.c])
  39 AM_INIT_AUTOMAKE
  40 AC_CANONICAL_HOST
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 PKG_PROG_PKG_CONFIG
  44 AC_USE_SYSTEM_EXTENSIONS
  45 AC_CHECK_FUNCS_ONCE(accept4)
  46 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  47 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  48 AC_CHECK_FUNCS([clock_gettime])
  49
  50 # Check system type
  51 case "$host_os" in
  52 freebsd*)
  53         build_target=freebsd
  54         ;;
  55 darwin*)
  56         build_target=macos
  57         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  58         ;;
  59 *)
  60         ;;
  61 esac
  62
  63 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  64 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  65
  66 AC_ARG_ENABLE(
  67         [plugin-nfacct],
  68         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  69         ,
  70         [enable_plugin_nfacct="no"]
  71 )
  72 AC_ARG_ENABLE(
  73         [pedantic],
  74         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  75         ,
  76         [enable_pedantic="no"]
  77 )
  78 AC_ARG_WITH(
  79         [webdir],
  80         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  81         [webdir="${withval}"],
  82         [webdir="\$(pkgdatadir)/web"]
  83 )
  84 AC_ARG_WITH(
  85         [zlib],
  86         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  87         ,
  88         [with_zlib="yes"]
  89 )
  90 AC_ARG_WITH(
  91         [math],
  92         [AS_HELP_STRING([--with-math], [build with math])],
  93         ,
  94         [with_math="yes"]
  95 )
  96 AC_ARG_WITH(
  97         [user],
  98         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  99         ,
 100         [with_user="nobody"]
 101 )
 102 AC_ARG_ENABLE(
 103         [x86-sse],
 104         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 105         ,
 106         [enable_x86_sse="yes"]
 107 )
 108
 109 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 110 LIBS="${PTHREAD_LIBS} ${LIBS}"
 111 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 112 CC="${PTHREAD_CC}"
 113
 114 TS_CHECK_JEMALLOC
 115 if test "$has_jemalloc" = "1"; then
 116         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 117 else
 118         TS_CHECK_TCMALLOC
 119         if test "$has_tcmalloc" = "1"; then
 120                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 121         else
 122                 AC_C_MALLOPT
 123                 AC_C_MALLINFO
 124         fi
 125 fi
 126
 127 AC_TYPE_UINT8_T
 128 AC_TYPE_UINT16_T
 129 AC_TYPE_UINT32_T
 130 AC_C_INLINE
 131 AC_FUNC_STRERROR_R
 132 AC_C__GENERIC
 133 AC_C___ATOMIC
 134 # AC_C_STMT_EXPR
 135 AC_CHECK_SIZEOF([void *])
 136 AC_CANONICAL_HOST
 137 AC_HEADER_MAJOR
 138 AC_HEADER_RESOLV
 139
 140 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 141 AS_CASE([$host_cpu],
 142         [i?86], [SSE_CANDIDATE="yes"]
 143 )
 144 AC_SUBST([SSE_CANDIDATE])
 145 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 146         opt="-msse2 -mfpmath=sse"
 147         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 148 fi
 149
 150 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 151 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 152 if test -z "${MATH_LIBS}"; then
 153         AC_CHECK_LIB(
 154                 [m],
 155                 [sin],
 156                 [MATH_LIBS="-lm"]
 157         )
 158 fi
 159
 160 PKG_CHECK_MODULES(
 161         [UUID],
 162         [uuid],
 163 )
 164 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 165 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 166 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 167 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 168
 169 if test "${enable_plugin_nfacct}" = "yes"; then
 170         PKG_CHECK_MODULES(
 171                 [NFACCT],
 172                 [libnetfilter_acct],
 173         )
 174         PKG_CHECK_MODULES(
 175                 [LIBMNL],
 176                 [libmnl],
 177         )
 178         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 179         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 180         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 181         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 182         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 183 fi
 184 if test "${with_zlib}" = "yes"; then
 185         PKG_CHECK_MODULES(
 186                 [ZLIB],
 187                 [zlib],
 188         )
 189         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 190         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 191         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 192         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 193 fi
 194 if test "${with_math}" = "yes"; then
 195         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 196         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 197         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 198         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 199 fi
 200
 201 if test "${GCC}" = "yes"; then
 202         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 203         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 204 else
 205         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 206         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 207 fi
 208
 209 if test "${enable_pedantic}" = "yes"; then
 210         enable_strict="yes"
 211         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 212 fi
 213
 214 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 215
 216 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 217 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 218 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 219 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 220 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 221 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 222 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 223 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 224 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 225 AC_SUBST([webdir])
 226
 227 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 228 AC_SUBST([OPTIONAL_MATH_LIBS])
 229 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 230 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 231 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 232 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 233 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 234 AC_SUBST([OPTIONAL_UUID_LIBS])
 235
 236 AC_CONFIG_FILES([
 237         Makefile
 238         charts.d/Makefile
 239         conf.d/Makefile
 240         netdata.spec
 241         python.d/Makefile
 242         node.d/Makefile
 243         plugins.d/Makefile
 244         src/Makefile
 245         system/Makefile
 246         web/Makefile
 247         contrib/Makefile
 248 ])
 249 AC_OUTPUT
 250
 251 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 252 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :