ax.zsh

   1 # AX-ZSH: Alex' Modular ZSH Configuration
   2 # Copyright (c) 2015-2017 Alexander Barton <alex@barton.de>
   3
   4 script_name="${${(%):-%N}:t}"
   5 script_type="$script_name[2,-1]"
   6
   7 # Load plugin code of a given type.
   8 # - $1: plugin name
   9 # - $2: plugin type (optional; defaults to "zshrc")
  10 # - $3: cache file (optional)
  11 function axzsh_load_plugin {
  12         local dname="$1:A"
  13         local plugin="$dname:t"
  14         [[ -z "$2" ]] && local type="zshrc" || local type="$2"
  15         local fname="$dname/$plugin.$type"
  16         local cache_file="$3"
  17
  18         # Strip repository prefix (like "alexbarton#test-plugin"):
  19         [[ "$plugin" =~ "#" ]] && plugin=$(echo $plugin | cut -d'#' -f2-)
  20
  21         # "short plugin name": strip ".zsh" suffix:
  22         plugin_short=${plugin%.zsh}
  23
  24         if [[ ! -d "$dname" ]]; then
  25                 # Plugin not found!
  26                 if [[ -n "$AXZSH_DEBUG" ]]; then
  27                         # Show error message for all stages in "debug mode":
  28                         echo "AX-ZSH plugin \"$plugin\" not found (type \"$type\")!" >&2
  29                 elif [[ "$type" == "zshrc" ]]; then
  30                         # Show error message for the "zshrc" stage:
  31                         echo "AX-ZSH plugin \"$plugin\" not found, skipped!" >&2
  32                 fi
  33                 return 1
  34         fi
  35
  36         if [[ ! -r "$fname" && "$type" == "zshrc" ]]; then
  37                 if [[ -r "$dname/$plugin.zprofile" || -r "$dname/$plugin.zlogout" ]]; then
  38                         # Native AX-ZSH plugin, but for different stage. Skip it!
  39                         :
  40                 elif [[ -r "$dname/${plugin_short}.plugin.zsh" ]]; then
  41                         # Oh My ZSH plugin
  42                         type="plugin.zsh"
  43                         fname="$dname/${plugin_short}.plugin.zsh"
  44                 elif [[ -r "$dname/${plugin_short##zsh-}.plugin.zsh" ]]; then
  45                         # Oh My ZSH plugin with "zsh-" prefix stripped
  46                         type="plugin.zsh"
  47                         fname="$dname/${plugin_short##zsh-}.plugin.zsh"
  48                 elif [[ -r "$dname/init.zsh" ]]; then
  49                         # Prezto module
  50                         type="init.zsh"
  51                         fname="$dname/init.zsh"
  52                 else
  53                         echo "AX-ZSH plugin type of \"$plugin\" unknown, skipped!" >&2
  54                         return 0
  55                 fi
  56         fi
  57
  58         if [[ "$type" == "zprofile" && -d "$dname/functions" ]]; then
  59                 # Add plugin function path when folder exists
  60                 [[ -n "$AXZSH_DEBUG" ]] \
  61                         && echo "   - $plugin ($type): functions ..."
  62                 axzsh_fpath+=("$dname/functions")
  63
  64                 # Add function path to cache file.
  65                 [[ -n "$cache_file" ]] \
  66                         && echo "axzsh_fpath+=('$dname/functions')" >>$cache_file
  67         fi
  68
  69         if [[ -r "$fname" ]]; then
  70                 # Read plugin ...
  71                 [[ -n "$AXZSH_DEBUG" ]] \
  72                         && echo "   - $plugin ($type) ..."
  73
  74                 # Note for "external" ("repo/*") plugins and "dumb" terminals:
  75                 # These (modern?) plugins most probably don't expect such an
  76                 # unusual old terminal configuration and don't behave well
  77                 # (echo color sequences, for example). Therefore we DON'T load
  78                 # any external plugins at all when running on such a terminal:
  79                 # this results in reduced/disabled functionality, but hopefully
  80                 # in readable output ...
  81
  82                 case "$fname" in
  83                         *"/repos/"*)
  84                                 axzsh_is_dumb_terminal || source "$fname"
  85                                 ;;
  86                         *)
  87                                 source "$fname"
  88                 esac
  89
  90                 if [[ -n "$cache_file" ]]; then
  91                         # Add plugin data to cache
  92                         printf "# BEGIN: %s\nax_plugin_init()\n{\n" "$fname" >>"$cache_file"
  93                         case "$fname" in
  94                                 *"/repos/"*)
  95                                         echo "[[ -n \"\$AXZSH_DEBUG\" ]] && echo '     - $plugin ($type): \"$fname\" ...'" >>$cache_file
  96                                         echo "axzsh_is_dumb_terminal || source '$fname'" >>$cache_file
  97                                         ;;
  98                                 *)
  99                                         echo "[[ -n \"\$AXZSH_DEBUG\" ]] && echo '     - $plugin ($type, cached) ...'" >>$cache_file
 100                                         "$cat_cmd" "$fname" >>"$cache_file"
 101                         esac
 102                         printf "}\nax_plugin_init\n# END: %s\n\n" "$fname" >>"$cache_file"
 103                 fi
 104         fi
 105
 106         # It is a success, even if only the plugin directory (and no script!)
 107         # exists at all! Rationale: The script could be of an other type ...
 108         return 0
 109 }
 110
 111 # Make sure that "my" (=ZSH) directory is in the search path ...
 112 if [[ -z "$AXZSH" ]]; then
 113         _p="${0:h}"
 114         [[ "$_p" != "." ]] && PATH="$PATH:${0:h}"
 115         unset _p
 116 fi
 117
 118 # Make sure that "SHELL" variable is set and exported
 119 [[ -n "$SHELL" ]] || export SHELL=$(command -v zsh)
 120
 121 # Make sure that "AXZSH" variable is set and exported
 122 if [[ -z "$AXZSH" ]]; then
 123         export AXZSH="$HOME/.axzsh"
 124         if [[ -f "$HOME/.axzsh.debug" ]]; then
 125                 export AXZSH_DEBUG=1
 126                 echo "AXZSH=$AXZSH"
 127                 echo "AXZSH_DEBUG=$AXZSH_DEBUG"
 128                 echo "AXZSH_PLUGIN_D=$AXZSH_PLUGIN_D"
 129         fi
 130 fi
 131
 132 [[ -n "$AXZSH_DEBUG" ]] && echo "» $script_name:"
 133
 134 # Initialize cache
 135 mkdir -p "$AXZSH/cache"
 136 cache_file="$AXZSH/cache/$script_type.cache"
 137
 138 cat_cmd=${commands[cat]:-cat}
 139
 140 if [[ -r "$cache_file" ]]; then
 141         # Cache file exists, use it!
 142         # But when in the "zshrc" stage, make sure that the "zprofile" stage
 143         # has already been handled (this uses the "01_zprofile" plugin which
 144         # is used in the "zshrc.cache" as well, but can't be used successfully
 145         # there because it becomes sourced inside of a ZSH function; so we have
 146         # to source it here in the global context manually ...):
 147         [[ -z "$AXZSH_ZPROFILE_READ" && "$script_type" = "zshrc" ]] \
 148                 && source "$AXZSH/core/01_zprofile/01_zprofile.zshrc"
 149         [[ -n "$AXZSH_DEBUG" ]] \
 150                 && echo "   - Reading cache file \"$cache_file\" ..."
 151         source "$cache_file"
 152         unfunction ax_plugin_init
 153 else
 154         # No cache file available.
 155         # Setup list of plugins to load:
 156         typeset -U plugin_list
 157         plugin_list=(
 158                 "$AXZSH/core/"[0-5]*
 159                 "$AXZSH/active_plugins/"*(N)
 160                 "$AXZSH/core/"[6-9]*
 161         )
 162
 163         # Create new cache file:
 164         if [[ -n "$cache_file" ]]; then
 165                 [[ -n "$AXZSH_DEBUG" ]] \
 166                         && echo "   (Writing new cache file to \"$cache_file\" ...)"
 167                 printf "# %s\n\n" "$(LC_ALL=C date)" >"$cache_file"
 168         fi
 169
 170         # Read in all the plugins for the current "type":
 171         for plugin ($plugin_list); do
 172                 axzsh_load_plugin "$plugin" "$script_type" "$cache_file"
 173         done
 174 fi
 175
 176 # Clean up ...
 177 unfunction axzsh_load_plugin
 178 unset script_name script_type plugin
 179 unset plugin_list
 180 unset cache_file
 181 unset cat_cmd