macros/netatalk.m4

   1 dnl Kitchen sink for configuration macros
   2
   3 dnl Check for docbook
   4 AC_DEFUN(AX_CHECK_DOCBOOK, [
   5   # It's just rude to go over the net to build
   6   XSLTPROC_FLAGS=--nonet
   7   DOCBOOK_ROOT=
   8   XSLTPROC_WORKS=no
   9
  10   AC_ARG_WITH(docbook,
  11     AS_HELP_STRING(
  12       [--with-docbook],
  13       [Path to Docbook XSL directory]
  14     ),
  15     [DOCBOOK_ROOT=$withval]
  16   )
  17
  18   if test -n "$DOCBOOK_ROOT" ; then
  19     AC_CHECK_PROG(XSLTPROC,xsltproc,xsltproc,)
  20     if test -n "$XSLTPROC"; then
  21       AC_MSG_CHECKING([whether xsltproc works])
  22       DB_FILE="$DOCBOOK_ROOT/html/docbook.xsl"
  23       $XSLTPROC $XSLTPROC_FLAGS $DB_FILE >/dev/null 2>&1 << END
  24 <?xml version="1.0" encoding='ISO-8859-1'?>
  25 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.1.2//EN" "http://www.oasis-open.org/docbook/xml/4.1.2/docbookx.dtd">
  26 <book id="test">
  27 </book>
  28 END
  29       if test "$?" = 0; then
  30         XSLTPROC_WORKS=yes
  31       fi
  32       AC_MSG_RESULT($XSLTPROC_WORKS)
  33     fi
  34   fi
  35
  36   AC_MSG_CHECKING([whether to build Docbook documentation])
  37   AC_MSG_RESULT($XSLTPROC_WORKS)
  38
  39   AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC_WORKS" = x"yes")
  40   AC_SUBST(XSLTPROC_FLAGS)
  41   AC_SUBST(DOCBOOK_ROOT)
  42   AC_SUBST(XSLTPROC)
  43 ])
  44
  45 dnl Check for dtrace
  46 AC_DEFUN([AC_NETATALK_DTRACE], [
  47   AC_ARG_WITH(dtrace,
  48     AS_HELP_STRING(
  49       [--with-dtrace],
  50       [Enable dtrace probes (default: enabled if dtrace found)]
  51     ),
  52     [WDTRACE=$withval],
  53     [WDTRACE=auto]
  54   )
  55   if test "x$WDTRACE" = "xyes" -o "x$WDTRACE" = "xauto" ; then
  56     AC_CHECK_PROG([atalk_cv_have_dtrace], [dtrace], [yes], [no])
  57     if test "x$atalk_cv_have_dtrace" = "xno" ; then
  58       if test "x$WDTRACE" = "xyes" ; then
  59         AC_MSG_FAILURE([dtrace requested but not found])
  60       fi
  61       WDTRACE="no"
  62     else
  63       WDTRACE="yes"
  64     fi
  65   fi
  66
  67   if test x"$WDTRACE" = x"yes" ; then
  68     AC_DEFINE([WITH_DTRACE], [1], [dtrace probes])
  69     DTRACE_LIBS=""
  70     if test x"$this_os" = x"freebsd" ; then
  71       DTRACE_LIBS="-lelf"
  72     fi
  73     AC_SUBST(DTRACE_LIBS)
  74   fi
  75   AM_CONDITIONAL(WITH_DTRACE, test "x$WDTRACE" = "xyes")
  76 ])
  77
  78 dnl Check for dbus-glib, for AFP stats
  79 AC_DEFUN([AC_NETATALK_DBUS_GLIB], [
  80   atalk_cv_with_dbus=no
  81
  82   AC_ARG_WITH(afpstats,
  83     AS_HELP_STRING(
  84       [--with-afpstats],
  85       [Enable AFP statistics via dbus (default: enabled if dbus found)]
  86     ),,[withval=auto]
  87   )
  88
  89   if test x"$withval" != x"no" ; then
  90     PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1, have_dbus=yes, have_dbus=no)
  91     PKG_CHECK_MODULES(DBUS_GLIB, dbus-glib-1, have_dbus_glib=yes, have_dbus_glib=no)
  92     PKG_CHECK_MODULES(DBUS_GTHREAD, gthread-2.0, have_dbus_gthread=yes, have_dbus_gthread=no)
  93     if test x$have_dbus_glib = xyes -a x$have_dbus = xyes -a x$have_dbus_gthread = xyes ; then
  94         saved_CFLAGS=$CFLAGS
  95         saved_LIBS=$LIBS
  96         CFLAGS="$CFLAGS $DBUS_GLIB_CFLAGS"
  97         LIBS="$LIBS $DBUS_GLIB_LIBS"
  98         AC_CHECK_FUNC([dbus_g_bus_get_private], [atalk_cv_with_dbus=yes], [atalk_cv_with_dbus=no])
  99         CFLAGS="$saved_CFLAGS"
 100         LIBS="$saved_LIBS"
 101     fi
 102   fi
 103
 104   if test x"$withval" = x"yes" -a x"$atalk_cv_with_dbus" = x"no"; then
 105     AC_MSG_ERROR([afpstats requested but dbus-glib not found])
 106   fi
 107
 108   AC_ARG_WITH(
 109       dbus-sysconf-dir,
 110       [AS_HELP_STRING([--with-dbus-sysconf-dir=PATH],[Path to dbus system bus security configuration directory (default: ${sysconfdir}/dbus-1/system.d/)])],
 111       ac_cv_dbus_sysdir=$withval,
 112       ac_cv_dbus_sysdir='${sysconfdir}/dbus-1/system.d'
 113   )
 114   DBUS_SYS_DIR=""
 115   if test x$atalk_cv_with_dbus = xyes ; then
 116       AC_DEFINE(HAVE_DBUS_GLIB, 1, [Define if support for dbus-glib was found])
 117       DBUS_SYS_DIR="$ac_cv_dbus_sysdir"
 118   fi
 119
 120   AC_SUBST(DBUS_SYS_DIR)
 121   AC_SUBST(DBUS_CFLAGS)
 122   AC_SUBST(DBUS_LIBS)
 123   AC_SUBST(DBUS_GLIB_CFLAGS)
 124   AC_SUBST(DBUS_GLIB_LIBS)
 125   AC_SUBST(DBUS_GTHREAD_CFLAGS)
 126   AC_SUBST(DBUS_GTHREAD_LIBS)
 127   AM_CONDITIONAL(HAVE_DBUS_GLIB, test x$atalk_cv_with_dbus = xyes)
 128 ])
 129
 130 dnl Whether to enable developer build
 131 AC_DEFUN([AC_DEVELOPER], [
 132     AC_MSG_CHECKING([whether to enable developer build])
 133     AC_ARG_ENABLE(
 134         developer,
 135         AS_HELP_STRING([--enable-developer], [whether to enable developer build (ABI checking)]),
 136         enable_dev=$enableval,
 137         enable_dev=no
 138     )
 139     AC_MSG_RESULT([$enable_dev])
 140     AM_CONDITIONAL(DEVELOPER, test x"$enable_dev" = x"yes")
 141 ])
 142
 143 dnl Tracker, for Spotlight
 144 AC_DEFUN([AC_NETATALK_SPOTLIGHT], [
 145     ac_cv_have_tracker=no
 146     ac_cv_tracker_pkg_version_default=0.12
 147     ac_cv_tracker_pkg_version_min=0.12
 148
 149     dnl Tracker SPARQL
 150     AC_ARG_WITH([tracker-pkgconfig-version],
 151       [AS_HELP_STRING([--with-tracker-pkgconfig-version=VERSION],[Version suffix of the Tracker SPARQL pkg-config (default: 0.12)])],
 152       [ac_cv_tracker_pkg_version=$withval],
 153       [ac_cv_tracker_pkg_version=$ac_cv_tracker_pkg_version_default]
 154     )
 155
 156     AC_ARG_WITH([tracker-prefix],
 157       [AS_HELP_STRING([--with-tracker-prefix=PATH],[Prefix of Tracker installation (default: none)])],
 158       [ac_cv_tracker_prefix=$withval],
 159       [ac_cv_tracker_prefix="`pkg-config --variable=prefix tracker-sparql-$ac_cv_tracker_pkg_version`"]
 160     )
 161
 162     AC_ARG_VAR([PKG_CONFIG_PATH], [Path to additional pkg-config packages])
 163     PKG_CHECK_MODULES([TRACKER], [tracker-sparql-$ac_cv_tracker_pkg_version >= $ac_cv_tracker_pkg_version_min], [ac_cv_have_tracker_sparql=yes], [ac_cv_have_tracker_sparql=no])
 164
 165     if test x"$ac_cv_have_tracker_sparql" = x"no" ; then
 166         if test x"$need_tracker_sparql" = x"yes" ; then
 167             AC_MSG_ERROR([$ac_cv_tracker_pkg not found])
 168         fi
 169     else
 170         ac_cv_have_tracker=yes
 171         AC_DEFINE(HAVE_TRACKER, 1, [Define if Tracker is available])
 172         AC_DEFINE_UNQUOTED(TRACKER_PREFIX, ["$ac_cv_tracker_prefix"], [Path to Tracker])
 173         AC_DEFINE([DBUS_DAEMON_PATH], ["/bin/dbus-daemon"], [Path to dbus-daemon])
 174     fi
 175
 176     AC_SUBST(TRACKER_CFLAGS)
 177     AC_SUBST(TRACKER_LIBS)
 178     AC_SUBST(TRACKER_MINER_CFLAGS)
 179     AC_SUBST(TRACKER_MINER_LIBS)
 180     AM_CONDITIONAL(HAVE_TRACKER, [test x"$ac_cv_have_tracker" = x"yes"])
 181 ])
 182
 183 dnl Whether to disable bundled libevent
 184 AC_DEFUN([AC_NETATALK_LIBEVENT], [
 185     AC_MSG_CHECKING([whether to use bundled libevent])
 186     AC_ARG_WITH(
 187         libevent,
 188         [AS_HELP_STRING([--with-libevent],[whether to use the bundled libevent (default: yes)])],
 189         use_bundled_libevent=$withval,
 190         use_bundled_libevent=yes
 191     )
 192     AC_ARG_WITH(
 193         libevent-header,
 194         [AS_HELP_STRING([--with-libevent-header],[path to libevent header files])],
 195         [use_bundled_libevent=no; LIBEVENT_CFLAGS=-I$withval]
 196     )
 197     AC_ARG_WITH(
 198         libevent-lib,
 199         [AS_HELP_STRING([--with-libevent-lib],[path to libevent library])],
 200         [use_bundled_libevent=no; LIBEVENT_LDFLAGS=-L$withval]
 201     )
 202     if test x"$LIBEVENT_CFLAGS" = x"-Iyes" -o x"$LIBEVENT_LDFLAGS" = x"-Lyes" ; then
 203         AC_MSG_ERROR([--with-libevent requires a path])
 204     fi
 205     AC_MSG_RESULT([$use_bundled_libevent])
 206     if test x"$use_bundled_libevent" = x"yes" ; then
 207         AC_CONFIG_SUBDIRS([libevent])
 208     fi
 209     AC_SUBST(LIBEVENT_CFLAGS)
 210     AC_SUBST(LIBEVENT_LDFLAGS)
 211     AM_CONDITIONAL(USE_BUILTIN_LIBEVENT, test x"$use_bundled_libevent" = x"yes")
 212 ])
 213
 214 dnl Whether to disable bundled tdb
 215 AC_DEFUN([AC_NETATALK_TDB], [
 216     AC_ARG_WITH(
 217         tdb,
 218         [AS_HELP_STRING([--with-tdb],[whether to use the bundled tdb (default: yes)])],
 219         use_bundled_tdb=$withval,
 220         use_bundled_tdb=yes
 221     )
 222     AC_MSG_CHECKING([whether to use bundled tdb])
 223     AC_MSG_RESULT([$use_bundled_tdb])
 224
 225     if test x"$use_bundled_tdb" = x"yes" ; then
 226         AC_DEFINE(USE_BUILTIN_TDB, 1, [Use internal tbd])
 227     else
 228         if test -z "$TDB_LIBS" ; then
 229             PKG_CHECK_MODULES(TDB, tdb, , [AC_MSG_ERROR([couldn't find tdb with pkg-config])])
 230         fi
 231         use_bundled_tdb=no
 232     fi
 233
 234     AC_SUBST(TDB_CFLAGS)
 235     AC_SUBST(TDB_LIBS)
 236     AM_CONDITIONAL(USE_BUILTIN_TDB, test x"$use_bundled_tdb" = x"yes")
 237 ])
 238
 239 dnl Filesystem Hierarchy Standard (FHS) compatibility
 240 AC_DEFUN([AC_NETATALK_FHS], [
 241 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 242 AC_ARG_ENABLE(fhs,
 243         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 244         if test "$enableval" = "yes"; then
 245                 bindir="/bin"
 246                 sbindir="/sbin"
 247                 sysconfdir="/etc"
 248                 libdir="/lib"
 249                 localstatedir="/var"
 250                 mandir="/usr/share/man"
 251                 uams_path="${libdir}/netatalk"
 252                 PKGCONFDIR="${sysconfdir}"
 253                 SERVERTEXT="${localstatedir}/netatalk/msg"
 254                 use_pam_so=yes
 255                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 256                 AC_MSG_RESULT([yes])
 257         atalk_cv_fhs_compat=yes
 258         else
 259                 AC_MSG_RESULT([no])
 260         atalk_cv_fhs_compat=no
 261         fi
 262         ],[
 263                 AC_MSG_RESULT([no])
 264         atalk_cv_fhs_compat=no
 265 ])])
 266
 267 dnl netatalk lockfile path
 268 AC_DEFUN([AC_NETATALK_LOCKFILE], [
 269     AC_MSG_CHECKING([netatalk lockfile path])
 270     AC_ARG_WITH(
 271         lockfile,
 272         [AS_HELP_STRING([--with-lockfile=PATH],[Path of netatalk lockfile])],
 273         ac_cv_netatalk_lock=$withval,
 274         ac_cv_netatalk_lock=""
 275     )
 276     if test -z "$ac_cv_netatalk_lock" ; then
 277         ac_cv_netatalk_lock=/var/spool/locks/netatalk
 278         if test x"$atalk_cv_fhs_compat" = x"yes" ; then
 279             ac_cv_netatalk_lock=/var/run/netatalk.pid
 280         else
 281             case "$host_os" in
 282             *freebsd*)
 283                 ac_cv_netatalk_lock=/var/spool/lock/netatalk
 284                 ;;
 285             *netbsd*|*openbsd*)
 286                 ac_cv_netatalk_lock=/var/run/netatalk.pid
 287                 ;;
 288             *linux*)
 289                 ac_cv_netatalk_lock=/var/lock/netatalk
 290                 ;;
 291             esac
 292         fi
 293     fi
 294     AC_DEFINE_UNQUOTED(PATH_NETATALK_LOCK, ["$ac_cv_netatalk_lock"], [netatalk lockfile path])
 295     AC_SUBST(PATH_NETATALK_LOCK, ["$ac_cv_netatalk_lock"])
 296     AC_MSG_RESULT([$ac_cv_netatalk_lock])
 297 ])
 298
 299 dnl 64bit platform check
 300 AC_DEFUN([AC_NETATALK_64BIT_LIBS], [
 301 AC_MSG_CHECKING([whether to check for 64bit libraries])
 302 # Test if the compiler is in 64bit mode
 303 echo 'int i;' > conftest.$ac_ext
 304 atalk_cv_cc_64bit_output=no
 305 if AC_TRY_EVAL(ac_compile); then
 306     case `/usr/bin/file conftest.$ac_objext` in
 307     *"ELF 64"*)
 308       atalk_cv_cc_64bit_output=yes
 309       ;;
 310     esac
 311 fi
 312 rm -rf conftest*
 313
 314 case $host_cpu:$atalk_cv_cc_64bit_output in
 315 powerpc64:yes | s390x:yes | sparc*:yes | x86_64:yes | i386:yes)
 316     case $target_os in
 317     solaris2*)
 318         AC_MSG_RESULT([yes])
 319         atalk_libname="lib/64"
 320         ;;
 321     *bsd* | dragonfly*)
 322         AC_MSG_RESULT([no])
 323         atalk_libname="lib"
 324         ;;
 325     *)
 326         AC_MSG_RESULT([yes])
 327         atalk_libname="lib64"
 328         ;;
 329     esac
 330     ;;
 331 *:*)
 332     AC_MSG_RESULT([no])
 333     atalk_libname="lib"
 334     ;;
 335 esac
 336 ])
 337
 338 dnl Check for optional admin group support
 339 AC_DEFUN([AC_NETATALK_ADMIN_GROUP], [
 340     netatalk_cv_admin_group=yes
 341     AC_MSG_CHECKING([for administrative group support])
 342     AC_ARG_ENABLE(admin-group,
 343             [  --disable-admin-group   disable admin group],[
 344             if test x"$enableval" = x"no"; then
 345                          AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 346                          netatalk_cv_admin_group=no
 347                          AC_MSG_RESULT([no])
 348                 else
 349                          AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 350                          AC_MSG_RESULT([yes])
 351             fi],[
 352                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 353                 AC_MSG_RESULT([yes])
 354         ])
 355 ])
 356
 357 dnl Check for optional cracklib support
 358 AC_DEFUN([AC_NETATALK_CRACKLIB], [
 359 netatalk_cv_with_cracklib=no
 360 AC_ARG_WITH(cracklib,
 361         [  --with-cracklib[[=DICT]]  enable/set location of cracklib dictionary [[no]]],[
 362         if test "x$withval" != "xno" ; then
 363                 cracklib="$withval"
 364                 AC_CHECK_LIB(crack, main, [
 365                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 366                         LIBS="$LIBS -lcrack"
 367                         if test "$cracklib" = "yes"; then
 368                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 369                         fi
 370                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 371                                 [path to cracklib dictionary])
 372                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 373                         netatalk_cv_with_cracklib=yes
 374                         ],[
 375                         AC_MSG_ERROR([cracklib not found!])
 376                         ]
 377                 )
 378         fi
 379         ]
 380 )
 381 AC_MSG_CHECKING([for cracklib support])
 382 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 383 ])
 384
 385 dnl Check whether to enable debug code
 386 AC_DEFUN([AC_NETATALK_DEBUG], [
 387 AC_MSG_CHECKING([whether to enable verbose debug code])
 388 AC_ARG_ENABLE(debug,
 389         [  --enable-debug          enable verbose debug code],[
 390         if test "$enableval" != "no"; then
 391                 if test "$enableval" = "yes"; then
 392                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 393                 else
 394                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 395                 fi
 396                 AC_MSG_RESULT([yes])
 397         else
 398                 AC_MSG_RESULT([no])
 399         AC_DEFINE(NDEBUG, 1, [Disable assertions])
 400         fi
 401         ],[
 402                 AC_MSG_RESULT([no])
 403         AC_DEFINE(NDEBUG, 1, [Disable assertions])
 404         ]
 405 )
 406 ])
 407
 408 dnl Check whethe to disable tickle SIGALARM stuff, which eases debugging
 409 AC_DEFUN([AC_NETATALK_DEBUGGING], [
 410 AC_MSG_CHECKING([whether to enable debugging with debuggers])
 411 AC_ARG_ENABLE(debugging,
 412         [  --enable-debugging      disable SIGALRM timers and DSI tickles (eg for debugging with gdb/dbx/...)],[
 413         if test "$enableval" != "no"; then
 414                 if test "$enableval" = "yes"; then
 415                         AC_DEFINE(DEBUGGING, 1, [Define if you want to disable SIGALRM timers and DSI tickles])
 416                 else
 417                         AC_DEFINE_UNQUOTED(DEBUGGING, $enableval, [Define if you want to disable SIGALRM timers and DSI tickles])
 418                 fi
 419                 AC_MSG_RESULT([yes])
 420         else
 421                 AC_MSG_RESULT([no])
 422         fi
 423         ],[
 424                 AC_MSG_RESULT([no])
 425         ]
 426 )
 427
 428 ])
 429
 430 dnl Check for optional shadow password support
 431 AC_DEFUN([AC_NETATALK_SHADOW], [
 432 netatalk_cv_use_shadowpw=no
 433 AC_ARG_WITH(shadow,
 434         [  --with-shadow           enable shadow password support [[auto]]],
 435         [netatalk_cv_use_shadowpw="$withval"],
 436         [netatalk_cv_use_shadowpw=auto]
 437 )
 438
 439 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 440     AC_CHECK_HEADER([shadow.h])
 441     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 442         netatalk_cv_use_shadowpw=yes
 443         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 444     else
 445       if test "x$shadowpw" = "xyes"; then
 446         AC_MSG_ERROR([shadow support not available])
 447       else
 448         netatalk_cv_use_shadowpw=no
 449       fi
 450     fi
 451 fi
 452
 453 AC_MSG_CHECKING([whether shadow support should be enabled])
 454 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 455         AC_MSG_RESULT([yes])
 456 else
 457         AC_MSG_RESULT([no])
 458 fi
 459 ])
 460
 461 dnl Check for optional valid-shell-check support
 462 AC_DEFUN([AC_NETATALK_SHELL_CHECK], [
 463 netatalk_cv_use_shellcheck=yes
 464 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 465 AC_ARG_ENABLE(shell-check,
 466         [  --disable-shell-check   disable checking for a valid shell],[
 467         if test "$enableval" = "no"; then
 468                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 469                 AC_MSG_RESULT([no])
 470                 netatalk_cv_use_shellcheck=no
 471         else
 472                 AC_MSG_RESULT([yes])
 473         fi
 474         ],[
 475                 AC_MSG_RESULT([yes])
 476         ]
 477 )
 478 ])
 479
 480 dnl Check for optional initscript install
 481 AC_DEFUN([AC_NETATALK_INIT_STYLE], [
 482     AC_ARG_WITH(init-style,
 483                 [  --with-init-style       use OS specific init config [[redhat-sysv|redhat-systemd|suse-sysv|suse-systemd|gentoo|netbsd|debian|solaris|systemd]]],
 484                 init_style="$withval", init_style=none
 485     )
 486     case "$init_style" in
 487     "redhat")
 488             AC_MSG_ERROR([--with-init-style=redhat is obsoleted. Use redhat-sysv or redhat-systemd.])
 489         ;;
 490     "redhat-sysv")
 491             AC_MSG_RESULT([enabling redhat-style sysv initscript support])
 492             ac_cv_init_dir="/etc/rc.d/init.d"
 493             ;;
 494     "redhat-systemd")
 495             AC_MSG_RESULT([enabling redhat-style systemd support])
 496             ac_cv_init_dir="/usr/lib/systemd/system"
 497             ;;
 498     "suse")
 499             AC_MSG_ERROR([--with-init-style=suse is obsoleted. Use suse-sysv or suse-systemd.])
 500         ;;
 501     "suse-sysv")
 502             AC_MSG_RESULT([enabling suse-style sysv initscript support])
 503             ac_cv_init_dir="/etc/init.d"
 504             ;;
 505     "suse-systemd")
 506             AC_MSG_RESULT([enabling suse-style systemd support (>=openSUSE12.1)])
 507             ac_cv_init_dir="/usr/lib/systemd/system"
 508             ;;
 509     "gentoo")
 510             AC_MSG_RESULT([enabling gentoo-style initscript support])
 511             ac_cv_init_dir="/etc/init.d"
 512         ;;
 513     "netbsd")
 514             AC_MSG_RESULT([enabling netbsd-style initscript support])
 515             ac_cv_init_dir="/etc/rc.d"
 516         ;;
 517     "debian")
 518             AC_MSG_RESULT([enabling debian-style initscript support])
 519             ac_cv_init_dir="/etc/init.d"
 520         ;;
 521     "solaris")
 522             AC_MSG_RESULT([enabling solaris-style SMF support])
 523             ac_cv_init_dir="/lib/svc/manifest/network/"
 524         ;;
 525     "systemd")
 526             AC_MSG_RESULT([enabling general systemd support])
 527             ac_cv_init_dir="/usr/lib/systemd/system"
 528         ;;
 529     "none")
 530             AC_MSG_RESULT([disabling init-style support])
 531             ac_cv_init_dir="none"
 532         ;;
 533     *)
 534             AC_MSG_ERROR([illegal init-style])
 535         ;;
 536     esac
 537     AM_CONDITIONAL(USE_NETBSD, test x$init_style = xnetbsd)
 538     AM_CONDITIONAL(USE_REDHAT_SYSV, test x$init_style = xredhat-sysv)
 539     AM_CONDITIONAL(USE_SUSE_SYSV, test x$init_style = xsuse-sysv)
 540     AM_CONDITIONAL(USE_SOLARIS, test x$init_style = xsolaris)
 541     AM_CONDITIONAL(USE_GENTOO, test x$init_style = xgentoo)
 542     AM_CONDITIONAL(USE_DEBIAN, test x$init_style = xdebian)
 543     AM_CONDITIONAL(USE_SYSTEMD, test x$init_style = xsystemd || test x$init_style = xredhat-systemd || test x$init_style = xsuse-systemd)
 544     AM_CONDITIONAL(USE_UNDEF, test x$init_style = xnone)
 545
 546     AC_ARG_WITH(init-dir,
 547                 [  --with-init-dir=PATH    path to OS specific init directory],
 548                 ac_cv_init_dir="$withval", ac_cv_init_dir="$ac_cv_init_dir"
 549     )
 550     INIT_DIR="$ac_cv_init_dir"
 551     AC_SUBST(INIT_DIR, ["$ac_cv_init_dir"])
 552 ])
 553
 554 dnl OS specific configuration
 555 AC_DEFUN([AC_NETATALK_OS_SPECIFIC], [
 556 case "$host_os" in
 557         *aix*)                          this_os=aix ;;
 558         *freebsd*)                      this_os=freebsd ;;
 559         *hpux11*)                       this_os=hpux11 ;;
 560         *irix*)                         this_os=irix ;;
 561         *linux*)                        this_os=linux ;;
 562         *osx*)                          this_os=macosx ;;
 563         *darwin*)                       this_os=macosx ;;
 564         *netbsd*)                       this_os=netbsd ;;
 565         *openbsd*)                      this_os=openbsd ;;
 566         *osf*)                          this_os=tru64 ;;
 567         *solaris*)                      this_os=solaris ;;
 568 esac
 569
 570 case "$host_cpu" in
 571         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 572         alpha)                                          this_cpu=alpha ;;
 573         mips)                                           this_cpu=mips ;;
 574         powerpc|ppc)                            this_cpu=ppc ;;
 575 esac
 576
 577 dnl --------------------- GNU source
 578 case "$this_os" in
 579         linux)  AC_DEFINE(_GNU_SOURCE, 1, [Whether to use GNU libc extensions])
 580         ;;
 581      kfreebsd-gnu) AC_DEFINE(_GNU_SOURCE, 1, [Whether to use GNU libc extensions])
 582         ;;
 583 esac
 584
 585 dnl --------------------- operating system specific flags (port from sys/*)
 586
 587 dnl ----- FreeBSD specific -----
 588 if test x"$this_os" = "xfreebsd"; then
 589         AC_MSG_RESULT([ * FreeBSD specific configuration])
 590         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 591         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 592     AC_DEFINE(OPEN_NOFOLLOW_ERRNO, EMLINK, errno returned by open with O_NOFOLLOW)
 593 fi
 594
 595 dnl ----- GNU/kFreeBSD specific -----
 596 if test x"$this_os" = "xkfreebsd-gnu"; then
 597         AC_MSG_RESULT([ * GNU/kFreeBSD specific configuration])
 598         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 599         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 600     AC_DEFINE(OPEN_NOFOLLOW_ERRNO, EMLINK, errno returned by open with O_NOFOLLOW)
 601 fi
 602
 603 dnl ----- Linux specific -----
 604 if test x"$this_os" = "xlinux"; then
 605         AC_MSG_RESULT([ * Linux specific configuration])
 606     AC_DEFINE(LINUX, 1, [OS is Linux])
 607         dnl ----- check if we need the quotactl wrapper
 608     AC_CHECK_HEADERS(linux/dqblk_xfs.h,,
 609                 [AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 610                 AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)]
 611         )
 612
 613
 614         dnl ----- as far as I can tell, dbtob always does the wrong thing
 615         dnl ----- on every single version of linux I've ever played with.
 616         dnl ----- see etc/afpd/quota.c
 617         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 618
 619         need_dash_r=no
 620 fi
 621
 622 dnl ----- NetBSD specific -----
 623 if test x"$this_os" = "xnetbsd"; then
 624         AC_MSG_RESULT([ * NetBSD specific configuration])
 625         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 626         AC_DEFINE(NETBSD, 1, [Define if OS is NetBSD])
 627     AC_DEFINE(OPEN_NOFOLLOW_ERRNO, EFTYPE, errno returned by open with O_NOFOLLOW)
 628
 629         CFLAGS="-I\$(top_srcdir)/sys/netbsd $CFLAGS"
 630         need_dash_r=yes
 631
 632         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 633         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 634 fi
 635
 636 dnl ----- OpenBSD specific -----
 637 if test x"$this_os" = "xopenbsd"; then
 638         AC_MSG_RESULT([ * OpenBSD specific configuration])
 639     AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 640         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 641         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 642 fi
 643
 644 dnl ----- Solaris specific -----
 645 if test x"$this_os" = "xsolaris"; then
 646         AC_MSG_RESULT([ * Solaris specific configuration])
 647         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 648         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 649         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 650         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 651     AC_DEFINE(_XOPEN_SOURCE, 600, [Solaris compilation environment])
 652     AC_DEFINE(__EXTENSIONS__,  1, [Solaris compilation environment])
 653         need_dash_r=yes
 654         init_style=solaris
 655 fi
 656
 657 dnl Whether to run ldconfig after installing libraries
 658 AC_PATH_PROG(NETA_LDCONFIG, ldconfig, , [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/bin$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/usr/bin])
 659 echo NETA_LDCONFIG = $NETA_LDCONFIG
 660 AM_CONDITIONAL(RUN_LDCONFIG, test x"$this_os" = x"linux" -a x"$NETA_LDCONFIG" != x"")
 661 ])
 662
 663 dnl Check for building PGP UAM module
 664 AC_DEFUN([AC_NETATALK_PGP_UAM], [
 665 AC_MSG_CHECKING([whether the PGP UAM should be build])
 666 AC_ARG_ENABLE(pgp-uam,
 667         [  --enable-pgp-uam        enable build of PGP UAM module],[
 668         if test "$enableval" = "yes"; then
 669                 if test "x$neta_cv_have_openssl" = "xyes"; then
 670                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 671                         compile_pgp=yes
 672                         AC_MSG_RESULT([yes])
 673                 else
 674                         AC_MSG_RESULT([no])
 675                 fi
 676         fi
 677         ],[
 678                 AC_MSG_RESULT([no])
 679         ]
 680 )
 681 ])
 682
 683 dnl Check for building Kerberos V UAM module
 684 AC_DEFUN([AC_NETATALK_KRB5_UAM], [
 685 netatalk_cv_build_krb5_uam=no
 686 AC_ARG_ENABLE(krbV-uam,
 687         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 688         [
 689                 if test x"$enableval" = x"yes"; then
 690                         NETATALK_GSSAPI_CHECK([
 691                                 netatalk_cv_build_krb5_uam=yes
 692                         ],[
 693                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 694                         ])
 695                 fi
 696         ]
 697
 698 )
 699
 700 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 701 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 702         AC_MSG_RESULT([yes])
 703 else
 704         AC_MSG_RESULT([no])
 705 fi
 706 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 707 ])
 708
 709 dnl Check if we can directly use Kerberos 5 API, used for reading keytabs
 710 dnl and automatically construction DirectoryService names from that, instead
 711 dnl of requiring special configuration in afp.conf
 712 AC_DEFUN([AC_NETATALK_KERBEROS], [
 713 AC_MSG_CHECKING([for Kerberos 5 (necessary for GetSrvrInfo:DirectoryNames support)])
 714 AC_ARG_WITH([kerberos],
 715     [AS_HELP_STRING([--with-kerberos], [Kerberos 5 support (default=auto)])],
 716     [],
 717     [with_kerberos=auto])
 718 AC_MSG_RESULT($with_kerberos)
 719
 720 if test x"$with_kerberos" != x"no"; then
 721    have_krb5_header="no"
 722    AC_CHECK_HEADERS([krb5/krb5.h krb5.h], [have_krb5_header="yes"; break])
 723    if test x"$have_krb5_header" = x"no" && test x"$with_kerberos" != x"auto"; then
 724       AC_MSG_FAILURE([--with-kerberos was given, but no headers found])
 725    fi
 726
 727    AC_PATH_PROG([KRB5_CONFIG], [krb5-config])
 728    AC_MSG_CHECKING([for krb5-config])
 729    if test -x "$KRB5_CONFIG"; then
 730       AC_MSG_RESULT([$KRB5_CONFIG])
 731       KRB5_CFLAGS="`$KRB5_CONFIG --cflags krb5`"
 732       KRB5_LIBS="`$KRB5_CONFIG --libs krb5`"
 733       AC_SUBST(KRB5_CFLAGS)
 734       AC_SUBST(KRB5_LIBS)
 735       with_kerberos="yes"
 736    else
 737       AC_MSG_RESULT([not found])
 738       if test x"$with_kerberos" != x"auto"; then
 739          AC_MSG_FAILURE([--with-kerberos was given, but krb5-config could not be found])
 740       fi
 741    fi
 742 fi
 743
 744 if test x"$with_kerberos" = x"yes"; then
 745    AC_DEFINE([HAVE_KERBEROS], [1], [Define if Kerberos 5 is available])
 746 fi
 747
 748 dnl Check for krb5_free_unparsed_name and krb5_free_error_message
 749 save_CFLAGS="$CFLAGS"
 750 save_LIBS="$LIBS"
 751 CFLAGS="$KRB5_CFLAGS"
 752 LIBS="$KRB5_LIBS"
 753 AC_CHECK_FUNCS([krb5_free_unparsed_name krb5_free_error_message krb5_free_keytab_entry_contents krb5_kt_free_entry])
 754 CFLAGS="$save_CFLAGS"
 755 LIBS="$save_LIBS"
 756 ])
 757
 758 dnl Check for overwrite the config files or not
 759 AC_DEFUN([AC_NETATALK_OVERWRITE_CONFIG], [
 760 AC_MSG_CHECKING([whether configuration files should be overwritten])
 761 AC_ARG_ENABLE(overwrite,
 762         [  --enable-overwrite      overwrite configuration files during installation],
 763         [OVERWRITE_CONFIG="${enable_overwrite}"],
 764         [OVERWRITE_CONFIG="no"]
 765 )
 766 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 767 AC_SUBST(OVERWRITE_CONFIG)
 768 ])
 769
 770 dnl Check for LDAP support, for client-side ACL visibility
 771 AC_DEFUN([AC_NETATALK_LDAP], [
 772 AC_MSG_CHECKING(for LDAP (necessary for client-side ACL visibility))
 773 AC_ARG_WITH(ldap,
 774     [AS_HELP_STRING([--with-ldap[[=PATH]]],
 775         [LDAP support (default=auto)])],
 776         netatalk_cv_ldap=$withval,
 777         netatalk_cv_ldap=auto
 778         )
 779 AC_MSG_RESULT($netatalk_cv_ldap)
 780
 781 save_CFLAGS="$CFLAGS"
 782 save_LDFLAGS="$LDFLAGS"
 783 save_LIBS="$LIBS"
 784 CFLAGS=""
 785 LDFLAGS=""
 786 LIBS=""
 787 LDAP_CFLAGS=""
 788 LDAP_LDFLAGS=""
 789 LDAP_LIBS=""
 790
 791 if test x"$netatalk_cv_ldap" != x"no" ; then
 792    if test x"$netatalk_cv_ldap" != x"yes" -a x"$netatalk_cv_ldap" != x"auto"; then
 793        CFLAGS="-I$netatalk_cv_ldap/include"
 794        LDFLAGS="-L$netatalk_cv_ldap/lib"
 795    fi
 796         AC_CHECK_HEADER([ldap.h], netatalk_cv_ldap=yes,
 797         [ if test x"$netatalk_cv_ldap" = x"yes" ; then
 798             AC_MSG_ERROR([Missing LDAP headers])
 799         fi
 800                 netatalk_cv_ldap=no
 801         ])
 802         AC_CHECK_LIB(ldap, ldap_init, netatalk_cv_ldap=yes,
 803         [ if test x"$netatalk_cv_ldap" = x"yes" ; then
 804             AC_MSG_ERROR([Missing LDAP library])
 805         fi
 806                 netatalk_cv_ldap=no
 807         ])
 808 fi
 809
 810 if test x"$netatalk_cv_ldap" = x"yes"; then
 811     LDAP_CFLAGS="$CFLAGS"
 812     LDAP_LDFLAGS="$LDFLAGS"
 813     LDAP_LIBS="-lldap"
 814         AC_DEFINE(HAVE_LDAP,1,[Whether LDAP is available])
 815 fi
 816
 817 AC_SUBST(LDAP_CFLAGS)
 818 AC_SUBST(LDAP_LDFLAGS)
 819 AC_SUBST(LDAP_LIBS)
 820 CFLAGS="$save_CFLAGS"
 821 LDFLAGS="$save_LDFLAGS"
 822 LIBS="$save_LIBS"
 823 ])
 824
 825 dnl Check for ACL support
 826 AC_DEFUN([AC_NETATALK_ACL], [
 827 ac_cv_have_acls=no
 828 AC_MSG_CHECKING(whether to support ACLs)
 829 AC_ARG_WITH(acls,
 830     [AS_HELP_STRING([--with-acls],
 831         [Include ACL support (default=auto)])],
 832     [ case "$withval" in
 833       yes|no)
 834           with_acl_support="$withval"
 835                   ;;
 836       *)
 837           with_acl_support=auto
 838           ;;
 839       esac ],
 840     [with_acl_support=auto])
 841 AC_MSG_RESULT($with_acl_support)
 842
 843 if test x"$with_acl_support" = x"no"; then
 844         AC_MSG_RESULT(Disabling ACL support)
 845 fi
 846
 847 # Platform specific checks
 848 if test x"$with_acl_support" != x"no" ; then
 849         case "$host_os" in
 850         *solaris*)
 851                 AC_MSG_NOTICE(Using solaris ACLs)
 852                 AC_DEFINE(HAVE_SOLARIS_ACLS,1,[Whether Solaris ACLs are available])
 853                 AC_DEFINE(HAVE_NFSV4_ACLS,1,[Whether NFSv4 ACLs are available])
 854                 ACL_LIBS="$ACL_LIBS -lsec"
 855                 ac_cv_have_acls=yes
 856                 ;;
 857         *freebsd*)
 858                 AC_MSG_NOTICE(checking whether libsunacl is available)
 859                 sunacl_include_path="/usr/local/include"
 860                 sunacl_lib_path="/usr/local/lib"
 861
 862                 save_CPPFLAGS=$CPPFLAGS
 863                 save_LDFLAGS=$LDFLAGS
 864                 save_LIBS=$LIBS
 865
 866                 CPPFLAGS="-I$sunacl_include_path $CPPFLAGS"
 867                 AC_CHECK_HEADER([sunacl.h])
 868
 869                 LDFLAGS="-L$sunacl_lib_path $LDFLAGS"
 870                 AC_CHECK_LIB([sunacl], [acl])
 871
 872                 if test x"$ac_cv_header_sunacl_h" = x"yes" -a x"$ac_cv_lib_sunacl_acl" = x"yes" ; then
 873                         AC_MSG_NOTICE([Enabling support for ZFS ACLs using libsunacl])
 874                         ac_cv_have_acls=yes
 875                         CFLAGS="-I$sunacl_include_path $CFLAGS"
 876                         ACL_LIBS="$ACL_LIBS -L$sunacl_lib_path -lsunacl"
 877                         AC_DEFINE(HAVE_FREEBSD_SUNACL, 1, [Whether FreeBSD ZFS ACLs with libsunacl are available])
 878                         AC_DEFINE(HAVE_NFSV4_ACLS,1,[Whether NFSv4 ACLs are available])
 879                 else
 880                         AC_MSG_NOTICE([libsunacl not found, disabling ZFS ACL support])
 881                 fi
 882
 883                 CPPFLAGS=$save_CPPFLAGS
 884                 LDFLAGS=$save_LDFLAGS
 885                 LIBS=$save_LIBS
 886                 ;;
 887         esac
 888 fi
 889
 890 if test x"$with_acl_support" != x"no" -a x"$ac_cv_have_acls" != x"yes" ; then
 891         # Runtime checks for POSIX ACLs
 892         AC_CHECK_LIB(acl,acl_get_file,[ACL_LIBS="$ACL_LIBS -lacl"])
 893         case "$host_os" in
 894         *linux*)
 895                 AC_CHECK_LIB(attr,getxattr,[ACL_LIBS="$ACL_LIBS -lattr"])
 896                 ;;
 897         esac
 898
 899         AC_CACHE_CHECK([for POSIX ACL support],netatalk_cv_HAVE_POSIX_ACLS,[
 900                 acl_LIBS=$LIBS
 901                 LIBS="$LIBS $ACL_LIBS"
 902                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 903                         #include <sys/types.h>
 904                         #include <sys/acl.h>
 905                 ]], [[
 906                         acl_t acl;
 907                         int entry_id;
 908                         acl_entry_t *entry_p;
 909                         return acl_get_entry(acl, entry_id, entry_p);
 910                 ]])],
 911                         [netatalk_cv_HAVE_POSIX_ACLS=yes; ac_cv_have_acls=yes],
 912                         [netatalk_cv_HAVE_POSIX_ACLS=no; ac_cv_have_acls=no]
 913                 )
 914                 LIBS=$acl_LIBS
 915         ])
 916
 917         if test x"$netatalk_cv_HAVE_POSIX_ACLS" = x"yes"; then
 918                 AC_MSG_NOTICE(Using POSIX ACLs)
 919                 AC_DEFINE(HAVE_POSIX_ACLS,1,[Whether POSIX ACLs are available])
 920
 921                 AC_CACHE_CHECK([for acl_get_perm_np],netatalk_cv_HAVE_ACL_GET_PERM_NP,[
 922                         acl_LIBS=$LIBS
 923                         LIBS="$LIBS $ACL_LIBS"
 924                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 925                                 #include <sys/types.h>
 926                                 #include <sys/acl.h>
 927                         ]], [[
 928                                 acl_permset_t permset_d;
 929                                 acl_perm_t perm;
 930                                 return acl_get_perm_np(permset_d, perm);
 931                         ]])],[netatalk_cv_HAVE_ACL_GET_PERM_NP=yes],[netatalk_cv_HAVE_ACL_GET_PERM_NP=no])
 932                         LIBS=$acl_LIBS
 933                 ])
 934                 if test x"$netatalk_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 935                         AC_DEFINE(HAVE_ACL_GET_PERM_NP,1,[Whether acl_get_perm_np() is available])
 936                 fi
 937
 938                 AC_CACHE_CHECK([for acl_from_mode], netatalk_cv_HAVE_ACL_FROM_MODE,[
 939                         acl_LIBS=$LIBS
 940                         LIBS="$LIBS $ACL_LIBS"
 941                         AC_CHECK_FUNCS(acl_from_mode,
 942                                 [netatalk_cv_HAVE_ACL_FROM_MODE=yes],
 943                                 [netatalk_cv_HAVE_ACL_FROM_MODE=no]
 944                         )
 945                         LIBS=$acl_LIBS
 946                 ])
 947                 if test x"netatalk_cv_HAVE_ACL_FROM_MODE" = x"yes"; then
 948                    AC_DEFINE(HAVE_ACL_FROM_MODE,1,[Whether acl_from_mode() is available])
 949                 fi
 950         fi
 951 fi
 952
 953 if test x"$ac_cv_have_acls" = x"no" ; then
 954         if test x"$with_acl_support" = x"yes" ; then
 955                 AC_MSG_ERROR(ACL support requested but not found)
 956         else
 957                 AC_MSG_NOTICE(ACL support is not avaliable)
 958         fi
 959 else
 960         AC_CHECK_HEADERS([acl/libacl.h])
 961         AC_DEFINE(HAVE_ACLS,1,[Whether ACLs support is available])
 962 fi
 963 AC_SUBST(ACL_LIBS)
 964 ])
 965
 966 dnl Check for Extended Attributes support
 967 AC_DEFUN([AC_NETATALK_EXTENDED_ATTRIBUTES], [
 968 neta_cv_eas="ad"
 969 neta_cv_eas_sys_found=no
 970 neta_cv_eas_sys_not_found=no
 971
 972 AC_CHECK_HEADERS(sys/attributes.h attr/xattr.h sys/xattr.h sys/extattr.h sys/uio.h sys/ea.h)
 973
 974 case "$this_os" in
 975
 976   *osf*)
 977         AC_SEARCH_LIBS(getproplist, [proplist])
 978         AC_CHECK_FUNCS([getproplist fgetproplist setproplist fsetproplist],
 979                    [neta_cv_eas_sys_found=yes],
 980                    [neta_cv_eas_sys_not_found=yes])
 981         AC_CHECK_FUNCS([delproplist fdelproplist add_proplist_entry get_proplist_entry],,
 982                    [neta_cv_eas_sys_not_found=yes])
 983         AC_CHECK_FUNCS([sizeof_proplist_entry],,
 984                    [neta_cv_eas_sys_not_found=yes])
 985   ;;
 986
 987   *solaris*)
 988         AC_CHECK_FUNCS([attropen],
 989                    [neta_cv_eas_sys_found=yes; AC_DEFINE(HAVE_EAFD, 1, [extattr API has full fledged fds for EAs])],
 990                    [neta_cv_eas_sys_not_found=yes])
 991   ;;
 992
 993   'freebsd')
 994     AC_CHECK_FUNCS([extattr_delete_fd extattr_delete_file extattr_delete_link],
 995                    [neta_cv_eas_sys_found=yes],
 996                    [neta_cv_eas_sys_not_found=yes])
 997     AC_CHECK_FUNCS([extattr_get_fd extattr_get_file extattr_get_link],,
 998                    [neta_cv_eas_sys_not_found=yes])
 999     AC_CHECK_FUNCS([extattr_list_fd extattr_list_file extattr_list_link],,
1000                    [neta_cv_eas_sys_not_found=yes])
1001     AC_CHECK_FUNCS([extattr_set_fd extattr_set_file extattr_set_link],,
1002                    [neta_cv_eas_sys_not_found=yes])
1003   ;;
1004
1005   *freebsd4* | *dragonfly* )
1006     AC_DEFINE(BROKEN_EXTATTR, 1, [Does extattr API work])
1007   ;;
1008
1009   *)
1010         AC_SEARCH_LIBS(getxattr, [attr])
1011
1012     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1013        AC_CHECK_FUNCS([getxattr lgetxattr fgetxattr listxattr llistxattr],
1014                       [neta_cv_eas_sys_found=yes],
1015                       [neta_cv_eas_sys_not_found=yes])
1016            AC_CHECK_FUNCS([flistxattr removexattr lremovexattr fremovexattr],,
1017                       [neta_cv_eas_sys_not_found=yes])
1018            AC_CHECK_FUNCS([setxattr lsetxattr fsetxattr],,
1019                       [neta_cv_eas_sys_not_found=yes])
1020     fi
1021
1022     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1023            AC_CHECK_FUNCS([getea fgetea lgetea listea flistea llistea],
1024                       [neta_cv_eas_sys_found=yes],
1025                       [neta_cv_eas_sys_not_found=yes])
1026            AC_CHECK_FUNCS([removeea fremoveea lremoveea setea fsetea lsetea],,
1027                       [neta_cv_eas_sys_not_found=yes])
1028     fi
1029
1030     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1031            AC_CHECK_FUNCS([attr_get attr_list attr_set attr_remove],,
1032                       [neta_cv_eas_sys_not_found=yes])
1033        AC_CHECK_FUNCS([attr_getf attr_listf attr_setf attr_removef],,
1034                       [neta_cv_eas_sys_not_found=yes])
1035     fi
1036   ;;
1037 esac
1038
1039 # Do xattr functions take additional options like on Darwin?
1040 if test x"$ac_cv_func_getxattr" = x"yes" ; then
1041         AC_CACHE_CHECK([whether xattr interface takes additional options], smb_attr_cv_xattr_add_opt, [
1042                 old_LIBS=$LIBS
1043                 LIBS="$LIBS $ACL_LIBS"
1044                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1045                         #include <sys/types.h>
1046                         #if HAVE_ATTR_XATTR_H
1047                         #include <attr/xattr.h>
1048                         #elif HAVE_SYS_XATTR_H
1049                         #include <sys/xattr.h>
1050                         #endif
1051                 ]], [[
1052                         getxattr(0, 0, 0, 0, 0, 0);
1053                 ]])],[smb_attr_cv_xattr_add_opt=yes],[smb_attr_cv_xattr_add_opt=no;LIBS=$old_LIBS])
1054         ])
1055         if test x"$smb_attr_cv_xattr_add_opt" = x"yes"; then
1056                 AC_DEFINE(XATTR_ADD_OPT, 1, [xattr functions have additional options])
1057         fi
1058 fi
1059
1060 if test "x$neta_cv_eas_sys_found" = "xyes" ; then
1061    if test "x$neta_cv_eas_sys_not_found" != "xyes" ; then
1062       neta_cv_eas="$neta_cv_eas | sys"
1063    fi
1064 fi
1065 AC_DEFINE_UNQUOTED(EA_MODULES,["$neta_cv_eas"],[Available Extended Attributes modules])
1066 ])
1067
1068 dnl Check for libsmbsharemodes from Samba for Samba/Netatalk access/deny/share modes interop
1069 dnl Defines "neta_cv_have_smbshmd" to "yes" or "no"
1070 dnl AC_SUBST's "SMB_SHAREMODES_CFLAGS" and "SMB_SHAREMODES_LDFLAGS"
1071 dnl AM_CONDITIONAL's "USE_SMB_SHAREMODES"
1072 AC_DEFUN([AC_NETATALK_SMB_SHAREMODES], [
1073     neta_cv_have_smbshmd=no
1074     AC_ARG_WITH(smbsharemodes-lib,
1075                 [  --with-smbsharemodes-lib=PATH        PATH to libsmbsharemodes lib from Samba],
1076                 [SMB_SHAREMODES_LDFLAGS="-L$withval -lsmbsharemodes"]
1077     )
1078     AC_ARG_WITH(smbsharemodes-include,
1079                 [  --with-smbsharemodes-include=PATH    PATH to libsmbsharemodes header from Samba],
1080                 [SMB_SHAREMODES_CFLAGS="-I$withval"]
1081     )
1082     AC_ARG_WITH(smbsharemodes,
1083                 [AS_HELP_STRING([--with-smbsharemodes],[Samba interop (default is yes)])],
1084                 [use_smbsharemodes=$withval],
1085                 [use_smbsharemodes=yes]
1086     )
1087
1088     if test x"$use_smbsharemodes" = x"yes" ; then
1089         AC_MSG_CHECKING([whether to enable Samba/Netatalk access/deny/share-modes interop])
1090
1091         saved_CFLAGS="$CFLAGS"
1092         saved_LDFLAGS="$LDFLAGS"
1093         CFLAGS="$SMB_SHAREMODES_CFLAGS $CFLAGS"
1094         LDFLAGS="$SMB_SHAREMODES_LDFLAGS $LDFLAGS"
1095
1096         AC_LINK_IFELSE(
1097             [#include <unistd.h>
1098              #include <stdio.h>
1099              #include <sys/time.h>
1100              #include <time.h>
1101              #include <stdint.h>
1102              /* From messages.h */
1103              struct server_id {
1104                  pid_t pid;
1105              };
1106              #include "smb_share_modes.h"
1107              int main(void) { (void)smb_share_mode_db_open(""); return 0;}],
1108             [neta_cv_have_smbshmd=yes]
1109         )
1110
1111         AC_MSG_RESULT($neta_cv_have_smbshmd)
1112         AC_SUBST(SMB_SHAREMODES_CFLAGS, [$SMB_SHAREMODES_CFLAGS])
1113         AC_SUBST(SMB_SHAREMODES_LDFLAGS, [$SMB_SHAREMODES_LDFLAGS])
1114         CFLAGS="$saved_CFLAGS"
1115         LDFLAGS="$saved_LDFLAGS"
1116     fi
1117
1118     AM_CONDITIONAL(USE_SMB_SHAREMODES, test x"$neta_cv_have_smbshmd" = x"yes")
1119 ])
1120
1121 dnl ------ Check for sendfile() --------
1122 AC_DEFUN([AC_NETATALK_SENDFILE], [
1123 netatalk_cv_search_sendfile=yes
1124 AC_ARG_ENABLE(sendfile,
1125     [  --disable-sendfile       disable sendfile syscall],
1126     [if test x"$enableval" = x"no"; then
1127             netatalk_cv_search_sendfile=no
1128         fi]
1129 )
1130
1131 if test x"$netatalk_cv_search_sendfile" = x"yes"; then
1132    case "$host_os" in
1133    *linux*)
1134         AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
1135         AC_CHECK_FUNC([sendfile], [netatalk_cv_HAVE_SENDFILE=yes])
1136         ;;
1137
1138     *solaris*)
1139         AC_DEFINE(SENDFILE_FLAVOR_SOLARIS, 1, [Solaris sendfile()])
1140         AC_SEARCH_LIBS(sendfile, sendfile)
1141         AC_CHECK_FUNC([sendfile], [netatalk_cv_HAVE_SENDFILE=yes])
1142         AC_CHECK_FUNCS([sendfilev])
1143         ;;
1144
1145     *freebsd*)
1146         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
1147         AC_CHECK_FUNC([sendfile], [netatalk_cv_HAVE_SENDFILE=yes])
1148         ;;
1149
1150     *)
1151         ;;
1152
1153     esac
1154
1155     if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
1156         AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
1157     fi
1158 fi
1159 ])
1160
1161 dnl ------ Check for recvfile() --------
1162 AC_DEFUN([AC_NETATALK_RECVFILE], [
1163 case "$host_os" in
1164 *linux*)
1165     AC_CHECK_FUNCS([splice], [atalk_cv_use_recvfile=yes])
1166     ;;
1167
1168 *)
1169     ;;
1170
1171 esac
1172
1173 if test x"$atalk_cv_use_recvfile" = x"yes"; then
1174     AC_DEFINE(WITH_RECVFILE, 1, [Whether recvfile should be used])
1175 fi
1176 ])
1177
1178 dnl --------------------- Check if realpath() takes NULL
1179 AC_DEFUN([AC_NETATALK_REALPATH], [
1180 AC_CACHE_CHECK([if the realpath function allows a NULL argument],
1181     neta_cv_REALPATH_TAKES_NULL, [
1182         AC_RUN_IFELSE([AC_LANG_SOURCE([[
1183             #include <stdio.h>
1184             #include <limits.h>
1185             #include <signal.h>
1186
1187             void exit_on_core(int ignored) {
1188                  exit(1);
1189             }
1190
1191             main() {
1192                 char *newpath;
1193                 signal(SIGSEGV, exit_on_core);
1194                 newpath = realpath("/tmp", NULL);
1195                 exit((newpath != NULL) ? 0 : 1);
1196             }]])],[neta_cv_REALPATH_TAKES_NULL=yes],[neta_cv_REALPATH_TAKES_NULL=no],[neta_cv_REALPATH_TAKES_NULL=cross
1197         ])
1198     ]
1199 )
1200
1201 if test x"$neta_cv_REALPATH_TAKES_NULL" = x"yes"; then
1202     AC_DEFINE(REALPATH_TAKES_NULL,1,[Whether the realpath function allows NULL])
1203 fi
1204 ])