configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [3])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38
  39 AC_ARG_ENABLE(
  40         [plugin-nfacct],
  41         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  42         ,
  43         [enable_plugin_nfacct="no"]
  44 )
  45 AC_ARG_ENABLE(
  46         [pedantic],
  47         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  48         ,
  49         [enable_pedantic="no"]
  50 )
  51 AC_ARG_WITH(
  52         [webdir],
  53         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  54         [webdir="${withval}"],
  55         [webdir="\$(pkgdatadir)/web"]
  56 )
  57 AC_ARG_WITH(
  58         [zlib],
  59         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  60         ,
  61         [with_zlib="yes"]
  62 )
  63 AC_ARG_WITH(
  64         [math],
  65         [AS_HELP_STRING([--with-math], [build with math])],
  66         ,
  67         [with_math="yes"]
  68 )
  69 AC_ARG_WITH(
  70         [user],
  71         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  72         ,
  73         [with_user="nobody"]
  74 )
  75
  76 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  77 LIBS="${PTHREAD_LIBS} ${LIBS}"
  78 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  79 CC="${PTHREAD_CC}"
  80
  81 AC_TYPE_UINT8_T
  82 AC_TYPE_UINT16_T
  83 AC_TYPE_UINT32_T
  84 AC_C_INLINE
  85
  86 # https://lists.gnu.org/archive/html/autoconf-commit/2012-12/msg00004.html
  87 # AC_C__GENERIC
  88 # -------------
  89 # Define HAVE_C__GENERIC if _Generic works, a la C11.
  90 AN_IDENTIFIER([_Generic], [AC_C__GENERIC])
  91 AC_DEFUN([AC_C__GENERIC],
  92 [AC_CACHE_CHECK([for _Generic], ac_cv_c__Generic,
  93 [AC_COMPILE_IFELSE(
  94    [AC_LANG_SOURCE(
  95       [[int
  96         main (int argc, char **argv)
  97         {
  98           int a = _Generic (argc, int: argc = 1);
  99           int *b = &_Generic (argc, default: argc);
 100           char ***c = _Generic (argv, int: argc, default: argv ? &argv : 0);
 101           _Generic (1 ? 0 : b, int: a, default: b) = &argc;
 102           _Generic (a = 1, default: a) = 3;
 103           return a + !b + !c;
 104         }
 105       ]])],
 106    [ac_cv_c__Generic=yes],
 107    [ac_cv_c__Generic=no])])
 108 if test $ac_cv_c__Generic = yes; then
 109   AC_DEFINE([HAVE_C__GENERIC], 1,
 110            [Define to 1 if C11-style _Generic works.])
 111 fi
 112 ])# AC_C__GENERIC
 113
 114 AC_C__GENERIC
 115 AC_FUNC_STRERROR_R
 116
 117 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 118 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 119 if test -z "${MATH_LIBS}"; then
 120         AC_CHECK_LIB(
 121                 [m],
 122                 [sin],
 123                 [MATH_LIBS="-lm"]
 124         )
 125 fi
 126
 127 PKG_CHECK_MODULES(
 128         [UUID],
 129         [uuid],
 130 )
 131 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 132 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 133 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 134 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 135
 136 if test "${enable_plugin_nfacct}" = "yes"; then
 137         PKG_CHECK_MODULES(
 138                 [NFACCT],
 139                 [libnetfilter_acct],
 140         )
 141         PKG_CHECK_MODULES(
 142                 [LIBMNL],
 143                 [libmnl],
 144         )
 145         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 146         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 147         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 148         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 149         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 150 fi
 151 if test "${with_zlib}" = "yes"; then
 152         PKG_CHECK_MODULES(
 153                 [ZLIB],
 154                 [zlib],
 155         )
 156         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 157         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 158         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 159         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 160 fi
 161 if test "${with_math}" = "yes"; then
 162         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 163         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 164         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 165         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 166 fi
 167
 168 if test "${GCC}" = "yes"; then
 169         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 170         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 171 else
 172         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 173         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 174 fi
 175
 176 if test "${enable_pedantic}" = "yes"; then
 177         enable_strict="yes"
 178         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 179 fi
 180
 181 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 182
 183 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 184 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 185 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 186 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 187 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 188 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 189 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 190 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 191 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 192 AC_SUBST([webdir])
 193
 194 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 195 AC_SUBST([OPTIONAL_MATH_LIBS])
 196 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 197 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 198 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 199 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 200 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 201 AC_SUBST([OPTIONAL_UUID_LIBS])
 202
 203 AC_CONFIG_FILES([
 204         Makefile
 205         charts.d/Makefile
 206         conf.d/Makefile
 207         netdata.spec
 208         python.d/Makefile
 209         node.d/Makefile
 210         plugins.d/Makefile
 211         src/Makefile
 212         system/Makefile
 213         web/Makefile
 214         contrib/Makefile
 215 ])
 216 AC_OUTPUT
 217
 218 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 219 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :