configure.in

   1 dnl $Id: configure.in,v 1.161 2002-08-25 13:26:19 rlewczuk Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(bin/adv1tov2/adv1tov2.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AM_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 dnl Checks for libraries.
  31 dnl Replace `main' with a function in -labs:
  32 AC_CHECK_LIB(abs, main)
  33 dnl Replace `main' with a function in -laudit:
  34 AC_CHECK_LIB(audit, main)
  35 dnl Replace `main' with a function in -lauth:
  36 AC_CHECK_LIB(auth, main)
  37 dnl Replace `main' with a function in -lcmd:
  38 AC_CHECK_LIB(cmd, main)
  39 dnl Replace `main' with a function in -lcrypt:
  40 AC_CHECK_LIB(crypt, main)
  41 dnl Replace `main' with a function in -ld:
  42 AC_CHECK_LIB(d, main)
  43 dnl Replace `main' with a function in -ldl:
  44 AC_CHECK_LIB(dl, main)
  45 dnl Replace `main' with a function in -lkauth:
  46 AC_CHECK_LIB(kauth, main)
  47 dnl Replace `main' with a function in -lkrb:
  48 AC_CHECK_LIB(krb, main)
  49 dnl Replace `main' with a function in -llwp:
  50 AC_CHECK_LIB(lwp, main)
  51 dnl Replace `main' with a function in -ln:
  52 AC_CHECK_LIB(n, main)
  53 dnl Replace `main' with a function in -lnsl:
  54 AC_CHECK_LIB(nsl, main)
  55 dnl Replace `main' with a function in -lprot:
  56 AC_CHECK_LIB(prot, main)
  57 dnl Replace `main' with a function in -lrx:
  58 AC_CHECK_LIB(rx, main)
  59 dnl Replace `main' with a function in -lrxkad:
  60 AC_CHECK_LIB(rxkad, main)
  61 dnl Replace `main' with a function in -lsocket:
  62 AC_CHECK_LIB(socket, main)
  63 dnl Replace `main' with a function in -lsys:
  64 AC_CHECK_LIB(sys, main)
  65 dnl Replace `main' with a function in -lubik:
  66 AC_CHECK_LIB(ubik, main)
  67
  68 #
  69 # Check presence of some functions
  70 #
  71 # Check for XPG4 access() function
  72 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  73 # has such a function that works only on AFS filesystems.
  74 AC_CHECK_FUNCS(access)
  75
  76 dnl Checks for header files.
  77 AC_HEADER_DIRENT
  78 AC_HEADER_STDC
  79 AC_HEADER_SYS_WAIT
  80 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h sys/mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h)
  81 AC_CHECK_HEADER(sys/cdefs.h,,
  82         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  83         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  84 )
  85
  86 dnl Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_UID_T
  89 AC_C_INLINE
  90 AC_TYPE_MODE_T
  91 AC_TYPE_OFF_T
  92 AC_TYPE_PID_T
  93 AC_TYPE_SIZE_T
  94 AC_STRUCT_ST_RDEV
  95 AC_HEADER_TIME
  96 AC_STRUCT_TM
  97
  98 dnl Checks for library functions.
  99 AC_TYPE_GETGROUPS
 100 AC_PROG_GCC_TRADITIONAL
 101 AC_FUNC_MEMCMP
 102 AC_HEADER_MAJOR
 103 AC_FUNC_MMAP
 104 AC_TYPE_SIGNAL
 105 AC_FUNC_UTIME_NULL
 106 AC_FUNC_WAIT3
 107 AC_CHECK_FUNCS(flock getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strstr strtoul setpgrp strchr memcpy)
 108 AC_FUNC_SETPGRP
 109
 110 dnl --------------------------------------------------------------------------
 111 dnl specific configuration comes in here:
 112 dnl --------------------------------------------------------------------------
 113
 114 AC_DEFINE(ADMIN_GRP, 1)
 115
 116 AC_ARG_WITH(admin-group,
 117         [  --disable-admin-group   disable admin group],
 118         if test "$enableval" = "no"; then
 119                 AC_DEFINE(ADMIN_GRP, 0)
 120                 AC_MSG_RESULT([disabling administrative group support])
 121         fi
 122 )
 123
 124 NETATALK_AFS_CHECK
 125
 126 NETATALK_CONFIG_DIRS
 127
 128 AC_ARG_WITH(logfile,
 129         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 130                           use --without-logfile to disable logger],
 131         if test "$withval" = "no"; then
 132                 AC_DEFINE(DISABLE_LOGGER, 1)
 133                 AC_MSG_RESULT([logger disabled])
 134         elif test "$withval" != "yes"; then
 135                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval")
 136                 AC_MSG_RESULT([logfile set to $withval])
 137         else
 138                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log")
 139                 AC_MSG_RESULT([logfile set to default])
 140         fi,
 141                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log")
 142                 AC_MSG_RESULT([logfile set to default])
 143 )
 144
 145 AC_ARG_WITH(cracklib,
 146         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],
 147         if test "x$withval" != "xno" ; then
 148                 cracklib="$withval"
 149                 AC_CHECK_LIB(crack, main,
 150                         AC_DEFINE(USE_CRACKLIB)
 151                         LIBS="$LIBS -lcrack"
 152                         AC_MSG_RESULT([enabling cracklib support])
 153                         if test "$cracklib" = "yes"; then
 154                                 cracklib="/usr/lib/cracklib_dict"
 155                         fi
 156                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 157                                 [path to cracklib dictionary])
 158                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib]),
 159                         AC_MSG_ERROR([cracklib not found!])
 160                 )
 161         fi
 162 )
 163
 164 AC_ARG_ENABLE(ddp,
 165         [  --disable-ddp           disable DDP],
 166         if test "$enableval" = "no"; then
 167                 AC_DEFINE(NO_DDP, 1)
 168                 AC_MSG_RESULT([disabling DDP])
 169         fi
 170 )
 171
 172 AC_ARG_ENABLE(debug,
 173         [  --enable-debug          enable debug code],
 174         if test "$enableval" != "no"; then
 175                 if test "$enableval" = "yes"; then
 176                         AC_DEFINE(DEBUG, 1)
 177                 else
 178                         AC_DEFINE_UNQUOTED(DEBUG, $enableval)
 179                 fi
 180                 AC_MSG_RESULT([enabling debugging code])
 181         fi
 182 )
 183
 184
 185 dnl ----------- A NOTE ABOUT DROPKLUDGE
 186 dnl The trouble with this fix is that if you know what the file is called, it
 187 dnl can be read from the Unix side.  That's okay for most academic institutions
 188 dnl since the students don't have telnet access to the Mac servers.  There is
 189 dnl currently no one working on further development/fixes of DROPKLUDGE.
 190 dnl -----------
 191
 192 AC_ARG_ENABLE(dropkludge,
 193         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],
 194         if test "$enableval" = "yes"; then
 195                 AC_DEFINE(DROPKLUDGE, 1)
 196                 AC_MSG_RESULT([enabling experimental dropbox support])
 197         fi
 198 )
 199
 200 AC_ARG_ENABLE(force-uidgid,
 201         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],
 202         if test "$enableval" = "yes"; then
 203                 AC_DEFINE(FORCE_UIDGID, 1)
 204                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 205         fi
 206 )
 207
 208 dnl Don't use DB3 unless it's needed
 209 db3_required=no
 210
 211 dnl Determine DID scheme
 212 AC_MSG_CHECKING([for DID scheme to use])
 213 AC_ARG_WITH(did,
 214         [  --with-did=SCHEME       set DID scheme (last,hash,mtab,cnid)],
 215         [ did_scheme="$withval" ],
 216         [ did_scheme="last" ]
 217 )
 218
 219 if test "x$did_scheme" = "xlast"; then
 220         AC_DEFINE(USE_LASTDID, 1)
 221         AC_MSG_RESULT([last])
 222 elif test "x$did_scheme" = "xhash"; then
 223         AC_MSG_RESULT([device/inode-based hashing])
 224 elif test "x$did_scheme" = "xmtab"; then
 225         AC_DEFINE(DID_MTAB, 1)
 226         AC_MSG_RESULT([mtab-based DID creation support])
 227 elif test "x$did_scheme" = "xcnid"; then
 228         db3_required="yes"
 229         AC_DEFINE(CNID_DB, 1)
 230         AC_MSG_RESULT([enabling build with CNID DB support])
 231 else
 232         AC_MSG_ERROR([unknown DID scheme])
 233 fi
 234 AM_CONDITIONAL(COMPILE_CNID, test "x$did_scheme" = "xcnid")
 235
 236 dnl Determine whether or not to use filename mangling
 237 AC_MSG_CHECKING([whether or not to use filename mangling])
 238 AC_ARG_WITH(mangling,
 239         [ --with-mangling       enable filename mangling],
 240         if test "$withval" = "yes"; then
 241             if test "x$did_scheme" != "xcnid"; then
 242                 AC_MSG_ERROR([DID scheme must be CNID to use filename mangling])
 243             else
 244                 AC_DEFINE(FILE_MANGLING, 1)
 245                 AC_MSG_RESULT([yes])
 246             fi
 247         fi
 248 )
 249
 250 dnl Check for Berkeley DB3 library
 251 if test "x$db3_required" = "xyes"; then
 252         AC_PATH_DB3(, [AC_MSG_ERROR([Berkeley DB3 library not found!])])
 253 fi
 254
 255 dnl Check for quota support
 256 AC_CHECK_QUOTA
 257
 258 dnl Check for optional server location protocol support (used by MacOS X)
 259 NETATALK_SRVLOC
 260
 261 dnl Check for PAM libs
 262 AC_PATH_PAM([
 263         PAPD_LIBS="$PAPD_LIBS $PAM_LIBS"
 264         AFPD_LIBS="$AFPD_LIBS $PAM_LIBS"
 265         use_pam_so=yes
 266         compile_pam=yes
 267         AC_DEFINE(USE_PAM)
 268 ])
 269
 270 AC_MSG_CHECKING([whether shadow support should be enabled])
 271 AC_ARG_WITH(shadow,
 272         [  --with-shadow           enable shadow password support],
 273         [shadowpw="$withval"],
 274         [shadowpw=no]
 275 )
 276 if test "x$shadowpw" = "xyes"; then
 277         AC_DEFINE(SHADOWPW)
 278 fi
 279 AC_MSG_RESULT([$shadowpw])
 280
 281 AC_ARG_ENABLE(shell-check,
 282         [  --disable-shell-check   disable checking for a valid shell],
 283         if test "$enableval" = "no"; then
 284                 AC_DEFINE(DISABLE_SHELLCHECK, 1)
 285                 AC_MSG_RESULT([disabling valid shell check])
 286         fi
 287 )
 288
 289 AC_MSG_CHECKING([whether flock locks should be enabled])
 290 AC_ARG_WITH(flock-locks,
 291         [  --with-flock-locks      enable flock locks support],
 292         [flock_locks="$withval"],
 293         [flock_locks="no"]
 294 )
 295 if test "x$flock_locks" = "xyes"; then
 296         AC_DEFINE(USE_FLOCK_LOCKS)
 297 fi
 298 AC_MSG_RESULT([$flock_locks])
 299
 300 AC_ARG_WITH(tcp-wrappers,
 301         [  --with-tcp-wrappers     enable TCP wrappers support],
 302         AC_CHECK_LIB(wrap, tcpd_warn,
 303                 AC_DEFINE(TCPWRAP)
 304                 AFPD_LIBS="$AFPD_LIBS -lwrap"
 305                 AC_MSG_RESULT([enabling TCP wrappers support])
 306         )
 307 )
 308
 309 AC_ARG_ENABLE(redhat,
 310         [  --enable-redhat         use redhat-style sysv configuration ],
 311         if test "$enableval" = "yes"; then
 312                 sysv_style=redhat
 313         fi
 314         AC_MSG_RESULT([enabling redhat-style sysv support])
 315 )
 316
 317 AC_ARG_ENABLE(suse,
 318         [  --enable-suse           use suse-style sysv configuration ],
 319         if test "$enableval" = "yes"; then
 320                 sysv_style=suse
 321         fi
 322         AC_MSG_RESULT([enabling suse-style sysv support])
 323 )
 324
 325 AC_ARG_ENABLE(cobalt,
 326         [  --enable-cobalt         use cobalt-style sysv configuration ],
 327         if test "$enableval" = "yes"; then
 328                 sysv_style=cobalt
 329         fi
 330         AC_MSG_RESULT([enabling cobalt-style sysv support])
 331 )
 332
 333 AC_ARG_ENABLE(netbsd,
 334         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 335         if test "x$enableval" = "xyes"; then
 336                 sysv_style=netbsd
 337         fi
 338         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 339 )
 340
 341 dnl ----- timelord compilation (disabled by default)
 342 AC_MSG_CHECKING([whether timelord should be compiled])
 343 compile_timelord=no
 344 AC_ARG_ENABLE(timelord,
 345         [  --enable-timelord       enable compilation of timelord server],
 346         [compile_timelord="$enableval"],
 347         [compile_timelord="no"]
 348 )
 349 AC_MSG_RESULT([$compile_timelord])
 350
 351 AC_ARG_WITH(uams-path,
 352         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],
 353         uams_path="$withval",
 354         uams_path="${PKGCONFDIR}/uams"
 355 )
 356
 357 AC_ARG_WITH(catsearch,
 358         [  --with-catsearch     enable fpCatSearch functionality (experimental)])
 359         if test "$withval" = "yes"; then
 360             AC_DEFINE(WITH_CATSEARCH, 1)
 361         fi
 362
 363 dnl --------------------------------------------------------------------------
 364 dnl FHS stuff has to be done last because it overrides other defaults
 365 dnl --------------------------------------------------------------------------
 366
 367 AC_ARG_ENABLE(fhs,
 368         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],
 369         if test "$enableval" = "yes"; then
 370                 uams_path="/usr/lib/netatalk"
 371                 sysconfdir="/etc"
 372                 PKGCONFDIR=${sysconfdir}/netatalk
 373                 use_pam_so=yes
 374                 mandir="/usr/share/man"
 375                 AC_DEFINE(FHS_COMPATIBILITY)
 376         fi
 377         AC_MSG_RESULT([enabling Filesystem Hierarchy Standard (FHS) compatibility])
 378 )
 379
 380 dnl --------------------------------------------------------------------------
 381 dnl post-FHS substitutions, etc
 382 dnl --------------------------------------------------------------------------
 383
 384 dnl ***** UAMS_PATH
 385 AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 386         [path to UAMs [default=PKGCONF/uams]])
 387 UAMS_PATH="${uams_path}"
 388 AC_SUBST(UAMS_PATH)
 389
 390 dnl --------------------------------------------------------------------------
 391 dnl drop in includes for top level directory structures here...
 392 dnl --------------------------------------------------------------------------
 393
 394 dnl Note: $(top_srcdir)/include should be added before all other includes
 395 dnl       so that includes from that directory a preferred to includes from
 396 dnl       /usr/include or similar places.
 397 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 398 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 399
 400 dnl --------------------------------------------------------------------------
 401 dnl specific configuration comes in here:
 402 dnl --------------------------------------------------------------------------
 403
 404 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 405
 406 dnl --------------------- determine operating system from "target"
 407 case "$host_os" in
 408         *aix*)                          this_os=aix ;;
 409         *freebsd*)                      this_os=freebsd ;;
 410         *hpux11*)                       this_os=hpux11 ;;
 411         *irix*)                         this_os=irix ;;
 412         *linux*)                        this_os=linux ;;
 413         *osx*)                          this_os=macosx ;;
 414         *darwin*)                       this_os=macosx ;;
 415         *netbsd*)                       this_os=netbsd ;;
 416         *openbsd*)                      this_os=openbsd ;;
 417         *osf*)                          this_os=tru64 ;;
 418         *solaris*)                      this_os=solaris ;;
 419 esac
 420
 421 case "$host_cpu" in
 422         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 423         alpha)                                          this_cpu=alpha ;;
 424         mips)                                           this_cpu=mips ;;
 425         powerpc|ppc)                            this_cpu=ppc ;;
 426 esac
 427
 428 dnl --------------------- operating system specific flags (port from sys/*)
 429
 430 dnl ----- AIX specific -----
 431 if test x"$this_os" = "xaix"; then
 432         AC_MSG_RESULT([ * AIX specific configuration])
 433         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 434
 435         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 436         dnl compilation environment.  It's enough to get things defined
 437         dnl right in endian.h provided that long long is supported, though.
 438         AC_DEFINE(HAVE_32BIT_LONGS)
 439 fi
 440
 441 dnl ----- FreeBSD specific -----
 442 if test x"$this_os" = "xfreebsd"; then
 443         AC_MSG_RESULT([ * FreeBSD specific configuration])
 444         AC_DEFINE(BSD4_4)
 445         AC_DEFINE(SENDFILE_FLAVOR_BSD)
 446
 447         AC_DEFINE(NO_CRYPT_H, 1)
 448 fi
 449
 450 dnl ----- HP-UX 11 specific -----
 451 if test x"$this_os" = "xhpux11"; then
 452         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 453
 454         AC_DEFINE(_ISOC9X_SOURCE)
 455         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 456 fi
 457
 458 dnl ----- IRIX specific -----
 459 if test x"$this_os" = "xirix"; then
 460         AC_MSG_RESULT([ * IRIX specific configuration])
 461
 462         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 463 fi
 464
 465 dnl ----- Linux specific -----
 466 if test x"$this_os" = "xlinux"; then
 467         AC_MSG_RESULT([ * Linux specific configuration])
 468
 469         dnl ----- check if we need the quotactl wrapper
 470         AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 471         AC_CHECK_FUNC(quotactl,,
 472                 AC_DEFINE(NEED_QUOTACTL_WRAPPER)
 473                 AC_MSG_RESULT([enabling quotactl wrapper])
 474         )
 475
 476         dnl ----- as far as I can tell, dbtob always does the wrong thing
 477         dnl ----- on every single version of linux I've ever played with.
 478         dnl ----- see etc/afpd/quota.c
 479         AC_DEFINE(HAVE_BROKEN_DBTOB)
 480
 481         dnl --- added by Yoshinobu Ishizaki (2001.03.13) ---
 482         dnl ----- check if version is newer than 2.2.x
 483         changequote(<<,>>)
 484         majorvers="`uname -r | sed 's/\([0-9]\)..*/\1/'`"
 485         minorvers="`uname -r | sed 's/[0-9]\.\([0-9]\)\..*/\1/'`"
 486         if [ $majorvers -ge 2 ]; then
 487                 if [ $minorvers -ge 2 ]; then
 488                         changequote([,])
 489                         AC_MSG_RESULT([ * found Linux 2.2.x or higher])
 490                         AC_DEFINE(SENDFILE_FLAVOR_LINUX)
 491                 else
 492                         AC_MSG_RESULT([ * found Linux 2.0.x ])
 493                 fi
 494         fi
 495
 496         dnl ----- Linux/alpha specific -----
 497         if test x"$this_cpu" = "xalpha"; then
 498                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 499                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG)
 500         fi
 501         need_dash_r=no
 502 fi
 503
 504 dnl ----- Mac OSX specific -----
 505 if test x"$this_os" = "xmacosx"; then
 506         AC_MSG_RESULT([ * Mac OSX specific configuration])
 507         AC_DEFINE(BSD4_4)
 508         AC_DEFINE(HAVE_BROKEN_CPP)
 509         AC_DEFINE(HAVE_2ARG_DBTOB)
 510         dnl AC_DEFINE(NO_DLFCN_H)
 511         AC_DEFINE(MACOSX_SERVER)
 512 fi
 513
 514 dnl ----- NetBSD specific -----
 515 if test x"$this_os" = "xnetbsd"; then
 516         AC_MSG_RESULT([ * NetBSD specific configuration])
 517         AC_DEFINE(BSD4_4)
 518         if echo __ELF__ | $CC -E - | grep __ELF__ > /dev/null; then
 519                 # NetBSD ELF machines don't have to have DLSYM_PREPEND_UNDERSCORE.
 520                 # If this test is true, it's not an ELF box.
 521                 # This REALLY should be a configure test.
 522                 AC_DEFINE(DLSYM_PREPEND_UNDERSCORE)
 523         fi
 524         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 525         need_dash_r=yes
 526
 527         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 528         AC_DEFINE(UAM_DHX, 1)
 529         AC_DEFINE(NO_CRYPT_H, 1)
 530 fi
 531
 532 dnl ----- OpenBSD specific -----
 533 if test x"$this_os" = "xopenbsd"; then
 534         AC_MSG_RESULT([ * OpenBSD specific configuration])
 535         AC_DEFINE(BSD4_4)
 536         AC_DEFINE(DLSYM_PREPEND_UNDERSCORE)
 537
 538         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 539         AC_DEFINE(UAM_DHX, 1)
 540         AC_DEFINE(NO_CRYPT_H, 1)
 541 fi
 542
 543 dnl ----- Solaris specific -----
 544 if test x"$this_os" = "xsolaris"; then
 545         AC_MSG_RESULT([ * Solaris specific configuration])
 546         AC_DEFINE(__svr4__)
 547         AC_DEFINE(_ISOC9X_SOURCE)
 548         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 549         AC_DEFINE(SOLARIS)
 550         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 551         need_dash_r=yes
 552
 553         AC_MSG_RESULT([enabling Solaris kernel module build])
 554         solaris_module=yes
 555 fi
 556
 557 dnl ----- Tru64 specific -----
 558 if test x"$this_os" = "xtru64"; then
 559         AC_MSG_RESULT([ * Tru64 specific configuration])
 560         AC_DEFINE(NO_DDP)
 561         AC_DEFINE(HAVE_64BIT_LONGS)
 562         dnl AC_DEFINE(USE_MOUNT_H)
 563         AC_DEFINE(USE_OLD_RQUOTA)
 564         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 565         AC_DEFINE(TRU64)
 566         AC_CHECK_LIB(security,set_auth_parameters)
 567         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 568         need_dash_r=no
 569         sysv_style=tru64
 570 fi
 571
 572 dnl -- look for openssl
 573 AC_PATH_SSL
 574
 575 dnl --------------------- check for building PGP UAM module
 576
 577 AC_ARG_ENABLE(pgp-uam,
 578         [  --enable-pgp-uam        enable build of PGP UAM module],
 579         if test "$enableval" = "yes"; then
 580                 if test "$compile_ssl" = "yes"; then
 581                         AC_DEFINE(UAM_PGP, 1)
 582                         compile_pgp=yes
 583                         AC_MSG_RESULT([enabling build with PGP UAM module])
 584                 fi
 585         fi
 586 )
 587
 588 dnl --------------------- check for building Kerberos v4 UAM module
 589
 590 AC_ARG_ENABLE(krb4-uam,
 591         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],
 592         if test "$enableval" = "yes"; then
 593                 AC_DEFINE(UAM_KRB4, 1)
 594                 compile_kerberos=yes
 595                 AC_MSG_RESULT([enabling build with Kerberos v4 UAM module])
 596         fi
 597 )
 598 dnl --------------------- overwrite the config files . . . or not.
 599
 600 AC_MSG_CHECKING([whether configuration files should be overwritten])
 601 AC_ARG_ENABLE(overwrite,
 602         [  --enable-overwrite      overwrite configuration files during installation],
 603         [OVERWRITE_CONFIG="${enable_overwrite}"],
 604         [OVERWRITE_CONFIG="no"]
 605 )
 606 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 607
 608 dnl --------------------- last minute substitutions
 609
 610 AC_SUBST(LIBS)
 611 AC_SUBST(AFPD_LIBS)
 612 AC_SUBST(PAPD_LIBS)
 613 AC_SUBST(CFLAGS)
 614 AC_SUBST(OVERWRITE_CONFIG)
 615
 616 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 617 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 618 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 619 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 620 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 621 AM_CONDITIONAL(USE_PAM, test x$compile_pam = xyes)
 622 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 623 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
 624 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 625 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
 626 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
 627 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
 628 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
 629 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
 630
 631 dnl --------------------- generate files
 632
 633 AC_OUTPUT([Makefile
 634         bin/Makefile
 635         bin/adv1tov2/Makefile
 636         bin/aecho/Makefile
 637         bin/afile/Makefile
 638         bin/afppasswd/Makefile
 639         bin/cnid/Makefile
 640         bin/cnid/cnid_maint
 641         bin/getzones/Makefile
 642         bin/megatron/Makefile
 643         bin/nbp/Makefile
 644         bin/pap/Makefile
 645         bin/psorder/Makefile
 646         config/Makefile
 647         contrib/Makefile
 648         contrib/macusers/Makefile
 649         contrib/macusers/macusers
 650         contrib/nu/Makefile
 651         contrib/nu/nu
 652         contrib/printing/Makefile
 653         contrib/shell_utils/Makefile
 654         contrib/shell_utils/afpd-mtab.pl
 655         contrib/shell_utils/apple_cp
 656         contrib/shell_utils/apple_mv
 657         contrib/shell_utils/apple_rm
 658         contrib/shell_utils/cleanappledouble.pl
 659         contrib/shell_utils/netatalkshorternamelinks.pl
 660         contrib/timelord/Makefile
 661         distrib/Makefile
 662         distrib/config/Makefile
 663         distrib/config/netatalk-config
 664         distrib/initscripts/Makefile
 665         distrib/m4/Makefile
 666         doc/Makefile
 667         etc/Makefile
 668         etc/afpd/Makefile
 669         etc/afpd/nls/Makefile
 670         etc/atalkd/Makefile
 671         etc/uams/Makefile
 672         etc/uams/uams_krb4/Makefile
 673         etc/papd/Makefile
 674         etc/psf/Makefile
 675         include/Makefile
 676         include/atalk/Makefile
 677         libatalk/Makefile
 678         libatalk/adouble/Makefile
 679         libatalk/asp/Makefile
 680         libatalk/atp/Makefile
 681         libatalk/cnid/Makefile
 682         libatalk/compat/Makefile
 683         libatalk/dsi/Makefile
 684         libatalk/nbp/Makefile
 685         libatalk/netddp/Makefile
 686         libatalk/util/Makefile
 687         macros/Makefile
 688         man/Makefile
 689         man/man1/Makefile
 690         man/man3/Makefile
 691         man/man4/Makefile
 692         man/man5/Makefile
 693         man/man8/Makefile
 694         sys/Makefile
 695         sys/generic/Makefile
 696         sys/generic/sys/Makefile
 697         sys/netatalk/Makefile
 698         sys/netbsd/Makefile
 699         sys/netbsd/netatalk/Makefile
 700         sys/solaris/Makefile
 701         sys/solaris/Makefile.kernel
 702         sys/sunos/Makefile
 703         sys/ultrix/Makefile
 704         ],
 705         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
 706 )
 707