configure.in

   1 dnl $Id: configure.in,v 1.190 2003-06-12 23:15:06 srittau Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AM_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24 AC_PROG_DVIPS
  25 AC_PROG_TROFF2PS
  26
  27 dnl *********************************************************************
  28 dnl FIXME! FIXME! These should be selectable properly, and should produce
  29 dnl the proper flags and defines...
  30 dnl *********************************************************************
  31
  32 dnl Checks for libraries.
  33 dnl Replace `main' with a function in -labs:
  34 AC_CHECK_LIB(abs, main)
  35 dnl Replace `main' with a function in -laudit:
  36 AC_CHECK_LIB(audit, main)
  37 dnl Replace `main' with a function in -lauth:
  38 AC_CHECK_LIB(auth, main)
  39 dnl Replace `main' with a function in -lcmd:
  40 AC_CHECK_LIB(cmd, main)
  41 dnl Replace `main' with a function in -lcrypt:
  42 AC_CHECK_LIB(crypt, main)
  43 dnl Replace `main' with a function in -ld:
  44 AC_CHECK_LIB(d, main)
  45 dnl Replace `main' with a function in -ldl:
  46 AC_CHECK_LIB(dl, main)
  47 dnl Replace `main' with a function in -lkauth:
  48 AC_CHECK_LIB(kauth, main)
  49 dnl Replace `main' with a function in -lkrb:
  50 AC_CHECK_LIB(krb, main)
  51 dnl Replace `main' with a function in -llwp:
  52 AC_CHECK_LIB(lwp, main)
  53 dnl Replace `main' with a function in -ln:
  54 AC_CHECK_LIB(n, main)
  55 dnl Replace `main' with a function in -lnsl:
  56 AC_CHECK_LIB(nsl, main)
  57 dnl Replace `main' with a function in -lprot:
  58 AC_CHECK_LIB(prot, main)
  59 dnl Replace `main' with a function in -lrx:
  60 AC_CHECK_LIB(rx, main)
  61 dnl Replace `main' with a function in -lrxkad:
  62 AC_CHECK_LIB(rxkad, main)
  63 dnl Replace `main' with a function in -lsocket:
  64 AC_CHECK_LIB(socket, main)
  65 dnl Replace `main' with a function in -lsys:
  66 AC_CHECK_LIB(sys, main)
  67 dnl Replace `main' with a function in -lubik:
  68 AC_CHECK_LIB(ubik, main)
  69
  70 #
  71 # Check presence of some functions
  72 #
  73 # Check for XPG4 access() function
  74 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  75 # has such a function that works only on AFS filesystems.
  76 AC_CHECK_FUNCS(access)
  77 #
  78 AC_CHECK_FUNCS(pread pwrite)
  79
  80 dnl Checks for header files.
  81 AC_HEADER_DIRENT
  82 AC_HEADER_STDC
  83 AC_HEADER_SYS_WAIT
  84 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h sys/mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h)
  85 AC_CHECK_HEADER(sys/cdefs.h,,
  86         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  87         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  88 )
  89
  90 dnl Checks for typedefs, structures, and compiler characteristics.
  91 AC_C_CONST
  92 AC_TYPE_UID_T
  93 AC_C_INLINE
  94 AC_TYPE_MODE_T
  95 AC_TYPE_OFF_T
  96 AC_TYPE_PID_T
  97 AC_TYPE_SIZE_T
  98 AC_STRUCT_ST_RDEV
  99 AC_HEADER_TIME
 100 AC_STRUCT_TM
 101
 102 dnl Checks for library functions.
 103 AC_TYPE_GETGROUPS
 104 AC_PROG_GCC_TRADITIONAL
 105 AC_FUNC_MEMCMP
 106 AC_HEADER_MAJOR
 107 AC_FUNC_MMAP
 108 AC_TYPE_SIGNAL
 109 AC_FUNC_UTIME_NULL
 110 AC_FUNC_WAIT3
 111 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul setpgrp strchr memcpy)
 112 AC_FUNC_SETPGRP
 113
 114 dnl Checks for (v)snprintf
 115 NETATALK_SNPRINTF_CHECK
 116
 117 dnl --------------------------------------------------------------------------
 118 dnl specific configuration comes in here:
 119 dnl --------------------------------------------------------------------------
 120
 121 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 122
 123 AC_MSG_CHECKING([for administrative group support])
 124 AC_ARG_WITH(admin-group,
 125         [  --disable-admin-group   disable admin group], [
 126         if test "$enableval" = "no"; then
 127                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 128                 AC_MSG_RESULT([no])
 129         else
 130                 AC_MSG_RESULT([yes])
 131         fi], [
 132                 AC_MSG_RESULT([yes])
 133         ]
 134 )
 135
 136 NETATALK_AFS_CHECK
 137
 138 NETATALK_CONFIG_DIRS
 139
 140 AC_MSG_CHECKING([for logfile path])
 141 AC_ARG_WITH(logfile,
 142         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 143                           use --without-logfile to disable logger], [
 144         if test "x$withval" == "xno"; then
 145                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 146                 AC_MSG_RESULT([syslog])
 147         elif test "$withval" != "yes"; then
 148                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 149                 AC_MSG_RESULT([$withval])
 150         else
 151                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 152                 AC_MSG_RESULT([/var/log/netatalk.log])
 153         fi], [
 154                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 155                 AC_MSG_RESULT([/var/log/netatalk.log])
 156         ]
 157 )
 158
 159 AC_ARG_WITH(cracklib,
 160         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],
 161         if test "x$withval" != "xno" ; then
 162                 cracklib="$withval"
 163                 AC_CHECK_LIB(crack, main,
 164                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 165                         LIBS="$LIBS -lcrack"
 166                         AC_MSG_RESULT([enabling cracklib support])
 167                         if test "$cracklib" = "yes"; then
 168                                 cracklib="/usr/lib/cracklib_dict"
 169                         fi
 170                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 171                                 [path to cracklib dictionary])
 172                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib]),
 173                         AC_MSG_ERROR([cracklib not found!])
 174                 )
 175         fi
 176 )
 177
 178 AC_MSG_CHECKING([whether to enable DDP])
 179 AC_ARG_ENABLE(ddp,
 180         [  --disable-ddp           disable DDP], [
 181         if test "x$enableval" = "xno"; then
 182                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 183                 AC_MSG_RESULT([no])
 184         else
 185                 AC_MSG_RESULT([yes])
 186         fi
 187         ], [
 188                 AC_MSG_RESULT([yes])
 189         ]
 190 )
 191
 192 AC_MSG_CHECKING([whether to enable debugging code])
 193 AC_ARG_ENABLE(debug,
 194         [  --enable-debug          enable debug code], [
 195         if test "x$enableval" != "xno"; then
 196                 if test "x$enableval" = "xyes"; then
 197                         AC_DEFINE(DEBUG, 1, [Define if debugging information should be included])
 198                 else
 199                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if debugging information should be included])
 200                 fi
 201                 AC_MSG_RESULT([yes])
 202         else
 203                 AC_MSG_RESULT([no])
 204         fi
 205         ], [
 206                 AC_MSG_RESULT([no])
 207         ]
 208 )
 209
 210 afp3=no
 211 AC_ARG_ENABLE(afp3,
 212         [  --enable-afp3           enable AFP 3.x calls],
 213         if test "$enableval" = "yes"; then
 214                 afp3=yes
 215                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 216                 AC_MSG_RESULT([enabling AFP 3.x calls])
 217         fi
 218 )
 219
 220 if test "$afp3" = "yes"; then
 221         AM_ICONV
 222         AC_SYS_LARGEFILE
 223 fi
 224
 225
 226 dnl ----------- A NOTE ABOUT DROPKLUDGE
 227 dnl The trouble with this fix is that if you know what the file is called, it
 228 dnl can be read from the Unix side.  That's okay for most academic institutions
 229 dnl since the students don't have telnet access to the Mac servers.  There is
 230 dnl currently no one working on further development/fixes of DROPKLUDGE.
 231 dnl -----------
 232
 233 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 234 AC_ARG_ENABLE(dropkludge,
 235         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ], [
 236         if test "x$enableval" = "xyes"; then
 237                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 238                 AC_MSG_RESULT([yes])
 239         else
 240                 AC_MSG_RESULT([no])
 241         fi
 242         ], [AC_MSG_RESULT([no])]
 243 )
 244
 245 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 246 AC_ARG_ENABLE(force-uidgid,
 247         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ], [
 248         if test "x$enableval" = "xyes"; then
 249                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 250                 AC_MSG_RESULT([yes])
 251         else
 252                 AC_MSG_RESULT([no])
 253         fi
 254         ], [AC_MSG_RESULT([no])]
 255 )
 256
 257 NETATALK_ARG_DID
 258
 259 dnl Determine whether or not to use filename mangling
 260 AC_MSG_CHECKING([whether to use filename mangling])
 261 AC_ARG_WITH(mangling,
 262         [  --with-mangling         enable filename mangling],
 263         [
 264                 if test "x$withval" = "xyes"; then
 265                         if test "x$did_scheme" != "xcnid"; then
 266                                 AC_MSG_ERROR([DID scheme must be CNID to use filename mangling])
 267                         else
 268                                 AC_DEFINE(FILE_MANGLING, 1, [Define if file name mangling should be used])
 269                                 AC_MSG_RESULT([yes])
 270                         fi
 271                 else
 272                         AC_MSG_RESULT([no])
 273                 fi
 274         ], [
 275                 if test "x$did_scheme" = "xcnid"; then
 276                         AC_DEFINE(FILE_MANGLING, 1, [Define if file name mangling should be used])
 277                         AC_MSG_RESULT([yes])
 278                 else
 279                         AC_MSG_RESULT([no])
 280                 fi
 281         ]
 282 )
 283
 284 if test "$did_scheme" = "cnid"; then
 285     USE_CDB="yes"
 286 else
 287     USE_CDB="no"
 288 fi
 289
 290 dnl Determine whether or not to use CDB or transactional DB store
 291 AC_MSG_CHECKING([whether to use CNID with Concurrent Data Store])
 292 AC_ARG_WITH(cdb,
 293         [  --with-cdb              enable CNID with Concurrent Data Store],
 294         if test "$withval" = "no"; then
 295             if test "x$did_scheme" != "xcnid"; then
 296                 USE_CDB="no"
 297                 AC_MSG_ERROR([DID scheme must be CNID to use CDB])
 298             else
 299                 USE_CDB="no"
 300                 AC_MSG_RESULT([no])
 301             fi
 302         else
 303             USE_CDB="yes"
 304             AC_MSG_RESULT([yes])
 305         fi
 306         , AC_MSG_RESULT([yes])
 307 )
 308
 309 if test "$USE_CDB" = "yes"; then
 310     AC_DEFINE(CNID_DB_CDB, 1, [Define if CNID should be used with Concurrent Data Store])
 311 fi
 312
 313 dnl Check for quota support
 314 AC_CHECK_QUOTA
 315
 316 dnl Check for optional server location protocol support (used by MacOS X)
 317 NETATALK_SRVLOC
 318
 319 dnl Check for PAM libs
 320 AC_PATH_PAM([
 321         use_pam_so=yes
 322         compile_pam=yes
 323         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 324 ])
 325
 326 AC_MSG_CHECKING([whether shadow support should be enabled])
 327 AC_ARG_WITH(shadow,
 328         [  --with-shadow           enable shadow password support],
 329         [shadowpw="$withval"],
 330         [shadowpw=no]
 331 )
 332 if test "x$shadowpw" = "xyes"; then
 333         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 334 fi
 335 AC_MSG_RESULT([$shadowpw])
 336
 337 AC_ARG_ENABLE(shell-check,
 338         [  --disable-shell-check   disable checking for a valid shell],
 339         if test "$enableval" = "no"; then
 340                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 341                 AC_MSG_RESULT([disabling valid shell check])
 342         fi
 343 )
 344
 345 NETATALK_TCP_WRAPPERS
 346
 347 AC_ARG_ENABLE(redhat,
 348         [  --enable-redhat         use redhat-style sysv configuration ],
 349         if test "$enableval" = "yes"; then
 350                 sysv_style=redhat
 351         fi
 352         AC_MSG_RESULT([enabling redhat-style sysv support])
 353 )
 354
 355 AC_ARG_ENABLE(suse,
 356         [  --enable-suse           use suse-style sysv configuration ],
 357         if test "$enableval" = "yes"; then
 358                 sysv_style=suse
 359         fi
 360         AC_MSG_RESULT([enabling suse-style sysv support])
 361 )
 362
 363 AC_ARG_ENABLE(cobalt,
 364         [  --enable-cobalt         use cobalt-style sysv configuration ],
 365         if test "$enableval" = "yes"; then
 366                 sysv_style=cobalt
 367         fi
 368         AC_MSG_RESULT([enabling cobalt-style sysv support])
 369 )
 370
 371 AC_ARG_ENABLE(netbsd,
 372         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 373         if test "x$enableval" = "xyes"; then
 374                 sysv_style=netbsd
 375         fi
 376         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 377 )
 378
 379 dnl ----- a2boot compilation (disabled by default)
 380 AC_MSG_CHECKING([whether a2boot should be compiled])
 381 compile_a2boot=no
 382 AC_ARG_ENABLE(a2boot,
 383         [  --enable-a2boot       enable compilation of Apple2 boot server],
 384         [compile_a2boot="$enableval"],
 385         [compile_a2boot="no"]
 386 )
 387 AC_MSG_RESULT([$compile_a2boot])
 388
 389 AC_ARG_WITH(uams-path,
 390         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],
 391         uams_path="$withval",
 392         uams_path="${PKGCONFDIR}/uams"
 393 )
 394
 395 dnl --------------------------------------------------------------------------
 396 dnl FHS stuff has to be done last because it overrides other defaults
 397 dnl --------------------------------------------------------------------------
 398
 399 AC_ARG_ENABLE(fhs,
 400         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],
 401         if test "$enableval" = "yes"; then
 402                 uams_path="${libdir}/netatalk"
 403                 sysconfdir="/etc"
 404                 PKGCONFDIR=${sysconfdir}/netatalk
 405                 SERVERTEXT="${PKGCONFDIR}/msg"
 406                 NLSDIR="${PKGCONFDIR}/nls"
 407                 use_pam_so=yes
 408                 mandir="/usr/share/man"
 409                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 410         fi
 411         AC_MSG_RESULT([enabling Filesystem Hierarchy Standard (FHS) compatibility])
 412 )
 413
 414 dnl --------------------------------------------------------------------------
 415 dnl post-FHS substitutions, etc
 416 dnl --------------------------------------------------------------------------
 417
 418 dnl ***** UAMS_PATH
 419 AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 420         [path to UAMs [default=PKGCONF/uams]])
 421 UAMS_PATH="${uams_path}"
 422 AC_SUBST(UAMS_PATH)
 423
 424 dnl --------------------------------------------------------------------------
 425 dnl drop in includes for top level directory structures here...
 426 dnl --------------------------------------------------------------------------
 427
 428 dnl Note: $(top_srcdir)/include should be added before all other includes
 429 dnl       so that includes from that directory a preferred to includes from
 430 dnl       /usr/include or similar places.
 431 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 432 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 433
 434 dnl --------------------------------------------------------------------------
 435 dnl specific configuration comes in here:
 436 dnl --------------------------------------------------------------------------
 437
 438 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 439
 440 dnl --------------------- determine operating system from "target"
 441 case "$host_os" in
 442         *aix*)                          this_os=aix ;;
 443         *freebsd*)                      this_os=freebsd ;;
 444         *hpux11*)                       this_os=hpux11 ;;
 445         *irix*)                         this_os=irix ;;
 446         *linux*)                        this_os=linux ;;
 447         *osx*)                          this_os=macosx ;;
 448         *darwin*)                       this_os=macosx ;;
 449         *netbsd*)                       this_os=netbsd ;;
 450         *openbsd*)                      this_os=openbsd ;;
 451         *osf*)                          this_os=tru64 ;;
 452         *solaris*)                      this_os=solaris ;;
 453 esac
 454
 455 case "$host_cpu" in
 456         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 457         alpha)                                          this_cpu=alpha ;;
 458         mips)                                           this_cpu=mips ;;
 459         powerpc|ppc)                            this_cpu=ppc ;;
 460 esac
 461
 462 dnl --------------------- operating system specific flags (port from sys/*)
 463
 464 dnl ----- AIX specific -----
 465 if test x"$this_os" = "xaix"; then
 466         AC_MSG_RESULT([ * AIX specific configuration])
 467         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 468
 469         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 470         dnl compilation environment.  It's enough to get things defined
 471         dnl right in endian.h provided that long long is supported, though.
 472         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 473 fi
 474
 475 dnl ----- FreeBSD specific -----
 476 if test x"$this_os" = "xfreebsd"; then
 477         AC_MSG_RESULT([ * FreeBSD specific configuration])
 478         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 479         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 480
 481         AC_DEFINE(NO_CRYPT_H, 1, [Define if crypt.h does not exist])
 482 fi
 483
 484 dnl ----- HP-UX 11 specific -----
 485 if test x"$this_os" = "xhpux11"; then
 486         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 487
 488         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 489         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 490 fi
 491
 492 dnl ----- IRIX specific -----
 493 if test x"$this_os" = "xirix"; then
 494         AC_MSG_RESULT([ * IRIX specific configuration])
 495
 496         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 497 fi
 498
 499 dnl ----- Linux specific -----
 500 if test x"$this_os" = "xlinux"; then
 501         AC_MSG_RESULT([ * Linux specific configuration])
 502
 503         dnl ----- check if we need the quotactl wrapper
 504         AC_CHECK_FUNC(quotactl,,
 505                 AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 506                 AC_MSG_RESULT([enabling quotactl wrapper])
 507         )
 508
 509         dnl ----- as far as I can tell, dbtob always does the wrong thing
 510         dnl ----- on every single version of linux I've ever played with.
 511         dnl ----- see etc/afpd/quota.c
 512         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 513
 514         dnl --- added by Yoshinobu Ishizaki (2001.03.13) ---
 515         dnl ----- check if version is newer than 2.2.x
 516         changequote(<<,>>)
 517         majorvers="`uname -r | sed 's/\([0-9]\)..*/\1/'`"
 518         minorvers="`uname -r | sed 's/[0-9]\.\([0-9]\)\..*/\1/'`"
 519         if [ $majorvers -ge 2 ]; then
 520                 if [ $minorvers -ge 2 ]; then
 521                         changequote([,])
 522                         AC_MSG_RESULT([ * found Linux 2.2.x or higher])
 523                         AC_DEFINE(SENDFILE_FLAVOR_LINUX, 1, [Define if the sendfile() function uses Linux semantics])
 524                 else
 525                         AC_MSG_RESULT([ * found Linux 2.0.x ])
 526                 fi
 527         fi
 528
 529         dnl ----- Linux/alpha specific -----
 530         if test x"$this_cpu" = "xalpha"; then
 531                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 532                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 533         fi
 534         need_dash_r=no
 535 fi
 536
 537 dnl ----- Mac OSX specific -----
 538 if test x"$this_os" = "xmacosx"; then
 539         AC_MSG_RESULT([ * Mac OSX specific configuration])
 540         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 541         AC_DEFINE(HAVE_BROKEN_CPP, 1, [Define if cpp is broken])
 542         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 543         dnl AC_DEFINE(NO_DLFCN_H)
 544         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 545 fi
 546
 547 dnl ----- NetBSD specific -----
 548 if test x"$this_os" = "xnetbsd"; then
 549         AC_MSG_RESULT([ * NetBSD specific configuration])
 550         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 551         if echo __ELF__ | $CC -E - | grep __ELF__ > /dev/null; then
 552                 # NetBSD ELF machines don't have to have DLSYM_PREPEND_UNDERSCORE.
 553                 # If this test is true, it's not an ELF box.
 554                 # This REALLY should be a configure test.
 555                 AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 556         fi
 557         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 558         need_dash_r=yes
 559
 560         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 561         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 562         AC_DEFINE(NO_CRYPT_H, 1, [Define if crypt.h does not exist])
 563 fi
 564
 565 dnl ----- OpenBSD specific -----
 566 if test x"$this_os" = "xopenbsd"; then
 567         AC_MSG_RESULT([ * OpenBSD specific configuration])
 568         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 569         AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 570
 571         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 572         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 573         AC_DEFINE(NO_CRYPT_H, 1, [Define if crypt.h does not exist])
 574 fi
 575
 576 dnl ----- Solaris specific -----
 577 if test x"$this_os" = "xsolaris"; then
 578         AC_MSG_RESULT([ * Solaris specific configuration])
 579         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 580         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 581         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 582         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 583         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 584         need_dash_r=yes
 585
 586         AC_MSG_RESULT([enabling Solaris kernel module build])
 587         solaris_module=yes
 588 fi
 589
 590 dnl ----- Tru64 specific -----
 591 if test x"$this_os" = "xtru64"; then
 592         AC_MSG_RESULT([ * Tru64 specific configuration])
 593         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 594         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 595         dnl AC_DEFINE(USE_MOUNT_H)
 596         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 597         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 598         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 599         AC_CHECK_LIB(security,set_auth_parameters)
 600         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 601         need_dash_r=no
 602         sysv_style=tru64
 603 fi
 604
 605 dnl -- look for OpenSSL and other crypt libraries
 606 AC_PATH_GCRYPT
 607 AC_PATH_SSL
 608
 609 dnl --------------------- check for building Kerberos v4 UAM module
 610
 611 AC_ARG_ENABLE(krb4-uam,
 612         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],
 613         if test "$enableval" = "yes"; then
 614                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 615                 compile_kerberos=yes
 616                 AC_MSG_RESULT([enabling build with Kerberos v4 UAM module])
 617         fi
 618 )
 619 dnl --------------------- overwrite the config files . . . or not.
 620
 621 AC_MSG_CHECKING([whether configuration files should be overwritten])
 622 AC_ARG_ENABLE(overwrite,
 623         [  --enable-overwrite      overwrite configuration files during installation],
 624         [OVERWRITE_CONFIG="${enable_overwrite}"],
 625         [OVERWRITE_CONFIG="no"]
 626 )
 627 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 628
 629 dnl --------------------- last minute substitutions
 630
 631 AC_SUBST(LIBS)
 632 AC_SUBST(CFLAGS)
 633 AC_SUBST(OVERWRITE_CONFIG)
 634
 635 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 636 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
 637 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 638 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 639 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 640 AM_CONDITIONAL(USE_PAM, test x$compile_pam = xyes)
 641 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 642 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 643 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
 644 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
 645 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
 646 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
 647 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
 648
 649 dnl --------------------- generate files
 650
 651 AC_OUTPUT([Makefile
 652         bin/Makefile
 653         bin/adv1tov2/Makefile
 654         bin/aecho/Makefile
 655         bin/afile/Makefile
 656         bin/afppasswd/Makefile
 657         bin/cnid/Makefile
 658         bin/cnid/cnid_maint
 659         bin/getzones/Makefile
 660         bin/megatron/Makefile
 661         bin/nbp/Makefile
 662         bin/pap/Makefile
 663         bin/psorder/Makefile
 664         config/Makefile
 665         contrib/Makefile
 666         contrib/macusers/Makefile
 667         contrib/macusers/macusers
 668         contrib/nu/Makefile
 669         contrib/nu/nu
 670         contrib/printing/Makefile
 671         contrib/shell_utils/Makefile
 672         contrib/shell_utils/afpd-mtab.pl
 673         contrib/shell_utils/apple_cp
 674         contrib/shell_utils/apple_mv
 675         contrib/shell_utils/apple_rm
 676         contrib/shell_utils/cleanappledouble.pl
 677         contrib/shell_utils/lp2pap.sh
 678         contrib/shell_utils/netatalkshorternamelinks.pl
 679         contrib/timelord/Makefile
 680         contrib/a2boot/Makefile
 681         distrib/Makefile
 682         distrib/config/Makefile
 683         distrib/config/netatalk-config
 684         distrib/initscripts/Makefile
 685         distrib/m4/Makefile
 686         doc/Makefile
 687         etc/Makefile
 688         etc/afpd/Makefile
 689         etc/afpd/nls/Makefile
 690         etc/atalkd/Makefile
 691         etc/uams/Makefile
 692         etc/uams/uams_krb4/Makefile
 693         etc/papd/Makefile
 694         etc/psf/Makefile
 695         etc/psf/etc2ps.sh
 696         include/Makefile
 697         include/atalk/Makefile
 698         libatalk/Makefile
 699         libatalk/adouble/Makefile
 700         libatalk/asp/Makefile
 701         libatalk/atp/Makefile
 702         libatalk/cnid/Makefile
 703         libatalk/compat/Makefile
 704         libatalk/dsi/Makefile
 705         libatalk/nbp/Makefile
 706         libatalk/netddp/Makefile
 707         libatalk/util/Makefile
 708         macros/Makefile
 709         man/Makefile
 710         man/man1/Makefile
 711         man/man3/Makefile
 712         man/man4/Makefile
 713         man/man5/Makefile
 714         man/man8/Makefile
 715         sys/Makefile
 716         sys/generic/Makefile
 717         sys/generic/sys/Makefile
 718         sys/netatalk/Makefile
 719         sys/netbsd/Makefile
 720         sys/netbsd/netatalk/Makefile
 721         sys/solaris/Makefile
 722         sys/solaris/Makefile.kernel
 723         sys/sunos/Makefile
 724         sys/ultrix/Makefile
 725         ],
 726         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
 727 )
 728