configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_rolling])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 # We do not use m4_esyscmd_s to support older autoconf.
  16 define([VERSION_STRING], m4_esyscmd(git describe 2>/dev/null | sed 's/^v//' | tr -d '\n'))
  17 m4_ifval(VERSION_STRING, [], [define([VERSION_STRING], VERSION_NUMBER)])
  18
  19 AC_INIT([netdata], VERSION_STRING[]VERSION_SUFFIX)
  20
  21 AM_MAINTAINER_MODE([disable])
  22 if test x"$USE_MAINTAINER_MODE" = xyes; then
  23 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  24 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  25 fi
  26
  27 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  28 AC_SUBST([PACKAGE_RPM_VERSION])
  29 AC_SUBST([PACKAGE_RPM_RELEASE])
  30
  31
  32 # -----------------------------------------------------------------------------
  33 # autoconf initialization
  34
  35 AC_CONFIG_AUX_DIR([.])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR([src/main.c])
  39 AM_INIT_AUTOMAKE
  40 AC_CANONICAL_HOST
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 PKG_PROG_PKG_CONFIG
  44 AC_USE_SYSTEM_EXTENSIONS
  45
  46
  47 # -----------------------------------------------------------------------------
  48 # configurable options
  49
  50 AC_ARG_ENABLE(
  51     [plugin-nfacct],
  52     [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  53     ,
  54     [enable_plugin_nfacct="no"]
  55 )
  56 AC_ARG_ENABLE(
  57     [plugin-freeipmi],
  58     [AS_HELP_STRING([--enable-plugin-freeipmi], [freeipmi plugin, requires root])],
  59     ,
  60     [enable_plugin_freeipmi="detect"]
  61 )
  62 AC_ARG_ENABLE(
  63     [pedantic],
  64     [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  65     ,
  66     [enable_pedantic="no"]
  67 )
  68 AC_ARG_WITH(
  69     [webdir],
  70     [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  71     [webdir="${withval}"],
  72     [webdir="\$(pkgdatadir)/web"]
  73 )
  74 AC_ARG_WITH(
  75     [libcap],
  76     [AS_HELP_STRING([--with-libcap], [build with libcap])],
  77     ,
  78     [with_libcap="detect"]
  79 )
  80 AC_ARG_WITH(
  81     [zlib],
  82     [AS_HELP_STRING([--with-zlib], [build with zlib])],
  83     ,
  84     [with_zlib="yes"]
  85 )
  86 AC_ARG_WITH(
  87     [math],
  88     [AS_HELP_STRING([--with-math], [build with math])],
  89     ,
  90     [with_math="yes"]
  91 )
  92 AC_ARG_WITH(
  93     [user],
  94     [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  95     ,
  96     [with_user="nobody"]
  97 )
  98 AC_ARG_ENABLE(
  99     [x86-sse],
 100     [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 101     ,
 102     [enable_x86_sse="yes"]
 103 )
 104 AC_ARG_ENABLE(
 105     [lto],
 106     [AS_HELP_STRING([--disable-lto], [Link Time Optimizations @<:@default enabled@:>@])],
 107     ,
 108     [enable_lto="detect"]
 109 )
 110
 111
 112 # -----------------------------------------------------------------------------
 113 # netdata required checks
 114
 115 # fails on centos6
 116 #AX_CHECK_ENABLE_DEBUG()
 117
 118 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 119 AX_GCC_FUNC_ATTRIBUTE([malloc])
 120 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 121 AX_GCC_FUNC_ATTRIBUTE([format])
 122 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 123
 124 AC_CHECK_FUNCS_ONCE(accept4)
 125 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
 126 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
 127 AC_CHECK_FUNCS([clock_gettime])
 128 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
 129
 130 AC_TYPE_INT8_T
 131 AC_TYPE_INT16_T
 132 AC_TYPE_INT32_T
 133 AC_TYPE_INT64_T
 134 AC_TYPE_UINT8_T
 135 AC_TYPE_UINT16_T
 136 AC_TYPE_UINT32_T
 137 AC_TYPE_UINT64_T
 138 AC_C_INLINE
 139 AC_FUNC_STRERROR_R
 140 AC_C__GENERIC
 141 AC_C___ATOMIC
 142 # AC_C_STMT_EXPR
 143 AC_CHECK_SIZEOF([void *])
 144 AC_CANONICAL_HOST
 145 AC_HEADER_MAJOR
 146 AC_HEADER_RESOLV
 147
 148 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 149
 150
 151 # -----------------------------------------------------------------------------
 152 # operating system detection
 153
 154 AC_MSG_CHECKING([operating system])
 155 case "$host_os" in
 156 freebsd*)
 157     build_target=freebsd
 158     ;;
 159 darwin*)
 160     build_target=macos
 161     LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
 162     ;;
 163 *)
 164     build_target=linux
 165     ;;
 166 esac
 167
 168 AM_CONDITIONAL([FREEBSD], [test "${build_target}" = "freebsd"])
 169 AM_CONDITIONAL([MACOS], [test "${build_target}" = "macos"])
 170 AM_CONDITIONAL([LINUX], [test "${build_target}" = "linux"])
 171 AC_MSG_RESULT([${build_target}])
 172
 173
 174 # -----------------------------------------------------------------------------
 175 # compiler options
 176
 177 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 178 AS_CASE([$host_cpu],
 179     [i?86], [SSE_CANDIDATE="yes"]
 180 )
 181 AC_SUBST([SSE_CANDIDATE])
 182 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 183     opt="-msse2 -mfpmath=sse"
 184     AX_CHECK_COMPILE_FLAG(${opt}, [CFLAGS="${CFLAGS} ${opt}"], [])
 185 fi
 186
 187 if test "${enable_lto}" != "no"; then
 188     opt="-flto"
 189     AX_CHECK_COMPILE_FLAG(${opt}, [have_lto=yes], [have_lto=no])
 190 fi
 191 test "${enable_lto}" = "yes" -a "${have_lto}" != "yes" && \
 192     AC_MSG_ERROR([LTO is required but is not available.])
 193 AC_MSG_CHECKING([if LTO should be enabled])
 194 if test "${enable_lto}" != "no" -a "${have_lto}" = "yes"; then
 195     enable_lto="yes"
 196     CFLAGS="${CFLAGS} -flto"
 197 else
 198     enable_lto="no"
 199 fi
 200 AC_MSG_RESULT([${enable_lto}])
 201
 202 if test "${GCC}" = "yes"; then
 203     AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 204     AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 205 else
 206     AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 207     AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 208 fi
 209
 210 if test "${enable_pedantic}" = "yes"; then
 211     enable_strict="yes"
 212     CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 213 fi
 214
 215
 216 # -----------------------------------------------------------------------------
 217 # pthreads
 218
 219 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 220 LIBS="${PTHREAD_LIBS} ${LIBS}"
 221 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 222 CC="${PTHREAD_CC}"
 223
 224
 225 # -----------------------------------------------------------------------------
 226 # memory allocation library
 227
 228 AC_MSG_CHECKING([for memory allocator])
 229 TS_CHECK_JEMALLOC
 230 if test "$has_jemalloc" = "1"; then
 231     AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 232     AC_MSG_RESULT([jemalloc])
 233 else
 234     TS_CHECK_TCMALLOC
 235     if test "$has_tcmalloc" = "1"; then
 236         AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 237         AC_MSG_RESULT([tcmalloc])
 238     else
 239         AC_MSG_RESULT([system])
 240         AC_C_MALLOPT
 241         AC_C_MALLINFO
 242     fi
 243 fi
 244
 245
 246 # -----------------------------------------------------------------------------
 247 # libm
 248
 249 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 250 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 251 if test -z "${MATH_LIBS}"; then
 252     AC_CHECK_LIB(
 253         [m],
 254         [sin],
 255         [MATH_LIBS="-lm"]
 256     )
 257 fi
 258 test "${with_math}" = "yes" -a -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 259
 260 AC_MSG_CHECKING([if libm should be used])
 261 if test "${with_math}" != "no" -a ! -z "${MATH_LIBS}"; then
 262     with_math="yes"
 263     AC_DEFINE([STORAGE_WITH_MATH], [1], [math usability])
 264     OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 265     OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 266 else
 267     with_math="no"
 268 fi
 269 AC_MSG_RESULT([${with_math}])
 270
 271
 272 # -----------------------------------------------------------------------------
 273 # zlib
 274
 275 PKG_CHECK_MODULES(
 276     [ZLIB],
 277     [zlib],
 278     [have_zlib=yes],
 279     [have_zlib=no]
 280 )
 281 test "${with_zlib}" = "yes" -a "${have_zlib}" != "yes" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 282
 283 AC_MSG_CHECKING([if zlib should be used])
 284 if test "${with_zlib}" != "no" -a "${have_zlib}" = "yes"; then
 285     with_zlib="yes"
 286     AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib usability])
 287     OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 288     OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 289 else
 290     with_zlib="no"
 291 fi
 292 AC_MSG_RESULT([${with_zlib}])
 293
 294
 295 # -----------------------------------------------------------------------------
 296 # libuuid
 297
 298 PKG_CHECK_MODULES(
 299     [UUID],
 300     [uuid],
 301     [have_uuid=yes],
 302     [AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])]
 303 )
 304 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid usability])
 305 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 306 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 307
 308
 309 # -----------------------------------------------------------------------------
 310 # libcap
 311
 312 PKG_CHECK_MODULES(
 313     [LIBCAP],
 314     [libcap],
 315     [AC_CHECK_LIB([cap], [cap_get_proc, cap_set_proc],
 316         [AC_CHECK_HEADER(
 317             [sys/capability.h],
 318             [have_libcap=yes],
 319             [have_libcap=no]
 320         )],
 321         [have_libcap=no]
 322     )],
 323     [have_libcap=no]
 324 )
 325 test "${with_libcap}" = "yes" -a "${have_libcap}" != "yes" && AC_MSG_ERROR([libcap required but not found.])
 326
 327 AC_MSG_CHECKING([if libcap should be used])
 328 if test "${with_libcap}" != "no" -a "${have_libcap}" = "yes"; then
 329     with_libcap="yes"
 330     AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 331     OPTIONAL_LIBCAP_CLFAGS="${LIBCAP_CFLAGS}"
 332     OPTIONAL_LIBCAP_LIBS="${LIBCAP_LIBS}"
 333 else
 334     with_libcap="no"
 335 fi
 336 AC_MSG_RESULT([${with_libcap}])
 337 AM_CONDITIONAL([ENABLE_CAPABILITY], [test "${with_libcap}" = "yes"])
 338
 339
 340 # -----------------------------------------------------------------------------
 341 # apps.plugin
 342
 343 AC_MSG_CHECKING([if apps.plugin should be enabled])
 344 if test "${build_target}" != "macos"; then
 345     enable_plugin_apps="yes"
 346 else
 347     enable_plugin_apps="no"
 348 fi
 349 AC_MSG_RESULT([${enable_plugin_apps}])
 350 AM_CONDITIONAL([ENABLE_PLUGIN_APPS], [test "${enable_plugin_apps}" = "yes"])
 351
 352
 353 # -----------------------------------------------------------------------------
 354 # freeipmi.plugin - libipmimonitoring
 355
 356 PKG_CHECK_MODULES(
 357     [IPMIMONITORING],
 358     [libipmimonitoring],
 359     [have_ipmimonitoring=yes],
 360     [have_ipmimonitoring=no]
 361 )
 362 test "${enable_plugin_freeipmi}" = "yes" -a "${have_ipmimonitoring}" != "yes" && \
 363     AC_MSG_ERROR([ipmimonitoring required but not found. Try installing 'libipmimonitoring-dev' or 'libipmimonitoring-devel'])
 364
 365 AC_MSG_CHECKING([if freeipmi.plugin should be enabled])
 366 if test "${enable_plugin_freeipmi}" != "no" -a "${have_ipmimonitoring}" = "yes"; then
 367     enable_plugin_freeipmi="yes"
 368     AC_DEFINE([HAVE_FREEIPMI], [1], [ipmimonitoring usability])
 369     OPTIONAL_IPMIMONITORING_CLFAGS="${IPMIMONITORING_CFLAGS}"
 370     OPTIONAL_IPMIMONITORING_LIBS="${IPMIMONITORING_LIBS}"
 371 else
 372     enable_plugin_freeipmi="no"
 373 fi
 374 AC_MSG_RESULT([${enable_plugin_freeipmi}])
 375 AM_CONDITIONAL([ENABLE_PLUGIN_FREEIPMI], [test "${enable_plugin_freeipmi}" = "yes"])
 376
 377
 378 # -----------------------------------------------------------------------------
 379 # nfacct.plugin - libmnl, libnetfilter_acct
 380
 381 PKG_CHECK_MODULES(
 382     [NFACCT],
 383     [libnetfilter_acct],
 384     [have_libnetfilter_acct=yes],
 385     [have_libnetfilter_acct=no]
 386 )
 387 PKG_CHECK_MODULES(
 388     [LIBMNL],
 389     [libmnl],
 390     [have_libmnl=yes],
 391     [have_libmnl=no]
 392 )
 393
 394 test "${enable_plugin_nfacct}" = "yes" -a "${have_libnetfilter_acct}" != "yes" && \
 395     AC_MSG_ERROR([netfilter_acct required but not found])
 396
 397 test "${enable_plugin_nfacct}" = "yes" -a "${have_libmnl}" != "yes" && \
 398     AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 399
 400 AC_MSG_CHECKING([if nfacct.plugin should be enabled])
 401 if test "${enable_plugin_nfacct}" != "no" -a "${have_libnetfilter_acct}" = "yes" -a "${have_libmnl}" = "yes"; then
 402     enable_plugin_nfacct="yes"
 403     AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin usability])
 404     OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 405     OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 406 else
 407     enable_plugin_nfacct="no"
 408 fi
 409 AC_MSG_RESULT([${enable_plugin_nfacct}])
 410 AM_CONDITIONAL([ENABLE_PLUGIN_NFACCT], [test "${enable_plugin_nfacct}" = "yes"])
 411
 412
 413 # -----------------------------------------------------------------------------
 414
 415 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 416
 417 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 418 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 419 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 420 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 421 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 422 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 423 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 424 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 425 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 426 AC_SUBST([webdir])
 427
 428 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 429 AC_SUBST([OPTIONAL_MATH_LIBS])
 430 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 431 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 432 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 433 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 434 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 435 AC_SUBST([OPTIONAL_UUID_LIBS])
 436 AC_SUBST([OPTIONAL_LIBCAP_CFLAGS])
 437 AC_SUBST([OPTIONAL_LIBCAP_LIBS])
 438 AC_SUBST([OPTIONAL_IPMIMONITORING_CFLAGS])
 439 AC_SUBST([OPTIONAL_IPMIMONITORING_LIBS])
 440
 441 AC_CONFIG_FILES([
 442     Makefile
 443     charts.d/Makefile
 444     conf.d/Makefile
 445     netdata.spec
 446     python.d/Makefile
 447     node.d/Makefile
 448     plugins.d/Makefile
 449     src/Makefile
 450     system/Makefile
 451     web/Makefile
 452     contrib/Makefile
 453 ])
 454 AC_OUTPUT
 455
 456 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 457 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to transfer a lot less data with web clients. It should be enabled.]) || :