configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [0])
   8 define([VERSION_FIX], [0])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  13 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  14 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed 's/^_//')"
  15 AC_SUBST([PACKAGE_RPM_VERSION])
  16 AC_SUBST([PACKAGE_RPM_RELEASE])
  17
  18 AC_CONFIG_AUX_DIR([.])
  19 AC_CONFIG_HEADERS([config.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AM_INIT_AUTOMAKE
  23 AC_CANONICAL_HOST
  24 AC_PROG_CC
  25 AC_PROG_INSTALL
  26 PKG_PROG_PKG_CONFIG
  27 AC_USE_SYSTEM_EXTENSIONS
  28
  29 AC_ARG_ENABLE(
  30         [plugin-nfacct],
  31         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  32         ,
  33         [enable_plugin_nfacct="no"]
  34 )
  35 AC_ARG_ENABLE(
  36         [pedantic],
  37         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  38         ,
  39         [enable_pedantic="no"]
  40 )
  41 AC_ARG_WITH(
  42         [webdir],
  43         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  44         [webdir="${withval}"],
  45         [webdir="\$(pkgdatadir)/web"]
  46 )
  47 AC_ARG_WITH(
  48         [zlib],
  49         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  50         ,
  51         [with_zlib="yes"]
  52 )
  53 AC_ARG_WITH(
  54         [math],
  55         [AS_HELP_STRING([--with-math], [build with math])],
  56         ,
  57         [with_math="yes"]
  58 )
  59 AC_ARG_WITH(
  60         [user],
  61         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  62         ,
  63         [with_user="nobody"]
  64 )
  65
  66 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  67 LIBS="${PTHREAD_LIBS} ${LIBS}"
  68 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  69 CC="${PTHREAD_CC}"
  70
  71 AC_TYPE_UINT8_T
  72 AC_TYPE_UINT16_T
  73 AC_TYPE_UINT32_T
  74 AC_C_INLINE
  75
  76 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
  77 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
  78 if test -z "${MATH_LIBS}"; then
  79         AC_CHECK_LIB(
  80                 [m],
  81                 [sin],
  82                 [MATH_LIBS="-lm"]
  83         )
  84 fi
  85
  86 if test "${enable_plugin_nfacct}" = "yes"; then
  87         PKG_CHECK_MODULES(
  88                 [NFACCT],
  89                 [libnetfilter_acct],
  90         )
  91         PKG_CHECK_MODULES(
  92                 [LIBMNL],
  93                 [libmnl],
  94         )
  95         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
  96         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found])
  97         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
  98         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
  99         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 100 fi
 101 if test "${with_zlib}" = "yes"; then
 102         PKG_CHECK_MODULES(
 103                 [ZLIB],
 104                 [zlib],
 105         )
 106         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found])
 107         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 108         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 109         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 110 fi
 111 if test "${with_math}" = "yes"; then
 112         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 113         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 114         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 115         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 116 fi
 117
 118 if test "${GCC}" = "yes"; then
 119         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 120         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 121 else
 122         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 123         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 124 fi
 125
 126 if test "${enable_pedantic}" = "yes"; then
 127         enable_strict="yes"
 128         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 129 fi
 130
 131 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 132
 133 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 134 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 135 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 136 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 137 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 138 AC_SUBST([webdir])
 139
 140 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 141 AC_SUBST([OPTIONAL_MATH_LIBS])
 142 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 143 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 144 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 145 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 146
 147 AC_CONFIG_FILES([
 148         Makefile
 149         charts.d/Makefile
 150         conf.d/Makefile
 151         netdata.spec
 152         plugins.d/Makefile
 153         src/Makefile
 154         web/Makefile
 155 ])
 156 AC_OUTPUT
 157
 158 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 159 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :