etc/afpd/spotlight_rawquery_parser.y

   1 %{
   2   #include <atalk/standards.h>
   3
   4   #include <stdbool.h>
   5   #include <stdio.h>
   6   #include <string.h>
   7   #include <time.h>
   8
   9   #include <gio/gio.h>
  10
  11   #include <atalk/talloc.h>
  12   #include <atalk/logger.h>
  13   #include <atalk/errchk.h>
  14
  15   #include "spotlight_SPARQL_map.h"
  16   #include "spotlight.h"
  17
  18   struct yy_buffer_state;
  19   typedef struct yy_buffer_state *YY_BUFFER_STATE;
  20   extern int yylex (void);
  21   extern void yyerror (char const *);
  22   extern void *yyterminate(void);
  23   extern YY_BUFFER_STATE yy_scan_string( const char *str);
  24   extern void yy_delete_buffer ( YY_BUFFER_STATE buffer );
  25
  26   /* forward declarations */
  27   static const char *map_expr(const char *attr, char op, const char *val);
  28   static const char *map_daterange(const char *dateattr, time_t date1, time_t date2);
  29   static time_t isodate2unix(const char *s);
  30
  31  /* global vars, eg needed by the lexer */
  32   slq_t *ssp_slq;
  33
  34   /* local vars */
  35   static gchar *ssp_result;
  36   static char sparqlvar;
  37 %}
  38
  39 %code provides {
  40   #define SPRAW_TIME_OFFSET 978307200
  41   extern int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result);
  42   extern slq_t *ssp_slq;
  43 }
  44
  45 %union {
  46     int ival;
  47     const char *sval;
  48     bool bval;
  49     time_t tval;
  50 }
  51
  52 %expect 1
  53 %error-verbose
  54
  55 %type <sval> match expr line function
  56 %type <tval> date
  57
  58 %token <sval> WORD
  59 %token <bval> BOOL
  60 %token FUNC_INRANGE
  61 %token DATE_ISO
  62 %token OBRACE CBRACE EQUAL UNEQUAL GT LT COMMA QUOTE
  63 %left AND
  64 %left OR
  65 %%
  66
  67 input:
  68 /* empty */
  69 | input line
  70 ;
  71
  72 line:
  73 expr                           {
  74     ssp_result = talloc_asprintf(ssp_slq,
  75                                  "SELECT DISTINCT ?url WHERE "
  76                                  "{ ?obj nie:url ?url FILTER(fn:starts-with(?url, 'file://%s/')) . %s}",
  77                                  ssp_slq->slq_vol->v_path, $1);
  78     $$ = ssp_result;
  79 }
  80 ;
  81
  82 expr:
  83 BOOL                             {
  84     if ($1 == false)
  85         YYACCEPT;
  86     else
  87         YYABORT;
  88 }
  89 | match OR match                 {
  90     if (strcmp($1, $3) != 0)
  91         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
  92     else
  93         $$ = talloc_asprintf(ssp_slq, "%s", $1);
  94 }
  95 | match                        {$$ = $1; if ($$ == NULL) YYABORT;}
  96 | function                     {$$ = $1;}
  97 | OBRACE expr CBRACE           {$$ = talloc_asprintf(ssp_slq, "%s", $2);}
  98 | expr AND expr                {$$ = talloc_asprintf(ssp_slq, "%s . %s", $1, $3);}
  99 | expr OR expr                 {
 100     if (strcmp($1, $3) != 0)
 101         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 102     else
 103         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 104 }
 105 ;
 106
 107 match:
 108 WORD EQUAL QUOTE WORD QUOTE     {$$ = map_expr($1, '=', $4);}
 109 | WORD UNEQUAL QUOTE WORD QUOTE {$$ = map_expr($1, '!', $4);}
 110 | WORD LT QUOTE WORD QUOTE      {$$ = map_expr($1, '<', $4);}
 111 | WORD GT QUOTE WORD QUOTE      {$$ = map_expr($1, '>', $4);}
 112 ;
 113
 114 function:
 115 FUNC_INRANGE OBRACE WORD COMMA date COMMA date CBRACE {$$ = map_daterange($3, $5, $7);}
 116 ;
 117
 118 date:
 119 DATE_ISO OBRACE WORD CBRACE    {$$ = isodate2unix($3);}
 120 | WORD                         {$$ = atoi($1) + SPRAW_TIME_OFFSET;}
 121 ;
 122
 123 %%
 124
 125 static time_t isodate2unix(const char *s)
 126 {
 127     struct tm tm;
 128
 129     if (strptime(s, "%Y-%m-%dT%H:%M:%SZ", &tm) == NULL)
 130         return (time_t)-1;
 131     return mktime(&tm);
 132 }
 133
 134 const char *map_daterange(const char *dateattr, time_t date1, time_t date2)
 135 {
 136     EC_INIT;
 137     char *result = NULL;
 138     struct spotlight_sparql_map *p;
 139     struct tm *tmp;
 140     char buf1[64], buf2[64];
 141
 142     EC_NULL_LOG( tmp = localtime(&date1) );
 143     strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 144     EC_NULL_LOG( tmp = localtime(&date2) );
 145     strftime(buf2, sizeof(buf2), "%Y-%m-%dT%H:%M:%SZ", tmp);
 146
 147     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 148         if (strcmp(dateattr, p->ssm_spotlight_attr) == 0) {
 149             result = talloc_asprintf(ssp_slq,
 150                                      "?obj %s ?%c FILTER (?%c > '%s' && ?%c < '%s')",
 151                                      p->ssm_sparql_attr,
 152                                      sparqlvar,
 153                                      sparqlvar,
 154                                      buf1,
 155                                      sparqlvar,
 156                                      buf2);
 157             sparqlvar++;
 158             break;
 159         }
 160     }
 161
 162 EC_CLEANUP:
 163     if (ret != 0)
 164         return NULL;
 165     return result;
 166 }
 167
 168 const char *map_expr(const char *attr, char op, const char *val)
 169 {
 170     EC_INIT;
 171     char *result = NULL;
 172     struct spotlight_sparql_map *p;
 173     time_t t;
 174     struct tm *tmp;
 175     char buf1[64];
 176
 177     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 178         if (strcmp(p->ssm_spotlight_attr, attr) == 0) {
 179             switch (p->ssm_type) {
 180             case ssmt_bool:
 181                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 182                 break;
 183             case ssmt_num:
 184                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c '%s')",
 185                                          p->ssm_sparql_attr,
 186                                          sparqlvar,
 187                                          sparqlvar,
 188                                          op,
 189                                          val);
 190                 sparqlvar++;
 191                 break;
 192             case ssmt_str:
 193                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(regex(?%c, '%s'))",
 194                                          p->ssm_sparql_attr,
 195                                          sparqlvar,
 196                                          sparqlvar,
 197                                          val);
 198                 sparqlvar++;
 199                 break;
 200             case ssmt_fts:
 201                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 202                 break;
 203             case ssmt_date:
 204                 t = atoi(val) + SPRAW_TIME_OFFSET;
 205                 EC_NULL( tmp = localtime(&t) );
 206                 strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 207                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c '%s')",
 208                                          p->ssm_sparql_attr,
 209                                          sparqlvar,
 210                                          sparqlvar,
 211                                          op,
 212                                          buf1);
 213                 sparqlvar++;
 214                 break;
 215             default:
 216                 yyerror("unknown Spotlight attribute type");
 217                 EC_FAIL;
 218             }
 219             break;
 220         }
 221     }
 222
 223 EC_CLEANUP:
 224     return result;
 225 }
 226
 227 void yyerror(const char *str)
 228 {
 229 #ifdef MAIN
 230     printf("yyerror: %s\n", str);
 231 #else
 232     LOG(log_error, logtype_sl, "yyerror: %s", str);
 233 #endif
 234 }
 235
 236 int yywrap()
 237 {
 238     return 1;
 239 }
 240
 241 /**
 242  * Map a Spotlight RAW query string to a SPARQL query string
 243  *
 244  * @param[in]     slq            Spotlight query handle
 245  * @param[out]    sparql_result  Mapped SPARQL query, string is allocated in
 246  *                               talloc context of slq
 247  * @return        0 on success, -1 on error
 248  **/
 249 int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result)
 250 {
 251     EC_INIT;
 252     YY_BUFFER_STATE s = NULL;
 253     ssp_result = NULL;
 254
 255     ssp_slq = slq;
 256     s = yy_scan_string(slq->slq_qstring);
 257     sparqlvar = 'a';
 258
 259     EC_ZERO( yyparse() );
 260
 261 EC_CLEANUP:
 262     if (s)
 263         yy_delete_buffer(s);
 264     if (ret == 0)
 265         *sparql_result = ssp_result;
 266     else
 267         *sparql_result = NULL;
 268     EC_EXIT;
 269 }
 270
 271 #ifdef MAIN
 272 int main(int argc, char **argv)
 273 {
 274     int ret;
 275     YY_BUFFER_STATE s;
 276
 277     if (argc != 2) {
 278         printf("usage: %s QUERY\n", argv[0]);
 279         return 1;
 280     }
 281
 282     ssp_slq = talloc_zero(NULL, slq_t);
 283     struct vol *vol = talloc_zero(ssp_slq, struct vol);
 284     vol->v_path = "/Volumes/test";
 285     ssp_slq->slq_vol = vol;
 286     sparqlvar = 'a';
 287
 288     s = yy_scan_string(argv[1]);
 289
 290     ret = yyparse();
 291
 292     yy_delete_buffer(s);
 293
 294     if (ret == 0)
 295         printf("SPARQL: %s\n", ssp_result ? ssp_result : "(empty)");
 296
 297     return 0;
 298 }
 299 #endif