etc/afpd/spotlight_rawquery_parser.y

   1 %{
   2   #include <atalk/standards.h>
   3
   4   #include <stdbool.h>
   5   #include <stdio.h>
   6   #include <string.h>
   7   #include <time.h>
   8
   9   #include <gio/gio.h>
  10
  11   #include <atalk/talloc.h>
  12   #include <atalk/logger.h>
  13   #include <atalk/errchk.h>
  14
  15   #include "spotlight_SPARQL_map.h"
  16   #include "spotlight.h"
  17
  18   struct yy_buffer_state;
  19   typedef struct yy_buffer_state *YY_BUFFER_STATE;
  20   extern int yylex (void);
  21   extern void yyerror (char const *);
  22   extern void *yyterminate(void);
  23   extern YY_BUFFER_STATE yy_scan_string( const char *str);
  24   extern void yy_delete_buffer ( YY_BUFFER_STATE buffer );
  25
  26   /* forward declarations */
  27   static const char *map_expr(const char *attr, char op, const char *val);
  28   static const char *map_daterange(const char *dateattr, time_t date1, time_t date2);
  29   static time_t isodate2unix(const char *s);
  30
  31  /* global vars, eg needed by the lexer */
  32   slq_t *ssp_slq;
  33
  34   /* local vars */
  35   static gchar *ssp_result;
  36   static char sparqlvar;
  37 %}
  38
  39 %code provides {
  40   #define SPRAW_TIME_OFFSET 978307200
  41   extern int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result);
  42   extern slq_t *ssp_slq;
  43 }
  44
  45 %union {
  46     int ival;
  47     const char *sval;
  48     bool bval;
  49     time_t tval;
  50 }
  51
  52 %expect 5
  53 %error-verbose
  54
  55 %type <sval> match expr line function
  56 %type <tval> date
  57
  58 %token <sval> WORD
  59 %token <bval> BOOL
  60 %token FUNC_INRANGE
  61 %token DATE_ISO
  62 %token OBRACE CBRACE EQUAL UNEQUAL GT LT COMMA QUOTE
  63 %left AND
  64 %left OR
  65 %%
  66
  67 input:
  68 /* empty */
  69 | input line
  70 ;
  71
  72 line:
  73 expr                           {
  74     ssp_result = talloc_asprintf(ssp_slq,
  75                                  "SELECT DISTINCT ?url WHERE "
  76                                  "{ ?obj nie:url ?url FILTER(fn:starts-with(?url, 'file://%s/')) . %s}",
  77                                  ssp_slq->slq_vol->v_path, $1);
  78     $$ = ssp_result;
  79 }
  80 ;
  81
  82 expr:
  83 BOOL                             {
  84     if ($1 == false)
  85         YYACCEPT;
  86     else
  87         YYABORT;
  88 }
  89 | match OR match                 {
  90     if (strcmp($1, $3) != 0)
  91         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
  92     else
  93         $$ = talloc_asprintf(ssp_slq, "%s", $1);
  94 }
  95 | match                        {$$ = $1; if ($$ == NULL) YYABORT;}
  96 | function                     {$$ = $1;}
  97 | OBRACE expr CBRACE           {$$ = talloc_asprintf(ssp_slq, "%s", $2);}
  98 | expr AND expr                {$$ = talloc_asprintf(ssp_slq, "%s . %s", $1, $3);}
  99 | expr OR expr                 {
 100     if (strcmp($1, $3) != 0)
 101         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 102     else
 103         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 104 }
 105 ;
 106
 107 match:
 108 WORD EQUAL QUOTE WORD QUOTE     {$$ = map_expr($1, '=', $4);}
 109 | WORD UNEQUAL QUOTE WORD QUOTE {$$ = map_expr($1, '!', $4);}
 110 | WORD LT QUOTE WORD QUOTE      {$$ = map_expr($1, '<', $4);}
 111 | WORD GT QUOTE WORD QUOTE      {$$ = map_expr($1, '>', $4);}
 112 | WORD EQUAL QUOTE WORD QUOTE WORD    {$$ = map_expr($1, '=', $4);}
 113 | WORD UNEQUAL QUOTE WORD QUOTE WORD {$$ = map_expr($1, '!', $4);}
 114 | WORD LT QUOTE WORD QUOTE WORD     {$$ = map_expr($1, '<', $4);}
 115 | WORD GT QUOTE WORD QUOTE WORD     {$$ = map_expr($1, '>', $4);}
 116 ;
 117
 118 function:
 119 FUNC_INRANGE OBRACE WORD COMMA date COMMA date CBRACE {$$ = map_daterange($3, $5, $7);}
 120 ;
 121
 122 date:
 123 DATE_ISO OBRACE WORD CBRACE    {$$ = isodate2unix($3);}
 124 | WORD                         {$$ = atoi($1) + SPRAW_TIME_OFFSET;}
 125 ;
 126
 127 %%
 128
 129 static time_t isodate2unix(const char *s)
 130 {
 131     struct tm tm;
 132
 133     if (strptime(s, "%Y-%m-%dT%H:%M:%SZ", &tm) == NULL)
 134         return (time_t)-1;
 135     return mktime(&tm);
 136 }
 137
 138 const char *map_daterange(const char *dateattr, time_t date1, time_t date2)
 139 {
 140     EC_INIT;
 141     char *result = NULL;
 142     struct spotlight_sparql_map *p;
 143     struct tm *tmp;
 144     char buf1[64], buf2[64];
 145
 146     EC_NULL_LOG( tmp = localtime(&date1) );
 147     strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 148     EC_NULL_LOG( tmp = localtime(&date2) );
 149     strftime(buf2, sizeof(buf2), "%Y-%m-%dT%H:%M:%SZ", tmp);
 150
 151     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 152         if (strcmp(dateattr, p->ssm_spotlight_attr) == 0) {
 153             result = talloc_asprintf(ssp_slq,
 154                                      "?obj %s ?%c FILTER (?%c > '%s' && ?%c < '%s')",
 155                                      p->ssm_sparql_attr,
 156                                      sparqlvar,
 157                                      sparqlvar,
 158                                      buf1,
 159                                      sparqlvar,
 160                                      buf2);
 161             sparqlvar++;
 162             break;
 163         }
 164     }
 165
 166 EC_CLEANUP:
 167     if (ret != 0)
 168         return NULL;
 169     return result;
 170 }
 171
 172 const char *map_expr(const char *attr, char op, const char *val)
 173 {
 174     EC_INIT;
 175     char *result = NULL;
 176     struct spotlight_sparql_map *p;
 177     time_t t;
 178     struct tm *tmp;
 179     char buf1[64];
 180     bstring q = NULL, search = NULL, replace = NULL;
 181
 182     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 183         if (strcmp(p->ssm_spotlight_attr, attr) == 0) {
 184             switch (p->ssm_type) {
 185             case ssmt_bool:
 186                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 187                 break;
 188             case ssmt_num:
 189                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c%c '%s')",
 190                                          p->ssm_sparql_attr,
 191                                          sparqlvar,
 192                                          sparqlvar,
 193                                          op,
 194                                          op == '!' ? '=' : ' ', /* append '=' to '!' */
 195                                          val);
 196                 sparqlvar++;
 197                 break;
 198             case ssmt_str:
 199                 q = bformat("^%s$", val);
 200                 search = bfromcstr("*");
 201                 replace = bfromcstr(".*");
 202                 bfindreplace(q, search, replace, 0);
 203                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(regex(?%c, '%s'))",
 204                                          p->ssm_sparql_attr,
 205                                          sparqlvar,
 206                                          sparqlvar,
 207                                          bdata(q));
 208                 sparqlvar++;
 209                 break;
 210             case ssmt_fts:
 211                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 212                 break;
 213             case ssmt_date:
 214                 t = atoi(val) + SPRAW_TIME_OFFSET;
 215                 EC_NULL( tmp = localtime(&t) );
 216                 strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 217                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c '%s')",
 218                                          p->ssm_sparql_attr,
 219                                          sparqlvar,
 220                                          sparqlvar,
 221                                          op,
 222                                          buf1);
 223                 sparqlvar++;
 224                 break;
 225             default:
 226                 yyerror("unknown Spotlight attribute type");
 227                 EC_FAIL;
 228             }
 229             break;
 230         }
 231     }
 232
 233 EC_CLEANUP:
 234     if (q)
 235         bdestroy(q);
 236     if (search)
 237         bdestroy(search);
 238     if (replace)
 239         bdestroy(replace);
 240     return result;
 241 }
 242
 243 void yyerror(const char *str)
 244 {
 245 #ifdef MAIN
 246     printf("yyerror: %s\n", str);
 247 #else
 248     LOG(log_error, logtype_sl, "yyerror: %s", str);
 249 #endif
 250 }
 251
 252 int yywrap()
 253 {
 254     return 1;
 255 }
 256
 257 /**
 258  * Map a Spotlight RAW query string to a SPARQL query string
 259  *
 260  * @param[in]     slq            Spotlight query handle
 261  * @param[out]    sparql_result  Mapped SPARQL query, string is allocated in
 262  *                               talloc context of slq
 263  * @return        0 on success, -1 on error
 264  **/
 265 int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result)
 266 {
 267     EC_INIT;
 268     YY_BUFFER_STATE s = NULL;
 269     ssp_result = NULL;
 270
 271     ssp_slq = slq;
 272     s = yy_scan_string(slq->slq_qstring);
 273     sparqlvar = 'a';
 274
 275     EC_ZERO( yyparse() );
 276
 277 EC_CLEANUP:
 278     if (s)
 279         yy_delete_buffer(s);
 280     if (ret == 0)
 281         *sparql_result = ssp_result;
 282     else
 283         *sparql_result = NULL;
 284     EC_EXIT;
 285 }
 286
 287 #ifdef MAIN
 288 int main(int argc, char **argv)
 289 {
 290     int ret;
 291     YY_BUFFER_STATE s;
 292
 293     if (argc != 2) {
 294         printf("usage: %s QUERY\n", argv[0]);
 295         return 1;
 296     }
 297
 298     ssp_slq = talloc_zero(NULL, slq_t);
 299     struct vol *vol = talloc_zero(ssp_slq, struct vol);
 300     vol->v_path = "/Volumes/test";
 301     ssp_slq->slq_vol = vol;
 302     sparqlvar = 'a';
 303
 304     s = yy_scan_string(argv[1]);
 305
 306     ret = yyparse();
 307
 308     yy_delete_buffer(s);
 309
 310     if (ret == 0)
 311         printf("SPARQL: %s\n", ssp_result ? ssp_result : "(empty)");
 312
 313     return 0;
 314 }
 315 #endif