etc/spotlight/slmod_sparql_parser.y

   1 %{
   2   #include <atalk/standards.h>
   3
   4   #include <stdbool.h>
   5   #include <stdio.h>
   6   #include <string.h>
   7   #include <time.h>
   8
   9   #include <gio/gio.h>
  10
  11   #include <atalk/talloc.h>
  12   #include <atalk/logger.h>
  13   #include <atalk/errchk.h>
  14   #include <atalk/spotlight.h>
  15
  16   #include "slmod_sparql_map.h"
  17
  18   struct yy_buffer_state;
  19   typedef struct yy_buffer_state *YY_BUFFER_STATE;
  20   extern int yylex (void);
  21   extern void yyerror (char const *);
  22   extern void *yyterminate(void);
  23   extern YY_BUFFER_STATE yy_scan_string( const char *str);
  24   extern void yy_delete_buffer ( YY_BUFFER_STATE buffer );
  25
  26   /* forward declarations */
  27   static const char *map_expr(const char *attr, char op, const char *val);
  28   static const char *map_daterange(const char *dateattr, time_t date1, time_t date2);
  29   static time_t isodate2unix(const char *s);
  30
  31  /* global vars, eg needed by the lexer */
  32   slq_t *ssp_slq;
  33
  34   /* local vars */
  35   static gchar *ssp_result;
  36   static char sparqlvar;
  37   static char *result_limit;
  38 %}
  39
  40 %code provides {
  41   #define SPRAW_TIME_OFFSET 978307200
  42   extern int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result);
  43   extern slq_t *ssp_slq;
  44 }
  45
  46 %union {
  47     int ival;
  48     const char *sval;
  49     bool bval;
  50     time_t tval;
  51 }
  52
  53 %expect 5
  54 %error-verbose
  55
  56 %type <sval> match expr line function
  57 %type <tval> date
  58
  59 %token <sval> WORD
  60 %token <bval> BOOL
  61 %token FUNC_INRANGE
  62 %token DATE_ISO
  63 %token OBRACE CBRACE EQUAL UNEQUAL GT LT COMMA QUOTE
  64 %left AND
  65 %left OR
  66 %%
  67
  68 input:
  69 /* empty */
  70 | input line
  71 ;
  72
  73 line:
  74 expr                           {
  75     if (ssp_slq->slq_result_limit)
  76         result_limit = talloc_asprintf(ssp_slq, "LIMIT %ld", ssp_slq->slq_result_limit);
  77     else
  78         result_limit = "";
  79     ssp_result = talloc_asprintf(ssp_slq,
  80                                  "SELECT ?url WHERE "
  81                                  "{ %s . ?obj nie:url ?url . FILTER(tracker:uri-is-descendant('file://%s/', ?url)) } %s",
  82                                  $1, ssp_slq->slq_vol->v_path, result_limit);
  83     $$ = ssp_result;
  84 }
  85 ;
  86
  87 expr:
  88 BOOL                             {
  89     if ($1 == false)
  90         YYACCEPT;
  91     else
  92         YYABORT;
  93 }
  94 | match OR match                 {
  95     if (!ssp_slq->slq_allow_expr)
  96         YYABORT;
  97     if ($1 == NULL || $3 == NULL)
  98         YYABORT;
  99     if (strcmp($1, $3) != 0)
 100         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 101     else
 102         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 103 }
 104 | match                        {$$ = $1; if ($$ == NULL) YYABORT;}
 105 | function                     {$$ = $1;}
 106 | OBRACE expr CBRACE           {$$ = talloc_asprintf(ssp_slq, "%s", $2);}
 107 | expr AND expr                {
 108     if (!ssp_slq->slq_allow_expr)
 109         YYABORT;
 110     $$ = talloc_asprintf(ssp_slq, "%s . %s", $1, $3);
 111 }
 112 | expr OR expr                 {
 113     if (strcmp($1, $3) != 0)
 114         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 115     else
 116         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 117 }
 118 ;
 119
 120 match:
 121 WORD EQUAL QUOTE WORD QUOTE     {$$ = map_expr($1, '=', $4);}
 122 | WORD UNEQUAL QUOTE WORD QUOTE {$$ = map_expr($1, '!', $4);}
 123 | WORD LT QUOTE WORD QUOTE      {$$ = map_expr($1, '<', $4);}
 124 | WORD GT QUOTE WORD QUOTE      {$$ = map_expr($1, '>', $4);}
 125 | WORD EQUAL QUOTE WORD QUOTE WORD    {$$ = map_expr($1, '=', $4);}
 126 | WORD UNEQUAL QUOTE WORD QUOTE WORD {$$ = map_expr($1, '!', $4);}
 127 | WORD LT QUOTE WORD QUOTE WORD     {$$ = map_expr($1, '<', $4);}
 128 | WORD GT QUOTE WORD QUOTE WORD     {$$ = map_expr($1, '>', $4);}
 129 ;
 130
 131 function:
 132 FUNC_INRANGE OBRACE WORD COMMA date COMMA date CBRACE {$$ = map_daterange($3, $5, $7);}
 133 ;
 134
 135 date:
 136 DATE_ISO OBRACE WORD CBRACE    {$$ = isodate2unix($3);}
 137 | WORD                         {$$ = atoi($1) + SPRAW_TIME_OFFSET;}
 138 ;
 139
 140 %%
 141
 142 static time_t isodate2unix(const char *s)
 143 {
 144     struct tm tm;
 145
 146     if (strptime(s, "%Y-%m-%dT%H:%M:%SZ", &tm) == NULL)
 147         return (time_t)-1;
 148     return mktime(&tm);
 149 }
 150
 151 static const char *map_daterange(const char *dateattr, time_t date1, time_t date2)
 152 {
 153     EC_INIT;
 154     char *result = NULL;
 155     struct spotlight_sparql_map *p;
 156     struct tm *tmp;
 157     char buf1[64], buf2[64];
 158
 159     EC_NULL_LOG( tmp = localtime(&date1) );
 160     strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 161     EC_NULL_LOG( tmp = localtime(&date2) );
 162     strftime(buf2, sizeof(buf2), "%Y-%m-%dT%H:%M:%SZ", tmp);
 163
 164     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 165         if (strcmp(dateattr, p->ssm_spotlight_attr) == 0) {
 166             result = talloc_asprintf(ssp_slq,
 167                                      "?obj %s ?%c FILTER (?%c > '%s' && ?%c < '%s')",
 168                                      p->ssm_sparql_attr,
 169                                      sparqlvar,
 170                                      sparqlvar,
 171                                      buf1,
 172                                      sparqlvar,
 173                                      buf2);
 174             sparqlvar++;
 175             break;
 176         }
 177     }
 178
 179 EC_CLEANUP:
 180     if (ret != 0)
 181         return NULL;
 182     return result;
 183 }
 184
 185 static char *map_type_search(const char *attr, char op, const char *val)
 186 {
 187     char *result = NULL;
 188     const char *sparqlAttr;
 189
 190     for (struct MDTypeMap *p = MDTypeMap; p->mdtm_value; p++) {
 191         if (strcmp(p->mdtm_value, val) == 0) {
 192             switch (p->mdtm_type) {
 193             case kMDTypeMapRDF:
 194                 sparqlAttr = "rdf:type";
 195                 break;
 196             case kMDTypeMapMime:
 197                 sparqlAttr = "nie:mimeType";
 198                 break;
 199             default:
 200                 return NULL;
 201             }
 202             result = talloc_asprintf(ssp_slq, "?obj %s '%s'",
 203                                      sparqlAttr,
 204                                      p->mdtm_sparql);
 205             break;
 206         }
 207     }
 208     return result;
 209 }
 210
 211 static const char *map_expr(const char *attr, char op, const char *val)
 212 {
 213     EC_INIT;
 214     char *result = NULL;
 215     struct spotlight_sparql_map *p;
 216     time_t t;
 217     struct tm *tmp;
 218     char buf1[64];
 219     bstring q = NULL, search = NULL, replace = NULL;
 220
 221     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 222         if (p->ssm_enabled && (strcmp(p->ssm_spotlight_attr, attr) == 0)) {
 223             if (p->ssm_type != ssmt_type && p->ssm_sparql_attr == NULL) {
 224                 yyerror("unsupported Spotlight attribute");
 225                 EC_FAIL;
 226             }
 227             switch (p->ssm_type) {
 228             case ssmt_bool:
 229                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 230                 break;
 231             case ssmt_num:
 232                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c%c '%s')",
 233                                          p->ssm_sparql_attr,
 234                                          sparqlvar,
 235                                          sparqlvar,
 236                                          op,
 237                                          op == '!' ? '=' : ' ', /* append '=' to '!' */
 238                                          val);
 239                 sparqlvar++;
 240                 break;
 241             case ssmt_str:
 242                 q = bformat("^%s$", val);
 243                 search = bfromcstr("*");
 244                 replace = bfromcstr(".*");
 245                 bfindreplace(q, search, replace, 0);
 246                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(regex(?%c, '%s'))",
 247                                          p->ssm_sparql_attr,
 248                                          sparqlvar,
 249                                          sparqlvar,
 250                                          bdata(q));
 251                 sparqlvar++;
 252                 break;
 253             case ssmt_fts:
 254                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 255                 break;
 256             case ssmt_date:
 257                 t = atoi(val) + SPRAW_TIME_OFFSET;
 258                 EC_NULL( tmp = localtime(&t) );
 259                 strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 260                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c '%s')",
 261                                          p->ssm_sparql_attr,
 262                                          sparqlvar,
 263                                          sparqlvar,
 264                                          op,
 265                                          buf1);
 266                 sparqlvar++;
 267                 break;
 268             case ssmt_type:
 269                 result = map_type_search(attr, op, val);
 270                 break;
 271             default:
 272                 EC_FAIL;
 273             }
 274             break;
 275         }
 276     }
 277
 278 EC_CLEANUP:
 279     if (q)
 280         bdestroy(q);
 281     if (search)
 282         bdestroy(search);
 283     if (replace)
 284         bdestroy(replace);
 285     return result;
 286 }
 287
 288 void yyerror(const char *str)
 289 {
 290 #ifdef MAIN
 291     printf("yyerror: %s\n", str);
 292 #else
 293     LOG(log_error, logtype_sl, "yyerror: %s", str);
 294 #endif
 295 }
 296
 297 int yywrap()
 298 {
 299     return 1;
 300 }
 301
 302 /**
 303  * Map a Spotlight RAW query string to a SPARQL query string
 304  *
 305  * @param[in]     slq            Spotlight query handle
 306  * @param[out]    sparql_result  Mapped SPARQL query, string is allocated in
 307  *                               talloc context of slq
 308  * @return        0 on success, -1 on error
 309  **/
 310 int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result)
 311 {
 312     EC_INIT;
 313     YY_BUFFER_STATE s = NULL;
 314     ssp_result = NULL;
 315
 316     ssp_slq = slq;
 317     s = yy_scan_string(slq->slq_qstring);
 318     sparqlvar = 'a';
 319
 320     EC_ZERO( yyparse() );
 321
 322 EC_CLEANUP:
 323     if (s)
 324         yy_delete_buffer(s);
 325     if (ret == 0)
 326         *sparql_result = ssp_result;
 327     else
 328         *sparql_result = NULL;
 329     EC_EXIT;
 330 }
 331
 332 #ifdef MAIN
 333 int main(int argc, char **argv)
 334 {
 335     int ret;
 336     YY_BUFFER_STATE s;
 337
 338     if (argc != 2) {
 339         printf("usage: %s QUERY\n", argv[0]);
 340         return 1;
 341     }
 342
 343     ssp_slq = talloc_zero(NULL, slq_t);
 344     struct vol *vol = talloc_zero(ssp_slq, struct vol);
 345     vol->v_path = "/Volumes/test";
 346     ssp_slq->slq_vol = vol;
 347     ssp_slq->slq_allow_expr = true;
 348     sparqlvar = 'a';
 349
 350     s = yy_scan_string(argv[1]);
 351
 352     ret = yyparse();
 353
 354     yy_delete_buffer(s);
 355
 356     if (ret == 0)
 357         printf("SPARQL: %s\n", ssp_result ? ssp_result : "(empty)");
 358
 359     return 0;
 360 }
 361 #endif