configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [3])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38
  39 AC_ARG_ENABLE(
  40         [plugin-nfacct],
  41         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  42         ,
  43         [enable_plugin_nfacct="no"]
  44 )
  45 AC_ARG_ENABLE(
  46         [pedantic],
  47         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  48         ,
  49         [enable_pedantic="no"]
  50 )
  51 AC_ARG_WITH(
  52         [webdir],
  53         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  54         [webdir="${withval}"],
  55         [webdir="\$(pkgdatadir)/web"]
  56 )
  57 AC_ARG_WITH(
  58         [zlib],
  59         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  60         ,
  61         [with_zlib="yes"]
  62 )
  63 AC_ARG_WITH(
  64         [math],
  65         [AS_HELP_STRING([--with-math], [build with math])],
  66         ,
  67         [with_math="yes"]
  68 )
  69 AC_ARG_WITH(
  70         [user],
  71         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  72         ,
  73         [with_user="nobody"]
  74 )
  75 AC_ARG_ENABLE([x86-sse],
  76         AS_HELP_STRING([--enable-x86-sse=yes|no], [enable SSE/SS2 optimizations on x86 [default=yes]]),
  77         ,
  78         [enable_x86_sse="yes"]
  79 )
  80
  81 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  82 LIBS="${PTHREAD_LIBS} ${LIBS}"
  83 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  84 CC="${PTHREAD_CC}"
  85
  86 AC_TYPE_UINT8_T
  87 AC_TYPE_UINT16_T
  88 AC_TYPE_UINT32_T
  89 AC_C_INLINE
  90 AC_FUNC_STRERROR_R
  91 AC_C__GENERIC
  92 AC_C___ATOMIC
  93 AC_CHECK_SIZEOF([void *])
  94 AC_CANONICAL_HOST
  95
  96 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
  97 AS_CASE([$host_cpu],
  98         [i?86], [SSE_CANDIDATE="yes"]
  99 )
 100 AC_SUBST([SSE_CANDIDATE])
 101 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 102         opt="-msse2 -mfpmath=sse"
 103         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 104 fi
 105
 106 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 107 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 108 if test -z "${MATH_LIBS}"; then
 109         AC_CHECK_LIB(
 110                 [m],
 111                 [sin],
 112                 [MATH_LIBS="-lm"]
 113         )
 114 fi
 115
 116 PKG_CHECK_MODULES(
 117         [UUID],
 118         [uuid],
 119 )
 120 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 121 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 122 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 123 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 124
 125 if test "${enable_plugin_nfacct}" = "yes"; then
 126         PKG_CHECK_MODULES(
 127                 [NFACCT],
 128                 [libnetfilter_acct],
 129         )
 130         PKG_CHECK_MODULES(
 131                 [LIBMNL],
 132                 [libmnl],
 133         )
 134         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 135         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 136         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 137         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 138         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 139 fi
 140 if test "${with_zlib}" = "yes"; then
 141         PKG_CHECK_MODULES(
 142                 [ZLIB],
 143                 [zlib],
 144         )
 145         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 146         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 147         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 148         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 149 fi
 150 if test "${with_math}" = "yes"; then
 151         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 152         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 153         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 154         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 155 fi
 156
 157 if test "${GCC}" = "yes"; then
 158         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 159         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 160 else
 161         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 162         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 163 fi
 164
 165 if test "${enable_pedantic}" = "yes"; then
 166         enable_strict="yes"
 167         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 168 fi
 169
 170 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 171
 172 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 173 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 174 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 175 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 176 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 177 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 178 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 179 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 180 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 181 AC_SUBST([webdir])
 182
 183 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 184 AC_SUBST([OPTIONAL_MATH_LIBS])
 185 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 186 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 187 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 188 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 189 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 190 AC_SUBST([OPTIONAL_UUID_LIBS])
 191
 192 AC_CONFIG_FILES([
 193         Makefile
 194         charts.d/Makefile
 195         conf.d/Makefile
 196         netdata.spec
 197         python.d/Makefile
 198         node.d/Makefile
 199         plugins.d/Makefile
 200         src/Makefile
 201         system/Makefile
 202         web/Makefile
 203         contrib/Makefile
 204 ])
 205 AC_OUTPUT
 206
 207 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 208 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :