configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [5])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_rolling])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 # We do not use m4_esyscmd_s to support older autoconf.
  16 define([VERSION_STRING], m4_esyscmd(git describe 2>/dev/null | sed 's/^v//' | tr -d '\n'))
  17 m4_ifval(VERSION_STRING, [], [define([VERSION_STRING], VERSION_NUMBER)])
  18
  19 AC_INIT([netdata], VERSION_STRING[]VERSION_SUFFIX)
  20
  21 AM_MAINTAINER_MODE([disable])
  22 if test x"$USE_MAINTAINER_MODE" = xyes; then
  23 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  24 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  25 fi
  26
  27 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  28 AC_SUBST([PACKAGE_RPM_VERSION])
  29 AC_SUBST([PACKAGE_RPM_RELEASE])
  30
  31 # fails on centos6
  32 #AX_CHECK_ENABLE_DEBUG()
  33
  34 AX_GCC_FUNC_ATTRIBUTE(returns_nonnull)
  35 AX_GCC_FUNC_ATTRIBUTE(malloc)
  36 AX_GCC_FUNC_ATTRIBUTE(noreturn)
  37 AX_GCC_FUNC_ATTRIBUTE(format)
  38 AX_GCC_FUNC_ATTRIBUTE(warn_unused_result)
  39
  40 AC_CONFIG_AUX_DIR([.])
  41 AC_CONFIG_HEADERS([config.h])
  42 AC_CONFIG_MACRO_DIR([m4])
  43 AC_CONFIG_SRCDIR([src/main.c])
  44 AM_INIT_AUTOMAKE
  45 AC_CANONICAL_HOST
  46 AC_PROG_CC
  47 AC_PROG_INSTALL
  48 PKG_PROG_PKG_CONFIG
  49 AC_USE_SYSTEM_EXTENSIONS
  50 AC_CHECK_FUNCS_ONCE(accept4)
  51 AC_CHECK_TYPES([struct timespec, clockid_t], [], [], [[#include <time.h>]])
  52 AC_SEARCH_LIBS([clock_gettime], [rt posix4])
  53 AC_CHECK_FUNCS([clock_gettime])
  54 AC_CHECK_FUNCS([sched_setscheduler sched_get_priority_min sched_get_priority_max nice])
  55
  56 # Check system type
  57 case "$host_os" in
  58 freebsd*)
  59         build_target=freebsd
  60         ;;
  61 darwin*)
  62         build_target=macos
  63         LDFLAGS="${LDFLAGS} -framework CoreFoundation -framework IOKit"
  64         ;;
  65 *)
  66         build_target=linux
  67         ;;
  68 esac
  69
  70 AM_CONDITIONAL([FREEBSD], [test x$build_target = xfreebsd])
  71 AM_CONDITIONAL([MACOS], [test x$build_target = xmacos])
  72 AM_CONDITIONAL([LINUX], [test x$build_target = xlinux])
  73
  74 AC_ARG_ENABLE(
  75         [plugin-nfacct],
  76         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  77         ,
  78         [enable_plugin_nfacct="no"]
  79 )
  80 AC_ARG_ENABLE(
  81         [pedantic],
  82         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  83         ,
  84         [enable_pedantic="no"]
  85 )
  86 AC_ARG_WITH(
  87         [webdir],
  88         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  89         [webdir="${withval}"],
  90         [webdir="\$(pkgdatadir)/web"]
  91 )
  92 AC_ARG_WITH(
  93         [zlib],
  94         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  95         ,
  96         [with_zlib="yes"]
  97 )
  98 AC_ARG_WITH(
  99         [math],
 100         [AS_HELP_STRING([--with-math], [build with math])],
 101         ,
 102         [with_math="yes"]
 103 )
 104 AC_ARG_WITH(
 105         [user],
 106         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
 107         ,
 108         [with_user="nobody"]
 109 )
 110 AC_ARG_ENABLE(
 111         [x86-sse],
 112         [AS_HELP_STRING([--disable-x86-sse], [SSE/SS2 optimizations on x86 @<:@default enabled@:>@])],
 113         ,
 114         [enable_x86_sse="yes"]
 115 )
 116
 117 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
 118 LIBS="${PTHREAD_LIBS} ${LIBS}"
 119 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
 120 CC="${PTHREAD_CC}"
 121
 122 TS_CHECK_JEMALLOC
 123 if test "$has_jemalloc" = "1"; then
 124         AC_DEFINE([ENABLE_JEMALLOC], [1], [compile and link with jemalloc])
 125 else
 126         TS_CHECK_TCMALLOC
 127         if test "$has_tcmalloc" = "1"; then
 128                 AC_DEFINE([ENABLE_TCMALLOC], [1], [compile and link with tcmalloc])
 129         else
 130                 AC_C_MALLOPT
 131                 AC_C_MALLINFO
 132         fi
 133 fi
 134
 135 AC_TYPE_INT8_T
 136 AC_TYPE_INT16_T
 137 AC_TYPE_INT32_T
 138 AC_TYPE_INT64_T
 139 AC_TYPE_UINT8_T
 140 AC_TYPE_UINT16_T
 141 AC_TYPE_UINT32_T
 142 AC_TYPE_UINT64_T
 143 AC_C_INLINE
 144 AC_FUNC_STRERROR_R
 145 AC_C__GENERIC
 146 AC_C___ATOMIC
 147 # AC_C_STMT_EXPR
 148 AC_CHECK_SIZEOF([void *])
 149 AC_CANONICAL_HOST
 150 AC_HEADER_MAJOR
 151 AC_HEADER_RESOLV
 152 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 153
 154 AC_CHECK_LIB([cap], [cap_get_proc, cap_set_proc],
 155         [AC_CHECK_HEADER(
 156                 [sys/capability.h],
 157                 [
 158                         CAP_LIBS=-lcap
 159                         AC_DEFINE([HAVE_CAPABILITY], [1], [libcap usability])
 160                 ]
 161         )]
 162 )
 163 OPTIONAL_CAP_LIBS="${CAP_LIBS}"
 164
 165 AC_ARG_VAR([SSE_CANDIDATE], [C compiler flags for SSE])
 166 AS_CASE([$host_cpu],
 167         [i?86], [SSE_CANDIDATE="yes"]
 168 )
 169 AC_SUBST([SSE_CANDIDATE])
 170 if test "${SSE_CANDIDATE}" = "yes" -a "${enable_x86_sse}" = "yes"; then
 171         opt="-msse2 -mfpmath=sse"
 172         AX_CHECK_COMPILE_FLAG($opt, [CFLAGS="$CFLAGS $opt"], [])
 173 fi
 174
 175 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 176 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 177 if test -z "${MATH_LIBS}"; then
 178         AC_CHECK_LIB(
 179                 [m],
 180                 [sin],
 181                 [MATH_LIBS="-lm"]
 182         )
 183 fi
 184
 185 PKG_CHECK_MODULES(
 186         [UUID],
 187         [uuid],
 188 )
 189 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 190 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 191 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 192 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 193
 194 if test "${enable_plugin_nfacct}" = "yes"; then
 195         PKG_CHECK_MODULES(
 196                 [NFACCT],
 197                 [libnetfilter_acct],
 198         )
 199         PKG_CHECK_MODULES(
 200                 [LIBMNL],
 201                 [libmnl],
 202         )
 203         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 204         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 205         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 206         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 207         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 208 fi
 209 if test "${with_zlib}" = "yes"; then
 210         PKG_CHECK_MODULES(
 211                 [ZLIB],
 212                 [zlib],
 213         )
 214         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 215         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 216         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 217         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 218 fi
 219 if test "${with_math}" = "yes"; then
 220         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 221         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 222         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 223         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 224 fi
 225
 226 if test "${GCC}" = "yes"; then
 227         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 228         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 229 else
 230         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 231         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 232 fi
 233
 234 if test "${enable_pedantic}" = "yes"; then
 235         enable_strict="yes"
 236         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 237 fi
 238
 239 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 240
 241 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 242 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 243 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 244 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 245 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 246 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 247 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 248 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 249 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 250 AC_SUBST([webdir])
 251
 252 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 253 AC_SUBST([OPTIONAL_MATH_LIBS])
 254 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 255 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 256 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 257 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 258 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 259 AC_SUBST([OPTIONAL_UUID_LIBS])
 260 AC_SUBST([OPTIONAL_CAP_LIBS])
 261
 262 AC_CONFIG_FILES([
 263         Makefile
 264         charts.d/Makefile
 265         conf.d/Makefile
 266         netdata.spec
 267         python.d/Makefile
 268         node.d/Makefile
 269         plugins.d/Makefile
 270         src/Makefile
 271         system/Makefile
 272         web/Makefile
 273         contrib/Makefile
 274 ])
 275 AC_OUTPUT
 276
 277 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 278 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :