configure.in

   1 #
   2 # ngIRCd -- The Next Generation IRC Daemon
   3 # Copyright (c)2001-2003 by Alexander Barton (alex@barton.de)
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 # Please read the file COPYING, README and AUTHORS for more information.
  10 #
  11 # $Id: configure.in,v 1.69.2.6 2003/03/09 22:33:19 alex Exp $
  12 #
  13
  14 # -- Initialisierung --
  15
  16 AC_INIT
  17 AC_PREREQ(2.50)
  18 AC_CANONICAL_TARGET
  19 AC_CONFIG_SRCDIR(src/config.h.in)
  20 AM_INIT_AUTOMAKE(ngircd,0.6.x-CVS)
  21 AM_CONFIG_HEADER(src/config.h)
  22
  23 # -- Templates fuer config.h --
  24
  25 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
  26 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
  27 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
  28 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
  29 AH_TEMPLATE([USE_SYSLOG], [Define if syslog should be used for logging])
  30 AH_TEMPLATE([USE_ZLIB], [Define if zlib compression should be enabled])
  31 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
  32
  33 AH_TEMPLATE([TARGET_OS], [Target operating system name])
  34 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
  35 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
  36
  37 # -- C Compiler --
  38
  39 AC_PROG_CC
  40
  41 # -- Hilfsprogramme --
  42
  43 AC_PROG_AWK
  44 AC_PROG_INSTALL
  45 AC_PROG_LN_S
  46 AC_PROG_MAKE_SET
  47 AC_PROG_RANLIB
  48
  49 # -- Compiler Features --
  50
  51 AC_LANG_C
  52
  53 AM_C_PROTOTYPES
  54 AC_C_CONST
  55
  56 # -- Defines --
  57
  58 if test `uname` = "A/UX"; then
  59         # unter A/UX sollte _POSIX_SOURCE definiert sein.
  60         AC_MSG_RESULT([detected A/UX, defining _POSIX_SOURCE])
  61         CFLAGS="$CFLAGS -D_POSIX_SOURCE"
  62 fi
  63
  64 if test `uname` = "HP-UX"; then
  65         # unter HP-UX 11.11 muss _XOPEN_SOURCE_EXTENDED definiert sein.
  66         AC_MSG_RESULT([detected HP-UX, defining _XOPEN_SOURCE_EXTENDED])
  67         CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
  68 fi
  69
  70 # -- Header --
  71
  72 AC_HEADER_STDC
  73
  74 AC_HEADER_TIME
  75
  76 AC_HEADER_SYS_WAIT
  77
  78 AC_CHECK_HEADERS([ \
  79         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
  80         strings.h sys/socket.h sys/time.h unistd.h \
  81         ],,AC_MSG_ERROR([required C header missing!]))
  82
  83 AC_CHECK_HEADERS(arpa/inet.h ctype.h malloc.h stdint.h sys/select.h varargs.h)
  84
  85 # -- Datentypen --
  86
  87 AC_MSG_CHECKING(whether socklen_t exists)
  88 AC_TRY_COMPILE([
  89         #include <sys/socket.h>
  90         #include <sys/types.h>
  91         ],[
  92         socklen_t a, b;
  93         a = 2; b = 4; a += b;
  94         ],[
  95         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
  96         ],[
  97         AC_MSG_RESULT(no)
  98 ])
  99
 100 AC_TYPE_SIGNAL
 101
 102 AC_TYPE_SIZE_T
 103
 104 # -- Libraries --
 105
 106 AC_CHECK_LIB(UTIL,memmove)
 107 AC_CHECK_LIB(socket,bind)
 108 AC_CHECK_LIB(nsl,gethostent)
 109
 110 # -- Funktionen --
 111
 112 AC_FUNC_MALLOC
 113
 114 AC_FUNC_FORK
 115
 116 AC_FUNC_STRFTIME
 117
 118 AC_CHECK_FUNCS([ \
 119         bind gethostbyaddr gethostbyname gethostname inet_ntoa memmove \
 120         memset select setsockopt socket strcasecmp strchr strerror \
 121         strstr waitpid \
 122         ],,AC_MSG_ERROR([required function missing!]))
 123
 124 AC_CHECK_FUNCS(inet_aton isdigit sigaction snprintf vsnprintf)
 125
 126 # -- Konfigurationsoptionen --
 127
 128 x_syslog_on=no
 129 AC_ARG_ENABLE(syslog,
 130         [  --disable-syslog        disable syslog (autodetected by default)],
 131         [       if test "$enableval" = "yes"; then
 132                         AC_CHECK_HEADER(syslog.h, x_syslog_on=yes,
 133                                 AC_MSG_ERROR([Can't enable syslog: syslog.h not found!])
 134                         )
 135                 fi
 136         ],
 137         [       AC_CHECK_HEADER(syslog.h, x_syslog_on=yes) ]
 138 )
 139 if test "$x_syslog_on" = "yes"; then
 140         AC_DEFINE(USE_SYSLOG, 1)
 141         AC_CHECK_LIB(be,syslog)
 142 fi
 143
 144 x_zlib_on=no
 145 AC_ARG_ENABLE(zlib,
 146         [  --disable-zlib          disable zlib compression (autodetected by default)],
 147         [       if test "$enableval" = "yes"; then
 148                         AC_CHECK_HEADER(zlib.h, x_zlib_on=yes,
 149                                 AC_MSG_ERROR([Can't enable zlib: zlib.h not found!])
 150                         )
 151                 fi
 152         ],
 153         [       AC_CHECK_HEADER(zlib.h, x_zlib_on=yes) ]
 154 )
 155 if test "$x_zlib_on" = "yes"; then
 156         AC_DEFINE(USE_ZLIB, 1)
 157         AC_CHECK_LIB(z,deflate)
 158 fi
 159
 160 x_ircplus_on=yes
 161 AC_ARG_ENABLE(ircplus,
 162         [  --disable-ircplus       disable IRC+ protocol],
 163         if test "$enableval" = "no"; then x_ircplus_on=no; fi
 164 )
 165 if test "$x_ircplus_on" = "yes"; then
 166         AC_DEFINE(IRCPLUS, 1)
 167 fi
 168
 169 AC_ARG_ENABLE(sniffer,
 170         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
 171         if test "$enableval" = "yes"; then
 172                 AC_DEFINE(SNIFFER, 1)
 173                 x_sniffer_on=yes; x_debug_on=yes
 174         fi
 175 )
 176
 177 AC_ARG_ENABLE(debug,
 178         [  --enable-debug          show additional debug output],
 179         if test "$enableval" = "yes"; then x_debug_on=yes; fi
 180 )
 181 if test "$x_debug_on" = "yes"; then
 182         AC_DEFINE(DEBUG, 1)
 183 fi
 184
 185 AC_ARG_ENABLE(strict-rfc,
 186         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
 187         if test "$enableval" = "yes"; then
 188                 AC_DEFINE(STRICT_RFC, 1)
 189                 x_strict_rfc_on=yes
 190         fi
 191 )
 192
 193
 194 # -- Definitionen --
 195
 196 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
 197 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
 198 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
 199
 200 # -- Variablen --
 201
 202 if test "$GCC" = "yes"; then
 203         CFLAGS="-Wall $CFLAGS"
 204 fi
 205
 206 the_CFLAGS="$CFLAGS"
 207
 208 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
 209
 210 # -- Ausgabe der Dateien --
 211
 212 AC_OUTPUT([ \
 213         Makefile \
 214         doc/Makefile \
 215         doc/en/Makefile \
 216         MacOSX/Makefile \
 217         MacOSX/ngircd.pbproj/Makefile \
 218         src/Makefile \
 219         src/portab/Makefile \
 220         src/ngircd/Makefile \
 221         src/testsuite/Makefile \
 222         man/Makefile \
 223         contrib/Makefile \
 224 ])
 225
 226 # -- Ergebnis --
 227
 228 echo
 229
 230 # Someone please show me a better way :)  [borrowed by OpenSSH]
 231 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
 232 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
 233 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
 234 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
 235
 236 echo "                host: ${host}"
 237 echo "            compiler: ${CC}"
 238 echo "      compiler flags: ${the_CFLAGS}"
 239 echo "  preprocessor flags: ${CPPFLAGS}"
 240 echo "        linker flags: ${LDFLAGS}"
 241 echo "           libraries: ${LIBS}"
 242 echo
 243 echo "     'ngircd' binary: $S"
 244 echo "  configuration file: $C"
 245 echo "        manual pages: $M"
 246 echo
 247
 248 echo $ECHO_N "      active options: $ECHO_C"
 249 test "$x_syslog_on" = "yes"     && echo $ECHO_N "Syslog $ECHO_C"
 250 test "$x_zlib_on" = "yes"       && echo $ECHO_N "zLib $ECHO_C"
 251 test "$x_debug_on" = "yes"      && echo $ECHO_N "Debug $ECHO_C"
 252 test "$x_sniffer_on" = "yes"    && echo $ECHO_N "Sniffer $ECHO_C"
 253 test "$x_strict_rfc_on" = "yes" && echo $ECHO_N "Strict-RFC $ECHO_C"
 254 test "$x_ircplus_on" = "yes"    && echo $ECHO_N "IRC+ $ECHO_C"
 255 echo; echo
 256
 257 # -eof-