macros/srvloc.m4

   1 dnl Check for optional server location protocol support (used by MacOS X)
   2
   3 AC_DEFUN([AC_NETATALK_SRVLOC], [
   4
   5         SLP_LIBS=""
   6         SLP_CFLAGS=""
   7         found_slp=no
   8         srvlocdir=""
   9
  10         AC_ARG_ENABLE(srvloc,
  11                 [  --enable-srvloc[[=DIR]]   enable Server Location Protocol (SLP) support],
  12                 [srvloc=$enableval],
  13                 [srvloc=no]
  14         )
  15
  16     dnl make sure atalk_libname is defined beforehand
  17     [[ -n "$atalk_libname" ]] || AC_MSG_ERROR([internal error, atalk_libname undefined])
  18
  19         if test "x$srvloc" != "xno"; then
  20
  21                 savedcppflags="$CPPFLAGS"
  22                 savedldflags="$LDFLAGS"
  23                 if test "x$srvloc" = "xyes" ; then
  24                         srvlocdir="/usr"
  25                 else
  26                         srvlocdir="$srvloc"
  27                 fi
  28                 CPPFLAGS="$CPPFLAGS -I$srvlocdir/include"
  29                 LDFLAGS="$LDFLAGS -L$srvlocdir/$atalk_libname"
  30
  31                 AC_MSG_CHECKING([for slp.h])
  32                 AC_TRY_CPP([#include <slp.h>],
  33                         [
  34                                 AC_MSG_RESULT([yes])
  35                                 found_slp=yes
  36                         ],
  37                         [
  38                                 AC_MSG_RESULT([no])
  39                         ]
  40                 )
  41
  42                 if test "x$found_slp" = "xyes"; then
  43                         AC_CHECK_LIB(slp, SLPOpen, [
  44                            SLP_LIBS="-L$srvlocdir/$atalk_libname -lslp"
  45                            SLP_CFLAGS="-I$srvlocdir/include"
  46                         ],[
  47                            AC_MSG_RESULT([no])
  48                            found_slp=no
  49                         ])
  50                 fi
  51
  52                 CPPFLAGS="$savedcppflags"
  53                 LDFLAGS="$savedldflags"
  54         fi
  55
  56         netatalk_cv_srvloc=no
  57         AC_MSG_CHECKING([whether to enable srvloc (SLP) support])
  58         if test "x$found_slp" = "xyes"; then
  59                 AC_MSG_RESULT([yes])
  60                 AC_DEFINE(USE_SRVLOC, 1, [Define to enable SLP support])
  61                 netatalk_cv_srvloc=yes
  62         else
  63                 AC_MSG_RESULT([no])
  64                 if test "x$srvloc" != "xno" -a "x$srvloc" != "xyes"; then
  65                         AC_MSG_ERROR([SLP installation not found])
  66                 fi
  67         fi
  68
  69
  70
  71         LIB_REMOVE_USR_LIB(SLP_LIBS)
  72         CFLAGS_REMOVE_USR_INCLUDE(SLP_CFLAGS)
  73         AC_SUBST(SLP_LIBS)
  74         AC_SUBST(SLP_CFLAGS)
  75 ])