configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.22 2004-02-29 17:38:03 bfernhomberg Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58 dnl Replace `main' with a function in -lnsl:
  59 AC_CHECK_LIB(nsl, main)
  60 dnl Replace `main' with a function in -lprot:
  61 dnl AC_CHECK_LIB(prot, main)
  62 dnl Replace `main' with a function in -lrx:
  63 dnl AC_CHECK_LIB(rx, main)
  64 dnl Replace `main' with a function in -lrxkad:
  65 dnl AC_CHECK_LIB(rxkad, main)
  66 dnl Replace `main' with a function in -lsocket:
  67 AC_CHECK_LIB(socket, socket)
  68 dnl Replace `main' with a function in -lsys:
  69 dnl AC_CHECK_LIB(sys, main)
  70 dnl Replace `main' with a function in -lubik:
  71 dnl AC_CHECK_LIB(ubik, main)
  72
  73
  74 #
  75 # Check presence of some functions
  76 #
  77 # Check for XPG4 access() function
  78 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  79 # has such a function that works only on AFS filesystems.
  80 AC_CHECK_FUNCS(access)
  81 #
  82 AC_CHECK_FUNCS(pread pwrite)
  83
  84 dnl Checks for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_STDC
  87 AC_HEADER_SYS_WAIT
  88 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h sys/mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  89 AC_CHECK_HEADER(sys/cdefs.h,,
  90         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  91         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  92 )
  93 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
  94
  95 dnl Checks for typedefs, structures, and compiler characteristics.
  96 AC_C_CONST
  97 AC_TYPE_UID_T
  98 AC_C_INLINE
  99 AC_TYPE_MODE_T
 100 AC_TYPE_OFF_T
 101 AC_TYPE_PID_T
 102 AC_TYPE_SIZE_T
 103 AC_STRUCT_ST_RDEV
 104 AC_HEADER_TIME
 105 AC_STRUCT_TM
 106
 107 dnl Checks for library functions.
 108 AC_TYPE_GETGROUPS
 109 AC_PROG_GCC_TRADITIONAL
 110 AC_FUNC_MEMCMP
 111 AC_HEADER_MAJOR
 112 AC_FUNC_MMAP
 113 AC_TYPE_SIGNAL
 114 AC_FUNC_UTIME_NULL
 115 AC_FUNC_WAIT3
 116 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul setpgrp strchr memcpy)
 117 AC_FUNC_SETPGRP
 118 AC_CHECK_FUNCS(backtrace_symbols)
 119 AC_CHECK_FUNCS(setlocale nl_langinfo)
 120 AC_CHECK_FUNCS(dlopen dlclose dlsym dlerror waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 121 AC_CHECK_FUNCS(strlcpy strlcat)
 122 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 123 AC_CACHE_SAVE
 124
 125
 126 dnl Checks for (v)snprintf
 127 NETATALK_SNPRINTF_CHECK
 128
 129 dnl --------------------------------------------------------------------------
 130 dnl specific configuration comes in here:
 131 dnl --------------------------------------------------------------------------
 132
 133 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 134
 135 netatalk_cv_admin_group=yes
 136 AC_MSG_CHECKING([for administrative group support])
 137 AC_ARG_WITH(admin-group,
 138         [  --disable-admin-group   disable admin group],[
 139         if test "$enableval" = "no"; then
 140                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 141                 AC_MSG_RESULT([yes])
 142         else
 143                 AC_MSG_RESULT([no])
 144                 netatalk_cv_admin_group=no
 145         fi],[
 146                 AC_MSG_RESULT([yes])
 147         ]
 148 )
 149
 150 NETATALK_AFS_CHECK
 151
 152 NETATALK_CONFIG_DIRS
 153
 154 AC_MSG_CHECKING([for logfile path])
 155 AC_ARG_WITH(logfile,
 156         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 157                           use --without-logfile to disable logger],[
 158         if test x"$withval" = x"no"; then
 159                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 160                 AC_MSG_RESULT([syslog])
 161         elif test "$withval" != "yes"; then
 162                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 163                 AC_MSG_RESULT([$withval])
 164         else
 165                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 166                 AC_MSG_RESULT([/var/log/netatalk.log])
 167         fi],[
 168                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 169                 AC_MSG_RESULT([/var/log/netatalk.log])
 170         ]
 171 )
 172
 173
 174 netatalk_cv_with_cracklib=no
 175 AC_MSG_CHECKING([for cracklib support])
 176 AC_ARG_WITH(cracklib,
 177         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 178         if test "x$withval" != "xno" ; then
 179                 cracklib="$withval"
 180                 AC_CHECK_LIB(crack, main, [
 181                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 182                         LIBS="$LIBS -lcrack"
 183                         AC_MSG_RESULT([yes])
 184                         if test "$cracklib" = "yes"; then
 185                                 cracklib="/usr/lib/cracklib_dict"
 186                         fi
 187                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 188                                 [path to cracklib dictionary])
 189                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 190                         netatalk_cv_with_cracklib=yes
 191                         ],[
 192                         AC_MSG_ERROR([cracklib not found!])
 193                         ]
 194                 )
 195         else
 196                 AC_MSG_RESULT([no])
 197         fi
 198         ],[
 199                 AC_MSG_RESULT([no])
 200         ]
 201 )
 202
 203 netatalk_cv_ddp_enabled=yes
 204 AC_MSG_CHECKING([whether to enable DDP])
 205 AC_ARG_ENABLE(ddp,
 206         [  --disable-ddp           disable DDP],[
 207         if test "$enableval" = "no"; then
 208                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 209                 AC_MSG_RESULT([no])
 210                 netatalk_cv_ddp_enabled=no
 211         else
 212                 AC_MSG_RESULT([yes])
 213         fi
 214         ],[
 215                 AC_MSG_RESULT([yes])
 216         ]
 217 )
 218
 219 AC_MSG_CHECKING([whether to enable debug code])
 220 AC_ARG_ENABLE(debug1,
 221         [  --enable-debug1         enable debug code],[
 222         if test "$enableval" != "no"; then
 223                 if test "$enableval" = "yes"; then
 224                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 225                 else
 226                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 227                 fi
 228                 AC_MSG_RESULT([yes])
 229         else
 230                 AC_MSG_RESULT([no])
 231         fi
 232         ],[
 233                 AC_MSG_RESULT([no])
 234         ]
 235 )
 236
 237 AC_MSG_CHECKING([whether to enable verbose debug code])
 238 AC_ARG_ENABLE(debug,
 239         [  --enable-debug          enable verbose debug code],[
 240         if test "$enableval" != "no"; then
 241                 if test "$enableval" = "yes"; then
 242                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 243                 else
 244                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 245                 fi
 246                 AC_MSG_RESULT([yes])
 247         else
 248                 AC_MSG_RESULT([no])
 249         fi
 250         ],[
 251                 AC_MSG_RESULT([no])
 252         ]
 253 )
 254
 255 afp3=no
 256 afp3set=no
 257 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 258 AC_ARG_ENABLE(afp3,
 259         [  --disable-afp3          disable AFP 3.x calls],
 260         [
 261             if test x"$enableval" != x"no"; then
 262                 afp3set=yes
 263                 afp3=yes
 264                 AC_MSG_RESULT([yes])
 265             else
 266                 AC_MSG_RESULT([no])
 267             fi
 268         ],[
 269             AC_MSG_RESULT([yes])
 270             afp3=yes
 271         ]
 272 )
 273
 274 if test x"$afp3" = x"yes"; then
 275         AC_SYS_LARGEFILE([
 276                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 277         ],[
 278                 if test x"$afp3set" = x"yes"; then
 279                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 280                 else
 281                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 282                         afp3=no
 283                 fi
 284         ])
 285 fi
 286
 287 AC_CHECK_ICONV
 288
 289 dnl ----------- A NOTE ABOUT DROPKLUDGE
 290 dnl The trouble with this fix is that if you know what the file is called, it
 291 dnl can be read from the Unix side.  That's okay for most academic institutions
 292 dnl since the students don't have telnet access to the Mac servers.  There is
 293 dnl currently no one working on further development/fixes of DROPKLUDGE.
 294 dnl -----------
 295
 296 netatalk_cv_dropkludge=no
 297 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 298 AC_ARG_ENABLE(dropkludge,
 299         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 300         if test "$enableval" = "yes"; then
 301                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 302                 AC_MSG_RESULT([yes])
 303                 netatalk_cv_dropkludge=yes
 304         else
 305                 AC_MSG_RESULT([no])
 306         fi
 307         ],[
 308                 AC_MSG_RESULT([no])
 309         ]
 310 )
 311
 312 netatalk_cv_force_uidgid=no
 313 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 314 AC_ARG_ENABLE(force-uidgid,
 315         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 316         if test "$enableval" = "yes"; then
 317                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 318                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 319                 AC_MSG_RESULT([yes])
 320                 netatalk_cv_force_uidgid=yes
 321         else
 322                 AC_MSG_RESULT([no])
 323         fi
 324         ],[
 325                 AC_MSG_RESULT([no])
 326         ]
 327 )
 328
 329 dnl Check for CNID database backends
 330 bdb_required=no
 331 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 332
 333 dnl Check for Berkeley DB library
 334 if test "x$bdb_required" = "xyes"; then
 335         AC_PATH_BDB(, [
 336                 AC_MSG_RESULT([])
 337                 AC_MSG_RESULT([Make sure you have the Berkeley DB libraries AND headers installed.])
 338                 AC_MSG_RESULT([You can download the latest version from http://www.sleepcat.com.])
 339                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 340                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option.])
 341                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 342         ])
 343 fi
 344
 345 dnl Check for quota support
 346 AC_CHECK_QUOTA
 347
 348 dnl Check for optional server location protocol support (used by MacOS X)
 349 NETATALK_SRVLOC
 350
 351 dnl Check for PAM libs
 352 netatalk_cv_use_pam=no
 353 AC_PATH_PAM([
 354         use_pam_so=yes
 355         compile_pam=yes
 356         netatalk_cv_use_pam=yes
 357         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 358 ])
 359
 360 netatalk_cv_use_shadowpw=no
 361 AC_ARG_WITH(shadow,
 362         [  --with-shadow           enable shadow password support [[auto]]],
 363         [netatalk_cv_use_shadowpw="$withval"],
 364         [netatalk_cv_use_shadowpw=auto]
 365 )
 366
 367 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 368     AC_CHECK_HEADER([shadow.h])
 369     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 370         netatalk_cv_use_shadowpw=yes
 371         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 372     else
 373       if test "x$shadowpw" = "xyes"; then
 374         AC_MSG_ERROR([shadow support not available])
 375       else
 376         netatalk_cv_use_shadowpw=no
 377       fi
 378     fi
 379 fi
 380
 381 AC_MSG_CHECKING([whether shadow support should be enabled])
 382 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 383         AC_MSG_RESULT([yes])
 384 else
 385         AC_MSG_RESULT([no])
 386 fi
 387
 388
 389
 390 netatalk_cv_use_shellcheck=yes
 391 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 392 AC_ARG_ENABLE(shell-check,
 393         [  --disable-shell-check   disable checking for a valid shell],[
 394         if test "$enableval" = "no"; then
 395                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 396                 AC_MSG_RESULT([no])
 397                 netatalk_cv_use_shellcheck=no
 398         else
 399                 AC_MSG_RESULT([yes])
 400         fi
 401         ],[
 402                 AC_MSG_RESULT([yes])
 403         ]
 404 )
 405
 406 NETATALK_TCP_WRAPPERS
 407
 408 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 409 AC_ARG_ENABLE(locking,
 410         [  --disable-locking       disable system locking],[
 411                 if test "$enableval" = "no"; then
 412                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 413                         AC_MSG_RESULT([yes])
 414                 else
 415                         AC_MSG_RESULT([no])
 416                 fi
 417
 418         ],[
 419                 AC_MSG_RESULT([no])
 420         ]
 421
 422 )
 423
 424
 425 AC_ARG_ENABLE(redhat,
 426         [  --enable-redhat         use redhat-style sysv configuration ],[
 427         if test "$enableval" = "yes"; then
 428                 sysv_style=redhat
 429         fi
 430         AC_MSG_RESULT([enabling redhat-style sysv support])
 431         ]
 432 )
 433
 434 AC_ARG_ENABLE(suse,
 435         [  --enable-suse           use suse-style sysv configuration ],[
 436         if test "$enableval" = "yes"; then
 437                 sysv_style=suse
 438         fi
 439         AC_MSG_RESULT([enabling suse-style sysv support])
 440         ]
 441 )
 442
 443 AC_ARG_ENABLE(cobalt,
 444         [  --enable-cobalt         use cobalt-style sysv configuration ],
 445         if test "$enableval" = "yes"; then
 446                 sysv_style=cobalt
 447         fi
 448         AC_MSG_RESULT([enabling cobalt-style sysv support])
 449 )
 450
 451 AC_ARG_ENABLE(netbsd,
 452         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 453         if test "x$enableval" = "xyes"; then
 454                 sysv_style=netbsd
 455         fi
 456         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 457 )
 458
 459 dnl ----- timelord compilation (disabled by default)
 460 AC_MSG_CHECKING([whether timelord should be compiled])
 461 compile_timelord=no
 462 AC_ARG_ENABLE(timelord,
 463         [  --enable-timelord       enable compilation of timelord server],
 464         [compile_timelord="$enableval"],
 465         [compile_timelord="no"]
 466 )
 467 AC_MSG_RESULT([$compile_timelord])
 468
 469 dnl ----- a2boot compilation (disabled by default)
 470 AC_MSG_CHECKING([whether a2boot should be compiled])
 471 compile_a2boot=no
 472 AC_ARG_ENABLE(a2boot,
 473         [  --enable-a2boot         enable compilation of Apple2 boot server],
 474         [compile_a2boot="$enableval"],
 475         [compile_a2boot="no"]
 476 )
 477 AC_MSG_RESULT([$compile_a2boot])
 478
 479 AC_ARG_WITH(uams-path,
 480         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 481                 uams_path="$withval"
 482         ],[
 483                 uams_path="${PKGCONFDIR}/uams"
 484         ]
 485 )
 486
 487 dnl --------------------------------------------------------------------------
 488 dnl FHS stuff has to be done last because it overrides other defaults
 489 dnl --------------------------------------------------------------------------
 490
 491 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 492 AC_ARG_ENABLE(fhs,
 493         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 494         if test "$enableval" = "yes"; then
 495                 uams_path="${libdir}/netatalk"
 496                 sysconfdir="/etc"
 497                 PKGCONFDIR=${sysconfdir}/netatalk
 498                 SERVERTEXT="${PKGCONFDIR}/msg"
 499                 use_pam_so=yes
 500                 mandir="/usr/share/man"
 501                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 502                 AC_MSG_RESULT([yes])
 503         else
 504                 AC_MSG_RESULT([no])
 505         fi
 506         ],[
 507                 AC_MSG_RESULT([no])
 508         ]
 509 )
 510
 511 dnl --------------------------------------------------------------------------
 512 dnl post-FHS substitutions, etc
 513 dnl --------------------------------------------------------------------------
 514
 515 dnl ***** UAMS_PATH
 516 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 517 dnl     [path to UAMs [default=PKGCONF/uams]])
 518 UAMS_PATH="${uams_path}"
 519 AC_SUBST(UAMS_PATH)
 520
 521 dnl --------------------------------------------------------------------------
 522 dnl drop in includes for top level directory structures here...
 523 dnl --------------------------------------------------------------------------
 524
 525 dnl Note: $(top_srcdir)/include should be added before all other includes
 526 dnl       so that includes from that directory a preferred to includes from
 527 dnl       /usr/include or similar places.
 528 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 529 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 530
 531 dnl --------------------------------------------------------------------------
 532 dnl specific configuration comes in here:
 533 dnl --------------------------------------------------------------------------
 534
 535 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 536
 537 dnl --------------------- determine operating system from "target"
 538 case "$host_os" in
 539         *aix*)                          this_os=aix ;;
 540         *freebsd*)                      this_os=freebsd ;;
 541         *hpux11*)                       this_os=hpux11 ;;
 542         *irix*)                         this_os=irix ;;
 543         *linux*)                        this_os=linux ;;
 544         *osx*)                          this_os=macosx ;;
 545         *darwin*)                       this_os=macosx ;;
 546         *netbsd*)                       this_os=netbsd ;;
 547         *openbsd*)                      this_os=openbsd ;;
 548         *osf*)                          this_os=tru64 ;;
 549         *solaris*)                      this_os=solaris ;;
 550 esac
 551
 552 case "$host_cpu" in
 553         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 554         alpha)                                          this_cpu=alpha ;;
 555         mips)                                           this_cpu=mips ;;
 556         powerpc|ppc)                            this_cpu=ppc ;;
 557 esac
 558
 559 dnl --------------------- operating system specific flags (port from sys/*)
 560
 561 dnl ----- AIX specific -----
 562 if test x"$this_os" = "xaix"; then
 563         AC_MSG_RESULT([ * AIX specific configuration])
 564         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 565
 566         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 567         dnl compilation environment.  It's enough to get things defined
 568         dnl right in endian.h provided that long long is supported, though.
 569         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 570 fi
 571
 572 dnl ----- FreeBSD specific -----
 573 if test x"$this_os" = "xfreebsd"; then
 574         AC_MSG_RESULT([ * FreeBSD specific configuration])
 575         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 576         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 577
 578 dnl     AC_DEFINE(NO_CRYPT_H, 1, [Define if crypt.h does not exist])
 579 fi
 580
 581 dnl ----- HP-UX 11 specific -----
 582 if test x"$this_os" = "xhpux11"; then
 583         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 584
 585         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 586         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 587 fi
 588
 589 dnl ----- IRIX specific -----
 590 if test x"$this_os" = "xirix"; then
 591         AC_MSG_RESULT([ * IRIX specific configuration])
 592
 593         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 594 fi
 595
 596 dnl ----- Linux specific -----
 597 if test x"$this_os" = "xlinux"; then
 598         AC_MSG_RESULT([ * Linux specific configuration])
 599
 600         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 601         AC_MSG_CHECKING([for struct atalk_addr])
 602 dnl     AC_COMPILE_IFELSE([
 603         AC_TRY_COMPILE([
 604 #include <sys/socket.h>
 605 #include <asm/types.h>
 606 #include <linux/atalk.h>
 607 ],
 608 [
 609 int main() {
 610         struct atalk_addr foo;
 611
 612         return 0;
 613 }
 614         ], [
 615                 ac_have_atalk_addr=yes
 616                 AC_MSG_RESULT([yes])
 617         ], [
 618                 AC_MSG_RESULT([no])
 619         ])
 620
 621 if test "x$ac_have_atalk_addr" = "xyes"; then
 622         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 623 fi
 624
 625         dnl ----- check if we need the quotactl wrapper
 626 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 627 #       AC_CHECK_FUNC(quotactl,,
 628 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 629 #               AC_MSG_RESULT([enabling quotactl wrapper])
 630 #       )
 631
 632         # For quotas on Linux XFS filesystems
 633         AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 634         AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)
 635         # For linux > 2.5.56
 636         AC_CHECK_HEADERS(linux/dqblk_xfs.h)
 637
 638
 639         dnl ----- as far as I can tell, dbtob always does the wrong thing
 640         dnl ----- on every single version of linux I've ever played with.
 641         dnl ----- see etc/afpd/quota.c
 642         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 643
 644         netatalk_cv_linux_sendfile=no
 645         AC_ARG_ENABLE(sendfile,
 646             [  --enable-sendfile       use sendfile syscall default (no) ],[
 647                 if test "$enableval" = "yes"; then
 648                         netatalk_cv_linux_sendfile=yes
 649                 fi
 650                 AC_MSG_RESULT([enabling sendfile syscall])
 651             ]
 652         )
 653
 654         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 655             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 656             AC_TRY_LINK([#include <sys/sendfile.h>],
 657 [\
 658 int tofd, fromfd;
 659 off_t offset;
 660 size_t total;
 661 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 662 ],
 663 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 664
 665 # Try and cope with broken Linux sendfile....
 666             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 667             AC_TRY_LINK([\
 668 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 669 #undef _FILE_OFFSET_BITS
 670 #endif
 671 #include <sys/sendfile.h>],
 672 [\
 673 int tofd, fromfd;
 674 off_t offset;
 675 size_t total;
 676 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 677 ],
 678 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 679
 680             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 681                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 682                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 683                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 684             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 685                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 686                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 687                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 688             else
 689                 netatalk_cv_linux_sendfile=no
 690                 AC_MSG_RESULT(no);
 691             fi
 692         fi
 693
 694         dnl ----- Linux/alpha specific -----
 695         if test x"$this_cpu" = "xalpha"; then
 696                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 697                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 698         fi
 699         need_dash_r=no
 700
 701
 702 fi
 703
 704 dnl ----- Mac OSX specific -----
 705 if test x"$this_os" = "xmacosx"; then
 706         AC_MSG_RESULT([ * Mac OSX specific configuration])
 707         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 708         AC_DEFINE(HAVE_BROKEN_CPP, 1, [Define if cpp is broken])
 709         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 710         dnl AC_DEFINE(NO_DLFCN_H)
 711         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 712         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 713         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 714 fi
 715
 716 dnl ----- NetBSD specific -----
 717 if test x"$this_os" = "xnetbsd"; then
 718         AC_MSG_RESULT([ * NetBSD specific configuration])
 719         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 720         if echo __ELF__ | $CC -E - | grep __ELF__ > /dev/null; then
 721                 # NetBSD ELF machines don't have to have DLSYM_PREPEND_UNDERSCORE.
 722                 # If this test is true, it's not an ELF box.
 723                 # This REALLY should be a configure test.
 724                 AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 725         fi
 726         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 727         need_dash_r=yes
 728
 729         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 730         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 731 fi
 732
 733 dnl ----- OpenBSD specific -----
 734 if test x"$this_os" = "xopenbsd"; then
 735         AC_MSG_RESULT([ * OpenBSD specific configuration])
 736         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 737         AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 738
 739         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 740         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 741 fi
 742
 743 dnl ----- Solaris specific -----
 744 if test x"$this_os" = "xsolaris"; then
 745         AC_MSG_RESULT([ * Solaris specific configuration])
 746         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 747         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 748         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 749         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 750         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 751         need_dash_r=yes
 752         sysv_style=solaris
 753
 754         solaris_module=no
 755         AC_MSG_CHECKING([if we can build Solaris kernel module])
 756         if test -x /usr/ccs/bin/ld; then
 757                 solaris_module=yes
 758         fi
 759         AC_MSG_RESULT([$solaris_module])
 760
 761         COMPILE_64BIT_KMODULE=no
 762         KCFLAGS=""
 763         KLDFLAGS=""
 764         COMPILE_KERNEL_GCC=no
 765
 766         if test "$solaris_module" = "yes"; then
 767            dnl Solaris kernel module stuff
 768            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 769
 770            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 771            if test -x /usr/bin/isainfo; then
 772                 # check for 64 bit platform
 773                 if isainfo -kv | grep '^64-bit'; then
 774                         COMPILE_64BIT_KMODULE=yes
 775                 fi
 776            fi
 777
 778            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 779
 780
 781            if test "${GCC}" = yes; then
 782                 COMPILE_KERNEL_GCC=yes
 783                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 784                         # use for 64 bit
 785                         KCFLAGS="-m64"
 786                         #KLDFLAGS="-melf64_sparc"
 787                         KLDFLAGS="-64"
 788                 else
 789                         KCFLAGS=""
 790                         KLDFLAGS=""
 791                 fi
 792                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 793            else
 794                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 795                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 796                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 797                         KLDFLAGS="-64"
 798                 else
 799                         KCFLAGS=""
 800                         KLDFLAGS=""
 801                 fi
 802                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 803            fi
 804
 805            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 806            AC_TRY_LINK([\
 807 #include <sys/stream.h>
 808 #include <sys/ddi.h>],
 809 [\
 810 timeout_id_t dummy;
 811 ],
 812 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 813
 814            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 815         fi
 816
 817         AC_SUBST(COMPILE_KERNEL_GCC)
 818         AC_SUBST(COMPILE_64BIT_KMODULE)
 819         AC_SUBST(KCFLAGS)
 820         AC_SUBST(KLDFLAGS)
 821 fi
 822
 823 dnl ----- Tru64 specific -----
 824 if test x"$this_os" = "xtru64"; then
 825         AC_MSG_RESULT([ * Tru64 specific configuration])
 826         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 827         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 828         dnl AC_DEFINE(USE_MOUNT_H)
 829         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 830         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 831         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 832         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 833         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 834         AC_CHECK_LIB(security,set_auth_parameters)
 835         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 836         need_dash_r=no
 837         sysv_style=tru64
 838 fi
 839
 840 dnl -- look for openssl
 841 AC_PATH_SSL
 842
 843 dnl -- check for crypt
 844 AC_CRYPT
 845
 846 dnl --------------------- check for building PGP UAM module
 847
 848 AC_MSG_CHECKING([whether the PGP UAM should be build])
 849 AC_ARG_ENABLE(pgp-uam,
 850         [  --enable-pgp-uam        enable build of PGP UAM module],[
 851         if test "$enableval" = "yes"; then
 852                 if test "$compile_ssl" = "yes"; then
 853                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 854                         compile_pgp=yes
 855                         AC_MSG_RESULT([yes])
 856                 else
 857                         AC_MSG_RESULT([no])
 858                 fi
 859         fi
 860         ],[
 861                 AC_MSG_RESULT([no])
 862         ]
 863 )
 864
 865 dnl --------------------- check for building Kerberos v4 UAM module
 866
 867 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 868 AC_ARG_ENABLE(krb4-uam,
 869         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 870         if test "$enableval" = "yes"; then
 871                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 872                 compile_kerberos=yes
 873                 AC_MSG_RESULT([yes])
 874         else
 875                 AC_MSG_RESULT([no])
 876         fi
 877         ],[
 878                 AC_MSG_RESULT([no])
 879         ]
 880 )
 881
 882 dnl --------------------- check for building Kerberos V UAM module
 883
 884 netatalk_cv_build_krb5_uam=no
 885 AC_ARG_ENABLE(krbV-uam,
 886         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 887         [
 888                 if test x"$enableval" = x"yes"; then
 889                         NETATALK_GSSAPI_CHECK([
 890                                 netatalk_cv_build_krb5_uam=yes
 891                         ],[
 892                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 893                         ])
 894                 fi
 895         ]
 896
 897 )
 898
 899 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 900 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 901         AC_MSG_RESULT([yes])
 902 else
 903         AC_MSG_RESULT([no])
 904 fi
 905 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 906
 907 dnl --------------------- overwrite the config files . . . or not.
 908
 909 AC_MSG_CHECKING([whether configuration files should be overwritten])
 910 AC_ARG_ENABLE(overwrite,
 911         [  --enable-overwrite      overwrite configuration files during installation],
 912         [OVERWRITE_CONFIG="${enable_overwrite}"],
 913         [OVERWRITE_CONFIG="no"]
 914 )
 915 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 916
 917 dnl --------------------- last minute substitutions
 918
 919 AC_SUBST(LIBS)
 920 AC_SUBST(CFLAGS)
 921 AC_SUBST(OVERWRITE_CONFIG)
 922
 923 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 924 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 925 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
 926 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 927 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 928 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 929 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
 930 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 931 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
 932 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 933 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
 934 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
 935 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
 936 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
 937 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
 938 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
 939 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
 940
 941 dnl --------------------- generate files
 942
 943 AC_OUTPUT([Makefile
 944         bin/Makefile
 945         bin/adv1tov2/Makefile
 946         bin/aecho/Makefile
 947         bin/afile/Makefile
 948         bin/afppasswd/Makefile
 949         bin/cnid/Makefile
 950         bin/cnid/cnid_maint
 951         bin/cnid/cnid2_create
 952         bin/getzones/Makefile
 953         bin/megatron/Makefile
 954         bin/nbp/Makefile
 955         bin/pap/Makefile
 956         bin/psorder/Makefile
 957         bin/uniconv/Makefile
 958         config/Makefile
 959         contrib/Makefile
 960         contrib/macusers/Makefile
 961         contrib/macusers/macusers
 962         contrib/nu/Makefile
 963         contrib/nu/nu
 964         contrib/printing/Makefile
 965         contrib/shell_utils/Makefile
 966         contrib/shell_utils/afpd-mtab.pl
 967         contrib/shell_utils/apple_cp
 968         contrib/shell_utils/apple_mv
 969         contrib/shell_utils/apple_rm
 970         contrib/shell_utils/cleanappledouble.pl
 971         contrib/shell_utils/netatalkshorternamelinks.pl
 972         contrib/timelord/Makefile
 973         contrib/a2boot/Makefile
 974         distrib/Makefile
 975         distrib/config/Makefile
 976         distrib/config/netatalk-config
 977         distrib/initscripts/Makefile
 978         distrib/m4/Makefile
 979         doc/Makefile
 980         etc/Makefile
 981         etc/afpd/Makefile
 982         etc/atalkd/Makefile
 983         etc/cnid_dbd/Makefile
 984         etc/uams/Makefile
 985         etc/uams/uams_krb4/Makefile
 986         etc/papd/Makefile
 987         etc/psf/Makefile
 988         include/Makefile
 989         include/atalk/Makefile
 990         libatalk/Makefile
 991         libatalk/adouble/Makefile
 992         libatalk/asp/Makefile
 993         libatalk/atp/Makefile
 994         libatalk/cnid/Makefile
 995         libatalk/cnid/db3/Makefile
 996         libatalk/cnid/cdb/Makefile
 997         libatalk/cnid/last/Makefile
 998         libatalk/cnid/mtab/Makefile
 999         libatalk/cnid/dbd/Makefile
1000         libatalk/cnid/hash/Makefile
1001         libatalk/cnid/tdb/Makefile
1002         libatalk/compat/Makefile
1003         libatalk/dsi/Makefile
1004         libatalk/nbp/Makefile
1005         libatalk/netddp/Makefile
1006         libatalk/util/Makefile
1007         libatalk/tdb/Makefile
1008         libatalk/unicode/Makefile
1009         libatalk/unicode/charsets/Makefile
1010         macros/Makefile
1011         man/Makefile
1012         man/man1/Makefile
1013         man/man3/Makefile
1014         man/man4/Makefile
1015         man/man5/Makefile
1016         man/man8/Makefile
1017         sys/Makefile
1018         sys/generic/Makefile
1019         sys/generic/sys/Makefile
1020         sys/netatalk/Makefile
1021         sys/netbsd/Makefile
1022         sys/netbsd/netatalk/Makefile
1023         sys/solaris/Makefile
1024         sys/sunos/Makefile
1025         sys/ultrix/Makefile
1026         ],
1027         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1028 )
1029
1030 AC_NETATALK_LIBS_SUMMARY
1031 AC_NETATALK_CONFIG_SUMMARY
1032