configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [1])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37
  38 AC_ARG_ENABLE(
  39         [plugin-nfacct],
  40         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  41         ,
  42         [enable_plugin_nfacct="no"]
  43 )
  44 AC_ARG_ENABLE(
  45         [pedantic],
  46         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  47         ,
  48         [enable_pedantic="no"]
  49 )
  50 AC_ARG_WITH(
  51         [webdir],
  52         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  53         [webdir="${withval}"],
  54         [webdir="\$(pkgdatadir)/web"]
  55 )
  56 AC_ARG_WITH(
  57         [zlib],
  58         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  59         ,
  60         [with_zlib="yes"]
  61 )
  62 AC_ARG_WITH(
  63         [math],
  64         [AS_HELP_STRING([--with-math], [build with math])],
  65         ,
  66         [with_math="yes"]
  67 )
  68 AC_ARG_WITH(
  69         [user],
  70         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  71         ,
  72         [with_user="nobody"]
  73 )
  74
  75 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  76 LIBS="${PTHREAD_LIBS} ${LIBS}"
  77 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  78 CC="${PTHREAD_CC}"
  79
  80 AC_TYPE_UINT8_T
  81 AC_TYPE_UINT16_T
  82 AC_TYPE_UINT32_T
  83 AC_C_INLINE
  84
  85 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
  86 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
  87 if test -z "${MATH_LIBS}"; then
  88         AC_CHECK_LIB(
  89                 [m],
  90                 [sin],
  91                 [MATH_LIBS="-lm"]
  92         )
  93 fi
  94
  95 AC_CHECK_LIB([uuid], [uuid_generate_time_safe], [], \
  96              [AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])])
  97
  98 if test "${enable_plugin_nfacct}" = "yes"; then
  99         PKG_CHECK_MODULES(
 100                 [NFACCT],
 101                 [libnetfilter_acct],
 102         )
 103         PKG_CHECK_MODULES(
 104                 [LIBMNL],
 105                 [libmnl],
 106         )
 107         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 108         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 109         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 110         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 111         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 112 fi
 113 if test "${with_zlib}" = "yes"; then
 114         PKG_CHECK_MODULES(
 115                 [ZLIB],
 116                 [zlib],
 117         )
 118         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 119         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 120         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 121         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 122 fi
 123 if test "${with_math}" = "yes"; then
 124         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 125         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 126         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 127         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 128 fi
 129
 130 if test "${GCC}" = "yes"; then
 131         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 132         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 133 else
 134         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 135         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 136 fi
 137
 138 if test "${enable_pedantic}" = "yes"; then
 139         enable_strict="yes"
 140         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 141 fi
 142
 143 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 144
 145 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 146 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 147 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 148 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 149 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 150 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 151 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 152 AC_SUBST([webdir])
 153
 154 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 155 AC_SUBST([OPTIONAL_MATH_LIBS])
 156 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 157 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 158 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 159 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 160
 161 AC_CONFIG_FILES([
 162         Makefile
 163         charts.d/Makefile
 164         conf.d/Makefile
 165         netdata.spec
 166         node.d/Makefile
 167         plugins.d/Makefile
 168         src/Makefile
 169         system/Makefile
 170         web/Makefile
 171         contrib/Makefile
 172 ])
 173 AC_OUTPUT
 174
 175 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 176 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :