etc/afpd/spotlight_rawquery_parser.y

   1 %{
   2   #include <atalk/standards.h>
   3
   4   #include <stdbool.h>
   5   #include <stdio.h>
   6   #include <string.h>
   7   #include <time.h>
   8
   9   #include <gio/gio.h>
  10
  11   #include <atalk/talloc.h>
  12   #include <atalk/logger.h>
  13   #include <atalk/errchk.h>
  14
  15   #include "spotlight_SPARQL_map.h"
  16   #include "spotlight.h"
  17
  18   struct yy_buffer_state;
  19   typedef struct yy_buffer_state *YY_BUFFER_STATE;
  20   extern int yylex (void);
  21   extern void yyerror (char const *);
  22   extern void *yyterminate(void);
  23   extern YY_BUFFER_STATE yy_scan_string( const char *str);
  24   extern void yy_delete_buffer ( YY_BUFFER_STATE buffer );
  25
  26   /* forward declarations */
  27   static const char *map_expr(const char *attr, char op, const char *val);
  28   static const char *map_daterange(const char *dateattr, time_t date1, time_t date2);
  29   static time_t isodate2unix(const char *s);
  30
  31  /* global vars, eg needed by the lexer */
  32   slq_t *ssp_slq;
  33
  34   /* local vars */
  35   static gchar *ssp_result;
  36   static char sparqlvar;
  37 %}
  38
  39 %code provides {
  40   #define SPRAW_TIME_OFFSET 978307200
  41   extern int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result);
  42   extern slq_t *ssp_slq;
  43 }
  44
  45 %union {
  46     int ival;
  47     const char *sval;
  48     bool bval;
  49     time_t tval;
  50 }
  51
  52 %expect 1
  53 %error-verbose
  54
  55 %type <sval> match expr line function
  56 %type <tval> date
  57
  58 %token <sval> WORD
  59 %token <bval> BOOL
  60 %token FUNC_INRANGE
  61 %token DATE_ISO
  62 %token OBRACE CBRACE EQUAL UNEQUAL GT LT COMMA QUOTE
  63 %left AND
  64 %left OR
  65 %%
  66
  67 input:
  68 /* empty */
  69 | input line
  70 ;
  71
  72 line:
  73 expr                           {
  74     ssp_result = talloc_asprintf(ssp_slq,
  75                                  "SELECT DISTINCT ?url WHERE "
  76                                  "{ ?obj nie:url ?url FILTER(fn:starts-with(?url, 'file://%s/')) . %s}",
  77                                  ssp_slq->slq_vol->v_path, $1);
  78     $$ = ssp_result;
  79 }
  80 ;
  81
  82 expr:
  83 BOOL                             {
  84     if ($1 == false)
  85         YYACCEPT;
  86     else
  87         YYABORT;
  88 }
  89 | match OR match                 {
  90     if (strcmp($1, $3) != 0)
  91         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
  92     else
  93         $$ = talloc_asprintf(ssp_slq, "%s", $1);
  94 }
  95 | match                        {$$ = $1; if ($$ == NULL) YYABORT;}
  96 | function                     {$$ = $1;}
  97 | OBRACE expr CBRACE           {$$ = talloc_asprintf(ssp_slq, "%s", $2);}
  98 | expr AND expr                {$$ = talloc_asprintf(ssp_slq, "%s . %s", $1, $3);}
  99 | expr OR expr                 {
 100     if (strcmp($1, $3) != 0)
 101         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 102     else
 103         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 104 }
 105 ;
 106
 107 match:
 108 WORD EQUAL QUOTE WORD QUOTE     {$$ = map_expr($1, '=', $4);}
 109 | WORD UNEQUAL QUOTE WORD QUOTE {$$ = map_expr($1, '!', $4);}
 110 | WORD LT QUOTE WORD QUOTE      {$$ = map_expr($1, '<', $4);}
 111 | WORD GT QUOTE WORD QUOTE      {$$ = map_expr($1, '>', $4);}
 112 ;
 113
 114 function:
 115 FUNC_INRANGE OBRACE WORD COMMA date COMMA date CBRACE {$$ = map_daterange($3, $5, $7);}
 116 ;
 117
 118 date:
 119 DATE_ISO OBRACE WORD CBRACE    {$$ = isodate2unix($3);}
 120 | WORD                         {$$ = atoi($1) + SPRAW_TIME_OFFSET;}
 121 ;
 122
 123 %%
 124
 125 static time_t isodate2unix(const char *s)
 126 {
 127     struct tm tm;
 128
 129     if (strptime(s, "%Y-%m-%dT%H:%M:%SZ", &tm) == NULL)
 130         return (time_t)-1;
 131     return mktime(&tm);
 132 }
 133
 134 const char *map_daterange(const char *dateattr, time_t date1, time_t date2)
 135 {
 136     EC_INIT;
 137     char *result = NULL;
 138     struct spotlight_sparql_map *p;
 139     struct tm *tmp;
 140     char buf1[64], buf2[64];
 141
 142     EC_NULL_LOG( tmp = localtime(&date1) );
 143     strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 144     EC_NULL_LOG( tmp = localtime(&date2) );
 145     strftime(buf2, sizeof(buf2), "%Y-%m-%dT%H:%M:%SZ", tmp);
 146
 147     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 148         if (strcmp(dateattr, p->ssm_spotlight_attr) == 0) {
 149             result = talloc_asprintf(ssp_slq,
 150                                      "?obj %s ?%c FILTER (?%c > '%s' && ?%c < '%s')",
 151                                      p->ssm_sparql_attr,
 152                                      sparqlvar,
 153                                      sparqlvar,
 154                                      buf1,
 155                                      sparqlvar,
 156                                      buf2);
 157             sparqlvar++;
 158             break;
 159         }
 160     }
 161
 162 EC_CLEANUP:
 163     if (ret != 0)
 164         return NULL;
 165     return result;
 166 }
 167
 168 const char *map_expr(const char *attr, char op, const char *val)
 169 {
 170     EC_INIT;
 171     char *result = NULL;
 172     struct spotlight_sparql_map *p;
 173     time_t t;
 174     struct tm *tmp;
 175     char buf1[64];
 176     bstring q = NULL, search = NULL, replace = NULL;
 177
 178     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 179         if (strcmp(p->ssm_spotlight_attr, attr) == 0) {
 180             switch (p->ssm_type) {
 181             case ssmt_bool:
 182                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 183                 break;
 184             case ssmt_num:
 185                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c%c '%s')",
 186                                          p->ssm_sparql_attr,
 187                                          sparqlvar,
 188                                          sparqlvar,
 189                                          op,
 190                                          op == '!' ? '=' : ' ', /* append '=' to '!' */
 191                                          val);
 192                 sparqlvar++;
 193                 break;
 194             case ssmt_str:
 195                 q = bformat("^%s$", val);
 196                 search = bfromcstr("*");
 197                 replace = bfromcstr(".*");
 198                 bfindreplace(q, search, replace, 0);
 199                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(regex(?%c, '%s'))",
 200                                          p->ssm_sparql_attr,
 201                                          sparqlvar,
 202                                          sparqlvar,
 203                                          bdata(q));
 204                 sparqlvar++;
 205                 break;
 206             case ssmt_fts:
 207                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 208                 break;
 209             case ssmt_date:
 210                 t = atoi(val) + SPRAW_TIME_OFFSET;
 211                 EC_NULL( tmp = localtime(&t) );
 212                 strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 213                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c '%s')",
 214                                          p->ssm_sparql_attr,
 215                                          sparqlvar,
 216                                          sparqlvar,
 217                                          op,
 218                                          buf1);
 219                 sparqlvar++;
 220                 break;
 221             default:
 222                 yyerror("unknown Spotlight attribute type");
 223                 EC_FAIL;
 224             }
 225             break;
 226         }
 227     }
 228
 229 EC_CLEANUP:
 230     if (q)
 231         bdestroy(q);
 232     if (search)
 233         bdestroy(search);
 234     if (replace)
 235         bdestroy(replace);
 236     return result;
 237 }
 238
 239 void yyerror(const char *str)
 240 {
 241 #ifdef MAIN
 242     printf("yyerror: %s\n", str);
 243 #else
 244     LOG(log_error, logtype_sl, "yyerror: %s", str);
 245 #endif
 246 }
 247
 248 int yywrap()
 249 {
 250     return 1;
 251 }
 252
 253 /**
 254  * Map a Spotlight RAW query string to a SPARQL query string
 255  *
 256  * @param[in]     slq            Spotlight query handle
 257  * @param[out]    sparql_result  Mapped SPARQL query, string is allocated in
 258  *                               talloc context of slq
 259  * @return        0 on success, -1 on error
 260  **/
 261 int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result)
 262 {
 263     EC_INIT;
 264     YY_BUFFER_STATE s = NULL;
 265     ssp_result = NULL;
 266
 267     ssp_slq = slq;
 268     s = yy_scan_string(slq->slq_qstring);
 269     sparqlvar = 'a';
 270
 271     EC_ZERO( yyparse() );
 272
 273 EC_CLEANUP:
 274     if (s)
 275         yy_delete_buffer(s);
 276     if (ret == 0)
 277         *sparql_result = ssp_result;
 278     else
 279         *sparql_result = NULL;
 280     EC_EXIT;
 281 }
 282
 283 #ifdef MAIN
 284 int main(int argc, char **argv)
 285 {
 286     int ret;
 287     YY_BUFFER_STATE s;
 288
 289     if (argc != 2) {
 290         printf("usage: %s QUERY\n", argv[0]);
 291         return 1;
 292     }
 293
 294     ssp_slq = talloc_zero(NULL, slq_t);
 295     struct vol *vol = talloc_zero(ssp_slq, struct vol);
 296     vol->v_path = "/Volumes/test";
 297     ssp_slq->slq_vol = vol;
 298     sparqlvar = 'a';
 299
 300     s = yy_scan_string(argv[1]);
 301
 302     ret = yyparse();
 303
 304     yy_delete_buffer(s);
 305
 306     if (ret == 0)
 307         printf("SPARQL: %s\n", ssp_result ? ssp_result : "(empty)");
 308
 309     return 0;
 310 }
 311 #endif