configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [2])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38
  39 AC_ARG_ENABLE(
  40         [plugin-nfacct],
  41         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  42         ,
  43         [enable_plugin_nfacct="no"]
  44 )
  45 AC_ARG_ENABLE(
  46         [pedantic],
  47         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  48         ,
  49         [enable_pedantic="no"]
  50 )
  51 AC_ARG_WITH(
  52         [webdir],
  53         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  54         [webdir="${withval}"],
  55         [webdir="\$(pkgdatadir)/web"]
  56 )
  57 AC_ARG_WITH(
  58         [zlib],
  59         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  60         ,
  61         [with_zlib="yes"]
  62 )
  63 AC_ARG_WITH(
  64         [math],
  65         [AS_HELP_STRING([--with-math], [build with math])],
  66         ,
  67         [with_math="yes"]
  68 )
  69 AC_ARG_WITH(
  70         [user],
  71         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  72         ,
  73         [with_user="nobody"]
  74 )
  75
  76 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  77 LIBS="${PTHREAD_LIBS} ${LIBS}"
  78 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  79 CC="${PTHREAD_CC}"
  80
  81 AC_TYPE_UINT8_T
  82 AC_TYPE_UINT16_T
  83 AC_TYPE_UINT32_T
  84 AC_C_INLINE
  85
  86 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
  87 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
  88 if test -z "${MATH_LIBS}"; then
  89         AC_CHECK_LIB(
  90                 [m],
  91                 [sin],
  92                 [MATH_LIBS="-lm"]
  93         )
  94 fi
  95
  96 PKG_CHECK_MODULES(
  97         [UUID],
  98         [uuid],
  99 )
 100 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 101 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 102 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 103 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 104
 105 if test "${enable_plugin_nfacct}" = "yes"; then
 106         PKG_CHECK_MODULES(
 107                 [NFACCT],
 108                 [libnetfilter_acct],
 109         )
 110         PKG_CHECK_MODULES(
 111                 [LIBMNL],
 112                 [libmnl],
 113         )
 114         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 115         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 116         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 117         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 118         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 119 fi
 120 if test "${with_zlib}" = "yes"; then
 121         PKG_CHECK_MODULES(
 122                 [ZLIB],
 123                 [zlib],
 124         )
 125         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 126         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 127         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 128         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 129 fi
 130 if test "${with_math}" = "yes"; then
 131         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 132         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 133         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 134         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 135 fi
 136
 137 if test "${GCC}" = "yes"; then
 138         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 139         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 140 else
 141         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 142         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 143 fi
 144
 145 if test "${enable_pedantic}" = "yes"; then
 146         enable_strict="yes"
 147         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 148 fi
 149
 150 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 151
 152 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 153 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 154 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 155 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 156 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 157 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 158 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 159 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 160 AC_SUBST([webdir])
 161
 162 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 163 AC_SUBST([OPTIONAL_MATH_LIBS])
 164 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 165 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 166 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 167 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 168 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 169 AC_SUBST([OPTIONAL_UUID_LIBS])
 170
 171 AC_CONFIG_FILES([
 172         Makefile
 173         charts.d/Makefile
 174         conf.d/Makefile
 175         netdata.spec
 176         python.d/Makefile
 177         node.d/Makefile
 178         plugins.d/Makefile
 179         src/Makefile
 180         system/Makefile
 181         web/Makefile
 182         contrib/Makefile
 183 ])
 184 AC_OUTPUT
 185
 186 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 187 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :