configure.in

   1 dnl $Id: configure.in,v 1.126.2.14 2002-02-07 23:50:21 srittau Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(bin/adv1tov2/adv1tov2.c)
   5
   6 NETATALK_VERSION=`cat VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AM_PROG_LIBTOOL
  21 NETATALK_PROG_PERL
  22
  23 dnl *********************************************************************
  24 dnl FIXME! FIXME! These should be selectable properly, and should produce
  25 dnl the proper flags and defines...
  26 dnl *********************************************************************
  27
  28 dnl Checks for libraries.
  29 dnl Replace `main' with a function in -labs:
  30 AC_CHECK_LIB(abs, main)
  31 dnl Replace `main' with a function in -laudit:
  32 AC_CHECK_LIB(audit, main)
  33 dnl Replace `main' with a function in -lauth:
  34 AC_CHECK_LIB(auth, main)
  35 dnl Replace `main' with a function in -lcmd:
  36 AC_CHECK_LIB(cmd, main)
  37 dnl Replace `main' with a function in -lcrypt:
  38 AC_CHECK_LIB(crypt, main)
  39 dnl Replace `main' with a function in -ld:
  40 AC_CHECK_LIB(d, main)
  41 dnl Replace `main' with a function in -ldl:
  42 AC_CHECK_LIB(dl, main)
  43 dnl Replace `main' with a function in -lkauth:
  44 AC_CHECK_LIB(kauth, main)
  45 dnl Replace `main' with a function in -lkrb:
  46 AC_CHECK_LIB(krb, main)
  47 dnl Replace `main' with a function in -llwp:
  48 AC_CHECK_LIB(lwp, main)
  49 dnl Replace `main' with a function in -ln:
  50 AC_CHECK_LIB(n, main)
  51 dnl Replace `main' with a function in -lnsl:
  52 AC_CHECK_LIB(nsl, main)
  53 dnl Replace `main' with a function in -lprot:
  54 AC_CHECK_LIB(prot, main)
  55 dnl Replace `main' with a function in -lrx:
  56 AC_CHECK_LIB(rx, main)
  57 dnl Replace `main' with a function in -lrxkad:
  58 AC_CHECK_LIB(rxkad, main)
  59 dnl Replace `main' with a function in -lsocket:
  60 AC_CHECK_LIB(socket, main)
  61 dnl Replace `main' with a function in -lsys:
  62 AC_CHECK_LIB(sys, main)
  63 dnl Replace `main' with a function in -lubik:
  64 AC_CHECK_LIB(ubik, main)
  65
  66 #
  67 # Check presence of some functions
  68 #
  69 # Check for XPG4 access() function
  70 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  71 # has such a function that works only on AFS filesystems.
  72 AC_CHECK_FUNCS(access)
  73
  74 dnl Checks for header files.
  75 AC_HEADER_DIRENT
  76 AC_HEADER_STDC
  77 AC_HEADER_SYS_WAIT
  78 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h sys/mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h)
  79 AC_CHECK_HEADER(sys/cdefs.h,,
  80         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  81         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  82 )
  83
  84 dnl Checks for typedefs, structures, and compiler characteristics.
  85 AC_C_CONST
  86 AC_TYPE_UID_T
  87 AC_C_INLINE
  88 AC_TYPE_MODE_T
  89 AC_TYPE_OFF_T
  90 AC_TYPE_PID_T
  91 AC_TYPE_SIZE_T
  92 AC_STRUCT_ST_RDEV
  93 AC_HEADER_TIME
  94 AC_STRUCT_TM
  95
  96 dnl Checks for library functions.
  97 AC_TYPE_GETGROUPS
  98 AC_PROG_GCC_TRADITIONAL
  99 AC_FUNC_MEMCMP
 100 AC_HEADER_MAJOR
 101 AC_FUNC_MMAP
 102 AC_TYPE_SIGNAL
 103 AC_FUNC_UTIME_NULL
 104 AC_FUNC_WAIT3
 105 AC_CHECK_FUNCS(flock getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strstr strtoul setpgrp strchr memcpy)
 106 AC_FUNC_SETPGRP
 107
 108 dnl --------------------------------------------------------------------------
 109 dnl specific configuration comes in here:
 110 dnl --------------------------------------------------------------------------
 111
 112 AC_DEFINE(ADMIN_GRP, 1)
 113
 114 AC_ARG_WITH(admin-group,
 115         [  --disable-admin-group   disable admin group],
 116         if test "$enableval" = "no"; then
 117                 AC_DEFINE(ADMIN_GRP, 0)
 118                 AC_MSG_RESULT([disabling administrative group support])
 119         fi
 120 )
 121
 122 NETATALK_AFS_CHECK
 123
 124 AC_ARG_WITH(pkgconfdir,
 125         [  --with-pkgconfdir=DIR   package specific configuration in DIR
 126                           [[SYSCONF/netatalk]]],
 127                 PKGCONFDIR="$withval",
 128                 PKGCONFDIR="${sysconfdir}/netatalk"
 129 )
 130
 131 dnl FIXME: make this an extra check
 132 NLSDIR="${PKGCONFDIR}/nls"
 133
 134 AC_ARG_WITH(cracklib,
 135         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],
 136         if test "x$withval" != "xno" ; then
 137                 cracklib="$withval"
 138                 AC_CHECK_LIB(crack, main,
 139                         AC_DEFINE(USE_CRACKLIB)
 140                         LIBS="$LIBS -lcrack"
 141                         AC_MSG_RESULT([enabling cracklib support])
 142                         if test "$cracklib" = "yes"; then
 143                                 cracklib="/usr/lib/cracklib_dict"
 144                         fi
 145                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 146                                 [path to cracklib dictionary])
 147                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib]),
 148                         AC_MSG_ERROR([cracklib not found!])
 149                 )
 150         fi
 151 )
 152
 153 AC_ARG_ENABLE(ddp,
 154         [  --disable-ddp           disable DDP],
 155         if test "$enableval" = "no"; then
 156                 AC_DEFINE(NO_DDP, 1)
 157                 AC_MSG_RESULT([disabling DDP])
 158         fi
 159 )
 160
 161 AC_ARG_ENABLE(debug,
 162         [  --enable-debug          enable debug code],
 163         if test "$enableval" != "no"; then
 164                 if test "$enableval" = "yes"; then
 165                         AC_DEFINE(DEBUG, 1)
 166                 else
 167                         AC_DEFINE_UNQUOTED(DEBUG, $enableval)
 168                 fi
 169                 AC_MSG_RESULT([enabling debugging code])
 170         fi
 171 )
 172
 173
 174 dnl ----------- A NOTE ABOUT DROPKLUDGE
 175 dnl The trouble with this fix is that if you know what the file is called, it
 176 dnl can be read from the Unix side.  That's okay for most academic institutions
 177 dnl since the students don't have telnet access to the Mac servers.  There is
 178 dnl currently no one working on further development/fixes of DROPKLUDGE.
 179 dnl -----------
 180
 181 AC_ARG_ENABLE(dropkludge,
 182         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],
 183         if test "$enableval" = "yes"; then
 184                 AC_DEFINE(DROPKLUDGE, 1)
 185                 AC_MSG_RESULT([enabling experimental dropbox support])
 186         fi
 187 )
 188
 189 AC_ARG_ENABLE(force-uidgid,
 190         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],
 191         if test "$enableval" = "yes"; then
 192                 AC_DEFINE(FORCE_UIDGID, 1)
 193                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 194         fi
 195 )
 196
 197 dnl Don't use DB3 unless it's needed
 198 db3_required=no
 199
 200
 201 dnl Determine DID scheme
 202 AC_MSG_CHECKING([for DID scheme to use])
 203 AC_ARG_WITH(did,
 204         [  --with-did=SCHEME       set DID scheme (last,hash,mtab,cnid)],
 205         [ did_scheme="$withval" ],
 206         [ did_scheme="last" ]
 207 )
 208
 209 if test "x$did_scheme" = "xlast"; then
 210         AC_DEFINE(USE_LASTDID, 1)
 211         AC_MSG_RESULT([last])
 212 elif test "x$did_scheme" = "xhash"; then
 213         AC_MSG_RESULT([device/inode-based hashing])
 214 elif test "x$did_scheme" = "xmtab"; then
 215         AC_DEFINE(DID_MTAB, 1)
 216         AC_MSG_RESULT([mtab-based DID creation support])
 217 elif test "x$did_scheme" = "xcnid"; then
 218         db3_required="yes"
 219         AC_DEFINE(CNID_DB, 1)
 220         AC_MSG_RESULT([enabling build with CNID DB support])
 221 else
 222         AC_MSG_ERROR([unknown DID scheme])
 223 fi
 224 AM_CONDITIONAL(COMPILE_CNID, test "x$did_scheme" = "xcnid")
 225
 226 dnl Check for Berkeley DB3 library
 227 if test "x$db3_required" = "xyes"; then
 228         AC_PATH_DB3(, [AC_MSG_ERROR([Berkeley DB3 library not found!])])
 229 fi
 230
 231 dnl Check for quota support
 232 AC_CHECK_QUOTA
 233
 234 msg_dir=""
 235 AC_ARG_WITH(message-dir,
 236         [  --with-message-dir=PATH path to message files [[PKGCONF/msg]]],
 237                 msg_dir="$withval"
 238                 if test x"$msg_dir" = "x"; then
 239                         msg_dir="${PKGCONFDIR}/msg"
 240                 fi
 241                 AC_DEFINE_UNQUOTED(SERVERTEXT, "$msg_dir",
 242                         [path to message dir [[PKGCONF/msg]]])
 243                 SERVERTEXT="$msg_dir"
 244                 AC_SUBST(SERVERTEXT)
 245 )
 246
 247 dnl Check for optional server location protocol support (used by MacOS X)
 248 NETATALK_SRVLOC
 249
 250 dnl Check for PAM libs
 251 AC_PATH_PAM([
 252         PAPD_LIBS="$PAPD_LIBS $PAM_LIBS"
 253         AFPD_LIBS="$AFPD_LIBS $PAM_LIBS"
 254         use_pam_so=yes
 255         compile_pam=yes
 256         AC_DEFINE(USE_PAM)
 257 ])
 258
 259 AC_MSG_CHECKING([whether shadow support should be enabled])
 260 AC_ARG_WITH(shadow,
 261         [  --with-shadow           enable shadow password support],
 262         [shadowpw="$withval"],
 263         [shadowpw=no]
 264 )
 265 if test "x$shadowpw" = "xyes"; then
 266         AC_DEFINE(SHADOWPW)
 267 fi
 268 AC_MSG_RESULT([$shadowpw])
 269
 270 AC_ARG_ENABLE(shell-check,
 271         [  --disable-shell-check   disable checking for a valid shell],
 272         if test "$enableval" = "no"; then
 273                 AC_DEFINE(DISABLE_SHELLCHECK, 1)
 274                 AC_MSG_RESULT([disabling valid shell check])
 275         fi
 276 )
 277
 278 AC_MSG_CHECKING([whether flock locks should be enabled])
 279 AC_ARG_WITH(flock-locks,
 280         [  --with-flock-locks      enable flock locks support],
 281         [flock_locks="$withval"],
 282         [flock_locks="no"]
 283 )
 284 if test "x$flock_locks" = "xyes"; then
 285         AC_DEFINE(USE_FLOCK_LOCKS)
 286 fi
 287 AC_MSG_RESULT([$flock_locks])
 288
 289 AC_ARG_WITH(tcp-wrappers,
 290         [  --with-tcp-wrappers     enable TCP wrappers support],
 291         AC_CHECK_LIB(wrap, tcpd_warn,
 292                 AC_DEFINE(TCPWRAP)
 293                 AFPD_LIBS="$AFPD_LIBS -lwrap"
 294                 AC_MSG_RESULT([enabling TCP wrappers support])
 295         )
 296 )
 297
 298 AC_ARG_ENABLE(redhat,
 299         [  --enable-redhat         use redhat-style sysv configuration ],
 300         if test "$enableval" = "yes"; then
 301                 sysv_style=redhat
 302         fi
 303         AC_MSG_RESULT([enabling redhat-style sysv support])
 304 )
 305
 306 AC_ARG_ENABLE(suse,
 307         [  --enable-suse           use suse-style sysv configuration ],
 308         if test "$enableval" = "yes"; then
 309                 sysv_style=suse
 310         fi
 311         AC_MSG_RESULT([enabling suse-style sysv support])
 312 )
 313
 314 AC_ARG_ENABLE(cobalt,
 315         [  --enable-cobalt         use cobalt-style sysv configuration ],
 316         if test "$enableval" = "yes"; then
 317                 sysv_style=cobalt
 318         fi
 319         AC_MSG_RESULT([enabling cobalt-style sysv support])
 320 )
 321
 322 AC_ARG_ENABLE(netbsd,
 323         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 324         if test "x$enableval" = "xyes"; then
 325                 sysv_style=netbsd
 326         fi
 327         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 328 )
 329
 330 dnl ----- timelord compilation (disabled by default)
 331 AC_MSG_CHECKING([whether timelord should be compiled])
 332 compile_timelord=no
 333 AC_ARG_ENABLE(timelord,
 334         [  --enable-timelord       enable compilation of timelord server],
 335         [compile_timelord="$enableval"],
 336         [compile_timelord="no"]
 337 )
 338 AC_MSG_RESULT([$compile_timelord])
 339
 340 AC_ARG_WITH(uams-path,
 341         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],
 342         uams_path="$withval",
 343         uams_path="${PKGCONFDIR}/uams"
 344 )
 345
 346 dnl --------------------------------------------------------------------------
 347 dnl FHS stuff has to be done last because it overrides other defaults
 348 dnl --------------------------------------------------------------------------
 349
 350 AC_ARG_ENABLE(fhs,
 351         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],
 352         if test "$enableval" = "yes"; then
 353                 uams_path="/usr/lib/netatalk"
 354                 sysconfdir="/etc"
 355                 PKGCONFDIR=${sysconfdir}/netatalk
 356                 use_pam_so=yes
 357                 mandir="/usr/share/man"
 358                 AC_DEFINE(FHS_COMPATIBILITY)
 359         fi
 360         AC_MSG_RESULT([enabling Filesystem Hierarchy Standard (FHS) compatibility])
 361 )
 362
 363 dnl --------------------------------------------------------------------------
 364 dnl post-FHS substitutions, etc
 365 dnl --------------------------------------------------------------------------
 366
 367 dnl ***** UAMS_PATH
 368 AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 369         [path to UAMs [default=PKGCONF/uams]])
 370 UAMS_PATH="${uams_path}"
 371 AC_SUBST(UAMS_PATH)
 372
 373 dnl --------------------------------------------------------------------------
 374 dnl drop in includes for top level directory structures here...
 375 dnl --------------------------------------------------------------------------
 376
 377 dnl Note: $(top_srcdir)/include should be added before all other includes
 378 dnl       so that includes from that directory a preferred to includes from
 379 dnl       /usr/include or similar places.
 380 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 381 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 382
 383 dnl --------------------------------------------------------------------------
 384 dnl specific configuration comes in here:
 385 dnl --------------------------------------------------------------------------
 386
 387 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 388
 389 dnl --------------------- determine operating system from "target"
 390 case "$host_os" in
 391         *aix*)                          this_os=aix ;;
 392         *freebsd*)                      this_os=freebsd ;;
 393         *hpux11*)                       this_os=hpux11 ;;
 394         *irix*)                         this_os=irix ;;
 395         *linux*)                        this_os=linux ;;
 396         *osx*)                          this_os=macosx ;;
 397         *darwin*)                       this_os=macosx ;;
 398         *netbsd*)                       this_os=netbsd ;;
 399         *openbsd*)                      this_os=openbsd ;;
 400         *osf*)                          this_os=tru64 ;;
 401         *solaris*)                      this_os=solaris ;;
 402 esac
 403
 404 case "$host_cpu" in
 405         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 406         alpha)                                          this_cpu=alpha ;;
 407         mips)                                           this_cpu=mips ;;
 408         powerpc|ppc)                            this_cpu=ppc ;;
 409 esac
 410
 411 dnl --------------------- operating system specific flags (port from sys/*)
 412
 413 dnl ----- AIX specific -----
 414 if test x"$this_os" = "xaix"; then
 415         AC_MSG_RESULT([ * AIX specific configuration])
 416         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 417
 418         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 419         dnl compilation environment.  It's enough to get things defined
 420         dnl right in endian.h provided that long long is supported, though.
 421         AC_DEFINE(HAVE_32BIT_LONGS)
 422 fi
 423
 424 dnl ----- FreeBSD specific -----
 425 if test x"$this_os" = "xfreebsd"; then
 426         AC_MSG_RESULT([ * FreeBSD specific configuration])
 427         AC_DEFINE(BSD4_4)
 428         AC_DEFINE(SENDFILE_FLAVOR_BSD)
 429
 430         AC_DEFINE(NO_CRYPT_H, 1)
 431 fi
 432
 433 dnl ----- HP-UX 11 specific -----
 434 if test x"$this_os" = "xhpux11"; then
 435         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 436
 437         AC_DEFINE(_ISOC9X_SOURCE)
 438         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 439 fi
 440
 441 dnl ----- IRIX specific -----
 442 if test x"$this_os" = "xirix"; then
 443         AC_MSG_RESULT([ * IRIX specific configuration])
 444
 445         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 446 fi
 447
 448 dnl ----- Linux specific -----
 449 if test x"$this_os" = "xlinux"; then
 450         AC_MSG_RESULT([ * Linux specific configuration])
 451
 452         dnl ----- check if we need the quotactl wrapper
 453         AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 454         AC_CHECK_FUNC(quotactl,,
 455                 AC_DEFINE(NEED_QUOTACTL_WRAPPER)
 456                 AC_MSG_RESULT([enabling quotactl wrapper])
 457         )
 458
 459         dnl ----- as far as I can tell, dbtob always does the wrong thing
 460         dnl ----- on every single version of linux I've ever played with.
 461         dnl ----- see etc/afpd/quota.c
 462         AC_DEFINE(HAVE_BROKEN_DBTOB)
 463
 464         dnl --- added by Yoshinobu Ishizaki (2001.03.13) ---
 465         dnl ----- check if version is newer than 2.2.x
 466         changequote(<<,>>)
 467         majorvers="`uname -r | sed 's/\([0-9]\)..*/\1/'`"
 468         minorvers="`uname -r | sed 's/[0-9]\.\([0-9]\)\..*/\1/'`"
 469         if [ $majorvers -ge 2 ]; then
 470                 if [ $minorvers -ge 2 ]; then
 471                         changequote([,])
 472                         AC_MSG_RESULT([ * found Linux 2.2.x or higher])
 473                         AC_DEFINE(SENDFILE_FLAVOR_LINUX)
 474                 else
 475                         AC_MSG_RESULT([ * found Linux 2.0.x ])
 476                 fi
 477         fi
 478
 479         dnl ----- Linux/alpha specific -----
 480         if test x"$this_cpu" = "xalpha"; then
 481                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 482                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG)
 483         fi
 484         need_dash_r=no
 485 fi
 486
 487 dnl ----- Mac OSX specific -----
 488 if test x"$this_os" = "xmacosx"; then
 489         AC_MSG_RESULT([ * Mac OSX specific configuration])
 490         AC_DEFINE(BSD4_4)
 491         AC_DEFINE(HAVE_BROKEN_CPP)
 492         AC_DEFINE(HAVE_2ARG_DBTOB)
 493         dnl AC_DEFINE(NO_DLFCN_H)
 494         AC_DEFINE(MACOSX_SERVER)
 495 fi
 496
 497 dnl ----- NetBSD specific -----
 498 if test x"$this_os" = "xnetbsd"; then
 499         AC_MSG_RESULT([ * NetBSD specific configuration])
 500         AC_DEFINE(BSD4_4)
 501         AC_DEFINE(DLSYM_PREPEND_UNDERSCORE)
 502         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 503         need_dash_r=yes
 504
 505         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 506         AC_DEFINE(UAM_DHX, 1)
 507         AC_DEFINE(NO_CRYPT_H, 1)
 508 fi
 509
 510 dnl ----- OpenBSD specific -----
 511 if test x"$this_os" = "xopenbsd"; then
 512         AC_MSG_RESULT([ * OpenBSD specific configuration])
 513         AC_DEFINE(BSD4_4)
 514         AC_DEFINE(DLSYM_PREPEND_UNDERSCORE)
 515
 516         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 517         AC_DEFINE(UAM_DHX, 1)
 518         AC_DEFINE(NO_CRYPT_H, 1)
 519 fi
 520
 521 dnl ----- Solaris specific -----
 522 if test x"$this_os" = "xsolaris"; then
 523         AC_MSG_RESULT([ * Solaris specific configuration])
 524         AC_DEFINE(__svr4__)
 525         AC_DEFINE(_ISOC9X_SOURCE)
 526         AC_DEFINE(NO_STRUCT_TM_GMTOFF)
 527         AC_DEFINE(SOLARIS)
 528         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 529         need_dash_r=yes
 530
 531         AC_MSG_RESULT([enabling Solaris kernel module build])
 532         solaris_module=yes
 533 fi
 534
 535 dnl ----- Tru64 specific -----
 536 if test x"$this_os" = "xtru64"; then
 537         AC_MSG_RESULT([ * Tru64 specific configuration])
 538         AC_DEFINE(NO_DDP)
 539         AC_DEFINE(HAVE_64BIT_LONGS)
 540         dnl AC_DEFINE(USE_MOUNT_H)
 541         AC_DEFINE(USE_OLD_RQUOTA)
 542         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 543         AC_DEFINE(TRU64)
 544         AC_CHECK_LIB(security,set_auth_parameters)
 545         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 546         need_dash_r=no
 547         sysv_style=tru64
 548 fi
 549
 550 dnl -- look for openssl
 551 AC_PATH_SSL
 552
 553 dnl --------------------- check for building PGP UAM module
 554
 555 AC_ARG_ENABLE(pgp-uam,
 556         [  --enable-pgp-uam        enable build of PGP UAM module],
 557         if test "$enableval" = "yes"; then
 558                 if test "$compile_ssl" = "yes"; then
 559                         AC_DEFINE(UAM_PGP, 1)
 560                         compile_pgp=yes
 561                         AC_MSG_RESULT([enabling build with PGP UAM module])
 562                 fi
 563         fi
 564 )
 565
 566 dnl --------------------- check for building Kerberos v4 UAM module
 567
 568 AC_ARG_ENABLE(krb4-uam,
 569         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],
 570         if test "$enableval" = "yes"; then
 571                 AC_DEFINE(UAM_KRB4, 1)
 572                 compile_kerberos=yes
 573                 AC_MSG_RESULT([enabling build with Kerberos v4 UAM module])
 574         fi
 575 )
 576 dnl --------------------- overwrite the config files . . . or not.
 577
 578 AC_MSG_CHECKING([whether configuration files should be overwritten])
 579 AC_ARG_ENABLE(overwrite,
 580         [  --enable-overwrite      overwrite configuration files during installation],
 581         [OVERWRITE_CONFIG="${enable_overwrite}"],
 582         [OVERWRITE_CONFIG="no"]
 583 )
 584 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 585
 586 dnl --------------------- last minute substitutions
 587
 588 AC_SUBST(LIBS)
 589 AC_SUBST(AFPD_LIBS)
 590 AC_SUBST(PAPD_LIBS)
 591 AC_SUBST(CFLAGS)
 592 AC_SUBST(PKGCONFDIR)
 593 AC_SUBST(NLSDIR)
 594 AC_SUBST(OVERWRITE_CONFIG)
 595
 596 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 597 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 598 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 599 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 600 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 601 AM_CONDITIONAL(USE_PAM, test x$compile_pam = xyes)
 602 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 603 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
 604 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 605 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
 606 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
 607 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
 608 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
 609 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
 610
 611 dnl --------------------- generate files
 612
 613 AC_OUTPUT([Makefile
 614         bin/Makefile
 615         bin/adv1tov2/Makefile
 616         bin/aecho/Makefile
 617         bin/afile/Makefile
 618         bin/afppasswd/Makefile
 619         bin/cnid/Makefile
 620         bin/getzones/Makefile
 621         bin/megatron/Makefile
 622         bin/nbp/Makefile
 623         bin/pap/Makefile
 624         bin/psorder/Makefile
 625         config/Makefile
 626         contrib/Makefile
 627         contrib/macusers/Makefile
 628         contrib/macusers/macusers
 629         contrib/nu/Makefile
 630         contrib/nu/nu
 631         contrib/printing/Makefile
 632         contrib/shell_utils/Makefile
 633         contrib/shell_utils/afpd-mtab.pl
 634         contrib/shell_utils/apple_cp
 635         contrib/shell_utils/apple_mv
 636         contrib/shell_utils/apple_rm
 637         contrib/shell_utils/cleanappledouble.pl
 638         contrib/shell_utils/netatalkshorternamelinks.pl
 639         contrib/timelord/Makefile
 640         distrib/Makefile
 641         distrib/config/Makefile
 642         distrib/config/netatalk-config
 643         distrib/initscripts/Makefile
 644         distrib/m4/Makefile
 645         doc/Makefile
 646         etc/Makefile
 647         etc/afpd/Makefile
 648         etc/afpd/nls/Makefile
 649         etc/atalkd/Makefile
 650         etc/uams/Makefile
 651         etc/uams/uams_krb4/Makefile
 652         etc/papd/Makefile
 653         etc/psf/Makefile
 654         include/Makefile
 655         include/atalk/Makefile
 656         libatalk/Makefile
 657         libatalk/adouble/Makefile
 658         libatalk/asp/Makefile
 659         libatalk/atp/Makefile
 660         libatalk/cnid/Makefile
 661         libatalk/compat/Makefile
 662         libatalk/dsi/Makefile
 663         libatalk/nbp/Makefile
 664         libatalk/netddp/Makefile
 665         libatalk/util/Makefile
 666         macros/Makefile
 667         man/Makefile
 668         man/man1/Makefile
 669         man/man3/Makefile
 670         man/man4/Makefile
 671         man/man5/Makefile
 672         man/man8/Makefile
 673         sys/Makefile
 674         sys/generic/Makefile
 675         sys/generic/sys/Makefile
 676         sys/netatalk/Makefile
 677         sys/netbsd/Makefile
 678         sys/netbsd/netatalk/Makefile
 679         sys/solaris/Makefile
 680         sys/solaris/Makefile.kernel
 681         sys/sunos/Makefile
 682         sys/ultrix/Makefile
 683         ],
 684         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
 685 )
 686