configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.35 2004-08-11 02:33:47 bfernhomberg Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58 dnl Replace `main' with a function in -lnsl:
  59 AC_CHECK_LIB(nsl, main)
  60 dnl Replace `main' with a function in -lprot:
  61 dnl AC_CHECK_LIB(prot, main)
  62 dnl Replace `main' with a function in -lrx:
  63 dnl AC_CHECK_LIB(rx, main)
  64 dnl Replace `main' with a function in -lrxkad:
  65 dnl AC_CHECK_LIB(rxkad, main)
  66 dnl Replace `main' with a function in -lsocket:
  67 AC_CHECK_LIB(socket, socket)
  68 dnl Replace `main' with a function in -lsys:
  69 dnl AC_CHECK_LIB(sys, main)
  70 dnl Replace `main' with a function in -lubik:
  71 dnl AC_CHECK_LIB(ubik, main)
  72
  73
  74 #
  75 # Check presence of some functions
  76 #
  77 # Check for XPG4 access() function
  78 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  79 # has such a function that works only on AFS filesystems.
  80 AC_CHECK_FUNCS(access)
  81 #
  82 AC_CHECK_FUNCS(pread pwrite)
  83
  84 dnl Checks for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_STDC
  87 AC_HEADER_SYS_WAIT
  88 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  89 AC_CHECK_HEADER(sys/cdefs.h,,
  90         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  91         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  92 )
  93 AC_CHECK_HEADERS([sys/mount.h], , ,
  94 [#ifdef HAVE_SYS_PARAM_H
  95 #include <sys/param.h>
  96 #endif
  97 ])
  98
  99 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 100
 101 dnl Checks for typedefs, structures, and compiler characteristics.
 102 AC_C_CONST
 103 AC_TYPE_UID_T
 104 AC_C_INLINE
 105 AC_TYPE_MODE_T
 106 AC_TYPE_OFF_T
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_STRUCT_ST_RDEV
 110 AC_HEADER_TIME
 111 AC_STRUCT_TM
 112
 113 dnl --------------------------------------------------------------------------
 114 dnl check if dlsym needs to add an underscore, uses libtool macros
 115 dnl --------------------------------------------------------------------------
 116 AC_LTDL_DLLIB
 117 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 118 AC_LTDL_DLSYM_USCORE
 119 if test x"$libltdl_cv_need_uscore" = xyes; then
 120     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 121 fi
 122
 123
 124 dnl Checks for library functions.
 125 AC_TYPE_GETGROUPS
 126 AC_PROG_GCC_TRADITIONAL
 127 AC_FUNC_MEMCMP
 128 AC_HEADER_MAJOR
 129 AC_FUNC_MMAP
 130 AC_TYPE_SIGNAL
 131 AC_FUNC_UTIME_NULL
 132 AC_FUNC_WAIT3
 133 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul setpgrp strchr memcpy)
 134 AC_FUNC_SETPGRP
 135 AC_CHECK_FUNCS(backtrace_symbols)
 136 AC_CHECK_FUNCS(setlocale nl_langinfo)
 137 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 138 AC_CHECK_FUNCS(strlcpy strlcat)
 139 AC_CHECK_FUNCS(setlinebuf)
 140 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 141 AC_CACHE_SAVE
 142
 143 dnl Checks for (v)snprintf
 144 NETATALK_SNPRINTF_CHECK
 145
 146 dnl --------------------------------------------------------------------------
 147 dnl 64bit platform check
 148 dnl --------------------------------------------------------------------------
 149
 150 AC_MSG_CHECKING([whether to check for 64bit libraries])
 151 dnl Determine libdir name
 152 case $host in
 153 *-*-linux*)
 154   # Test if the compiler is 64bit
 155   echo 'int i;' > conftest.$ac_ext
 156   atalk_cv_cc_64bit_output=no
 157   if AC_TRY_EVAL(ac_compile); then
 158     case `/usr/bin/file conftest.$ac_objext` in
 159     *"ELF 64"*)
 160       atalk_cv_cc_64bit_output=yes
 161       ;;
 162     esac
 163   fi
 164   rm -rf conftest*
 165   ;;
 166 esac
 167
 168 dnl
 169 dnl FIXME: Do we need something like this for Solaris 64bit?
 170 dnl
 171
 172 case $host_cpu:$atalk_cv_cc_64bit_output in
 173 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 174   atalk_libname="lib64"
 175   AC_MSG_RESULT([yes])
 176   ;;
 177 *:*)
 178   atalk_libname="lib"
 179   AC_MSG_RESULT([no])
 180   ;;
 181 esac
 182
 183 dnl --------------------------------------------------------------------------
 184 dnl specific configuration comes in here:
 185 dnl --------------------------------------------------------------------------
 186
 187 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 188
 189 netatalk_cv_admin_group=yes
 190 AC_MSG_CHECKING([for administrative group support])
 191 AC_ARG_WITH(admin-group,
 192         [  --disable-admin-group   disable admin group],[
 193         if test "$enableval" = "no"; then
 194                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 195                 AC_MSG_RESULT([yes])
 196         else
 197                 AC_MSG_RESULT([no])
 198                 netatalk_cv_admin_group=no
 199         fi],[
 200                 AC_MSG_RESULT([yes])
 201         ]
 202 )
 203
 204 NETATALK_AFS_CHECK
 205
 206 NETATALK_CONFIG_DIRS
 207
 208 AC_MSG_CHECKING([for logfile path])
 209 AC_ARG_WITH(logfile,
 210         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 211                           use --without-logfile to disable logger],[
 212         if test x"$withval" = x"no"; then
 213                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 214                 AC_MSG_RESULT([syslog])
 215         elif test "$withval" != "yes"; then
 216                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 217                 AC_MSG_RESULT([$withval])
 218         else
 219                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 220                 AC_MSG_RESULT([/var/log/netatalk.log])
 221         fi],[
 222                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 223                 AC_MSG_RESULT([/var/log/netatalk.log])
 224         ]
 225 )
 226
 227
 228 netatalk_cv_with_cracklib=no
 229 AC_ARG_WITH(cracklib,
 230         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 231         if test "x$withval" != "xno" ; then
 232                 cracklib="$withval"
 233                 AC_CHECK_LIB(crack, main, [
 234                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 235                         LIBS="$LIBS -lcrack"
 236                         if test "$cracklib" = "yes"; then
 237                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 238                         fi
 239                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 240                                 [path to cracklib dictionary])
 241                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 242                         netatalk_cv_with_cracklib=yes
 243                         ],[
 244                         AC_MSG_ERROR([cracklib not found!])
 245                         ]
 246                 )
 247         fi
 248         ]
 249 )
 250 AC_MSG_CHECKING([for cracklib support])
 251 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 252
 253 netatalk_cv_ddp_enabled=yes
 254 AC_MSG_CHECKING([whether to enable DDP])
 255 AC_ARG_ENABLE(ddp,
 256         [  --disable-ddp           disable DDP],[
 257         if test "$enableval" = "no"; then
 258                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 259                 AC_MSG_RESULT([no])
 260                 netatalk_cv_ddp_enabled=no
 261         else
 262                 AC_MSG_RESULT([yes])
 263         fi
 264         ],[
 265                 AC_MSG_RESULT([yes])
 266         ]
 267 )
 268
 269 AC_MSG_CHECKING([whether to enable debug code])
 270 AC_ARG_ENABLE(debug1,
 271         [  --enable-debug1         enable debug code],[
 272         if test "$enableval" != "no"; then
 273                 if test "$enableval" = "yes"; then
 274                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 275                 else
 276                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 277                 fi
 278                 AC_MSG_RESULT([yes])
 279         else
 280                 AC_MSG_RESULT([no])
 281         fi
 282         ],[
 283                 AC_MSG_RESULT([no])
 284         ]
 285 )
 286
 287 AC_MSG_CHECKING([whether to enable verbose debug code])
 288 AC_ARG_ENABLE(debug,
 289         [  --enable-debug          enable verbose debug code],[
 290         if test "$enableval" != "no"; then
 291                 if test "$enableval" = "yes"; then
 292                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 293                 else
 294                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 295                 fi
 296                 AC_MSG_RESULT([yes])
 297         else
 298                 AC_MSG_RESULT([no])
 299         fi
 300         ],[
 301                 AC_MSG_RESULT([no])
 302         ]
 303 )
 304
 305 afp3=no
 306 afp3set=no
 307 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 308 AC_ARG_ENABLE(afp3,
 309         [  --disable-afp3          disable AFP 3.x calls],
 310         [
 311             if test x"$enableval" != x"no"; then
 312                 afp3set=yes
 313                 afp3=yes
 314                 AC_MSG_RESULT([yes])
 315             else
 316                 AC_MSG_RESULT([no])
 317             fi
 318         ],[
 319             AC_MSG_RESULT([yes])
 320             afp3=yes
 321         ]
 322 )
 323
 324 if test x"$afp3" = x"yes"; then
 325         AC_SYS_LARGEFILE([
 326                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 327         ],[
 328                 if test x"$afp3set" = x"yes"; then
 329                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 330                 else
 331                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 332                         afp3=no
 333                 fi
 334         ])
 335 fi
 336
 337 AC_CHECK_ICONV
 338
 339 dnl ----------- A NOTE ABOUT DROPKLUDGE
 340 dnl The trouble with this fix is that if you know what the file is called, it
 341 dnl can be read from the Unix side.  That's okay for most academic institutions
 342 dnl since the students don't have telnet access to the Mac servers.  There is
 343 dnl currently no one working on further development/fixes of DROPKLUDGE.
 344 dnl -----------
 345
 346 netatalk_cv_dropkludge=no
 347 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 348 AC_ARG_ENABLE(dropkludge,
 349         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 350         if test "$enableval" = "yes"; then
 351                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 352                 AC_MSG_RESULT([yes])
 353                 netatalk_cv_dropkludge=yes
 354         else
 355                 AC_MSG_RESULT([no])
 356         fi
 357         ],[
 358                 AC_MSG_RESULT([no])
 359         ]
 360 )
 361
 362 netatalk_cv_force_uidgid=no
 363 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 364 AC_ARG_ENABLE(force-uidgid,
 365         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 366         if test "$enableval" = "yes"; then
 367                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 368                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 369                 AC_MSG_RESULT([yes])
 370                 netatalk_cv_force_uidgid=yes
 371         else
 372                 AC_MSG_RESULT([no])
 373         fi
 374         ],[
 375                 AC_MSG_RESULT([no])
 376         ]
 377 )
 378
 379 dnl Check for CNID database backends
 380 bdb_required=no
 381 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 382
 383 dnl Check for Berkeley DB library
 384 if test "x$bdb_required" = "xyes"; then
 385         AC_PATH_BDB(, [
 386                 AC_MSG_RESULT([])
 387                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 388                 AC_MSG_RESULT([You can download the latest version from http://www.sleepycat.com.])
 389                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 390                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option and make sure])
 391                 AC_MSG_RESULT([your linker is configured to check for libraries there.])
 392                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 393         ])
 394 fi
 395
 396 dnl Check for quota support
 397 AC_CHECK_QUOTA
 398
 399 dnl Check for optional server location protocol support (used by MacOS X)
 400 NETATALK_SRVLOC
 401
 402 dnl Check for PAM libs
 403 netatalk_cv_use_pam=no
 404 AC_PATH_PAM([
 405         use_pam_so=yes
 406         compile_pam=yes
 407         netatalk_cv_use_pam=yes
 408         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 409 ])
 410
 411 netatalk_cv_use_shadowpw=no
 412 AC_ARG_WITH(shadow,
 413         [  --with-shadow           enable shadow password support [[auto]]],
 414         [netatalk_cv_use_shadowpw="$withval"],
 415         [netatalk_cv_use_shadowpw=auto]
 416 )
 417
 418 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 419     AC_CHECK_HEADER([shadow.h])
 420     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 421         netatalk_cv_use_shadowpw=yes
 422         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 423     else
 424       if test "x$shadowpw" = "xyes"; then
 425         AC_MSG_ERROR([shadow support not available])
 426       else
 427         netatalk_cv_use_shadowpw=no
 428       fi
 429     fi
 430 fi
 431
 432 AC_MSG_CHECKING([whether shadow support should be enabled])
 433 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 434         AC_MSG_RESULT([yes])
 435 else
 436         AC_MSG_RESULT([no])
 437 fi
 438
 439
 440
 441 netatalk_cv_use_shellcheck=yes
 442 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 443 AC_ARG_ENABLE(shell-check,
 444         [  --disable-shell-check   disable checking for a valid shell],[
 445         if test "$enableval" = "no"; then
 446                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 447                 AC_MSG_RESULT([no])
 448                 netatalk_cv_use_shellcheck=no
 449         else
 450                 AC_MSG_RESULT([yes])
 451         fi
 452         ],[
 453                 AC_MSG_RESULT([yes])
 454         ]
 455 )
 456
 457 NETATALK_TCP_WRAPPERS
 458
 459 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 460 AC_ARG_ENABLE(locking,
 461         [  --disable-locking       disable system locking],[
 462                 if test "$enableval" = "no"; then
 463                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 464                         AC_MSG_RESULT([yes])
 465                 else
 466                         AC_MSG_RESULT([no])
 467                 fi
 468
 469         ],[
 470                 AC_MSG_RESULT([no])
 471         ]
 472
 473 )
 474
 475
 476 AC_ARG_ENABLE(redhat,
 477         [  --enable-redhat         use redhat-style sysv configuration ],[
 478         if test "$enableval" = "yes"; then
 479                 sysv_style=redhat
 480         fi
 481         AC_MSG_RESULT([enabling redhat-style sysv support])
 482         ]
 483 )
 484
 485 AC_ARG_ENABLE(suse,
 486         [  --enable-suse           use suse-style sysv configuration ],[
 487         if test "$enableval" = "yes"; then
 488                 sysv_style=suse
 489         fi
 490         AC_MSG_RESULT([enabling suse-style sysv support])
 491         ]
 492 )
 493
 494 AC_ARG_ENABLE(gentoo,
 495         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 496         if test "$enableval" = "yes"; then
 497                 sysv_style=gentoo
 498         fi
 499         AC_MSG_RESULT([enabling gentoo-style sysv support])
 500         ]
 501 )
 502
 503 AC_ARG_ENABLE(cobalt,
 504         [  --enable-cobalt         use cobalt-style sysv configuration ],
 505         if test "$enableval" = "yes"; then
 506                 sysv_style=cobalt
 507         fi
 508         AC_MSG_RESULT([enabling cobalt-style sysv support])
 509 )
 510
 511 AC_ARG_ENABLE(netbsd,
 512         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 513         if test "x$enableval" = "xyes"; then
 514                 sysv_style=netbsd
 515         fi
 516         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 517 )
 518
 519 dnl ----- timelord compilation (disabled by default)
 520 AC_MSG_CHECKING([whether timelord should be compiled])
 521 compile_timelord=no
 522 AC_ARG_ENABLE(timelord,
 523         [  --enable-timelord       enable compilation of timelord server],
 524         [compile_timelord="$enableval"],
 525         [compile_timelord="no"]
 526 )
 527 AC_MSG_RESULT([$compile_timelord])
 528
 529 dnl ----- a2boot compilation (disabled by default)
 530 AC_MSG_CHECKING([whether a2boot should be compiled])
 531 compile_a2boot=no
 532 AC_ARG_ENABLE(a2boot,
 533         [  --enable-a2boot         enable compilation of Apple2 boot server],
 534         [compile_a2boot="$enableval"],
 535         [compile_a2boot="no"]
 536 )
 537 AC_MSG_RESULT([$compile_a2boot])
 538
 539 AC_ARG_WITH(uams-path,
 540         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 541                 uams_path="$withval"
 542         ],[
 543                 uams_path="${PKGCONFDIR}/uams"
 544         ]
 545 )
 546
 547 NETATALK_AC_CUPS
 548
 549 dnl --------------------------------------------------------------------------
 550 dnl FHS stuff has to be done last because it overrides other defaults
 551 dnl --------------------------------------------------------------------------
 552
 553 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 554 AC_ARG_ENABLE(fhs,
 555         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 556         if test "$enableval" = "yes"; then
 557                 uams_path="${libdir}/netatalk"
 558                 sysconfdir="/etc"
 559                 PKGCONFDIR=${sysconfdir}/netatalk
 560                 SERVERTEXT="${PKGCONFDIR}/msg"
 561                 use_pam_so=yes
 562                 mandir="/usr/share/man"
 563                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 564                 AC_MSG_RESULT([yes])
 565         else
 566                 AC_MSG_RESULT([no])
 567         fi
 568         ],[
 569                 AC_MSG_RESULT([no])
 570         ]
 571 )
 572
 573 dnl --------------------------------------------------------------------------
 574 dnl post-FHS substitutions, etc
 575 dnl --------------------------------------------------------------------------
 576
 577 dnl ***** UAMS_PATH
 578 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 579 dnl     [path to UAMs [default=PKGCONF/uams]])
 580 UAMS_PATH="${uams_path}"
 581 AC_SUBST(UAMS_PATH)
 582
 583 dnl --------------------------------------------------------------------------
 584 dnl drop in includes for top level directory structures here...
 585 dnl --------------------------------------------------------------------------
 586
 587 dnl Note: $(top_srcdir)/include should be added before all other includes
 588 dnl       so that includes from that directory a preferred to includes from
 589 dnl       /usr/include or similar places.
 590 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 591 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 592
 593 dnl --------------------------------------------------------------------------
 594 dnl specific configuration comes in here:
 595 dnl --------------------------------------------------------------------------
 596
 597 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 598
 599 dnl --------------------- determine operating system from "target"
 600 case "$host_os" in
 601         *aix*)                          this_os=aix ;;
 602         *freebsd*)                      this_os=freebsd ;;
 603         *hpux11*)                       this_os=hpux11 ;;
 604         *irix*)                         this_os=irix ;;
 605         *linux*)                        this_os=linux ;;
 606         *osx*)                          this_os=macosx ;;
 607         *darwin*)                       this_os=macosx ;;
 608         *netbsd*)                       this_os=netbsd ;;
 609         *openbsd*)                      this_os=openbsd ;;
 610         *osf*)                          this_os=tru64 ;;
 611         *solaris*)                      this_os=solaris ;;
 612 esac
 613
 614 case "$host_cpu" in
 615         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 616         alpha)                                          this_cpu=alpha ;;
 617         mips)                                           this_cpu=mips ;;
 618         powerpc|ppc)                            this_cpu=ppc ;;
 619 esac
 620
 621 dnl --------------------- operating system specific flags (port from sys/*)
 622
 623 dnl ----- AIX specific -----
 624 if test x"$this_os" = "xaix"; then
 625         AC_MSG_RESULT([ * AIX specific configuration])
 626         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 627
 628         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 629         dnl compilation environment.  It's enough to get things defined
 630         dnl right in endian.h provided that long long is supported, though.
 631         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 632 fi
 633
 634 dnl ----- FreeBSD specific -----
 635 if test x"$this_os" = "xfreebsd"; then
 636         AC_MSG_RESULT([ * FreeBSD specific configuration])
 637         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 638         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 639         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 640 fi
 641
 642 dnl ----- HP-UX 11 specific -----
 643 if test x"$this_os" = "xhpux11"; then
 644         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 645
 646         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 647         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 648 fi
 649
 650 dnl ----- IRIX specific -----
 651 if test x"$this_os" = "xirix"; then
 652         AC_MSG_RESULT([ * IRIX specific configuration])
 653
 654         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 655 fi
 656
 657 dnl ----- Linux specific -----
 658 if test x"$this_os" = "xlinux"; then
 659         AC_MSG_RESULT([ * Linux specific configuration])
 660
 661         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 662         AC_MSG_CHECKING([for struct atalk_addr])
 663 dnl     AC_COMPILE_IFELSE([
 664         AC_TRY_COMPILE([
 665 #include <sys/socket.h>
 666 #include <asm/types.h>
 667 #include <linux/atalk.h>
 668 ],
 669 [
 670 int main() {
 671         struct atalk_addr foo;
 672
 673         return 0;
 674 }
 675         ], [
 676                 ac_have_atalk_addr=yes
 677                 AC_MSG_RESULT([yes])
 678         ], [
 679                 AC_MSG_RESULT([no])
 680         ])
 681
 682 if test "x$ac_have_atalk_addr" = "xyes"; then
 683         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 684 fi
 685
 686         dnl ----- check if we need the quotactl wrapper
 687 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 688 #       AC_CHECK_FUNC(quotactl,,
 689 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 690 #               AC_MSG_RESULT([enabling quotactl wrapper])
 691 #       )
 692
 693         # For quotas on Linux XFS filesystems
 694         AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 695         AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)
 696         # For linux > 2.5.56
 697         AC_CHECK_HEADERS(linux/dqblk_xfs.h)
 698
 699
 700         dnl ----- as far as I can tell, dbtob always does the wrong thing
 701         dnl ----- on every single version of linux I've ever played with.
 702         dnl ----- see etc/afpd/quota.c
 703         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 704
 705         netatalk_cv_linux_sendfile=no
 706 dnl     disable this for now, code doesn't use sendfile anyway
 707 dnl        AC_ARG_ENABLE(sendfile,
 708 dnl         [  --enable-sendfile       use sendfile syscall default (no) ],[
 709 dnl             if test "$enableval" = "yes"; then
 710 dnl                     netatalk_cv_linux_sendfile=yes
 711 dnl             fi
 712 dnl             AC_MSG_RESULT([enabling sendfile syscall])
 713 dnl         ]
 714 dnl       )
 715
 716         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 717             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 718             AC_TRY_LINK([#include <sys/sendfile.h>],
 719 [\
 720 int tofd, fromfd;
 721 off_t offset;
 722 size_t total;
 723 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 724 ],
 725 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 726
 727 # Try and cope with broken Linux sendfile....
 728             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 729             AC_TRY_LINK([\
 730 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 731 #undef _FILE_OFFSET_BITS
 732 #endif
 733 #include <sys/sendfile.h>],
 734 [\
 735 int tofd, fromfd;
 736 off_t offset;
 737 size_t total;
 738 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 739 ],
 740 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 741
 742             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 743                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 744                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 745                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 746             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 747                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 748                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 749                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 750             else
 751                 netatalk_cv_linux_sendfile=no
 752                 AC_MSG_RESULT(no);
 753             fi
 754         fi
 755
 756         dnl ----- Linux/alpha specific -----
 757         if test x"$this_cpu" = "xalpha"; then
 758                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 759                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 760         fi
 761         need_dash_r=no
 762
 763
 764 fi
 765
 766 dnl ----- Mac OSX specific -----
 767 if test x"$this_os" = "xmacosx"; then
 768         AC_MSG_RESULT([ * Mac OSX specific configuration])
 769         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 770         AC_DEFINE(HAVE_BROKEN_CPP, 1, [Define if cpp is broken])
 771         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 772         dnl AC_DEFINE(NO_DLFCN_H)
 773         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 774         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 775         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 776 fi
 777
 778 dnl ----- NetBSD specific -----
 779 if test x"$this_os" = "xnetbsd"; then
 780         AC_MSG_RESULT([ * NetBSD specific configuration])
 781         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 782         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 783         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 784         need_dash_r=yes
 785
 786         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 787         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 788 fi
 789
 790 dnl ----- OpenBSD specific -----
 791 if test x"$this_os" = "xopenbsd"; then
 792         AC_MSG_RESULT([ * OpenBSD specific configuration])
 793         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 794         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 795 fi
 796
 797 dnl ----- Solaris specific -----
 798 if test x"$this_os" = "xsolaris"; then
 799         AC_MSG_RESULT([ * Solaris specific configuration])
 800         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 801         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 802         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 803         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 804         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 805         need_dash_r=yes
 806         sysv_style=solaris
 807
 808         solaris_module=no
 809         AC_MSG_CHECKING([if we can build Solaris kernel module])
 810         if test -x /usr/ccs/bin/ld; then
 811                 solaris_module=yes
 812         fi
 813         AC_MSG_RESULT([$solaris_module])
 814
 815         COMPILE_64BIT_KMODULE=no
 816         KCFLAGS=""
 817         KLDFLAGS=""
 818         COMPILE_KERNEL_GCC=no
 819
 820         if test "$solaris_module" = "yes"; then
 821            dnl Solaris kernel module stuff
 822            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 823
 824            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 825            if test -x /usr/bin/isainfo; then
 826                 # check for 64 bit platform
 827                 if isainfo -kv | grep '^64-bit'; then
 828                         COMPILE_64BIT_KMODULE=yes
 829                 fi
 830            fi
 831
 832            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 833
 834            if test "${GCC}" = yes; then
 835                 COMPILE_KERNEL_GCC=yes
 836                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 837
 838                         AC_MSG_CHECKING([if we can build a 64bit kernel module])
 839
 840                         case `$CC --version 2>/dev/null` in
 841                         [[12]].* | 3.0.*)
 842                                 COMPILE_64BIT_KMODULE=no
 843                                 COMPILE_KERNEL_GCC=no
 844                                 solaris_module=no;;
 845                         *)
 846                                 # use for 64 bit
 847                                 KCFLAGS="-m64"
 848                                 #KLDFLAGS="-melf64_sparc"
 849                                 KLDFLAGS="-64";;
 850                         esac
 851
 852                         AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 853
 854                 else
 855                         KCFLAGS=""
 856                         KLDFLAGS=""
 857                 fi
 858                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 859            else
 860                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 861                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 862                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 863                         KLDFLAGS="-64"
 864                 else
 865                         KCFLAGS=""
 866                         KLDFLAGS=""
 867                 fi
 868                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 869            fi
 870
 871            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 872            AC_TRY_LINK([\
 873 #include <sys/stream.h>
 874 #include <sys/ddi.h>],
 875 [\
 876 timeout_id_t dummy;
 877 ],
 878 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 879
 880            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 881         fi
 882
 883         AC_SUBST(COMPILE_KERNEL_GCC)
 884         AC_SUBST(COMPILE_64BIT_KMODULE)
 885         AC_SUBST(KCFLAGS)
 886         AC_SUBST(KLDFLAGS)
 887 fi
 888
 889 dnl ----- Tru64 specific -----
 890 if test x"$this_os" = "xtru64"; then
 891         AC_MSG_RESULT([ * Tru64 specific configuration])
 892         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 893         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 894         dnl AC_DEFINE(USE_MOUNT_H)
 895         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 896         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 897         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 898         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 899         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 900         AC_CHECK_LIB(security,set_auth_parameters)
 901         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 902         need_dash_r=no
 903         sysv_style=tru64
 904 fi
 905
 906 dnl -- look for openssl
 907 AC_PATH_SSL
 908
 909 dnl -- check for crypt
 910 AC_CRYPT
 911
 912 dnl --------------------- check for building PGP UAM module
 913
 914 AC_MSG_CHECKING([whether the PGP UAM should be build])
 915 AC_ARG_ENABLE(pgp-uam,
 916         [  --enable-pgp-uam        enable build of PGP UAM module],[
 917         if test "$enableval" = "yes"; then
 918                 if test "$compile_ssl" = "yes"; then
 919                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 920                         compile_pgp=yes
 921                         AC_MSG_RESULT([yes])
 922                 else
 923                         AC_MSG_RESULT([no])
 924                 fi
 925         fi
 926         ],[
 927                 AC_MSG_RESULT([no])
 928         ]
 929 )
 930
 931 dnl --------------------- check for building Kerberos v4 UAM module
 932
 933 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 934 AC_ARG_ENABLE(krb4-uam,
 935         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 936         if test "$enableval" = "yes"; then
 937                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 938                 compile_kerberos=yes
 939                 AC_MSG_RESULT([yes])
 940         else
 941                 AC_MSG_RESULT([no])
 942         fi
 943         ],[
 944                 AC_MSG_RESULT([no])
 945         ]
 946 )
 947
 948 dnl --------------------- check for building Kerberos V UAM module
 949
 950 netatalk_cv_build_krb5_uam=no
 951 AC_ARG_ENABLE(krbV-uam,
 952         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 953         [
 954                 if test x"$enableval" = x"yes"; then
 955                         NETATALK_GSSAPI_CHECK([
 956                                 netatalk_cv_build_krb5_uam=yes
 957                         ],[
 958                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 959                         ])
 960                 fi
 961         ]
 962
 963 )
 964
 965 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 966 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 967         AC_MSG_RESULT([yes])
 968 else
 969         AC_MSG_RESULT([no])
 970 fi
 971 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 972
 973 dnl --------------------- overwrite the config files . . . or not.
 974
 975 AC_MSG_CHECKING([whether configuration files should be overwritten])
 976 AC_ARG_ENABLE(overwrite,
 977         [  --enable-overwrite      overwrite configuration files during installation],
 978         [OVERWRITE_CONFIG="${enable_overwrite}"],
 979         [OVERWRITE_CONFIG="no"]
 980 )
 981 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 982
 983 dnl --------------------- last minute substitutions
 984
 985 AC_SUBST(LIBS)
 986 AC_SUBST(CFLAGS)
 987 AC_SUBST(OVERWRITE_CONFIG)
 988
 989 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 990 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 991 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
 992 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 993 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 994 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 995 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
 996 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 997 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
 998 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 999 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
1000 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
1001 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
1002 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
1003 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
1004 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
1005 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
1006 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
1007
1008 dnl --------------------- generate files
1009
1010 AC_OUTPUT([Makefile
1011         bin/Makefile
1012         bin/adv1tov2/Makefile
1013         bin/aecho/Makefile
1014         bin/afile/Makefile
1015         bin/afppasswd/Makefile
1016         bin/cnid/Makefile
1017         bin/cnid/cnid_maint
1018         bin/cnid/cnid2_create
1019         bin/getzones/Makefile
1020         bin/megatron/Makefile
1021         bin/nbp/Makefile
1022         bin/pap/Makefile
1023         bin/psorder/Makefile
1024         bin/uniconv/Makefile
1025         config/Makefile
1026         contrib/Makefile
1027         contrib/macusers/Makefile
1028         contrib/macusers/macusers
1029         contrib/nu/Makefile
1030         contrib/nu/nu
1031         contrib/printing/Makefile
1032         contrib/shell_utils/Makefile
1033         contrib/shell_utils/afpd-mtab.pl
1034         contrib/shell_utils/apple_cp
1035         contrib/shell_utils/apple_mv
1036         contrib/shell_utils/apple_rm
1037         contrib/shell_utils/asip-status.pl
1038         contrib/shell_utils/cleanappledouble.pl
1039         contrib/shell_utils/netatalkshorternamelinks.pl
1040         contrib/timelord/Makefile
1041         contrib/a2boot/Makefile
1042         distrib/Makefile
1043         distrib/config/Makefile
1044         distrib/config/netatalk-config
1045         distrib/initscripts/Makefile
1046         distrib/m4/Makefile
1047         doc/Makefile
1048         etc/Makefile
1049         etc/afpd/Makefile
1050         etc/atalkd/Makefile
1051         etc/cnid_dbd/Makefile
1052         etc/uams/Makefile
1053         etc/uams/uams_krb4/Makefile
1054         etc/papd/Makefile
1055         etc/psf/Makefile
1056         include/Makefile
1057         include/atalk/Makefile
1058         libatalk/Makefile
1059         libatalk/adouble/Makefile
1060         libatalk/asp/Makefile
1061         libatalk/atp/Makefile
1062         libatalk/cnid/Makefile
1063         libatalk/cnid/db3/Makefile
1064         libatalk/cnid/cdb/Makefile
1065         libatalk/cnid/last/Makefile
1066         libatalk/cnid/mtab/Makefile
1067         libatalk/cnid/dbd/Makefile
1068         libatalk/cnid/hash/Makefile
1069         libatalk/cnid/tdb/Makefile
1070         libatalk/compat/Makefile
1071         libatalk/dsi/Makefile
1072         libatalk/nbp/Makefile
1073         libatalk/netddp/Makefile
1074         libatalk/util/Makefile
1075         libatalk/tdb/Makefile
1076         libatalk/unicode/Makefile
1077         libatalk/unicode/charsets/Makefile
1078         macros/Makefile
1079         man/Makefile
1080         man/man1/Makefile
1081         man/man3/Makefile
1082         man/man4/Makefile
1083         man/man5/Makefile
1084         man/man8/Makefile
1085         sys/Makefile
1086         sys/generic/Makefile
1087         sys/generic/sys/Makefile
1088         sys/netatalk/Makefile
1089         sys/netbsd/Makefile
1090         sys/netbsd/netatalk/Makefile
1091         sys/solaris/Makefile
1092         sys/sunos/Makefile
1093         sys/ultrix/Makefile
1094         ],
1095         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1096 )
1097
1098 AC_NETATALK_LIBS_SUMMARY
1099 AC_NETATALK_CONFIG_SUMMARY
1100