configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.27 2004-05-17 02:21:48 bfernhomberg Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58 dnl Replace `main' with a function in -lnsl:
  59 AC_CHECK_LIB(nsl, main)
  60 dnl Replace `main' with a function in -lprot:
  61 dnl AC_CHECK_LIB(prot, main)
  62 dnl Replace `main' with a function in -lrx:
  63 dnl AC_CHECK_LIB(rx, main)
  64 dnl Replace `main' with a function in -lrxkad:
  65 dnl AC_CHECK_LIB(rxkad, main)
  66 dnl Replace `main' with a function in -lsocket:
  67 AC_CHECK_LIB(socket, socket)
  68 dnl Replace `main' with a function in -lsys:
  69 dnl AC_CHECK_LIB(sys, main)
  70 dnl Replace `main' with a function in -lubik:
  71 dnl AC_CHECK_LIB(ubik, main)
  72
  73
  74 #
  75 # Check presence of some functions
  76 #
  77 # Check for XPG4 access() function
  78 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  79 # has such a function that works only on AFS filesystems.
  80 AC_CHECK_FUNCS(access)
  81 #
  82 AC_CHECK_FUNCS(pread pwrite)
  83
  84 dnl Checks for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_STDC
  87 AC_HEADER_SYS_WAIT
  88 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  89 AC_CHECK_HEADER(sys/cdefs.h,,
  90         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  91         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  92 )
  93 AC_CHECK_HEADERS([sys/mount.h], , ,
  94 [#ifdef HAVE_SYS_PARAM_H
  95 #include <sys/param.h>
  96 #endif
  97 ])
  98
  99 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 100
 101 dnl Checks for typedefs, structures, and compiler characteristics.
 102 AC_C_CONST
 103 AC_TYPE_UID_T
 104 AC_C_INLINE
 105 AC_TYPE_MODE_T
 106 AC_TYPE_OFF_T
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_STRUCT_ST_RDEV
 110 AC_HEADER_TIME
 111 AC_STRUCT_TM
 112
 113 dnl --------------------------------------------------------------------------
 114 dnl check if dlsym needs to add an underscore, uses libtool macros
 115 dnl --------------------------------------------------------------------------
 116 AC_LTDL_DLLIB
 117 AC_LTDL_DLSYM_USCORE
 118 if test x"$libltdl_cv_need_uscore" = xyes; then
 119     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 120 fi
 121
 122
 123 dnl Checks for library functions.
 124 AC_TYPE_GETGROUPS
 125 AC_PROG_GCC_TRADITIONAL
 126 AC_FUNC_MEMCMP
 127 AC_HEADER_MAJOR
 128 AC_FUNC_MMAP
 129 AC_TYPE_SIGNAL
 130 AC_FUNC_UTIME_NULL
 131 AC_FUNC_WAIT3
 132 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul setpgrp strchr memcpy)
 133 AC_FUNC_SETPGRP
 134 AC_CHECK_FUNCS(backtrace_symbols)
 135 AC_CHECK_FUNCS(setlocale nl_langinfo)
 136 AC_CHECK_FUNCS(dlopen dlclose dlsym dlerror waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 137 AC_CHECK_FUNCS(strlcpy strlcat)
 138 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 139 AC_CACHE_SAVE
 140
 141 dnl Checks for (v)snprintf
 142 NETATALK_SNPRINTF_CHECK
 143
 144 dnl --------------------------------------------------------------------------
 145 dnl 64bit platform check
 146 dnl --------------------------------------------------------------------------
 147
 148 AC_MSG_CHECKING([whether to check for 64bit libraries])
 149 dnl Determine libdir name
 150 case $host in
 151 *-*-linux*)
 152   # Test if the compiler is 64bit
 153   echo 'int i;' > conftest.$ac_ext
 154   atalk_cv_cc_64bit_output=no
 155   if AC_TRY_EVAL(ac_compile); then
 156     case `/usr/bin/file conftest.$ac_objext` in
 157     *"ELF 64"*)
 158       atalk_cv_cc_64bit_output=yes
 159       ;;
 160     esac
 161   fi
 162   rm -rf conftest*
 163   ;;
 164 esac
 165
 166 dnl
 167 dnl FIXME: Do we need something like this for Solaris 64bit?
 168 dnl
 169
 170 case $host_cpu:$atalk_cv_cc_64bit_output in
 171 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 172   atalk_libname="lib64"
 173   AC_MSG_RESULT([yes])
 174   ;;
 175 *:*)
 176   atalk_libname="lib"
 177   AC_MSG_RESULT([no])
 178   ;;
 179 esac
 180
 181 dnl --------------------------------------------------------------------------
 182 dnl specific configuration comes in here:
 183 dnl --------------------------------------------------------------------------
 184
 185 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 186
 187 netatalk_cv_admin_group=yes
 188 AC_MSG_CHECKING([for administrative group support])
 189 AC_ARG_WITH(admin-group,
 190         [  --disable-admin-group   disable admin group],[
 191         if test "$enableval" = "no"; then
 192                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 193                 AC_MSG_RESULT([yes])
 194         else
 195                 AC_MSG_RESULT([no])
 196                 netatalk_cv_admin_group=no
 197         fi],[
 198                 AC_MSG_RESULT([yes])
 199         ]
 200 )
 201
 202 NETATALK_AFS_CHECK
 203
 204 NETATALK_CONFIG_DIRS
 205
 206 AC_MSG_CHECKING([for logfile path])
 207 AC_ARG_WITH(logfile,
 208         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 209                           use --without-logfile to disable logger],[
 210         if test x"$withval" = x"no"; then
 211                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 212                 AC_MSG_RESULT([syslog])
 213         elif test "$withval" != "yes"; then
 214                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 215                 AC_MSG_RESULT([$withval])
 216         else
 217                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 218                 AC_MSG_RESULT([/var/log/netatalk.log])
 219         fi],[
 220                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 221                 AC_MSG_RESULT([/var/log/netatalk.log])
 222         ]
 223 )
 224
 225
 226 netatalk_cv_with_cracklib=no
 227 AC_MSG_CHECKING([for cracklib support])
 228 AC_ARG_WITH(cracklib,
 229         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 230         if test "x$withval" != "xno" ; then
 231                 cracklib="$withval"
 232                 AC_CHECK_LIB(crack, main, [
 233                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 234                         LIBS="$LIBS -lcrack"
 235                         AC_MSG_RESULT([yes])
 236                         if test "$cracklib" = "yes"; then
 237                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 238                         fi
 239                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 240                                 [path to cracklib dictionary])
 241                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 242                         netatalk_cv_with_cracklib=yes
 243                         ],[
 244                         AC_MSG_ERROR([cracklib not found!])
 245                         ]
 246                 )
 247         else
 248                 AC_MSG_RESULT([no])
 249         fi
 250         ],[
 251                 AC_MSG_RESULT([no])
 252         ]
 253 )
 254
 255 netatalk_cv_ddp_enabled=yes
 256 AC_MSG_CHECKING([whether to enable DDP])
 257 AC_ARG_ENABLE(ddp,
 258         [  --disable-ddp           disable DDP],[
 259         if test "$enableval" = "no"; then
 260                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 261                 AC_MSG_RESULT([no])
 262                 netatalk_cv_ddp_enabled=no
 263         else
 264                 AC_MSG_RESULT([yes])
 265         fi
 266         ],[
 267                 AC_MSG_RESULT([yes])
 268         ]
 269 )
 270
 271 AC_MSG_CHECKING([whether to enable debug code])
 272 AC_ARG_ENABLE(debug1,
 273         [  --enable-debug1         enable debug code],[
 274         if test "$enableval" != "no"; then
 275                 if test "$enableval" = "yes"; then
 276                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 277                 else
 278                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 279                 fi
 280                 AC_MSG_RESULT([yes])
 281         else
 282                 AC_MSG_RESULT([no])
 283         fi
 284         ],[
 285                 AC_MSG_RESULT([no])
 286         ]
 287 )
 288
 289 AC_MSG_CHECKING([whether to enable verbose debug code])
 290 AC_ARG_ENABLE(debug,
 291         [  --enable-debug          enable verbose debug code],[
 292         if test "$enableval" != "no"; then
 293                 if test "$enableval" = "yes"; then
 294                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 295                 else
 296                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 297                 fi
 298                 AC_MSG_RESULT([yes])
 299         else
 300                 AC_MSG_RESULT([no])
 301         fi
 302         ],[
 303                 AC_MSG_RESULT([no])
 304         ]
 305 )
 306
 307 afp3=no
 308 afp3set=no
 309 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 310 AC_ARG_ENABLE(afp3,
 311         [  --disable-afp3          disable AFP 3.x calls],
 312         [
 313             if test x"$enableval" != x"no"; then
 314                 afp3set=yes
 315                 afp3=yes
 316                 AC_MSG_RESULT([yes])
 317             else
 318                 AC_MSG_RESULT([no])
 319             fi
 320         ],[
 321             AC_MSG_RESULT([yes])
 322             afp3=yes
 323         ]
 324 )
 325
 326 if test x"$afp3" = x"yes"; then
 327         AC_SYS_LARGEFILE([
 328                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 329         ],[
 330                 if test x"$afp3set" = x"yes"; then
 331                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 332                 else
 333                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 334                         afp3=no
 335                 fi
 336         ])
 337 fi
 338
 339 AC_CHECK_ICONV
 340
 341 dnl ----------- A NOTE ABOUT DROPKLUDGE
 342 dnl The trouble with this fix is that if you know what the file is called, it
 343 dnl can be read from the Unix side.  That's okay for most academic institutions
 344 dnl since the students don't have telnet access to the Mac servers.  There is
 345 dnl currently no one working on further development/fixes of DROPKLUDGE.
 346 dnl -----------
 347
 348 netatalk_cv_dropkludge=no
 349 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 350 AC_ARG_ENABLE(dropkludge,
 351         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 352         if test "$enableval" = "yes"; then
 353                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 354                 AC_MSG_RESULT([yes])
 355                 netatalk_cv_dropkludge=yes
 356         else
 357                 AC_MSG_RESULT([no])
 358         fi
 359         ],[
 360                 AC_MSG_RESULT([no])
 361         ]
 362 )
 363
 364 netatalk_cv_force_uidgid=no
 365 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 366 AC_ARG_ENABLE(force-uidgid,
 367         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 368         if test "$enableval" = "yes"; then
 369                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 370                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 371                 AC_MSG_RESULT([yes])
 372                 netatalk_cv_force_uidgid=yes
 373         else
 374                 AC_MSG_RESULT([no])
 375         fi
 376         ],[
 377                 AC_MSG_RESULT([no])
 378         ]
 379 )
 380
 381 dnl Check for CNID database backends
 382 bdb_required=no
 383 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 384
 385 dnl Check for Berkeley DB library
 386 if test "x$bdb_required" = "xyes"; then
 387         AC_PATH_BDB(, [
 388                 AC_MSG_RESULT([])
 389                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 390                 AC_MSG_RESULT([You can download the latest version from http://www.sleepcat.com.])
 391                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 392                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option.])
 393                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 394         ])
 395 fi
 396
 397 dnl Check for quota support
 398 AC_CHECK_QUOTA
 399
 400 dnl Check for optional server location protocol support (used by MacOS X)
 401 NETATALK_SRVLOC
 402
 403 dnl Check for PAM libs
 404 netatalk_cv_use_pam=no
 405 AC_PATH_PAM([
 406         use_pam_so=yes
 407         compile_pam=yes
 408         netatalk_cv_use_pam=yes
 409         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 410 ])
 411
 412 netatalk_cv_use_shadowpw=no
 413 AC_ARG_WITH(shadow,
 414         [  --with-shadow           enable shadow password support [[auto]]],
 415         [netatalk_cv_use_shadowpw="$withval"],
 416         [netatalk_cv_use_shadowpw=auto]
 417 )
 418
 419 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 420     AC_CHECK_HEADER([shadow.h])
 421     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 422         netatalk_cv_use_shadowpw=yes
 423         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 424     else
 425       if test "x$shadowpw" = "xyes"; then
 426         AC_MSG_ERROR([shadow support not available])
 427       else
 428         netatalk_cv_use_shadowpw=no
 429       fi
 430     fi
 431 fi
 432
 433 AC_MSG_CHECKING([whether shadow support should be enabled])
 434 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 435         AC_MSG_RESULT([yes])
 436 else
 437         AC_MSG_RESULT([no])
 438 fi
 439
 440
 441
 442 netatalk_cv_use_shellcheck=yes
 443 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 444 AC_ARG_ENABLE(shell-check,
 445         [  --disable-shell-check   disable checking for a valid shell],[
 446         if test "$enableval" = "no"; then
 447                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 448                 AC_MSG_RESULT([no])
 449                 netatalk_cv_use_shellcheck=no
 450         else
 451                 AC_MSG_RESULT([yes])
 452         fi
 453         ],[
 454                 AC_MSG_RESULT([yes])
 455         ]
 456 )
 457
 458 NETATALK_TCP_WRAPPERS
 459
 460 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 461 AC_ARG_ENABLE(locking,
 462         [  --disable-locking       disable system locking],[
 463                 if test "$enableval" = "no"; then
 464                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 465                         AC_MSG_RESULT([yes])
 466                 else
 467                         AC_MSG_RESULT([no])
 468                 fi
 469
 470         ],[
 471                 AC_MSG_RESULT([no])
 472         ]
 473
 474 )
 475
 476
 477 AC_ARG_ENABLE(redhat,
 478         [  --enable-redhat         use redhat-style sysv configuration ],[
 479         if test "$enableval" = "yes"; then
 480                 sysv_style=redhat
 481         fi
 482         AC_MSG_RESULT([enabling redhat-style sysv support])
 483         ]
 484 )
 485
 486 AC_ARG_ENABLE(suse,
 487         [  --enable-suse           use suse-style sysv configuration ],[
 488         if test "$enableval" = "yes"; then
 489                 sysv_style=suse
 490         fi
 491         AC_MSG_RESULT([enabling suse-style sysv support])
 492         ]
 493 )
 494
 495 AC_ARG_ENABLE(gentoo,
 496         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 497         if test "$enableval" = "yes"; then
 498                 sysv_style=gentoo
 499         fi
 500         AC_MSG_RESULT([enabling gentoo-style sysv support])
 501         ]
 502 )
 503
 504 AC_ARG_ENABLE(cobalt,
 505         [  --enable-cobalt         use cobalt-style sysv configuration ],
 506         if test "$enableval" = "yes"; then
 507                 sysv_style=cobalt
 508         fi
 509         AC_MSG_RESULT([enabling cobalt-style sysv support])
 510 )
 511
 512 AC_ARG_ENABLE(netbsd,
 513         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 514         if test "x$enableval" = "xyes"; then
 515                 sysv_style=netbsd
 516         fi
 517         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 518 )
 519
 520 dnl ----- timelord compilation (disabled by default)
 521 AC_MSG_CHECKING([whether timelord should be compiled])
 522 compile_timelord=no
 523 AC_ARG_ENABLE(timelord,
 524         [  --enable-timelord       enable compilation of timelord server],
 525         [compile_timelord="$enableval"],
 526         [compile_timelord="no"]
 527 )
 528 AC_MSG_RESULT([$compile_timelord])
 529
 530 dnl ----- a2boot compilation (disabled by default)
 531 AC_MSG_CHECKING([whether a2boot should be compiled])
 532 compile_a2boot=no
 533 AC_ARG_ENABLE(a2boot,
 534         [  --enable-a2boot         enable compilation of Apple2 boot server],
 535         [compile_a2boot="$enableval"],
 536         [compile_a2boot="no"]
 537 )
 538 AC_MSG_RESULT([$compile_a2boot])
 539
 540 AC_ARG_WITH(uams-path,
 541         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 542                 uams_path="$withval"
 543         ],[
 544                 uams_path="${PKGCONFDIR}/uams"
 545         ]
 546 )
 547
 548 dnl --------------------------------------------------------------------------
 549 dnl FHS stuff has to be done last because it overrides other defaults
 550 dnl --------------------------------------------------------------------------
 551
 552 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 553 AC_ARG_ENABLE(fhs,
 554         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 555         if test "$enableval" = "yes"; then
 556                 uams_path="${libdir}/netatalk"
 557                 sysconfdir="/etc"
 558                 PKGCONFDIR=${sysconfdir}/netatalk
 559                 SERVERTEXT="${PKGCONFDIR}/msg"
 560                 use_pam_so=yes
 561                 mandir="/usr/share/man"
 562                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 563                 AC_MSG_RESULT([yes])
 564         else
 565                 AC_MSG_RESULT([no])
 566         fi
 567         ],[
 568                 AC_MSG_RESULT([no])
 569         ]
 570 )
 571
 572 dnl --------------------------------------------------------------------------
 573 dnl post-FHS substitutions, etc
 574 dnl --------------------------------------------------------------------------
 575
 576 dnl ***** UAMS_PATH
 577 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 578 dnl     [path to UAMs [default=PKGCONF/uams]])
 579 UAMS_PATH="${uams_path}"
 580 AC_SUBST(UAMS_PATH)
 581
 582 dnl --------------------------------------------------------------------------
 583 dnl drop in includes for top level directory structures here...
 584 dnl --------------------------------------------------------------------------
 585
 586 dnl Note: $(top_srcdir)/include should be added before all other includes
 587 dnl       so that includes from that directory a preferred to includes from
 588 dnl       /usr/include or similar places.
 589 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 590 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 591
 592 dnl --------------------------------------------------------------------------
 593 dnl specific configuration comes in here:
 594 dnl --------------------------------------------------------------------------
 595
 596 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 597
 598 dnl --------------------- determine operating system from "target"
 599 case "$host_os" in
 600         *aix*)                          this_os=aix ;;
 601         *freebsd*)                      this_os=freebsd ;;
 602         *hpux11*)                       this_os=hpux11 ;;
 603         *irix*)                         this_os=irix ;;
 604         *linux*)                        this_os=linux ;;
 605         *osx*)                          this_os=macosx ;;
 606         *darwin*)                       this_os=macosx ;;
 607         *netbsd*)                       this_os=netbsd ;;
 608         *openbsd*)                      this_os=openbsd ;;
 609         *osf*)                          this_os=tru64 ;;
 610         *solaris*)                      this_os=solaris ;;
 611 esac
 612
 613 case "$host_cpu" in
 614         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 615         alpha)                                          this_cpu=alpha ;;
 616         mips)                                           this_cpu=mips ;;
 617         powerpc|ppc)                            this_cpu=ppc ;;
 618 esac
 619
 620 dnl --------------------- operating system specific flags (port from sys/*)
 621
 622 dnl ----- AIX specific -----
 623 if test x"$this_os" = "xaix"; then
 624         AC_MSG_RESULT([ * AIX specific configuration])
 625         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 626
 627         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 628         dnl compilation environment.  It's enough to get things defined
 629         dnl right in endian.h provided that long long is supported, though.
 630         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 631 fi
 632
 633 dnl ----- FreeBSD specific -----
 634 if test x"$this_os" = "xfreebsd"; then
 635         AC_MSG_RESULT([ * FreeBSD specific configuration])
 636         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 637         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 638         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 639 fi
 640
 641 dnl ----- HP-UX 11 specific -----
 642 if test x"$this_os" = "xhpux11"; then
 643         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 644
 645         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 646         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 647 fi
 648
 649 dnl ----- IRIX specific -----
 650 if test x"$this_os" = "xirix"; then
 651         AC_MSG_RESULT([ * IRIX specific configuration])
 652
 653         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 654 fi
 655
 656 dnl ----- Linux specific -----
 657 if test x"$this_os" = "xlinux"; then
 658         AC_MSG_RESULT([ * Linux specific configuration])
 659
 660         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 661         AC_MSG_CHECKING([for struct atalk_addr])
 662 dnl     AC_COMPILE_IFELSE([
 663         AC_TRY_COMPILE([
 664 #include <sys/socket.h>
 665 #include <asm/types.h>
 666 #include <linux/atalk.h>
 667 ],
 668 [
 669 int main() {
 670         struct atalk_addr foo;
 671
 672         return 0;
 673 }
 674         ], [
 675                 ac_have_atalk_addr=yes
 676                 AC_MSG_RESULT([yes])
 677         ], [
 678                 AC_MSG_RESULT([no])
 679         ])
 680
 681 if test "x$ac_have_atalk_addr" = "xyes"; then
 682         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 683 fi
 684
 685         dnl ----- check if we need the quotactl wrapper
 686 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 687 #       AC_CHECK_FUNC(quotactl,,
 688 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 689 #               AC_MSG_RESULT([enabling quotactl wrapper])
 690 #       )
 691
 692         # For quotas on Linux XFS filesystems
 693         AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 694         AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)
 695         # For linux > 2.5.56
 696         AC_CHECK_HEADERS(linux/dqblk_xfs.h)
 697
 698
 699         dnl ----- as far as I can tell, dbtob always does the wrong thing
 700         dnl ----- on every single version of linux I've ever played with.
 701         dnl ----- see etc/afpd/quota.c
 702         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 703
 704         netatalk_cv_linux_sendfile=no
 705         AC_ARG_ENABLE(sendfile,
 706             [  --enable-sendfile       use sendfile syscall default (no) ],[
 707                 if test "$enableval" = "yes"; then
 708                         netatalk_cv_linux_sendfile=yes
 709                 fi
 710                 AC_MSG_RESULT([enabling sendfile syscall])
 711             ]
 712         )
 713
 714         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 715             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 716             AC_TRY_LINK([#include <sys/sendfile.h>],
 717 [\
 718 int tofd, fromfd;
 719 off_t offset;
 720 size_t total;
 721 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 722 ],
 723 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 724
 725 # Try and cope with broken Linux sendfile....
 726             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 727             AC_TRY_LINK([\
 728 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 729 #undef _FILE_OFFSET_BITS
 730 #endif
 731 #include <sys/sendfile.h>],
 732 [\
 733 int tofd, fromfd;
 734 off_t offset;
 735 size_t total;
 736 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 737 ],
 738 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 739
 740             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 741                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 742                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 743                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 744             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 745                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 746                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 747                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 748             else
 749                 netatalk_cv_linux_sendfile=no
 750                 AC_MSG_RESULT(no);
 751             fi
 752         fi
 753
 754         dnl ----- Linux/alpha specific -----
 755         if test x"$this_cpu" = "xalpha"; then
 756                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 757                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 758         fi
 759         need_dash_r=no
 760
 761
 762 fi
 763
 764 dnl ----- Mac OSX specific -----
 765 if test x"$this_os" = "xmacosx"; then
 766         AC_MSG_RESULT([ * Mac OSX specific configuration])
 767         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 768         AC_DEFINE(HAVE_BROKEN_CPP, 1, [Define if cpp is broken])
 769         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 770         dnl AC_DEFINE(NO_DLFCN_H)
 771         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 772         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 773         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 774 fi
 775
 776 dnl ----- NetBSD specific -----
 777 if test x"$this_os" = "xnetbsd"; then
 778         AC_MSG_RESULT([ * NetBSD specific configuration])
 779         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 780         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 781         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 782         need_dash_r=yes
 783
 784         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 785         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 786 fi
 787
 788 dnl ----- OpenBSD specific -----
 789 if test x"$this_os" = "xopenbsd"; then
 790         AC_MSG_RESULT([ * OpenBSD specific configuration])
 791         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 792         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 793 fi
 794
 795 dnl ----- Solaris specific -----
 796 if test x"$this_os" = "xsolaris"; then
 797         AC_MSG_RESULT([ * Solaris specific configuration])
 798         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 799         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 800         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 801         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 802         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 803         need_dash_r=yes
 804         sysv_style=solaris
 805
 806         solaris_module=no
 807         AC_MSG_CHECKING([if we can build Solaris kernel module])
 808         if test -x /usr/ccs/bin/ld; then
 809                 solaris_module=yes
 810         fi
 811         AC_MSG_RESULT([$solaris_module])
 812
 813         COMPILE_64BIT_KMODULE=no
 814         KCFLAGS=""
 815         KLDFLAGS=""
 816         COMPILE_KERNEL_GCC=no
 817
 818         if test "$solaris_module" = "yes"; then
 819            dnl Solaris kernel module stuff
 820            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 821
 822            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 823            if test -x /usr/bin/isainfo; then
 824                 # check for 64 bit platform
 825                 if isainfo -kv | grep '^64-bit'; then
 826                         COMPILE_64BIT_KMODULE=yes
 827                 fi
 828            fi
 829
 830            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 831
 832
 833            if test "${GCC}" = yes; then
 834                 COMPILE_KERNEL_GCC=yes
 835                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 836                         # use for 64 bit
 837                         KCFLAGS="-m64"
 838                         #KLDFLAGS="-melf64_sparc"
 839                         KLDFLAGS="-64"
 840                 else
 841                         KCFLAGS=""
 842                         KLDFLAGS=""
 843                 fi
 844                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 845            else
 846                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 847                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 848                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 849                         KLDFLAGS="-64"
 850                 else
 851                         KCFLAGS=""
 852                         KLDFLAGS=""
 853                 fi
 854                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 855            fi
 856
 857            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 858            AC_TRY_LINK([\
 859 #include <sys/stream.h>
 860 #include <sys/ddi.h>],
 861 [\
 862 timeout_id_t dummy;
 863 ],
 864 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 865
 866            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 867         fi
 868
 869         AC_SUBST(COMPILE_KERNEL_GCC)
 870         AC_SUBST(COMPILE_64BIT_KMODULE)
 871         AC_SUBST(KCFLAGS)
 872         AC_SUBST(KLDFLAGS)
 873 fi
 874
 875 dnl ----- Tru64 specific -----
 876 if test x"$this_os" = "xtru64"; then
 877         AC_MSG_RESULT([ * Tru64 specific configuration])
 878         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 879         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 880         dnl AC_DEFINE(USE_MOUNT_H)
 881         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 882         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 883         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 884         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 885         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 886         AC_CHECK_LIB(security,set_auth_parameters)
 887         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 888         need_dash_r=no
 889         sysv_style=tru64
 890 fi
 891
 892 dnl -- look for openssl
 893 AC_PATH_SSL
 894
 895 dnl -- check for crypt
 896 AC_CRYPT
 897
 898 dnl --------------------- check for building PGP UAM module
 899
 900 AC_MSG_CHECKING([whether the PGP UAM should be build])
 901 AC_ARG_ENABLE(pgp-uam,
 902         [  --enable-pgp-uam        enable build of PGP UAM module],[
 903         if test "$enableval" = "yes"; then
 904                 if test "$compile_ssl" = "yes"; then
 905                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 906                         compile_pgp=yes
 907                         AC_MSG_RESULT([yes])
 908                 else
 909                         AC_MSG_RESULT([no])
 910                 fi
 911         fi
 912         ],[
 913                 AC_MSG_RESULT([no])
 914         ]
 915 )
 916
 917 dnl --------------------- check for building Kerberos v4 UAM module
 918
 919 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 920 AC_ARG_ENABLE(krb4-uam,
 921         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 922         if test "$enableval" = "yes"; then
 923                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 924                 compile_kerberos=yes
 925                 AC_MSG_RESULT([yes])
 926         else
 927                 AC_MSG_RESULT([no])
 928         fi
 929         ],[
 930                 AC_MSG_RESULT([no])
 931         ]
 932 )
 933
 934 dnl --------------------- check for building Kerberos V UAM module
 935
 936 netatalk_cv_build_krb5_uam=no
 937 AC_ARG_ENABLE(krbV-uam,
 938         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 939         [
 940                 if test x"$enableval" = x"yes"; then
 941                         NETATALK_GSSAPI_CHECK([
 942                                 netatalk_cv_build_krb5_uam=yes
 943                         ],[
 944                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 945                         ])
 946                 fi
 947         ]
 948
 949 )
 950
 951 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 952 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 953         AC_MSG_RESULT([yes])
 954 else
 955         AC_MSG_RESULT([no])
 956 fi
 957 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 958
 959 dnl --------------------- overwrite the config files . . . or not.
 960
 961 AC_MSG_CHECKING([whether configuration files should be overwritten])
 962 AC_ARG_ENABLE(overwrite,
 963         [  --enable-overwrite      overwrite configuration files during installation],
 964         [OVERWRITE_CONFIG="${enable_overwrite}"],
 965         [OVERWRITE_CONFIG="no"]
 966 )
 967 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 968
 969 dnl --------------------- last minute substitutions
 970
 971 AC_SUBST(LIBS)
 972 AC_SUBST(CFLAGS)
 973 AC_SUBST(OVERWRITE_CONFIG)
 974
 975 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 976 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 977 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
 978 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 979 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 980 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 981 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
 982 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 983 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
 984 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 985 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
 986 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
 987 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
 988 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
 989 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
 990 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
 991 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
 992 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
 993
 994 dnl --------------------- generate files
 995
 996 AC_OUTPUT([Makefile
 997         bin/Makefile
 998         bin/adv1tov2/Makefile
 999         bin/aecho/Makefile
1000         bin/afile/Makefile
1001         bin/afppasswd/Makefile
1002         bin/cnid/Makefile
1003         bin/cnid/cnid_maint
1004         bin/cnid/cnid2_create
1005         bin/getzones/Makefile
1006         bin/megatron/Makefile
1007         bin/nbp/Makefile
1008         bin/pap/Makefile
1009         bin/psorder/Makefile
1010         bin/uniconv/Makefile
1011         config/Makefile
1012         contrib/Makefile
1013         contrib/macusers/Makefile
1014         contrib/macusers/macusers
1015         contrib/nu/Makefile
1016         contrib/nu/nu
1017         contrib/printing/Makefile
1018         contrib/shell_utils/Makefile
1019         contrib/shell_utils/afpd-mtab.pl
1020         contrib/shell_utils/apple_cp
1021         contrib/shell_utils/apple_mv
1022         contrib/shell_utils/apple_rm
1023         contrib/shell_utils/cleanappledouble.pl
1024         contrib/shell_utils/netatalkshorternamelinks.pl
1025         contrib/timelord/Makefile
1026         contrib/a2boot/Makefile
1027         distrib/Makefile
1028         distrib/config/Makefile
1029         distrib/config/netatalk-config
1030         distrib/initscripts/Makefile
1031         distrib/m4/Makefile
1032         doc/Makefile
1033         etc/Makefile
1034         etc/afpd/Makefile
1035         etc/atalkd/Makefile
1036         etc/cnid_dbd/Makefile
1037         etc/uams/Makefile
1038         etc/uams/uams_krb4/Makefile
1039         etc/papd/Makefile
1040         etc/psf/Makefile
1041         include/Makefile
1042         include/atalk/Makefile
1043         libatalk/Makefile
1044         libatalk/adouble/Makefile
1045         libatalk/asp/Makefile
1046         libatalk/atp/Makefile
1047         libatalk/cnid/Makefile
1048         libatalk/cnid/db3/Makefile
1049         libatalk/cnid/cdb/Makefile
1050         libatalk/cnid/last/Makefile
1051         libatalk/cnid/mtab/Makefile
1052         libatalk/cnid/dbd/Makefile
1053         libatalk/cnid/hash/Makefile
1054         libatalk/cnid/tdb/Makefile
1055         libatalk/compat/Makefile
1056         libatalk/dsi/Makefile
1057         libatalk/nbp/Makefile
1058         libatalk/netddp/Makefile
1059         libatalk/util/Makefile
1060         libatalk/tdb/Makefile
1061         libatalk/unicode/Makefile
1062         libatalk/unicode/charsets/Makefile
1063         macros/Makefile
1064         man/Makefile
1065         man/man1/Makefile
1066         man/man3/Makefile
1067         man/man4/Makefile
1068         man/man5/Makefile
1069         man/man8/Makefile
1070         sys/Makefile
1071         sys/generic/Makefile
1072         sys/generic/sys/Makefile
1073         sys/netatalk/Makefile
1074         sys/netbsd/Makefile
1075         sys/netbsd/netatalk/Makefile
1076         sys/solaris/Makefile
1077         sys/sunos/Makefile
1078         sys/ultrix/Makefile
1079         ],
1080         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1081 )
1082
1083 AC_NETATALK_LIBS_SUMMARY
1084 AC_NETATALK_CONFIG_SUMMARY
1085