configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.37.2.8 2008-12-02 03:11:58 didg Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 dnl AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58
  59 dnl not the right stuff but should be enough for now
  60 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
  61 AC_CHECK_FUNC(connect,,[AC_CHECK_LIB(socket,connect)])
  62
  63 dnl Replace `main' with a function in -lprot:
  64 dnl AC_CHECK_LIB(prot, main)
  65 dnl Replace `main' with a function in -lrx:
  66 dnl AC_CHECK_LIB(rx, main)
  67 dnl Replace `main' with a function in -lrxkad:
  68 dnl AC_CHECK_LIB(rxkad, main)
  69 dnl Replace `main' with a function in -lsys:
  70 dnl AC_CHECK_LIB(sys, main)
  71 dnl Replace `main' with a function in -lubik:
  72 dnl AC_CHECK_LIB(ubik, main)
  73
  74
  75 #
  76 # Check presence of some functions
  77 #
  78 # Check for XPG4 access() function
  79 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  80 # has such a function that works only on AFS filesystems.
  81 AC_CHECK_FUNCS(access)
  82 #
  83 AC_CHECK_FUNCS(pread pwrite)
  84
  85 dnl Checks for header files.
  86 AC_HEADER_DIRENT
  87 AC_HEADER_STDC
  88 AC_HEADER_SYS_WAIT
  89 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  90 AC_CHECK_HEADER(sys/cdefs.h,,
  91         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  92         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  93 )
  94 AC_CHECK_HEADERS([sys/mount.h], , ,
  95 [#ifdef HAVE_SYS_PARAM_H
  96 #include <sys/param.h>
  97 #endif
  98 ])
  99
 100 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 101
 102 dnl Checks for typedefs, structures, and compiler characteristics.
 103 AC_C_CONST
 104 AC_TYPE_UID_T
 105 AC_C_INLINE
 106 AC_TYPE_MODE_T
 107 AC_TYPE_OFF_T
 108 AC_TYPE_PID_T
 109 AC_TYPE_SIZE_T
 110 AC_STRUCT_ST_RDEV
 111 AC_HEADER_TIME
 112 AC_STRUCT_TM
 113
 114 dnl --------------------------------------------------------------------------
 115 dnl check if dlsym needs to add an underscore, uses libtool macros
 116 dnl --------------------------------------------------------------------------
 117 AC_LTDL_DLLIB
 118 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 119 AC_LTDL_DLSYM_USCORE
 120 if test x"$libltdl_cv_need_uscore" = xyes; then
 121     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 122 fi
 123
 124
 125 dnl Checks for library functions.
 126 AC_TYPE_GETGROUPS
 127 AC_PROG_GCC_TRADITIONAL
 128 AC_FUNC_MEMCMP
 129 AC_HEADER_MAJOR
 130 AC_FUNC_MMAP
 131 AC_TYPE_SIGNAL
 132 AC_FUNC_UTIME_NULL
 133 AC_FUNC_WAIT3
 134 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul strchr memcpy)
 135 AC_CHECK_FUNCS(backtrace_symbols)
 136 AC_CHECK_FUNCS(setlocale nl_langinfo)
 137 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 138 AC_CHECK_FUNCS(strlcpy strlcat)
 139 AC_CHECK_FUNCS(setlinebuf)
 140 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 141 AC_CACHE_SAVE
 142
 143 dnl Checks for (v)snprintf
 144 NETATALK_SNPRINTF_CHECK
 145
 146 dnl --------------------------------------------------------------------------
 147 dnl 64bit platform check
 148 dnl --------------------------------------------------------------------------
 149
 150 AC_MSG_CHECKING([whether to check for 64bit libraries])
 151 dnl Determine libdir name
 152 case $host in
 153 *-*-linux*)
 154   # Test if the compiler is 64bit
 155   echo 'int i;' > conftest.$ac_ext
 156   atalk_cv_cc_64bit_output=no
 157   if AC_TRY_EVAL(ac_compile); then
 158     case `/usr/bin/file conftest.$ac_objext` in
 159     *"ELF 64"*)
 160       atalk_cv_cc_64bit_output=yes
 161       ;;
 162     esac
 163   fi
 164   rm -rf conftest*
 165   ;;
 166 esac
 167
 168 dnl
 169 dnl FIXME: Do we need something like this for Solaris 64bit?
 170 dnl
 171
 172 case $host_cpu:$atalk_cv_cc_64bit_output in
 173 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 174   atalk_libname="lib64"
 175   AC_MSG_RESULT([yes])
 176   ;;
 177 *:*)
 178   atalk_libname="lib"
 179   AC_MSG_RESULT([no])
 180   ;;
 181 esac
 182
 183 dnl --------------------------------------------------------------------------
 184 dnl specific configuration comes in here:
 185 dnl --------------------------------------------------------------------------
 186
 187
 188 netatalk_cv_admin_group=yes
 189 AC_MSG_CHECKING([for administrative group support])
 190 AC_ARG_ENABLE(admin-group,
 191         [  --disable-admin-group   disable admin group],[
 192         if test x"$enableval" = x"no"; then
 193                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 194                 netatalk_cv_admin_group=no
 195                 AC_MSG_RESULT([no])
 196         else
 197                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 198                 AC_MSG_RESULT([yes])
 199         fi],[
 200                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 201                 AC_MSG_RESULT([yes])
 202         ]
 203 )
 204
 205 NETATALK_AFS_CHECK
 206
 207 NETATALK_CONFIG_DIRS
 208
 209 AC_MSG_CHECKING([whether to use logfile])
 210 AC_ARG_WITH(logfile,
 211         [  --with-logfile=PATH     path for file used by logger],[
 212         if test x"$withval" = x"no"; then
 213                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 214                 AC_MSG_RESULT([no, syslog])
 215         elif test "$withval" != "yes"; then
 216                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 217                 AC_MSG_RESULT([$withval])
 218         else
 219                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 220                 AC_MSG_RESULT([/var/log/netatalk.log])
 221         fi],[
 222                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 223                 AC_MSG_RESULT([no, syslog])
 224         ]
 225 )
 226
 227
 228 netatalk_cv_with_cracklib=no
 229 AC_ARG_WITH(cracklib,
 230         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 231         if test "x$withval" != "xno" ; then
 232                 cracklib="$withval"
 233                 AC_CHECK_LIB(crack, main, [
 234                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 235                         LIBS="$LIBS -lcrack"
 236                         if test "$cracklib" = "yes"; then
 237                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 238                         fi
 239                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 240                                 [path to cracklib dictionary])
 241                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 242                         netatalk_cv_with_cracklib=yes
 243                         ],[
 244                         AC_MSG_ERROR([cracklib not found!])
 245                         ]
 246                 )
 247         fi
 248         ]
 249 )
 250 AC_MSG_CHECKING([for cracklib support])
 251 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 252
 253 netatalk_cv_ddp_enabled=yes
 254 AC_MSG_CHECKING([whether to enable DDP])
 255 AC_ARG_ENABLE(ddp,
 256         [  --disable-ddp           disable DDP],[
 257         if test "$enableval" = "no"; then
 258                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 259                 AC_MSG_RESULT([no])
 260                 netatalk_cv_ddp_enabled=no
 261         else
 262                 AC_MSG_RESULT([yes])
 263         fi
 264         ],[
 265                 AC_MSG_RESULT([yes])
 266         ]
 267 )
 268
 269 AC_MSG_CHECKING([whether to enable debug code])
 270 AC_ARG_ENABLE(debug1,
 271         [  --enable-debug1         enable debug code],[
 272         if test "$enableval" != "no"; then
 273                 if test "$enableval" = "yes"; then
 274                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 275                 else
 276                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 277                 fi
 278                 AC_MSG_RESULT([yes])
 279         else
 280                 AC_MSG_RESULT([no])
 281         fi
 282         ],[
 283                 AC_MSG_RESULT([no])
 284         ]
 285 )
 286
 287 AC_MSG_CHECKING([whether to enable verbose debug code])
 288 AC_ARG_ENABLE(debug,
 289         [  --enable-debug          enable verbose debug code],[
 290         if test "$enableval" != "no"; then
 291                 if test "$enableval" = "yes"; then
 292                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 293                 else
 294                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 295                 fi
 296                 AC_MSG_RESULT([yes])
 297         else
 298                 AC_MSG_RESULT([no])
 299         fi
 300         ],[
 301                 AC_MSG_RESULT([no])
 302         ]
 303 )
 304
 305 afp3=no
 306 afp3set=no
 307 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 308 AC_ARG_ENABLE(afp3,
 309         [  --disable-afp3          disable AFP 3.x calls],
 310         [
 311             if test x"$enableval" != x"no"; then
 312                 afp3set=yes
 313                 afp3=yes
 314                 AC_MSG_RESULT([yes])
 315             else
 316                 AC_MSG_RESULT([no])
 317             fi
 318         ],[
 319             AC_MSG_RESULT([yes])
 320             afp3=yes
 321         ]
 322 )
 323
 324 if test x"$afp3" = x"yes"; then
 325         AC_SYS_LARGEFILE([
 326                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 327         ],[
 328                 if test x"$afp3set" = x"yes"; then
 329                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 330                 else
 331                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 332                         afp3=no
 333                 fi
 334         ])
 335 fi
 336
 337 AC_CHECK_ICONV
 338
 339 dnl ----------- A NOTE ABOUT DROPKLUDGE
 340 dnl The trouble with this fix is that if you know what the file is called, it
 341 dnl can be read from the Unix side.  That's okay for most academic institutions
 342 dnl since the students don't have telnet access to the Mac servers.  There is
 343 dnl currently no one working on further development/fixes of DROPKLUDGE.
 344 dnl -----------
 345
 346 netatalk_cv_dropkludge=no
 347 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 348 AC_ARG_ENABLE(dropkludge,
 349         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 350         if test "$enableval" = "yes"; then
 351                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 352                 AC_MSG_RESULT([yes])
 353                 netatalk_cv_dropkludge=yes
 354         else
 355                 AC_MSG_RESULT([no])
 356         fi
 357         ],[
 358                 AC_MSG_RESULT([no])
 359         ]
 360 )
 361
 362 netatalk_cv_force_uidgid=no
 363 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 364 AC_ARG_ENABLE(force-uidgid,
 365         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 366         if test "$enableval" = "yes"; then
 367                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 368                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 369                 AC_MSG_RESULT([yes])
 370                 netatalk_cv_force_uidgid=yes
 371         else
 372                 AC_MSG_RESULT([no])
 373         fi
 374         ],[
 375                 AC_MSG_RESULT([no])
 376         ]
 377 )
 378
 379 dnl Check for CNID database backends
 380 bdb_required=no
 381 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 382
 383 dnl Check for Berkeley DB library
 384 if test "x$bdb_required" = "xyes"; then
 385         AC_PATH_BDB(, [
 386                 AC_MSG_RESULT([])
 387                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 388                 AC_MSG_RESULT([You can download the latest version from http://www.sleepycat.com.])
 389                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 390                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option and make sure])
 391                 AC_MSG_RESULT([your linker is configured to check for libraries there.])
 392                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 393         ])
 394 fi
 395
 396 dnl Check for quota support
 397 AC_CHECK_QUOTA
 398
 399 dnl Check for optional server location protocol support (used by MacOS X)
 400 NETATALK_SRVLOC
 401
 402 dnl Check for PAM libs
 403 netatalk_cv_use_pam=no
 404 AC_PATH_PAM([
 405         use_pam_so=yes
 406         compile_pam=yes
 407         netatalk_cv_use_pam=yes
 408         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 409 ])
 410
 411 netatalk_cv_use_shadowpw=no
 412 AC_ARG_WITH(shadow,
 413         [  --with-shadow           enable shadow password support [[auto]]],
 414         [netatalk_cv_use_shadowpw="$withval"],
 415         [netatalk_cv_use_shadowpw=auto]
 416 )
 417
 418 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 419     AC_CHECK_HEADER([shadow.h])
 420     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 421         netatalk_cv_use_shadowpw=yes
 422         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 423     else
 424       if test "x$shadowpw" = "xyes"; then
 425         AC_MSG_ERROR([shadow support not available])
 426       else
 427         netatalk_cv_use_shadowpw=no
 428       fi
 429     fi
 430 fi
 431
 432 AC_MSG_CHECKING([whether shadow support should be enabled])
 433 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 434         AC_MSG_RESULT([yes])
 435 else
 436         AC_MSG_RESULT([no])
 437 fi
 438
 439
 440
 441 netatalk_cv_use_shellcheck=yes
 442 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 443 AC_ARG_ENABLE(shell-check,
 444         [  --disable-shell-check   disable checking for a valid shell],[
 445         if test "$enableval" = "no"; then
 446                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 447                 AC_MSG_RESULT([no])
 448                 netatalk_cv_use_shellcheck=no
 449         else
 450                 AC_MSG_RESULT([yes])
 451         fi
 452         ],[
 453                 AC_MSG_RESULT([yes])
 454         ]
 455 )
 456
 457 NETATALK_TCP_WRAPPERS
 458
 459 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 460 AC_ARG_ENABLE(locking,
 461         [  --disable-locking       disable system locking],[
 462                 if test "$enableval" = "no"; then
 463                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 464                         AC_MSG_RESULT([yes])
 465                 else
 466                         AC_MSG_RESULT([no])
 467                 fi
 468
 469         ],[
 470                 AC_MSG_RESULT([no])
 471         ]
 472
 473 )
 474
 475
 476 AC_ARG_ENABLE(redhat,
 477         [  --enable-redhat         use redhat-style sysv configuration ],[
 478         if test "$enableval" = "yes"; then
 479                 sysv_style=redhat
 480         fi
 481         AC_MSG_RESULT([enabling redhat-style sysv support])
 482         ]
 483 )
 484
 485 AC_ARG_ENABLE(suse,
 486         [  --enable-suse           use suse-style sysv configuration ],[
 487         if test "$enableval" = "yes"; then
 488                 sysv_style=suse
 489         fi
 490         AC_MSG_RESULT([enabling suse-style sysv support])
 491         ]
 492 )
 493
 494 AC_ARG_ENABLE(gentoo,
 495         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 496         if test "$enableval" = "yes"; then
 497                 sysv_style=gentoo
 498         fi
 499         AC_MSG_RESULT([enabling gentoo-style sysv support])
 500         ]
 501 )
 502
 503 AC_ARG_ENABLE(cobalt,
 504         [  --enable-cobalt         use cobalt-style sysv configuration ],
 505         if test "$enableval" = "yes"; then
 506                 sysv_style=cobalt
 507         fi
 508         AC_MSG_RESULT([enabling cobalt-style sysv support])
 509 )
 510
 511 AC_ARG_ENABLE(netbsd,
 512         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 513         if test "x$enableval" = "xyes"; then
 514                 sysv_style=netbsd
 515         fi
 516         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 517 )
 518
 519 AC_ARG_ENABLE(debian,
 520         [  --enable-debian         use debian-style sysv configuration ],[
 521         if test "$enableval" = "yes"; then
 522                 sysv_style=debian
 523         fi
 524         AC_MSG_RESULT([enabling debian-style sysv support])
 525         ]
 526 )
 527
 528 dnl ----- timelord compilation (disabled by default)
 529 AC_MSG_CHECKING([whether timelord should be compiled])
 530 compile_timelord=no
 531 AC_ARG_ENABLE(timelord,
 532         [  --enable-timelord       enable compilation of timelord server],
 533         [compile_timelord="$enableval"],
 534         [compile_timelord="no"]
 535 )
 536 AC_MSG_RESULT([$compile_timelord])
 537
 538 dnl ----- a2boot compilation (disabled by default)
 539 AC_MSG_CHECKING([whether a2boot should be compiled])
 540 compile_a2boot=no
 541 AC_ARG_ENABLE(a2boot,
 542         [  --enable-a2boot         enable compilation of Apple2 boot server],
 543         [compile_a2boot="$enableval"],
 544         [compile_a2boot="no"]
 545 )
 546 AC_MSG_RESULT([$compile_a2boot])
 547
 548 AC_ARG_WITH(uams-path,
 549         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 550                 uams_path="$withval"
 551         ],[
 552                 uams_path="${PKGCONFDIR}/uams"
 553         ]
 554 )
 555
 556 NETATALK_AC_CUPS
 557
 558 dnl check if we can use attribute unused (gcc only) from ethereal
 559 AC_MSG_CHECKING(to see if we can add '__attribute__((unused))' to CFLAGS)
 560 if test x$GCC != x ; then
 561   CFLAGS="-D_U_=\"__attribute__((unused))\" $CFLAGS"
 562   AC_MSG_RESULT(yes)
 563 else
 564   CFLAGS="-D_U_=\"\" $CFLAGS"
 565   AC_MSG_RESULT(no)
 566 fi
 567
 568 dnl --------------------------------------------------------------------------
 569 dnl FHS stuff has to be done last because it overrides other defaults
 570 dnl --------------------------------------------------------------------------
 571
 572 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 573 AC_ARG_ENABLE(fhs,
 574         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 575         if test "$enableval" = "yes"; then
 576                 uams_path="${libdir}/netatalk"
 577                 sysconfdir="/etc"
 578                 PKGCONFDIR=${sysconfdir}/netatalk
 579                 SERVERTEXT="${PKGCONFDIR}/msg"
 580                 use_pam_so=yes
 581                 mandir="/usr/share/man"
 582                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 583                 AC_MSG_RESULT([yes])
 584         else
 585                 AC_MSG_RESULT([no])
 586         fi
 587         ],[
 588                 AC_MSG_RESULT([no])
 589         ]
 590 )
 591
 592 dnl --------------------------------------------------------------------------
 593 dnl post-FHS substitutions, etc
 594 dnl --------------------------------------------------------------------------
 595
 596 dnl ***** UAMS_PATH
 597 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 598 dnl     [path to UAMs [default=PKGCONF/uams]])
 599 UAMS_PATH="${uams_path}"
 600 AC_SUBST(UAMS_PATH)
 601
 602 dnl --------------------------------------------------------------------------
 603 dnl drop in includes for top level directory structures here...
 604 dnl --------------------------------------------------------------------------
 605
 606 dnl Note: $(top_srcdir)/include should be added before all other includes
 607 dnl       so that includes from that directory a preferred to includes from
 608 dnl       /usr/include or similar places.
 609 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 610 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 611
 612 dnl --------------------------------------------------------------------------
 613 dnl specific configuration comes in here:
 614 dnl --------------------------------------------------------------------------
 615
 616 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 617
 618 dnl --------------------- determine operating system from "target"
 619 case "$host_os" in
 620         *aix*)                          this_os=aix ;;
 621         *freebsd*)                      this_os=freebsd ;;
 622         *hpux11*)                       this_os=hpux11 ;;
 623         *irix*)                         this_os=irix ;;
 624         *linux*)                        this_os=linux ;;
 625         *osx*)                          this_os=macosx ;;
 626         *darwin*)                       this_os=macosx ;;
 627         *netbsd*)                       this_os=netbsd ;;
 628         *openbsd*)                      this_os=openbsd ;;
 629         *osf*)                          this_os=tru64 ;;
 630         *solaris*)                      this_os=solaris ;;
 631 esac
 632
 633 case "$host_cpu" in
 634         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 635         alpha)                                          this_cpu=alpha ;;
 636         mips)                                           this_cpu=mips ;;
 637         powerpc|ppc)                            this_cpu=ppc ;;
 638 esac
 639
 640 dnl --------------------- operating system specific flags (port from sys/*)
 641
 642 dnl ----- AIX specific -----
 643 if test x"$this_os" = "xaix"; then
 644         AC_MSG_RESULT([ * AIX specific configuration])
 645         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 646
 647         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 648         dnl compilation environment.  It's enough to get things defined
 649         dnl right in endian.h provided that long long is supported, though.
 650         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 651 fi
 652
 653 dnl ----- FreeBSD specific -----
 654 if test x"$this_os" = "xfreebsd"; then
 655         AC_MSG_RESULT([ * FreeBSD specific configuration])
 656         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 657         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 658         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 659 fi
 660
 661 dnl ----- HP-UX 11 specific -----
 662 if test x"$this_os" = "xhpux11"; then
 663         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 664
 665         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 666         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 667 fi
 668
 669 dnl ----- IRIX specific -----
 670 if test x"$this_os" = "xirix"; then
 671         AC_MSG_RESULT([ * IRIX specific configuration])
 672
 673         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 674 fi
 675
 676 dnl ----- Linux specific -----
 677 if test x"$this_os" = "xlinux"; then
 678         AC_MSG_RESULT([ * Linux specific configuration])
 679
 680         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 681         AC_MSG_CHECKING([for struct atalk_addr])
 682 dnl     AC_COMPILE_IFELSE([
 683         AC_TRY_COMPILE([
 684 #include <sys/socket.h>
 685 #include <asm/types.h>
 686 #include <linux/atalk.h>
 687
 688         struct atalk_addr foo;
 689 ],
 690 [ ], [
 691                 ac_have_atalk_addr=yes
 692                 AC_MSG_RESULT([yes])
 693         ], [
 694                 AC_MSG_RESULT([no])
 695         ])
 696
 697 if test "x$ac_have_atalk_addr" = "xyes"; then
 698         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 699 fi
 700
 701         dnl ----- check if we need the quotactl wrapper
 702 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 703 #       AC_CHECK_FUNC(quotactl,,
 704 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 705 #               AC_MSG_RESULT([enabling quotactl wrapper])
 706 #       )
 707
 708         # For quotas on Linux XFS filesystems
 709
 710         # For linux > 2.5.56
 711         AC_CHECK_HEADERS(linux/dqblk_xfs.h,,
 712                 [AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 713                 AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)]
 714         )
 715
 716
 717         dnl ----- as far as I can tell, dbtob always does the wrong thing
 718         dnl ----- on every single version of linux I've ever played with.
 719         dnl ----- see etc/afpd/quota.c
 720         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 721
 722         netatalk_cv_linux_sendfile=no
 723 dnl     disable this for now, code doesn't use sendfile anyway
 724 dnl        AC_ARG_ENABLE(sendfile,
 725 dnl         [  --enable-sendfile       use sendfile syscall default (no) ],[
 726 dnl             if test "$enableval" = "yes"; then
 727 dnl                     netatalk_cv_linux_sendfile=yes
 728 dnl             fi
 729 dnl             AC_MSG_RESULT([enabling sendfile syscall])
 730 dnl         ]
 731 dnl       )
 732
 733         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 734             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 735             AC_TRY_LINK([#include <sys/sendfile.h>],
 736 [\
 737 int tofd, fromfd;
 738 off_t offset;
 739 size_t total;
 740 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 741 ],
 742 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 743
 744 # Try and cope with broken Linux sendfile....
 745             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 746             AC_TRY_LINK([\
 747 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 748 #undef _FILE_OFFSET_BITS
 749 #endif
 750 #include <sys/sendfile.h>],
 751 [\
 752 int tofd, fromfd;
 753 off_t offset;
 754 size_t total;
 755 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 756 ],
 757 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 758
 759             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 760                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 761                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 762                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 763             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 764                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 765                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 766                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 767             else
 768                 netatalk_cv_linux_sendfile=no
 769                 AC_MSG_RESULT(no);
 770             fi
 771         fi
 772
 773         dnl ----- Linux/alpha specific -----
 774         if test x"$this_cpu" = "xalpha"; then
 775                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 776                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 777         fi
 778         need_dash_r=no
 779
 780
 781 fi
 782
 783 dnl ----- Mac OSX specific -----
 784 if test x"$this_os" = "xmacosx"; then
 785         AC_MSG_RESULT([ * Mac OSX specific configuration])
 786         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 787         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 788         dnl AC_DEFINE(NO_DLFCN_H)
 789         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 790         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 791         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 792 fi
 793
 794 dnl ----- NetBSD specific -----
 795 if test x"$this_os" = "xnetbsd"; then
 796         AC_MSG_RESULT([ * NetBSD specific configuration])
 797         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 798         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 799         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 800         need_dash_r=yes
 801
 802         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 803         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 804 fi
 805
 806 dnl ----- OpenBSD specific -----
 807 if test x"$this_os" = "xopenbsd"; then
 808         AC_MSG_RESULT([ * OpenBSD specific configuration])
 809         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 810         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 811 fi
 812
 813 dnl ----- Solaris specific -----
 814 if test x"$this_os" = "xsolaris"; then
 815         AC_MSG_RESULT([ * Solaris specific configuration])
 816         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 817         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 818         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 819         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 820         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 821         need_dash_r=yes
 822         sysv_style=solaris
 823
 824         solaris_module=no
 825         AC_MSG_CHECKING([if we can build Solaris kernel module])
 826         if test -x /usr/ccs/bin/ld; then
 827                 solaris_module=yes
 828         fi
 829         AC_MSG_RESULT([$solaris_module])
 830
 831         COMPILE_64BIT_KMODULE=no
 832         KCFLAGS=""
 833         KLDFLAGS=""
 834         COMPILE_KERNEL_GCC=no
 835
 836         if test "$solaris_module" = "yes"; then
 837            dnl Solaris kernel module stuff
 838            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 839
 840            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 841            if test -x /usr/bin/isainfo; then
 842                 # check for 64 bit platform
 843                 if isainfo -kv | grep '^64-bit'; then
 844                         COMPILE_64BIT_KMODULE=yes
 845                 fi
 846            fi
 847
 848            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 849
 850            if test "${GCC}" = yes; then
 851                 COMPILE_KERNEL_GCC=yes
 852                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 853
 854                         AC_MSG_CHECKING([if we can build a 64bit kernel module])
 855
 856                         case `$CC --version 2>/dev/null` in
 857                         [[12]].* | 3.0.*)
 858                                 COMPILE_64BIT_KMODULE=no
 859                                 COMPILE_KERNEL_GCC=no
 860                                 solaris_module=no;;
 861                         *)
 862                                 # use for 64 bit
 863                                 KCFLAGS="-m64"
 864                                 #KLDFLAGS="-melf64_sparc"
 865                                 KLDFLAGS="-64";;
 866                         esac
 867
 868                         AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 869
 870                 else
 871                         KCFLAGS=""
 872                         KLDFLAGS=""
 873                 fi
 874                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 875            else
 876                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 877                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 878                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 879                         KLDFLAGS="-64"
 880                 else
 881                         KCFLAGS=""
 882                         KLDFLAGS=""
 883                 fi
 884                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 885            fi
 886
 887            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 888            AC_TRY_LINK([\
 889 #include <sys/stream.h>
 890 #include <sys/ddi.h>],
 891 [\
 892 timeout_id_t dummy;
 893 ],
 894 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 895
 896            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 897         fi
 898
 899         AC_SUBST(COMPILE_KERNEL_GCC)
 900         AC_SUBST(COMPILE_64BIT_KMODULE)
 901         AC_SUBST(KCFLAGS)
 902         AC_SUBST(KLDFLAGS)
 903 fi
 904
 905 dnl ----- Tru64 specific -----
 906 if test x"$this_os" = "xtru64"; then
 907         AC_MSG_RESULT([ * Tru64 specific configuration])
 908         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 909         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 910         dnl AC_DEFINE(USE_MOUNT_H)
 911         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 912         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 913         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 914         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 915         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 916         AC_CHECK_LIB(security,set_auth_parameters)
 917         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 918         need_dash_r=no
 919         sysv_style=tru64
 920 fi
 921
 922 dnl -- check for libgcrypt, if found enables DHX UAM
 923 AM_PATH_LIBGCRYPT([1:1.2.3],[neta_cv_compile_dhx2=yes
 924                         neta_cv_have_libgcrypt=yes
 925                         AC_MSG_NOTICE([Enabling DHX2 UAM])
 926                         AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define if the DHX2 modules should be built with libgcrypt])
 927                         AC_DEFINE(UAM_DHX2, 1, [Define if the DHX2 UAM modules should be compiled])
 928                         ])
 929
 930 dnl -- look for openssl, if found enables DHX UAM and Randnum UAM
 931 AC_PATH_SSL
 932
 933 dnl -- check for crypt
 934 AC_CRYPT
 935
 936 dnl --------------------- check for building PGP UAM module
 937
 938 AC_MSG_CHECKING([whether the PGP UAM should be build])
 939 AC_ARG_ENABLE(pgp-uam,
 940         [  --enable-pgp-uam        enable build of PGP UAM module],[
 941         if test "$enableval" = "yes"; then
 942                 if test "x$neta_cv_have_openssl" = "xyes"; then
 943                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 944                         compile_pgp=yes
 945                         AC_MSG_RESULT([yes])
 946                 else
 947                         AC_MSG_RESULT([no])
 948                 fi
 949         fi
 950         ],[
 951                 AC_MSG_RESULT([no])
 952         ]
 953 )
 954
 955 dnl --------------------- check for building Kerberos v4 UAM module
 956
 957 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 958 AC_ARG_ENABLE(krb4-uam,
 959         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 960         if test "$enableval" = "yes"; then
 961                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 962                 compile_kerberos=yes
 963                 AC_MSG_RESULT([yes])
 964         else
 965                 AC_MSG_RESULT([no])
 966         fi
 967         ],[
 968                 AC_MSG_RESULT([no])
 969         ]
 970 )
 971
 972 dnl --------------------- check for building Kerberos V UAM module
 973
 974 netatalk_cv_build_krb5_uam=no
 975 AC_ARG_ENABLE(krbV-uam,
 976         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 977         [
 978                 if test x"$enableval" = x"yes"; then
 979                         NETATALK_GSSAPI_CHECK([
 980                                 netatalk_cv_build_krb5_uam=yes
 981                         ],[
 982                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 983                         ])
 984                 fi
 985         ]
 986
 987 )
 988
 989 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 990 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 991         AC_MSG_RESULT([yes])
 992 else
 993         AC_MSG_RESULT([no])
 994 fi
 995 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 996
 997 dnl --------------------- overwrite the config files . . . or not.
 998
 999 AC_MSG_CHECKING([whether configuration files should be overwritten])
1000 AC_ARG_ENABLE(overwrite,
1001         [  --enable-overwrite      overwrite configuration files during installation],
1002         [OVERWRITE_CONFIG="${enable_overwrite}"],
1003         [OVERWRITE_CONFIG="no"]
1004 )
1005 AC_MSG_RESULT([$OVERWRITE_CONFIG])
1006
1007 dnl --------------------- last minute substitutions
1008
1009 AC_SUBST(LIBS)
1010 AC_SUBST(CFLAGS)
1011 AC_SUBST(OVERWRITE_CONFIG)
1012
1013 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
1014 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
1015 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
1016 AM_CONDITIONAL(HAVE_LIBGCRYPT, test x$neta_cv_have_libgcrypt = xyes)
1017 AM_CONDITIONAL(HAVE_OPENSSL, test x$neta_cv_have_openssl = xyes)
1018 AM_CONDITIONAL(USE_DHX, test x$neta_cv_compile_dhx = xyes)
1019 AM_CONDITIONAL(USE_DHX2, test x$neta_cv_compile_dhx2 = xyes)
1020 AM_CONDITIONAL(USE_RANDNUM, test x$neta_cv_have_openssl = xyes)
1021 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
1022 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
1023 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
1024 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
1025 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
1026 AM_CONDITIONAL(DEFAULT_HOOK, test x$neta_cv_have_libgcrypt != xyes && test x$neta_cv_have_openssl != xyes)
1027 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
1028 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
1029 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
1030 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
1031 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
1032 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
1033 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
1034 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
1035 AM_CONDITIONAL(USE_DEBIAN, test x$sysv_style = xdebian)
1036 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
1037
1038 dnl --------------------- generate files
1039
1040 AC_OUTPUT([Makefile
1041         bin/Makefile
1042         bin/adv1tov2/Makefile
1043         bin/aecho/Makefile
1044         bin/afile/Makefile
1045         bin/afppasswd/Makefile
1046         bin/cnid/Makefile
1047         bin/cnid/cnid_maint
1048         bin/cnid/cnid2_create
1049         bin/getzones/Makefile
1050         bin/megatron/Makefile
1051         bin/nbp/Makefile
1052         bin/pap/Makefile
1053         bin/psorder/Makefile
1054         bin/uniconv/Makefile
1055         config/Makefile
1056         contrib/Makefile
1057         contrib/macusers/Makefile
1058         contrib/macusers/macusers
1059         contrib/nu/Makefile
1060         contrib/nu/nu
1061         contrib/printing/Makefile
1062         contrib/shell_utils/Makefile
1063         contrib/shell_utils/afpd-mtab.pl
1064         contrib/shell_utils/apple_cp
1065         contrib/shell_utils/apple_mv
1066         contrib/shell_utils/apple_rm
1067         contrib/shell_utils/asip-status.pl
1068         contrib/shell_utils/cleanappledouble.pl
1069         contrib/timelord/Makefile
1070         contrib/a2boot/Makefile
1071         distrib/Makefile
1072         distrib/config/Makefile
1073         distrib/config/netatalk-config
1074         distrib/initscripts/Makefile
1075         distrib/m4/Makefile
1076         doc/Makefile
1077         etc/Makefile
1078         etc/afpd/Makefile
1079         etc/atalkd/Makefile
1080         etc/cnid_dbd/Makefile
1081         etc/uams/Makefile
1082         etc/uams/uams_krb4/Makefile
1083         etc/papd/Makefile
1084         etc/psf/Makefile
1085         include/Makefile
1086         include/atalk/Makefile
1087         libatalk/Makefile
1088         libatalk/adouble/Makefile
1089         libatalk/asp/Makefile
1090         libatalk/atp/Makefile
1091         libatalk/cnid/Makefile
1092         libatalk/cnid/db3/Makefile
1093         libatalk/cnid/cdb/Makefile
1094         libatalk/cnid/last/Makefile
1095         libatalk/cnid/mtab/Makefile
1096         libatalk/cnid/dbd/Makefile
1097         libatalk/cnid/hash/Makefile
1098         libatalk/cnid/tdb/Makefile
1099         libatalk/compat/Makefile
1100         libatalk/dsi/Makefile
1101         libatalk/nbp/Makefile
1102         libatalk/netddp/Makefile
1103         libatalk/util/Makefile
1104         libatalk/tdb/Makefile
1105         libatalk/unicode/Makefile
1106         libatalk/unicode/charsets/Makefile
1107         macros/Makefile
1108         man/Makefile
1109         man/man1/Makefile
1110         man/man3/Makefile
1111         man/man4/Makefile
1112         man/man5/Makefile
1113         man/man8/Makefile
1114         sys/Makefile
1115         sys/generic/Makefile
1116         sys/generic/sys/Makefile
1117         sys/netatalk/Makefile
1118         sys/netbsd/Makefile
1119         sys/netbsd/netatalk/Makefile
1120         sys/solaris/Makefile
1121         sys/sunos/Makefile
1122         sys/ultrix/Makefile
1123         ],
1124         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1125 )
1126
1127 AC_NETATALK_LIBS_SUMMARY
1128 AC_NETATALK_CONFIG_SUMMARY
1129