configure.in

   1 dnl $Id: configure.in,v 1.239 2010-03-12 15:16:48 franklahm Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_CC_C99
  17 AC_PROG_INSTALL
  18 AC_PROG_LN_S
  19 AC_PROG_MAKE_SET
  20 AC_LIBTOOL_DLOPEN
  21 AC_PROG_LIBTOOL
  22 AC_PROG_PERL
  23 AC_PROG_GREP
  24 AC_PROG_PS
  25
  26 AM_PROG_CC_C_O
  27
  28 dnl *********************************************************************
  29 dnl FIXME! FIXME! These should be selectable properly, and should produce
  30 dnl the proper flags and defines...
  31 dnl *********************************************************************
  32
  33 ############################################
  34 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  35 #AC_SEARCH_LIBS(dlopen, [dl])
  36 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  37
  38 dnl Checks for libraries.
  39 dnl Replace `main' with a function in -labs:
  40 dnl AC_CHECK_LIB(abs, main)
  41 dnl Replace `main' with a function in -laudit:
  42 dnl AC_CHECK_LIB(audit, main)
  43 dnl Replace `main' with a function in -lauth:
  44 dnl AC_CHECK_LIB(auth, main)
  45 dnl Replace `main' with a function in -lcmd:
  46 dnl AC_CHECK_LIB(cmd, main)
  47 dnl Replace `main' with a function in -lcrypt:
  48 dnl AC_CHECK_LIB(crypt, main)
  49 dnl Replace `main' with a function in -ld:
  50 dnl AC_CHECK_LIB(d, main)
  51 dnl Replace `main' with a function in -ldl:
  52 dnl AC_CHECK_LIB(dl, dlopen)
  53 dnl Replace `main' with a function in -lkauth:
  54 dnl AC_CHECK_LIB(kauth, main)
  55 dnl Replace `main' with a function in -lkrb:
  56 dnl AC_CHECK_LIB(krb, main)
  57 dnl Replace `main' with a function in -llwp:
  58 dnl AC_CHECK_LIB(lwp, main)
  59 dnl Replace `main' with a function in -ln:
  60 dnl AC_CHECK_LIB(n, main)
  61
  62 dnl not the right stuff but should be enough for now
  63 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
  64 AC_CHECK_FUNC(connect,,[AC_CHECK_LIB(socket,connect)])
  65
  66 dnl Replace `main' with a function in -lprot:
  67 dnl AC_CHECK_LIB(prot, main)
  68 dnl Replace `main' with a function in -lrx:
  69 dnl AC_CHECK_LIB(rx, main)
  70 dnl Replace `main' with a function in -lrxkad:
  71 dnl AC_CHECK_LIB(rxkad, main)
  72 dnl Replace `main' with a function in -lsys:
  73 dnl AC_CHECK_LIB(sys, main)
  74 dnl Replace `main' with a function in -lubik:
  75 dnl AC_CHECK_LIB(ubik, main)
  76
  77
  78 #
  79 # Check presence of some functions
  80 #
  81 # Check for XPG4 access() function
  82 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  83 # has such a function that works only on AFS filesystems.
  84 AC_CHECK_FUNCS(access)
  85 #
  86 AC_CHECK_FUNCS(pread pwrite)
  87
  88 dnl Checks for header files.
  89 AC_HEADER_DIRENT
  90 AC_HEADER_STDC
  91 AC_HEADER_SYS_WAIT
  92 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  93 AC_CHECK_HEADER(sys/cdefs.h,,
  94         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  95         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  96 )
  97 AC_CHECK_HEADERS([sys/mount.h], , ,
  98 [#ifdef HAVE_SYS_PARAM_H
  99 #include <sys/param.h>
 100 #endif
 101 ])
 102
 103 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 104
 105 dnl Checks for typedefs, structures, and compiler characteristics.
 106 AC_C_CONST
 107 AC_TYPE_UID_T
 108 AC_C_INLINE
 109 AC_TYPE_MODE_T
 110 AC_TYPE_OFF_T
 111 AC_TYPE_PID_T
 112 AC_TYPE_SIZE_T
 113 AC_STRUCT_ST_RDEV
 114 AC_HEADER_TIME
 115 AC_STRUCT_TM
 116
 117 dnl --------------------------------------------------------------------------
 118 dnl check if dlsym needs to add an underscore, uses libtool macros
 119 dnl --------------------------------------------------------------------------
 120 AC_LTDL_DLLIB
 121 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 122 AC_LTDL_DLSYM_USCORE
 123 if test x"$libltdl_cv_need_uscore" = xyes; then
 124     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 125 fi
 126
 127
 128 dnl Checks for library functions.
 129 AC_TYPE_GETGROUPS
 130 AC_PROG_GCC_TRADITIONAL
 131 AC_FUNC_MEMCMP
 132 AC_HEADER_MAJOR
 133 AC_FUNC_MMAP
 134 AC_TYPE_SIGNAL
 135 AC_FUNC_UTIME_NULL
 136 AC_FUNC_WAIT3
 137 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul strchr memcpy)
 138 AC_CHECK_FUNCS(backtrace_symbols setlocale nl_langinfo)
 139 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 140 AC_CHECK_FUNCS(strlcpy strlcat setlinebuf gethostid dirfd)
 141 AC_CHECK_FUNC(renameat, AC_DEFINE([_ATFILE_SOURCE], 1, AT file source))
 142 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 143 AC_CACHE_SAVE
 144
 145 dnl Checks for (v)snprintf
 146 NETATALK_SNPRINTF_CHECK
 147
 148 dnl --------------------------------------------------------------------------
 149 dnl 64bit platform check
 150 dnl --------------------------------------------------------------------------
 151
 152 AC_MSG_CHECKING([whether to check for 64bit libraries])
 153 dnl Determine libdir name
 154 case $host in
 155 *-*-linux*)
 156   # Test if the compiler is 64bit
 157   echo 'int i;' > conftest.$ac_ext
 158   atalk_cv_cc_64bit_output=no
 159   if AC_TRY_EVAL(ac_compile); then
 160     case `/usr/bin/file conftest.$ac_objext` in
 161     *"ELF 64"*)
 162       atalk_cv_cc_64bit_output=yes
 163       ;;
 164     esac
 165   fi
 166   rm -rf conftest*
 167   ;;
 168 esac
 169
 170 dnl
 171 dnl FIXME: Do we need something like this for Solaris 64bit?
 172 dnl
 173
 174 case $host_cpu:$atalk_cv_cc_64bit_output in
 175 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 176   atalk_libname="lib64"
 177   AC_MSG_RESULT([yes])
 178   ;;
 179 *:*)
 180   atalk_libname="lib"
 181   AC_MSG_RESULT([no])
 182   ;;
 183 esac
 184
 185 dnl --------------------------------------------------------------------------
 186 dnl specific configuration comes in here:
 187 dnl --------------------------------------------------------------------------
 188
 189
 190 netatalk_cv_admin_group=yes
 191 AC_MSG_CHECKING([for administrative group support])
 192 AC_ARG_ENABLE(admin-group,
 193         [  --disable-admin-group   disable admin group],[
 194         if test x"$enableval" = x"no"; then
 195                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 196                 netatalk_cv_admin_group=no
 197                 AC_MSG_RESULT([no])
 198         else
 199                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 200                 AC_MSG_RESULT([yes])
 201         fi],[
 202                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 203                 AC_MSG_RESULT([yes])
 204         ]
 205 )
 206
 207 NETATALK_AFS_CHECK
 208
 209 NETATALK_CONFIG_DIRS
 210
 211 netatalk_cv_with_cracklib=no
 212 AC_ARG_WITH(cracklib,
 213         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 214         if test "x$withval" != "xno" ; then
 215                 cracklib="$withval"
 216                 AC_CHECK_LIB(crack, main, [
 217                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 218                         LIBS="$LIBS -lcrack"
 219                         if test "$cracklib" = "yes"; then
 220                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 221                         fi
 222                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 223                                 [path to cracklib dictionary])
 224                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 225                         netatalk_cv_with_cracklib=yes
 226                         ],[
 227                         AC_MSG_ERROR([cracklib not found!])
 228                         ]
 229                 )
 230         fi
 231         ]
 232 )
 233 AC_MSG_CHECKING([for cracklib support])
 234 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 235
 236 netatalk_cv_ddp_enabled=yes
 237 AC_MSG_CHECKING([whether to enable DDP])
 238 AC_ARG_ENABLE(ddp,
 239         [  --disable-ddp           disable DDP],[
 240         if test "$enableval" = "no"; then
 241                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 242                 AC_MSG_RESULT([no])
 243                 netatalk_cv_ddp_enabled=no
 244         else
 245                 AC_MSG_RESULT([yes])
 246         fi
 247         ],[
 248                 AC_MSG_RESULT([yes])
 249         ]
 250 )
 251
 252 AC_MSG_CHECKING([whether to enable debug code])
 253 AC_ARG_ENABLE(debug1,
 254         [  --enable-debug1         enable debug code],[
 255         if test "$enableval" != "no"; then
 256                 if test "$enableval" = "yes"; then
 257                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 258                 else
 259                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 260                 fi
 261                 AC_MSG_RESULT([yes])
 262         else
 263                 AC_MSG_RESULT([no])
 264         fi
 265         ],[
 266                 AC_MSG_RESULT([no])
 267         ]
 268 )
 269
 270 AC_MSG_CHECKING([whether to enable verbose debug code])
 271 AC_ARG_ENABLE(debug,
 272         [  --enable-debug          enable verbose debug code],[
 273         if test "$enableval" != "no"; then
 274                 if test "$enableval" = "yes"; then
 275                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 276                 else
 277                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 278                 fi
 279                 AC_MSG_RESULT([yes])
 280         else
 281                 AC_MSG_RESULT([no])
 282         fi
 283         ],[
 284                 AC_MSG_RESULT([no])
 285         ]
 286 )
 287
 288 AC_MSG_CHECKING([whether to enable debugging with debuggers])
 289 AC_ARG_ENABLE(debugging,
 290         [  --enable-debugging      disable SIGALRM timers and DSI tickles (eg for debugging with gdb/dbx/...)],[
 291         if test "$enableval" != "no"; then
 292                 if test "$enableval" = "yes"; then
 293                         AC_DEFINE(DEBUGGING, 1, [Define if you want to disable SIGALRM timers and DSI tickles])
 294                 else
 295                         AC_DEFINE_UNQUOTED(DEBUGGING, $enableval, [Define if you want to disable SIGALRM timers and DSI tickles])
 296                 fi
 297                 AC_MSG_RESULT([yes])
 298         else
 299                 AC_MSG_RESULT([no])
 300         fi
 301         ],[
 302                 AC_MSG_RESULT([no])
 303         ]
 304 )
 305
 306
 307 afp3=no
 308 afp3set=no
 309 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 310 AC_ARG_ENABLE(afp3,
 311         [  --disable-afp3          disable AFP 3.x calls],
 312         [
 313             if test x"$enableval" != x"no"; then
 314                 afp3set=yes
 315                 afp3=yes
 316                 AC_MSG_RESULT([yes])
 317             else
 318                 AC_MSG_RESULT([no])
 319             fi
 320         ],[
 321             AC_MSG_RESULT([yes])
 322             afp3=yes
 323         ]
 324 )
 325
 326 if test x"$afp3" = x"yes"; then
 327         AC_SYS_LARGEFILE([
 328                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 329         ],[
 330                 if test x"$afp3set" = x"yes"; then
 331                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 332                 else
 333                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 334                         afp3=no
 335                 fi
 336         ])
 337 fi
 338
 339 AC_CHECK_ICONV
 340
 341 dnl ----------- A NOTE ABOUT DROPKLUDGE
 342 dnl The trouble with this fix is that if you know what the file is called, it
 343 dnl can be read from the Unix side.  That's okay for most academic institutions
 344 dnl since the students don't have telnet access to the Mac servers.  There is
 345 dnl currently no one working on further development/fixes of DROPKLUDGE.
 346 dnl -----------
 347
 348 netatalk_cv_dropkludge=no
 349 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 350 AC_ARG_ENABLE(dropkludge,
 351         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 352         if test "$enableval" = "yes"; then
 353                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 354                 AC_MSG_RESULT([yes])
 355                 netatalk_cv_dropkludge=yes
 356         else
 357                 AC_MSG_RESULT([no])
 358         fi
 359         ],[
 360                 AC_MSG_RESULT([no])
 361         ]
 362 )
 363
 364 netatalk_cv_force_uidgid=no
 365 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 366 AC_ARG_ENABLE(force-uidgid,
 367         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 368         if test "$enableval" = "yes"; then
 369                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 370                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 371                 AC_MSG_RESULT([yes])
 372                 netatalk_cv_force_uidgid=yes
 373         else
 374                 AC_MSG_RESULT([no])
 375         fi
 376         ],[
 377                 AC_MSG_RESULT([no])
 378         ]
 379 )
 380
 381 dnl Check for CNID database backends
 382 bdb_required=no
 383 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 384
 385 dnl Check for quota support
 386 AC_CHECK_QUOTA
 387
 388 dnl Check for optional server location protocol support (used by MacOS X)
 389 NETATALK_SRVLOC
 390
 391 dnl Check for PAM libs
 392 netatalk_cv_use_pam=no
 393 AC_PATH_PAM([
 394         use_pam_so=yes
 395         compile_pam=yes
 396         netatalk_cv_use_pam=yes
 397         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 398 ])
 399
 400 netatalk_cv_use_shadowpw=no
 401 AC_ARG_WITH(shadow,
 402         [  --with-shadow           enable shadow password support [[auto]]],
 403         [netatalk_cv_use_shadowpw="$withval"],
 404         [netatalk_cv_use_shadowpw=auto]
 405 )
 406
 407 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 408     AC_CHECK_HEADER([shadow.h])
 409     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 410         netatalk_cv_use_shadowpw=yes
 411         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 412     else
 413       if test "x$shadowpw" = "xyes"; then
 414         AC_MSG_ERROR([shadow support not available])
 415       else
 416         netatalk_cv_use_shadowpw=no
 417       fi
 418     fi
 419 fi
 420
 421 AC_MSG_CHECKING([whether shadow support should be enabled])
 422 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 423         AC_MSG_RESULT([yes])
 424 else
 425         AC_MSG_RESULT([no])
 426 fi
 427
 428
 429
 430 netatalk_cv_use_shellcheck=yes
 431 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 432 AC_ARG_ENABLE(shell-check,
 433         [  --disable-shell-check   disable checking for a valid shell],[
 434         if test "$enableval" = "no"; then
 435                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 436                 AC_MSG_RESULT([no])
 437                 netatalk_cv_use_shellcheck=no
 438         else
 439                 AC_MSG_RESULT([yes])
 440         fi
 441         ],[
 442                 AC_MSG_RESULT([yes])
 443         ]
 444 )
 445
 446 NETATALK_TCP_WRAPPERS
 447
 448 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 449 AC_ARG_ENABLE(locking,
 450         [  --disable-locking       disable system locking],[
 451                 if test "$enableval" = "no"; then
 452                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 453                         AC_MSG_RESULT([yes])
 454                 else
 455                         AC_MSG_RESULT([no])
 456                 fi
 457
 458         ],[
 459                 AC_MSG_RESULT([no])
 460         ]
 461
 462 )
 463
 464
 465 AC_ARG_ENABLE(redhat,
 466         [  --enable-redhat         use redhat-style sysv configuration ],[
 467         if test "$enableval" = "yes"; then
 468                 sysv_style=redhat
 469         fi
 470         AC_MSG_RESULT([enabling redhat-style sysv support])
 471         ]
 472 )
 473
 474 AC_ARG_ENABLE(suse,
 475         [  --enable-suse           use suse-style sysv configuration ],[
 476         if test "$enableval" = "yes"; then
 477                 sysv_style=suse
 478         fi
 479         AC_MSG_RESULT([enabling suse-style sysv support])
 480         ]
 481 )
 482
 483 AC_ARG_ENABLE(gentoo,
 484         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 485         if test "$enableval" = "yes"; then
 486                 sysv_style=gentoo
 487         fi
 488         AC_MSG_RESULT([enabling gentoo-style sysv support])
 489         ]
 490 )
 491
 492 AC_ARG_ENABLE(cobalt,
 493         [  --enable-cobalt         use cobalt-style sysv configuration ],
 494         if test "$enableval" = "yes"; then
 495                 sysv_style=cobalt
 496         fi
 497         AC_MSG_RESULT([enabling cobalt-style sysv support])
 498 )
 499
 500 AC_ARG_ENABLE(netbsd,
 501         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 502         if test "x$enableval" = "xyes"; then
 503                 sysv_style=netbsd
 504         fi
 505         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 506 )
 507
 508 AC_ARG_ENABLE(debian,
 509         [  --enable-debian         use debian-style sysv configuration ],[
 510         if test "$enableval" = "yes"; then
 511                 sysv_style=debian
 512         fi
 513         AC_MSG_RESULT([enabling debian-style sysv support])
 514         ]
 515 )
 516
 517 dnl ----- timelord compilation (disabled by default)
 518 AC_MSG_CHECKING([whether timelord should be compiled])
 519 compile_timelord=no
 520 AC_ARG_ENABLE(timelord,
 521         [  --enable-timelord       enable compilation of timelord server],
 522         [compile_timelord="$enableval"],
 523         [compile_timelord="no"]
 524 )
 525 AC_MSG_RESULT([$compile_timelord])
 526
 527 dnl ----- a2boot compilation (disabled by default)
 528 AC_MSG_CHECKING([whether a2boot should be compiled])
 529 compile_a2boot=no
 530 AC_ARG_ENABLE(a2boot,
 531         [  --enable-a2boot         enable compilation of Apple2 boot server],
 532         [compile_a2boot="$enableval"],
 533         [compile_a2boot="no"]
 534 )
 535 AC_MSG_RESULT([$compile_a2boot])
 536
 537 AC_ARG_WITH(uams-path,
 538         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 539                 uams_path="$withval"
 540         ],[
 541                 uams_path="${PKGCONFDIR}/uams"
 542         ]
 543 )
 544
 545 NETATALK_AC_CUPS
 546
 547 dnl check if we can use attribute unused (gcc only) from ethereal
 548 AC_MSG_CHECKING(to see if we can add '__attribute__((unused))' to CFLAGS)
 549 if test x$GCC != x ; then
 550   CFLAGS="-D_U_=\"__attribute__((unused))\" $CFLAGS"
 551   AC_MSG_RESULT(yes)
 552 else
 553   CFLAGS="-D_U_=\"\" $CFLAGS"
 554   AC_MSG_RESULT(no)
 555 fi
 556
 557 dnl --------------------------------------------------------------------------
 558 dnl FHS stuff has to be done last because it overrides other defaults
 559 dnl --------------------------------------------------------------------------
 560
 561 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 562 AC_ARG_ENABLE(fhs,
 563         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 564         if test "$enableval" = "yes"; then
 565                 uams_path="${libdir}/netatalk"
 566                 sysconfdir="/etc"
 567                 PKGCONFDIR=${sysconfdir}/netatalk
 568                 SERVERTEXT="${PKGCONFDIR}/msg"
 569                 use_pam_so=yes
 570                 mandir="/usr/share/man"
 571                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 572                 AC_MSG_RESULT([yes])
 573         else
 574                 AC_MSG_RESULT([no])
 575         fi
 576         ],[
 577                 AC_MSG_RESULT([no])
 578         ]
 579 )
 580
 581 dnl --------------------------------------------------------------------------
 582 dnl post-FHS substitutions, etc
 583 dnl --------------------------------------------------------------------------
 584
 585 dnl ***** UAMS_PATH
 586 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 587 dnl     [path to UAMs [default=PKGCONF/uams]])
 588 UAMS_PATH="${uams_path}"
 589 AC_SUBST(UAMS_PATH)
 590
 591 dnl --------------------------------------------------------------------------
 592 dnl drop in includes for top level directory structures here...
 593 dnl --------------------------------------------------------------------------
 594
 595 dnl Note: $(top_srcdir)/include should be added before all other includes
 596 dnl       so that includes from that directory a preferred to includes from
 597 dnl       /usr/include or similar places.
 598 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 599 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 600
 601 dnl --------------------------------------------------------------------------
 602 dnl specific configuration comes in here:
 603 dnl --------------------------------------------------------------------------
 604
 605 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 606
 607 dnl --------------------- determine operating system from "target"
 608 case "$host_os" in
 609         *aix*)                          this_os=aix ;;
 610         *freebsd*)                      this_os=freebsd ;;
 611         *hpux11*)                       this_os=hpux11 ;;
 612         *irix*)                         this_os=irix ;;
 613         *linux*)                        this_os=linux ;;
 614         *osx*)                          this_os=macosx ;;
 615         *darwin*)                       this_os=macosx ;;
 616         *netbsd*)                       this_os=netbsd ;;
 617         *openbsd*)                      this_os=openbsd ;;
 618         *osf*)                          this_os=tru64 ;;
 619         *solaris*)                      this_os=solaris ;;
 620 esac
 621
 622 case "$host_cpu" in
 623         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 624         alpha)                                          this_cpu=alpha ;;
 625         mips)                                           this_cpu=mips ;;
 626         powerpc|ppc)                            this_cpu=ppc ;;
 627 esac
 628
 629 dnl --------------------- GNU source
 630 case "$this_os" in
 631         linux)  AC_DEFINE(_GNU_SOURCE, 1, [Whether to use GNU libc extensions])
 632         ;;
 633 esac
 634
 635 dnl --------------------- operating system specific flags (port from sys/*)
 636
 637 dnl ----- AIX specific -----
 638 if test x"$this_os" = "xaix"; then
 639         AC_MSG_RESULT([ * AIX specific configuration])
 640         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 641
 642         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 643         dnl compilation environment.  It's enough to get things defined
 644         dnl right in endian.h provided that long long is supported, though.
 645         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 646 fi
 647
 648 dnl ----- FreeBSD specific -----
 649 if test x"$this_os" = "xfreebsd"; then
 650         AC_MSG_RESULT([ * FreeBSD specific configuration])
 651         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 652         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 653         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 654 fi
 655
 656 dnl ----- HP-UX 11 specific -----
 657 if test x"$this_os" = "xhpux11"; then
 658         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 659
 660         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 661         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 662 fi
 663
 664 dnl ----- IRIX specific -----
 665 if test x"$this_os" = "xirix"; then
 666         AC_MSG_RESULT([ * IRIX specific configuration])
 667
 668         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 669 fi
 670
 671 dnl ----- Linux specific -----
 672 if test x"$this_os" = "xlinux"; then
 673         AC_MSG_RESULT([ * Linux specific configuration])
 674
 675         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 676         AC_MSG_CHECKING([for struct atalk_addr])
 677 dnl     AC_COMPILE_IFELSE([
 678         AC_TRY_COMPILE([
 679 #include <sys/socket.h>
 680 #include <asm/types.h>
 681 #include <linux/atalk.h>
 682
 683         struct atalk_addr foo;
 684 ],
 685 [ ], [
 686                 ac_have_atalk_addr=yes
 687                 AC_MSG_RESULT([yes])
 688         ], [
 689                 AC_MSG_RESULT([no])
 690         ])
 691
 692 if test "x$ac_have_atalk_addr" = "xyes"; then
 693         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 694 fi
 695
 696         dnl ----- check if we need the quotactl wrapper
 697 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 698 #       AC_CHECK_FUNC(quotactl,,
 699 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 700 #               AC_MSG_RESULT([enabling quotactl wrapper])
 701 #       )
 702
 703         # For quotas on Linux XFS filesystems
 704
 705         # For linux > 2.5.56
 706         AC_CHECK_HEADERS(linux/dqblk_xfs.h,,
 707                 [AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 708                 AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)]
 709         )
 710
 711
 712         dnl ----- as far as I can tell, dbtob always does the wrong thing
 713         dnl ----- on every single version of linux I've ever played with.
 714         dnl ----- see etc/afpd/quota.c
 715         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 716
 717         netatalk_cv_linux_sendfile=yes
 718         AC_MSG_CHECKING([use sendfile syscall])
 719         AC_ARG_ENABLE(sendfile,
 720             [  --disable-sendfile       disable linux sendfile syscall],[
 721                 if test x"$enableval" = x"no"; then
 722                         netatalk_cv_linux_sendfile=no
 723                         AC_MSG_RESULT([no])
 724                 else
 725                         AC_MSG_RESULT([yes])
 726
 727                 fi
 728             ],[
 729                 AC_MSG_RESULT([yes])
 730         ]
 731
 732        )
 733
 734         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 735             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 736             AC_TRY_LINK([#include <sys/sendfile.h>],
 737 [\
 738 int tofd, fromfd;
 739 off_t offset;
 740 size_t total;
 741 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 742 ],
 743 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 744
 745 # Try and cope with broken Linux sendfile....
 746             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 747             AC_TRY_LINK([\
 748 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 749 #undef _FILE_OFFSET_BITS
 750 #endif
 751 #include <sys/sendfile.h>],
 752 [\
 753 int tofd, fromfd;
 754 off_t offset;
 755 size_t total;
 756 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 757 ],
 758 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 759
 760             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 761                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 762                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 763                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 764             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 765                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 766                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 767                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 768             else
 769                 netatalk_cv_linux_sendfile=no
 770                 AC_MSG_RESULT(no);
 771             fi
 772         fi
 773
 774         dnl ----- Linux/alpha specific -----
 775         if test x"$this_cpu" = "xalpha"; then
 776                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 777                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 778         fi
 779         need_dash_r=no
 780
 781
 782 fi
 783
 784 dnl ----- Mac OSX specific -----
 785 if test x"$this_os" = "xmacosx"; then
 786         AC_MSG_RESULT([ * Mac OSX specific configuration])
 787         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 788         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 789         dnl AC_DEFINE(NO_DLFCN_H)
 790         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 791         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 792         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 793 fi
 794
 795 dnl ----- NetBSD specific -----
 796 if test x"$this_os" = "xnetbsd"; then
 797         AC_MSG_RESULT([ * NetBSD specific configuration])
 798         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 799         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 800         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 801         need_dash_r=yes
 802
 803         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 804         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 805 fi
 806
 807 dnl ----- OpenBSD specific -----
 808 if test x"$this_os" = "xopenbsd"; then
 809         AC_MSG_RESULT([ * OpenBSD specific configuration])
 810         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 811         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 812 fi
 813
 814 dnl ----- Solaris specific -----
 815 if test x"$this_os" = "xsolaris"; then
 816         AC_MSG_RESULT([ * Solaris specific configuration])
 817         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 818         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 819         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 820         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 821         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 822         need_dash_r=yes
 823         sysv_style=solaris
 824
 825         solaris_module=no
 826         AC_MSG_CHECKING([if we can build Solaris kernel module])
 827         if test -x /usr/ccs/bin/ld; then
 828                 solaris_module=yes
 829         fi
 830         AC_MSG_RESULT([$solaris_module])
 831
 832         COMPILE_64BIT_KMODULE=no
 833         KCFLAGS=""
 834         KLDFLAGS=""
 835         COMPILE_KERNEL_GCC=no
 836
 837         if test "$solaris_module" = "yes"; then
 838            dnl Solaris kernel module stuff
 839            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 840
 841            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 842            if test -x /usr/bin/isainfo; then
 843                 # check for 64 bit platform
 844                 if isainfo -kv | grep '^64-bit'; then
 845                         COMPILE_64BIT_KMODULE=yes
 846                 fi
 847            fi
 848
 849            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 850
 851            if test "${GCC}" = yes; then
 852                 COMPILE_KERNEL_GCC=yes
 853                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 854
 855                         AC_MSG_CHECKING([if we can build a 64bit kernel module])
 856
 857                         case `$CC --version 2>/dev/null` in
 858                         [[12]].* | 3.0.*)
 859                                 COMPILE_64BIT_KMODULE=no
 860                                 COMPILE_KERNEL_GCC=no
 861                                 solaris_module=no;;
 862                         *)
 863                                 # use for 64 bit
 864                                 KCFLAGS="-m64"
 865                                 #KLDFLAGS="-melf64_sparc"
 866                                 KLDFLAGS="-64";;
 867                         esac
 868
 869                         AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 870
 871                 else
 872                         KCFLAGS=""
 873                         KLDFLAGS=""
 874                 fi
 875                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 876            else
 877                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 878                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 879                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 880                         KLDFLAGS="-64"
 881                 else
 882                         KCFLAGS=""
 883                         KLDFLAGS=""
 884                 fi
 885                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 886            fi
 887
 888            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 889            AC_TRY_LINK([\
 890 #include <sys/stream.h>
 891 #include <sys/ddi.h>],
 892 [\
 893 timeout_id_t dummy;
 894 ],
 895 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 896
 897            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 898         fi
 899
 900         AC_SUBST(COMPILE_KERNEL_GCC)
 901         AC_SUBST(COMPILE_64BIT_KMODULE)
 902         AC_SUBST(KCFLAGS)
 903         AC_SUBST(KLDFLAGS)
 904 fi
 905
 906 dnl ----- Tru64 specific -----
 907 if test x"$this_os" = "xtru64"; then
 908         AC_MSG_RESULT([ * Tru64 specific configuration])
 909         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 910         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 911         dnl AC_DEFINE(USE_MOUNT_H)
 912         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 913         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 914         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 915         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 916         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 917         AC_CHECK_LIB(security,set_auth_parameters)
 918         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 919         need_dash_r=no
 920         sysv_style=tru64
 921 fi
 922
 923 dnl -- check for libgcrypt, if found enables DHX UAM
 924 AM_PATH_LIBGCRYPT([1:1.2.3],[neta_cv_compile_dhx2=yes
 925                         neta_cv_have_libgcrypt=yes
 926                         AC_MSG_NOTICE([Enabling DHX2 UAM])
 927                         AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define if the DHX2 modules should be built with libgcrypt])
 928                         AC_DEFINE(UAM_DHX2, 1, [Define if the DHX2 UAM modules should be compiled])
 929                         ])
 930
 931 dnl -- look for openssl, if found enables DHX UAM and Randnum UAM
 932 AC_PATH_SSL
 933
 934 dnl Check for Berkeley DB library
 935 if test "x$bdb_required" = "xyes"; then
 936         AC_PATH_BDB(, [
 937                 AC_MSG_RESULT([])
 938                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 939                 AC_MSG_RESULT([You can download the latest version from http://www.sleepycat.com.])
 940                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 941                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option and make sure])
 942                 AC_MSG_RESULT([your linker is configured to check for libraries there.])
 943                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 944         ])
 945 fi
 946
 947 dnl -- check for crypt
 948 AC_CRYPT
 949
 950 dnl --------------------- check for building PGP UAM module
 951
 952 AC_MSG_CHECKING([whether the PGP UAM should be build])
 953 AC_ARG_ENABLE(pgp-uam,
 954         [  --enable-pgp-uam        enable build of PGP UAM module],[
 955         if test "$enableval" = "yes"; then
 956                 if test "x$neta_cv_have_openssl" = "xyes"; then
 957                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 958                         compile_pgp=yes
 959                         AC_MSG_RESULT([yes])
 960                 else
 961                         AC_MSG_RESULT([no])
 962                 fi
 963         fi
 964         ],[
 965                 AC_MSG_RESULT([no])
 966         ]
 967 )
 968
 969 dnl --------------------- check for building Kerberos v4 UAM module
 970
 971 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 972 AC_ARG_ENABLE(krb4-uam,
 973         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 974         if test "$enableval" = "yes"; then
 975                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 976                 compile_kerberos=yes
 977                 AC_MSG_RESULT([yes])
 978         else
 979                 AC_MSG_RESULT([no])
 980         fi
 981         ],[
 982                 AC_MSG_RESULT([no])
 983         ]
 984 )
 985
 986 dnl --------------------- check for building Kerberos V UAM module
 987
 988 netatalk_cv_build_krb5_uam=no
 989 AC_ARG_ENABLE(krbV-uam,
 990         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 991         [
 992                 if test x"$enableval" = x"yes"; then
 993                         NETATALK_GSSAPI_CHECK([
 994                                 netatalk_cv_build_krb5_uam=yes
 995                         ],[
 996                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 997                         ])
 998                 fi
 999         ]
1000
1001 )
1002
1003 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
1004 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
1005         AC_MSG_RESULT([yes])
1006 else
1007         AC_MSG_RESULT([no])
1008 fi
1009 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
1010
1011 dnl --------------------- overwrite the config files . . . or not.
1012
1013 AC_MSG_CHECKING([whether configuration files should be overwritten])
1014 AC_ARG_ENABLE(overwrite,
1015         [  --enable-overwrite      overwrite configuration files during installation],
1016         [OVERWRITE_CONFIG="${enable_overwrite}"],
1017         [OVERWRITE_CONFIG="no"]
1018 )
1019 AC_MSG_RESULT([$OVERWRITE_CONFIG])
1020
1021 dnl --------------------- check for ACL support
1022 neta_cv_nfsv4acl="no"
1023 AC_MSG_CHECKING([if NFSv4 ACL Support should be enabled])
1024 AC_ARG_ENABLE(nfsv4acls,
1025         [  --enable-nfsv4acls      enable NFSv4 ACL Support],[
1026         if test x"$enableval" = x"yes"; then
1027            AC_MSG_RESULT([yes])
1028            neta_cv_nfsv4acl="yes"
1029         else
1030            AC_MSG_RESULT([no])
1031         fi],[
1032            AC_MSG_RESULT([no])
1033         ]
1034 )
1035 if test x$neta_cv_nfsv4acl = xyes; then
1036         AC_CHECK_HEADER([ldap.h],,[
1037                 AC_MSG_ERROR([ACL Support need the LDAP client headers not found.])
1038                 neta_cv_nfsv4acl=no
1039                 ]
1040         )
1041         AC_CHECK_LIB(ldap,ldap_init,neta_cv_nfsv4acl=yes,neta_cv_nfsv4acl=no)
1042 fi
1043 if test x$neta_cv_nfsv4acl = xyes; then
1044         AC_CHECK_HEADER([sys/acl.h],[
1045                 AC_DEFINE([HAVE_NFSv4_ACLS], 1, [Enable ACL code])
1046                 AC_MSG_NOTICE([Enabling ACL support])
1047                 ],
1048                 neta_cv_nfsv4acl=no
1049         )
1050 fi
1051 if test x$neta_cv_nfsv4acl = xyes; then
1052         LIBATALK_ACLS="acl/libacl.la"
1053 else
1054         LIBATALK_ACLS=""
1055 fi
1056 AC_SUBST(LIBATALK_ACLS)
1057
1058 dnl --------------------- check for Extended Attributes support
1059 neta_cv_eas="files"
1060 neta_cv_eas_sys_found=no
1061 neta_cv_eas_sys_not_found=no
1062
1063 AC_CHECK_HEADERS(sys/attributes.h attr/xattr.h sys/xattr.h sys/extattr.h sys/uio.h sys/ea.h)
1064
1065 case "$this_os" in
1066
1067   *osf*)
1068         AC_SEARCH_LIBS(getproplist, [proplist])
1069         AC_CHECK_FUNCS([getproplist fgetproplist setproplist fsetproplist],
1070                    [neta_cv_eas_sys_found=yes],
1071                    [neta_cv_eas_sys_not_found=yes])
1072         AC_CHECK_FUNCS([delproplist fdelproplist add_proplist_entry get_proplist_entry],,
1073                    [neta_cv_eas_sys_not_found=yes])
1074         AC_CHECK_FUNCS([sizeof_proplist_entry],,
1075                    [neta_cv_eas_sys_not_found=yes])
1076   ;;
1077
1078   *solaris*)
1079         AC_CHECK_FUNCS([attropen],
1080                    [neta_cv_eas_sys_found=yes],
1081                    [neta_cv_eas_sys_not_found=yes])
1082   ;;
1083
1084   *)
1085         AC_SEARCH_LIBS(getxattr, [attr])
1086
1087     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1088        AC_CHECK_FUNCS([getxattr lgetxattr fgetxattr listxattr llistxattr],
1089                       [neta_cv_eas_sys_found=yes],
1090                       [neta_cv_eas_sys_not_found=yes])
1091            AC_CHECK_FUNCS([flistxattr removexattr lremovexattr fremovexattr],,
1092                       [neta_cv_eas_sys_not_found=yes])
1093            AC_CHECK_FUNCS([setxattr lsetxattr fsetxattr],,
1094                       [neta_cv_eas_sys_not_found=yes])
1095     fi
1096
1097     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1098            AC_CHECK_FUNCS([getea fgetea lgetea listea flistea llistea],
1099                       [neta_cv_eas_sys_found=yes],
1100                       [neta_cv_eas_sys_not_found=yes])
1101            AC_CHECK_FUNCS([removeea fremoveea lremoveea setea fsetea lsetea],,
1102                       [neta_cv_eas_sys_not_found=yes])
1103     fi
1104
1105     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1106            AC_CHECK_FUNCS([attr_get attr_list attr_set attr_remove],,
1107                       [neta_cv_eas_sys_not_found=yes])
1108        AC_CHECK_FUNCS([attr_getf attr_listf attr_setf attr_removef],,
1109                       [neta_cv_eas_sys_not_found=yes])
1110     fi
1111   ;;
1112 esac
1113
1114 # Do xattr functions take additional options like on Darwin?
1115 if test x"$ac_cv_func_getxattr" = x"yes" ; then
1116         AC_CACHE_CHECK([whether xattr interface takes additional options], smb_attr_cv_xattr_add_opt, [
1117                 old_LIBS=$LIBS
1118                 LIBS="$LIBS $ACL_LIBS"
1119                 AC_TRY_COMPILE([
1120                         #include <sys/types.h>
1121                         #if HAVE_ATTR_XATTR_H
1122                         #include <attr/xattr.h>
1123                         #elif HAVE_SYS_XATTR_H
1124                         #include <sys/xattr.h>
1125                         #endif
1126                 ],[
1127                         getxattr(0, 0, 0, 0, 0, 0);
1128                 ],
1129                 [smb_attr_cv_xattr_add_opt=yes],
1130                 [smb_attr_cv_xattr_add_opt=no;LIBS=$old_LIBS])
1131         ])
1132         if test x"$smb_attr_cv_xattr_add_opt" = x"yes"; then
1133                 AC_DEFINE(XATTR_ADD_OPT, 1, [xattr functions have additional options])
1134         fi
1135 fi
1136
1137 # Check if we have extattr
1138 case "$this_os" in
1139   *freebsd4* | *dragonfly* )
1140     AC_DEFINE(BROKEN_EXTATTR, 1, [Does extattr API work])
1141     ;;
1142   *)
1143     AC_CHECK_FUNCS(extattr_delete_fd extattr_delete_file extattr_delete_link)
1144     AC_CHECK_FUNCS(extattr_get_fd extattr_get_file extattr_get_link)
1145     AC_CHECK_FUNCS(extattr_list_fd extattr_list_file extattr_list_link)
1146     AC_CHECK_FUNCS(extattr_set_fd extattr_set_file extattr_set_link)
1147     ;;
1148 esac
1149
1150 if test "x$neta_cv_eas_sys_found" = "xyes" ; then
1151    if test "x$neta_cv_eas_sys_not_found" != "xyes" ; then
1152       neta_cv_eas="$neta_cv_eas | native"
1153    fi
1154 fi
1155
1156 dnl --------------------- Check if realpath() takes NULL
1157 AC_CACHE_CHECK([if the realpath function allows a NULL argument],
1158     neta_cv_REALPATH_TAKES_NULL, [
1159         AC_TRY_RUN([
1160             #include <stdio.h>
1161             #include <limits.h>
1162             #include <signal.h>
1163
1164             void exit_on_core(int ignored) {
1165                  exit(1);
1166             }
1167
1168             main() {
1169                 char *newpath;
1170                 signal(SIGSEGV, exit_on_core);
1171                 newpath = realpath("/tmp", NULL);
1172                 exit((newpath != NULL) ? 0 : 1);
1173             }],
1174             neta_cv_REALPATH_TAKES_NULL=yes,
1175             neta_cv_REALPATH_TAKES_NULL=no,
1176             neta_cv_REALPATH_TAKES_NULL=cross
1177         )
1178     ]
1179 )
1180
1181 if test x"$neta_cv_REALPATH_TAKES_NULL" = x"yes"; then
1182     AC_DEFINE(REALPATH_TAKES_NULL,1,[Whether the realpath function allows NULL])
1183 fi
1184
1185 dnl --------------------- Netatalk Webmin
1186 NETATALK_WEBMIN
1187
1188 dnl --------------------- last minute substitutions
1189
1190 AC_SUBST(LIBS)
1191 AC_SUBST(CFLAGS)
1192 AC_SUBST(OVERWRITE_CONFIG)
1193
1194 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
1195 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
1196 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
1197 AM_CONDITIONAL(HAVE_LIBGCRYPT, test x$neta_cv_have_libgcrypt = xyes)
1198 AM_CONDITIONAL(HAVE_OPENSSL, test x$neta_cv_have_openssl = xyes)
1199 AM_CONDITIONAL(USE_NFSv4_ACLS, test x$neta_cv_nfsv4acl = xyes)
1200 AM_CONDITIONAL(USE_DHX, test x$neta_cv_compile_dhx = xyes)
1201 AM_CONDITIONAL(USE_DHX2, test x$neta_cv_compile_dhx2 = xyes)
1202 AM_CONDITIONAL(USE_RANDNUM, test x$neta_cv_have_openssl = xyes)
1203 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
1204 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
1205 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
1206 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
1207 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
1208 AM_CONDITIONAL(DEFAULT_HOOK, test x$neta_cv_have_libgcrypt != xyes && test x$neta_cv_have_openssl != xyes)
1209 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
1210 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
1211 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
1212 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
1213 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
1214 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
1215 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
1216 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
1217 AM_CONDITIONAL(USE_DEBIAN, test x$sysv_style = xdebian)
1218 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
1219 AM_CONDITIONAL(USE_BDB, test x$bdb_required = xyes)
1220
1221 dnl --------------------- generate files
1222
1223 AC_OUTPUT([Makefile
1224         bin/Makefile
1225         bin/adv1tov2/Makefile
1226         bin/aecho/Makefile
1227         bin/afile/Makefile
1228         bin/afppasswd/Makefile
1229         bin/cnid/Makefile
1230         bin/cnid/cnid2_create
1231         bin/getzones/Makefile
1232         bin/megatron/Makefile
1233     bin/misc/Makefile
1234         bin/nbp/Makefile
1235         bin/pap/Makefile
1236         bin/psorder/Makefile
1237         bin/uniconv/Makefile
1238         config/Makefile
1239     config/pam/Makefile
1240         contrib/Makefile
1241         contrib/macusers/Makefile
1242         contrib/macusers/macusers
1243         contrib/printing/Makefile
1244         contrib/shell_utils/Makefile
1245         contrib/shell_utils/afpd-mtab.pl
1246         contrib/shell_utils/apple_cp
1247     contrib/shell_utils/apple_dump
1248         contrib/shell_utils/apple_mv
1249         contrib/shell_utils/apple_rm
1250         contrib/shell_utils/asip-status.pl
1251         contrib/timelord/Makefile
1252         contrib/a2boot/Makefile
1253         distrib/Makefile
1254         distrib/config/Makefile
1255         distrib/config/netatalk-config
1256         distrib/initscripts/Makefile
1257         distrib/m4/Makefile
1258         doc/Makefile
1259         etc/Makefile
1260         etc/afpd/Makefile
1261         etc/atalkd/Makefile
1262         etc/cnid_dbd/Makefile
1263         etc/uams/Makefile
1264         etc/uams/uams_krb4/Makefile
1265         etc/papd/Makefile
1266         etc/psf/Makefile
1267         include/Makefile
1268         include/atalk/Makefile
1269         libatalk/Makefile
1270         libatalk/acl/Makefile
1271         libatalk/adouble/Makefile
1272         libatalk/asp/Makefile
1273         libatalk/atp/Makefile
1274         libatalk/cnid/Makefile
1275         libatalk/cnid/cdb/Makefile
1276         libatalk/cnid/last/Makefile
1277         libatalk/cnid/dbd/Makefile
1278         libatalk/cnid/tdb/Makefile
1279         libatalk/compat/Makefile
1280         libatalk/dsi/Makefile
1281         libatalk/nbp/Makefile
1282         libatalk/netddp/Makefile
1283         libatalk/util/Makefile
1284         libatalk/util/test/Makefile
1285         libatalk/tdb/Makefile
1286         libatalk/unicode/Makefile
1287         libatalk/unicode/charsets/Makefile
1288         libatalk/vfs/Makefile
1289         macros/Makefile
1290         man/Makefile
1291         man/man1/Makefile
1292         man/man3/Makefile
1293         man/man4/Makefile
1294         man/man5/Makefile
1295         man/man8/Makefile
1296         sys/Makefile
1297         sys/generic/Makefile
1298         sys/generic/sys/Makefile
1299         sys/netatalk/Makefile
1300         sys/netbsd/Makefile
1301         sys/netbsd/netatalk/Makefile
1302         sys/solaris/Makefile
1303         sys/sunos/Makefile
1304         sys/ultrix/Makefile
1305         ],
1306         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1307 )
1308
1309 AC_NETATALK_LIBS_SUMMARY
1310 AC_NETATALK_CONFIG_SUMMARY