configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.37.2.5 2005-09-27 10:40:40 didg Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58 dnl Replace `main' with a function in -lnsl:
  59 AC_CHECK_LIB(nsl, main)
  60 dnl Replace `main' with a function in -lprot:
  61 dnl AC_CHECK_LIB(prot, main)
  62 dnl Replace `main' with a function in -lrx:
  63 dnl AC_CHECK_LIB(rx, main)
  64 dnl Replace `main' with a function in -lrxkad:
  65 dnl AC_CHECK_LIB(rxkad, main)
  66 dnl Replace `main' with a function in -lsocket:
  67 AC_CHECK_LIB(socket, socket)
  68 dnl Replace `main' with a function in -lsys:
  69 dnl AC_CHECK_LIB(sys, main)
  70 dnl Replace `main' with a function in -lubik:
  71 dnl AC_CHECK_LIB(ubik, main)
  72
  73
  74 #
  75 # Check presence of some functions
  76 #
  77 # Check for XPG4 access() function
  78 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  79 # has such a function that works only on AFS filesystems.
  80 AC_CHECK_FUNCS(access)
  81 #
  82 AC_CHECK_FUNCS(pread pwrite)
  83
  84 dnl Checks for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_STDC
  87 AC_HEADER_SYS_WAIT
  88 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  89 AC_CHECK_HEADER(sys/cdefs.h,,
  90         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  91         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  92 )
  93 AC_CHECK_HEADERS([sys/mount.h], , ,
  94 [#ifdef HAVE_SYS_PARAM_H
  95 #include <sys/param.h>
  96 #endif
  97 ])
  98
  99 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 100
 101 dnl Checks for typedefs, structures, and compiler characteristics.
 102 AC_C_CONST
 103 AC_TYPE_UID_T
 104 AC_C_INLINE
 105 AC_TYPE_MODE_T
 106 AC_TYPE_OFF_T
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_STRUCT_ST_RDEV
 110 AC_HEADER_TIME
 111 AC_STRUCT_TM
 112
 113 dnl --------------------------------------------------------------------------
 114 dnl check if dlsym needs to add an underscore, uses libtool macros
 115 dnl --------------------------------------------------------------------------
 116 AC_LTDL_DLLIB
 117 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 118 AC_LTDL_DLSYM_USCORE
 119 if test x"$libltdl_cv_need_uscore" = xyes; then
 120     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 121 fi
 122
 123
 124 dnl Checks for library functions.
 125 AC_TYPE_GETGROUPS
 126 AC_PROG_GCC_TRADITIONAL
 127 AC_FUNC_MEMCMP
 128 AC_HEADER_MAJOR
 129 AC_FUNC_MMAP
 130 AC_TYPE_SIGNAL
 131 AC_FUNC_UTIME_NULL
 132 AC_FUNC_WAIT3
 133 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul strchr memcpy)
 134 AC_CHECK_FUNCS(backtrace_symbols)
 135 AC_CHECK_FUNCS(setlocale nl_langinfo)
 136 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 137 AC_CHECK_FUNCS(strlcpy strlcat)
 138 AC_CHECK_FUNCS(setlinebuf)
 139 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 140 AC_CACHE_SAVE
 141
 142 dnl Checks for (v)snprintf
 143 NETATALK_SNPRINTF_CHECK
 144
 145 dnl --------------------------------------------------------------------------
 146 dnl 64bit platform check
 147 dnl --------------------------------------------------------------------------
 148
 149 AC_MSG_CHECKING([whether to check for 64bit libraries])
 150 dnl Determine libdir name
 151 case $host in
 152 *-*-linux*)
 153   # Test if the compiler is 64bit
 154   echo 'int i;' > conftest.$ac_ext
 155   atalk_cv_cc_64bit_output=no
 156   if AC_TRY_EVAL(ac_compile); then
 157     case `/usr/bin/file conftest.$ac_objext` in
 158     *"ELF 64"*)
 159       atalk_cv_cc_64bit_output=yes
 160       ;;
 161     esac
 162   fi
 163   rm -rf conftest*
 164   ;;
 165 esac
 166
 167 dnl
 168 dnl FIXME: Do we need something like this for Solaris 64bit?
 169 dnl
 170
 171 case $host_cpu:$atalk_cv_cc_64bit_output in
 172 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 173   atalk_libname="lib64"
 174   AC_MSG_RESULT([yes])
 175   ;;
 176 *:*)
 177   atalk_libname="lib"
 178   AC_MSG_RESULT([no])
 179   ;;
 180 esac
 181
 182 dnl --------------------------------------------------------------------------
 183 dnl specific configuration comes in here:
 184 dnl --------------------------------------------------------------------------
 185
 186
 187 netatalk_cv_admin_group=yes
 188 AC_MSG_CHECKING([for administrative group support])
 189 AC_ARG_ENABLE(admin-group,
 190         [  --disable-admin-group   disable admin group],[
 191         if test x"$enableval" = x"no"; then
 192                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 193                 netatalk_cv_admin_group=no
 194                 AC_MSG_RESULT([no])
 195         else
 196                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 197                 AC_MSG_RESULT([yes])
 198         fi],[
 199                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 200                 AC_MSG_RESULT([yes])
 201         ]
 202 )
 203
 204 NETATALK_AFS_CHECK
 205
 206 NETATALK_CONFIG_DIRS
 207
 208 AC_MSG_CHECKING([whether to use logfile])
 209 AC_ARG_WITH(logfile,
 210         [  --with-logfile=PATH     path for file used by logger],[
 211         if test x"$withval" = x"no"; then
 212                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 213                 AC_MSG_RESULT([no, syslog])
 214         elif test "$withval" != "yes"; then
 215                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 216                 AC_MSG_RESULT([$withval])
 217         else
 218                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 219                 AC_MSG_RESULT([/var/log/netatalk.log])
 220         fi],[
 221                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 222                 AC_MSG_RESULT([no, syslog])
 223         ]
 224 )
 225
 226
 227 netatalk_cv_with_cracklib=no
 228 AC_ARG_WITH(cracklib,
 229         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 230         if test "x$withval" != "xno" ; then
 231                 cracklib="$withval"
 232                 AC_CHECK_LIB(crack, main, [
 233                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 234                         LIBS="$LIBS -lcrack"
 235                         if test "$cracklib" = "yes"; then
 236                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 237                         fi
 238                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 239                                 [path to cracklib dictionary])
 240                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 241                         netatalk_cv_with_cracklib=yes
 242                         ],[
 243                         AC_MSG_ERROR([cracklib not found!])
 244                         ]
 245                 )
 246         fi
 247         ]
 248 )
 249 AC_MSG_CHECKING([for cracklib support])
 250 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 251
 252 netatalk_cv_ddp_enabled=yes
 253 AC_MSG_CHECKING([whether to enable DDP])
 254 AC_ARG_ENABLE(ddp,
 255         [  --disable-ddp           disable DDP],[
 256         if test "$enableval" = "no"; then
 257                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 258                 AC_MSG_RESULT([no])
 259                 netatalk_cv_ddp_enabled=no
 260         else
 261                 AC_MSG_RESULT([yes])
 262         fi
 263         ],[
 264                 AC_MSG_RESULT([yes])
 265         ]
 266 )
 267
 268 AC_MSG_CHECKING([whether to enable debug code])
 269 AC_ARG_ENABLE(debug1,
 270         [  --enable-debug1         enable debug code],[
 271         if test "$enableval" != "no"; then
 272                 if test "$enableval" = "yes"; then
 273                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 274                 else
 275                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 276                 fi
 277                 AC_MSG_RESULT([yes])
 278         else
 279                 AC_MSG_RESULT([no])
 280         fi
 281         ],[
 282                 AC_MSG_RESULT([no])
 283         ]
 284 )
 285
 286 AC_MSG_CHECKING([whether to enable verbose debug code])
 287 AC_ARG_ENABLE(debug,
 288         [  --enable-debug          enable verbose debug code],[
 289         if test "$enableval" != "no"; then
 290                 if test "$enableval" = "yes"; then
 291                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 292                 else
 293                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 294                 fi
 295                 AC_MSG_RESULT([yes])
 296         else
 297                 AC_MSG_RESULT([no])
 298         fi
 299         ],[
 300                 AC_MSG_RESULT([no])
 301         ]
 302 )
 303
 304 afp3=no
 305 afp3set=no
 306 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 307 AC_ARG_ENABLE(afp3,
 308         [  --disable-afp3          disable AFP 3.x calls],
 309         [
 310             if test x"$enableval" != x"no"; then
 311                 afp3set=yes
 312                 afp3=yes
 313                 AC_MSG_RESULT([yes])
 314             else
 315                 AC_MSG_RESULT([no])
 316             fi
 317         ],[
 318             AC_MSG_RESULT([yes])
 319             afp3=yes
 320         ]
 321 )
 322
 323 if test x"$afp3" = x"yes"; then
 324         AC_SYS_LARGEFILE([
 325                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 326         ],[
 327                 if test x"$afp3set" = x"yes"; then
 328                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 329                 else
 330                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 331                         afp3=no
 332                 fi
 333         ])
 334 fi
 335
 336 AC_CHECK_ICONV
 337
 338 dnl ----------- A NOTE ABOUT DROPKLUDGE
 339 dnl The trouble with this fix is that if you know what the file is called, it
 340 dnl can be read from the Unix side.  That's okay for most academic institutions
 341 dnl since the students don't have telnet access to the Mac servers.  There is
 342 dnl currently no one working on further development/fixes of DROPKLUDGE.
 343 dnl -----------
 344
 345 netatalk_cv_dropkludge=no
 346 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 347 AC_ARG_ENABLE(dropkludge,
 348         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 349         if test "$enableval" = "yes"; then
 350                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 351                 AC_MSG_RESULT([yes])
 352                 netatalk_cv_dropkludge=yes
 353         else
 354                 AC_MSG_RESULT([no])
 355         fi
 356         ],[
 357                 AC_MSG_RESULT([no])
 358         ]
 359 )
 360
 361 netatalk_cv_force_uidgid=no
 362 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 363 AC_ARG_ENABLE(force-uidgid,
 364         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 365         if test "$enableval" = "yes"; then
 366                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 367                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 368                 AC_MSG_RESULT([yes])
 369                 netatalk_cv_force_uidgid=yes
 370         else
 371                 AC_MSG_RESULT([no])
 372         fi
 373         ],[
 374                 AC_MSG_RESULT([no])
 375         ]
 376 )
 377
 378 dnl Check for CNID database backends
 379 bdb_required=no
 380 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 381
 382 dnl Check for Berkeley DB library
 383 if test "x$bdb_required" = "xyes"; then
 384         AC_PATH_BDB(, [
 385                 AC_MSG_RESULT([])
 386                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 387                 AC_MSG_RESULT([You can download the latest version from http://www.sleepycat.com.])
 388                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 389                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option and make sure])
 390                 AC_MSG_RESULT([your linker is configured to check for libraries there.])
 391                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 392         ])
 393 fi
 394
 395 dnl Check for quota support
 396 AC_CHECK_QUOTA
 397
 398 dnl Check for optional server location protocol support (used by MacOS X)
 399 NETATALK_SRVLOC
 400
 401 dnl Check for PAM libs
 402 netatalk_cv_use_pam=no
 403 AC_PATH_PAM([
 404         use_pam_so=yes
 405         compile_pam=yes
 406         netatalk_cv_use_pam=yes
 407         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 408 ])
 409
 410 netatalk_cv_use_shadowpw=no
 411 AC_ARG_WITH(shadow,
 412         [  --with-shadow           enable shadow password support [[auto]]],
 413         [netatalk_cv_use_shadowpw="$withval"],
 414         [netatalk_cv_use_shadowpw=auto]
 415 )
 416
 417 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 418     AC_CHECK_HEADER([shadow.h])
 419     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 420         netatalk_cv_use_shadowpw=yes
 421         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 422     else
 423       if test "x$shadowpw" = "xyes"; then
 424         AC_MSG_ERROR([shadow support not available])
 425       else
 426         netatalk_cv_use_shadowpw=no
 427       fi
 428     fi
 429 fi
 430
 431 AC_MSG_CHECKING([whether shadow support should be enabled])
 432 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 433         AC_MSG_RESULT([yes])
 434 else
 435         AC_MSG_RESULT([no])
 436 fi
 437
 438
 439
 440 netatalk_cv_use_shellcheck=yes
 441 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 442 AC_ARG_ENABLE(shell-check,
 443         [  --disable-shell-check   disable checking for a valid shell],[
 444         if test "$enableval" = "no"; then
 445                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 446                 AC_MSG_RESULT([no])
 447                 netatalk_cv_use_shellcheck=no
 448         else
 449                 AC_MSG_RESULT([yes])
 450         fi
 451         ],[
 452                 AC_MSG_RESULT([yes])
 453         ]
 454 )
 455
 456 NETATALK_TCP_WRAPPERS
 457
 458 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 459 AC_ARG_ENABLE(locking,
 460         [  --disable-locking       disable system locking],[
 461                 if test "$enableval" = "no"; then
 462                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 463                         AC_MSG_RESULT([yes])
 464                 else
 465                         AC_MSG_RESULT([no])
 466                 fi
 467
 468         ],[
 469                 AC_MSG_RESULT([no])
 470         ]
 471
 472 )
 473
 474
 475 AC_ARG_ENABLE(redhat,
 476         [  --enable-redhat         use redhat-style sysv configuration ],[
 477         if test "$enableval" = "yes"; then
 478                 sysv_style=redhat
 479         fi
 480         AC_MSG_RESULT([enabling redhat-style sysv support])
 481         ]
 482 )
 483
 484 AC_ARG_ENABLE(suse,
 485         [  --enable-suse           use suse-style sysv configuration ],[
 486         if test "$enableval" = "yes"; then
 487                 sysv_style=suse
 488         fi
 489         AC_MSG_RESULT([enabling suse-style sysv support])
 490         ]
 491 )
 492
 493 AC_ARG_ENABLE(gentoo,
 494         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 495         if test "$enableval" = "yes"; then
 496                 sysv_style=gentoo
 497         fi
 498         AC_MSG_RESULT([enabling gentoo-style sysv support])
 499         ]
 500 )
 501
 502 AC_ARG_ENABLE(cobalt,
 503         [  --enable-cobalt         use cobalt-style sysv configuration ],
 504         if test "$enableval" = "yes"; then
 505                 sysv_style=cobalt
 506         fi
 507         AC_MSG_RESULT([enabling cobalt-style sysv support])
 508 )
 509
 510 AC_ARG_ENABLE(netbsd,
 511         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 512         if test "x$enableval" = "xyes"; then
 513                 sysv_style=netbsd
 514         fi
 515         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 516 )
 517
 518 AC_ARG_ENABLE(debian,
 519         [  --enable-debian         use debian-style sysv configuration ],[
 520         if test "$enableval" = "yes"; then
 521                 sysv_style=debian
 522         fi
 523         AC_MSG_RESULT([enabling debian-style sysv support])
 524         ]
 525 )
 526
 527 dnl ----- timelord compilation (disabled by default)
 528 AC_MSG_CHECKING([whether timelord should be compiled])
 529 compile_timelord=no
 530 AC_ARG_ENABLE(timelord,
 531         [  --enable-timelord       enable compilation of timelord server],
 532         [compile_timelord="$enableval"],
 533         [compile_timelord="no"]
 534 )
 535 AC_MSG_RESULT([$compile_timelord])
 536
 537 dnl ----- a2boot compilation (disabled by default)
 538 AC_MSG_CHECKING([whether a2boot should be compiled])
 539 compile_a2boot=no
 540 AC_ARG_ENABLE(a2boot,
 541         [  --enable-a2boot         enable compilation of Apple2 boot server],
 542         [compile_a2boot="$enableval"],
 543         [compile_a2boot="no"]
 544 )
 545 AC_MSG_RESULT([$compile_a2boot])
 546
 547 AC_ARG_WITH(uams-path,
 548         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 549                 uams_path="$withval"
 550         ],[
 551                 uams_path="${PKGCONFDIR}/uams"
 552         ]
 553 )
 554
 555 NETATALK_AC_CUPS
 556
 557 dnl check if we can use attribute unused (gcc only) from ethereal
 558 AC_MSG_CHECKING(to see if we can add '__attribute__((unused))' to CFLAGS)
 559 if test x$GCC != x ; then
 560   CFLAGS="-D_U_=\"__attribute__((unused))\" $CFLAGS"
 561   AC_MSG_RESULT(yes)
 562 else
 563   CFLAGS="-D_U_=\"\" $CFLAGS"
 564   AC_MSG_RESULT(no)
 565 fi
 566
 567 dnl --------------------------------------------------------------------------
 568 dnl FHS stuff has to be done last because it overrides other defaults
 569 dnl --------------------------------------------------------------------------
 570
 571 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 572 AC_ARG_ENABLE(fhs,
 573         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 574         if test "$enableval" = "yes"; then
 575                 uams_path="${libdir}/netatalk"
 576                 sysconfdir="/etc"
 577                 PKGCONFDIR=${sysconfdir}/netatalk
 578                 SERVERTEXT="${PKGCONFDIR}/msg"
 579                 use_pam_so=yes
 580                 mandir="/usr/share/man"
 581                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 582                 AC_MSG_RESULT([yes])
 583         else
 584                 AC_MSG_RESULT([no])
 585         fi
 586         ],[
 587                 AC_MSG_RESULT([no])
 588         ]
 589 )
 590
 591 dnl --------------------------------------------------------------------------
 592 dnl post-FHS substitutions, etc
 593 dnl --------------------------------------------------------------------------
 594
 595 dnl ***** UAMS_PATH
 596 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 597 dnl     [path to UAMs [default=PKGCONF/uams]])
 598 UAMS_PATH="${uams_path}"
 599 AC_SUBST(UAMS_PATH)
 600
 601 dnl --------------------------------------------------------------------------
 602 dnl drop in includes for top level directory structures here...
 603 dnl --------------------------------------------------------------------------
 604
 605 dnl Note: $(top_srcdir)/include should be added before all other includes
 606 dnl       so that includes from that directory a preferred to includes from
 607 dnl       /usr/include or similar places.
 608 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 609 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 610
 611 dnl --------------------------------------------------------------------------
 612 dnl specific configuration comes in here:
 613 dnl --------------------------------------------------------------------------
 614
 615 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 616
 617 dnl --------------------- determine operating system from "target"
 618 case "$host_os" in
 619         *aix*)                          this_os=aix ;;
 620         *freebsd*)                      this_os=freebsd ;;
 621         *hpux11*)                       this_os=hpux11 ;;
 622         *irix*)                         this_os=irix ;;
 623         *linux*)                        this_os=linux ;;
 624         *osx*)                          this_os=macosx ;;
 625         *darwin*)                       this_os=macosx ;;
 626         *netbsd*)                       this_os=netbsd ;;
 627         *openbsd*)                      this_os=openbsd ;;
 628         *osf*)                          this_os=tru64 ;;
 629         *solaris*)                      this_os=solaris ;;
 630 esac
 631
 632 case "$host_cpu" in
 633         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 634         alpha)                                          this_cpu=alpha ;;
 635         mips)                                           this_cpu=mips ;;
 636         powerpc|ppc)                            this_cpu=ppc ;;
 637 esac
 638
 639 dnl --------------------- operating system specific flags (port from sys/*)
 640
 641 dnl ----- AIX specific -----
 642 if test x"$this_os" = "xaix"; then
 643         AC_MSG_RESULT([ * AIX specific configuration])
 644         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 645
 646         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 647         dnl compilation environment.  It's enough to get things defined
 648         dnl right in endian.h provided that long long is supported, though.
 649         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 650 fi
 651
 652 dnl ----- FreeBSD specific -----
 653 if test x"$this_os" = "xfreebsd"; then
 654         AC_MSG_RESULT([ * FreeBSD specific configuration])
 655         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 656         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 657         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 658 fi
 659
 660 dnl ----- HP-UX 11 specific -----
 661 if test x"$this_os" = "xhpux11"; then
 662         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 663
 664         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 665         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 666 fi
 667
 668 dnl ----- IRIX specific -----
 669 if test x"$this_os" = "xirix"; then
 670         AC_MSG_RESULT([ * IRIX specific configuration])
 671
 672         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 673 fi
 674
 675 dnl ----- Linux specific -----
 676 if test x"$this_os" = "xlinux"; then
 677         AC_MSG_RESULT([ * Linux specific configuration])
 678
 679         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 680         AC_MSG_CHECKING([for struct atalk_addr])
 681 dnl     AC_COMPILE_IFELSE([
 682         AC_TRY_COMPILE([
 683 #include <sys/socket.h>
 684 #include <asm/types.h>
 685 #include <linux/atalk.h>
 686
 687         struct atalk_addr foo;
 688 ],
 689 [ ], [
 690                 ac_have_atalk_addr=yes
 691                 AC_MSG_RESULT([yes])
 692         ], [
 693                 AC_MSG_RESULT([no])
 694         ])
 695
 696 if test "x$ac_have_atalk_addr" = "xyes"; then
 697         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 698 fi
 699
 700         dnl ----- check if we need the quotactl wrapper
 701 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 702 #       AC_CHECK_FUNC(quotactl,,
 703 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 704 #               AC_MSG_RESULT([enabling quotactl wrapper])
 705 #       )
 706
 707         # For quotas on Linux XFS filesystems
 708         AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 709         AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)
 710         # For linux > 2.5.56
 711         AC_CHECK_HEADERS(linux/dqblk_xfs.h)
 712
 713
 714         dnl ----- as far as I can tell, dbtob always does the wrong thing
 715         dnl ----- on every single version of linux I've ever played with.
 716         dnl ----- see etc/afpd/quota.c
 717         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 718
 719         netatalk_cv_linux_sendfile=no
 720 dnl     disable this for now, code doesn't use sendfile anyway
 721 dnl        AC_ARG_ENABLE(sendfile,
 722 dnl         [  --enable-sendfile       use sendfile syscall default (no) ],[
 723 dnl             if test "$enableval" = "yes"; then
 724 dnl                     netatalk_cv_linux_sendfile=yes
 725 dnl             fi
 726 dnl             AC_MSG_RESULT([enabling sendfile syscall])
 727 dnl         ]
 728 dnl       )
 729
 730         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 731             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 732             AC_TRY_LINK([#include <sys/sendfile.h>],
 733 [\
 734 int tofd, fromfd;
 735 off_t offset;
 736 size_t total;
 737 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 738 ],
 739 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 740
 741 # Try and cope with broken Linux sendfile....
 742             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 743             AC_TRY_LINK([\
 744 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 745 #undef _FILE_OFFSET_BITS
 746 #endif
 747 #include <sys/sendfile.h>],
 748 [\
 749 int tofd, fromfd;
 750 off_t offset;
 751 size_t total;
 752 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 753 ],
 754 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 755
 756             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 757                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 758                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 759                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 760             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 761                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 762                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 763                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 764             else
 765                 netatalk_cv_linux_sendfile=no
 766                 AC_MSG_RESULT(no);
 767             fi
 768         fi
 769
 770         dnl ----- Linux/alpha specific -----
 771         if test x"$this_cpu" = "xalpha"; then
 772                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 773                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 774         fi
 775         need_dash_r=no
 776
 777
 778 fi
 779
 780 dnl ----- Mac OSX specific -----
 781 if test x"$this_os" = "xmacosx"; then
 782         AC_MSG_RESULT([ * Mac OSX specific configuration])
 783         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 784         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 785         dnl AC_DEFINE(NO_DLFCN_H)
 786         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 787         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 788         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 789 fi
 790
 791 dnl ----- NetBSD specific -----
 792 if test x"$this_os" = "xnetbsd"; then
 793         AC_MSG_RESULT([ * NetBSD specific configuration])
 794         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 795         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 796         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 797         need_dash_r=yes
 798
 799         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 800         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 801 fi
 802
 803 dnl ----- OpenBSD specific -----
 804 if test x"$this_os" = "xopenbsd"; then
 805         AC_MSG_RESULT([ * OpenBSD specific configuration])
 806         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 807         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 808 fi
 809
 810 dnl ----- Solaris specific -----
 811 if test x"$this_os" = "xsolaris"; then
 812         AC_MSG_RESULT([ * Solaris specific configuration])
 813         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 814         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 815         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 816         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 817         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 818         need_dash_r=yes
 819         sysv_style=solaris
 820
 821         solaris_module=no
 822         AC_MSG_CHECKING([if we can build Solaris kernel module])
 823         if test -x /usr/ccs/bin/ld; then
 824                 solaris_module=yes
 825         fi
 826         AC_MSG_RESULT([$solaris_module])
 827
 828         COMPILE_64BIT_KMODULE=no
 829         KCFLAGS=""
 830         KLDFLAGS=""
 831         COMPILE_KERNEL_GCC=no
 832
 833         if test "$solaris_module" = "yes"; then
 834            dnl Solaris kernel module stuff
 835            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 836
 837            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 838            if test -x /usr/bin/isainfo; then
 839                 # check for 64 bit platform
 840                 if isainfo -kv | grep '^64-bit'; then
 841                         COMPILE_64BIT_KMODULE=yes
 842                 fi
 843            fi
 844
 845            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 846
 847            if test "${GCC}" = yes; then
 848                 COMPILE_KERNEL_GCC=yes
 849                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 850
 851                         AC_MSG_CHECKING([if we can build a 64bit kernel module])
 852
 853                         case `$CC --version 2>/dev/null` in
 854                         [[12]].* | 3.0.*)
 855                                 COMPILE_64BIT_KMODULE=no
 856                                 COMPILE_KERNEL_GCC=no
 857                                 solaris_module=no;;
 858                         *)
 859                                 # use for 64 bit
 860                                 KCFLAGS="-m64"
 861                                 #KLDFLAGS="-melf64_sparc"
 862                                 KLDFLAGS="-64";;
 863                         esac
 864
 865                         AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 866
 867                 else
 868                         KCFLAGS=""
 869                         KLDFLAGS=""
 870                 fi
 871                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 872            else
 873                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 874                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 875                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 876                         KLDFLAGS="-64"
 877                 else
 878                         KCFLAGS=""
 879                         KLDFLAGS=""
 880                 fi
 881                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 882            fi
 883
 884            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 885            AC_TRY_LINK([\
 886 #include <sys/stream.h>
 887 #include <sys/ddi.h>],
 888 [\
 889 timeout_id_t dummy;
 890 ],
 891 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 892
 893            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 894         fi
 895
 896         AC_SUBST(COMPILE_KERNEL_GCC)
 897         AC_SUBST(COMPILE_64BIT_KMODULE)
 898         AC_SUBST(KCFLAGS)
 899         AC_SUBST(KLDFLAGS)
 900 fi
 901
 902 dnl ----- Tru64 specific -----
 903 if test x"$this_os" = "xtru64"; then
 904         AC_MSG_RESULT([ * Tru64 specific configuration])
 905         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 906         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 907         dnl AC_DEFINE(USE_MOUNT_H)
 908         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 909         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 910         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 911         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 912         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 913         AC_CHECK_LIB(security,set_auth_parameters)
 914         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 915         need_dash_r=no
 916         sysv_style=tru64
 917 fi
 918
 919 dnl -- look for openssl
 920 AC_PATH_SSL
 921
 922 dnl -- check for crypt
 923 AC_CRYPT
 924
 925 dnl --------------------- check for building PGP UAM module
 926
 927 AC_MSG_CHECKING([whether the PGP UAM should be build])
 928 AC_ARG_ENABLE(pgp-uam,
 929         [  --enable-pgp-uam        enable build of PGP UAM module],[
 930         if test "$enableval" = "yes"; then
 931                 if test "$compile_ssl" = "yes"; then
 932                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 933                         compile_pgp=yes
 934                         AC_MSG_RESULT([yes])
 935                 else
 936                         AC_MSG_RESULT([no])
 937                 fi
 938         fi
 939         ],[
 940                 AC_MSG_RESULT([no])
 941         ]
 942 )
 943
 944 dnl --------------------- check for building Kerberos v4 UAM module
 945
 946 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 947 AC_ARG_ENABLE(krb4-uam,
 948         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 949         if test "$enableval" = "yes"; then
 950                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 951                 compile_kerberos=yes
 952                 AC_MSG_RESULT([yes])
 953         else
 954                 AC_MSG_RESULT([no])
 955         fi
 956         ],[
 957                 AC_MSG_RESULT([no])
 958         ]
 959 )
 960
 961 dnl --------------------- check for building Kerberos V UAM module
 962
 963 netatalk_cv_build_krb5_uam=no
 964 AC_ARG_ENABLE(krbV-uam,
 965         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 966         [
 967                 if test x"$enableval" = x"yes"; then
 968                         NETATALK_GSSAPI_CHECK([
 969                                 netatalk_cv_build_krb5_uam=yes
 970                         ],[
 971                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 972                         ])
 973                 fi
 974         ]
 975
 976 )
 977
 978 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 979 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 980         AC_MSG_RESULT([yes])
 981 else
 982         AC_MSG_RESULT([no])
 983 fi
 984 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 985
 986 dnl --------------------- overwrite the config files . . . or not.
 987
 988 AC_MSG_CHECKING([whether configuration files should be overwritten])
 989 AC_ARG_ENABLE(overwrite,
 990         [  --enable-overwrite      overwrite configuration files during installation],
 991         [OVERWRITE_CONFIG="${enable_overwrite}"],
 992         [OVERWRITE_CONFIG="no"]
 993 )
 994 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 995
 996 dnl --------------------- last minute substitutions
 997
 998 AC_SUBST(LIBS)
 999 AC_SUBST(CFLAGS)
1000 AC_SUBST(OVERWRITE_CONFIG)
1001
1002 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
1003 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
1004 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
1005 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
1006 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
1007 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
1008 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
1009 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
1010 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
1011 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
1012 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
1013 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
1014 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
1015 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
1016 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
1017 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
1018 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
1019 AM_CONDITIONAL(USE_DEBIAN, test x$sysv_style = xdebian)
1020 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
1021
1022 dnl --------------------- generate files
1023
1024 AC_OUTPUT([Makefile
1025         bin/Makefile
1026         bin/adv1tov2/Makefile
1027         bin/aecho/Makefile
1028         bin/afile/Makefile
1029         bin/afppasswd/Makefile
1030         bin/cnid/Makefile
1031         bin/cnid/cnid_maint
1032         bin/cnid/cnid2_create
1033         bin/getzones/Makefile
1034         bin/megatron/Makefile
1035         bin/nbp/Makefile
1036         bin/pap/Makefile
1037         bin/psorder/Makefile
1038         bin/uniconv/Makefile
1039         config/Makefile
1040         contrib/Makefile
1041         contrib/macusers/Makefile
1042         contrib/macusers/macusers
1043         contrib/nu/Makefile
1044         contrib/nu/nu
1045         contrib/printing/Makefile
1046         contrib/shell_utils/Makefile
1047         contrib/shell_utils/afpd-mtab.pl
1048         contrib/shell_utils/apple_cp
1049         contrib/shell_utils/apple_mv
1050         contrib/shell_utils/apple_rm
1051         contrib/shell_utils/asip-status.pl
1052         contrib/shell_utils/cleanappledouble.pl
1053         contrib/timelord/Makefile
1054         contrib/a2boot/Makefile
1055         distrib/Makefile
1056         distrib/config/Makefile
1057         distrib/config/netatalk-config
1058         distrib/initscripts/Makefile
1059         distrib/m4/Makefile
1060         doc/Makefile
1061         etc/Makefile
1062         etc/afpd/Makefile
1063         etc/atalkd/Makefile
1064         etc/cnid_dbd/Makefile
1065         etc/uams/Makefile
1066         etc/uams/uams_krb4/Makefile
1067         etc/papd/Makefile
1068         etc/psf/Makefile
1069         include/Makefile
1070         include/atalk/Makefile
1071         libatalk/Makefile
1072         libatalk/adouble/Makefile
1073         libatalk/asp/Makefile
1074         libatalk/atp/Makefile
1075         libatalk/cnid/Makefile
1076         libatalk/cnid/db3/Makefile
1077         libatalk/cnid/cdb/Makefile
1078         libatalk/cnid/last/Makefile
1079         libatalk/cnid/mtab/Makefile
1080         libatalk/cnid/dbd/Makefile
1081         libatalk/cnid/hash/Makefile
1082         libatalk/cnid/tdb/Makefile
1083         libatalk/compat/Makefile
1084         libatalk/dsi/Makefile
1085         libatalk/nbp/Makefile
1086         libatalk/netddp/Makefile
1087         libatalk/util/Makefile
1088         libatalk/tdb/Makefile
1089         libatalk/unicode/Makefile
1090         libatalk/unicode/charsets/Makefile
1091         macros/Makefile
1092         man/Makefile
1093         man/man1/Makefile
1094         man/man3/Makefile
1095         man/man4/Makefile
1096         man/man5/Makefile
1097         man/man8/Makefile
1098         sys/Makefile
1099         sys/generic/Makefile
1100         sys/generic/sys/Makefile
1101         sys/netatalk/Makefile
1102         sys/netbsd/Makefile
1103         sys/netbsd/netatalk/Makefile
1104         sys/solaris/Makefile
1105         sys/sunos/Makefile
1106         sys/ultrix/Makefile
1107         ],
1108         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1109 )
1110
1111 AC_NETATALK_LIBS_SUMMARY
1112 AC_NETATALK_CONFIG_SUMMARY
1113