configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.29 2004-06-09 01:25:52 bfernhomberg Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58 dnl Replace `main' with a function in -lnsl:
  59 AC_CHECK_LIB(nsl, main)
  60 dnl Replace `main' with a function in -lprot:
  61 dnl AC_CHECK_LIB(prot, main)
  62 dnl Replace `main' with a function in -lrx:
  63 dnl AC_CHECK_LIB(rx, main)
  64 dnl Replace `main' with a function in -lrxkad:
  65 dnl AC_CHECK_LIB(rxkad, main)
  66 dnl Replace `main' with a function in -lsocket:
  67 AC_CHECK_LIB(socket, socket)
  68 dnl Replace `main' with a function in -lsys:
  69 dnl AC_CHECK_LIB(sys, main)
  70 dnl Replace `main' with a function in -lubik:
  71 dnl AC_CHECK_LIB(ubik, main)
  72
  73
  74 #
  75 # Check presence of some functions
  76 #
  77 # Check for XPG4 access() function
  78 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  79 # has such a function that works only on AFS filesystems.
  80 AC_CHECK_FUNCS(access)
  81 #
  82 AC_CHECK_FUNCS(pread pwrite)
  83
  84 dnl Checks for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_STDC
  87 AC_HEADER_SYS_WAIT
  88 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  89 AC_CHECK_HEADER(sys/cdefs.h,,
  90         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  91         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  92 )
  93 AC_CHECK_HEADERS([sys/mount.h], , ,
  94 [#ifdef HAVE_SYS_PARAM_H
  95 #include <sys/param.h>
  96 #endif
  97 ])
  98
  99 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 100
 101 dnl Checks for typedefs, structures, and compiler characteristics.
 102 AC_C_CONST
 103 AC_TYPE_UID_T
 104 AC_C_INLINE
 105 AC_TYPE_MODE_T
 106 AC_TYPE_OFF_T
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_STRUCT_ST_RDEV
 110 AC_HEADER_TIME
 111 AC_STRUCT_TM
 112
 113 dnl --------------------------------------------------------------------------
 114 dnl check if dlsym needs to add an underscore, uses libtool macros
 115 dnl --------------------------------------------------------------------------
 116 AC_LTDL_DLLIB
 117 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 118 AC_LTDL_DLSYM_USCORE
 119 if test x"$libltdl_cv_need_uscore" = xyes; then
 120     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 121 fi
 122
 123
 124 dnl Checks for library functions.
 125 AC_TYPE_GETGROUPS
 126 AC_PROG_GCC_TRADITIONAL
 127 AC_FUNC_MEMCMP
 128 AC_HEADER_MAJOR
 129 AC_FUNC_MMAP
 130 AC_TYPE_SIGNAL
 131 AC_FUNC_UTIME_NULL
 132 AC_FUNC_WAIT3
 133 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul setpgrp strchr memcpy)
 134 AC_FUNC_SETPGRP
 135 AC_CHECK_FUNCS(backtrace_symbols)
 136 AC_CHECK_FUNCS(setlocale nl_langinfo)
 137 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 138 AC_CHECK_FUNCS(strlcpy strlcat)
 139 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 140 AC_CACHE_SAVE
 141
 142 dnl Checks for (v)snprintf
 143 NETATALK_SNPRINTF_CHECK
 144
 145 dnl --------------------------------------------------------------------------
 146 dnl 64bit platform check
 147 dnl --------------------------------------------------------------------------
 148
 149 AC_MSG_CHECKING([whether to check for 64bit libraries])
 150 dnl Determine libdir name
 151 case $host in
 152 *-*-linux*)
 153   # Test if the compiler is 64bit
 154   echo 'int i;' > conftest.$ac_ext
 155   atalk_cv_cc_64bit_output=no
 156   if AC_TRY_EVAL(ac_compile); then
 157     case `/usr/bin/file conftest.$ac_objext` in
 158     *"ELF 64"*)
 159       atalk_cv_cc_64bit_output=yes
 160       ;;
 161     esac
 162   fi
 163   rm -rf conftest*
 164   ;;
 165 esac
 166
 167 dnl
 168 dnl FIXME: Do we need something like this for Solaris 64bit?
 169 dnl
 170
 171 case $host_cpu:$atalk_cv_cc_64bit_output in
 172 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 173   atalk_libname="lib64"
 174   AC_MSG_RESULT([yes])
 175   ;;
 176 *:*)
 177   atalk_libname="lib"
 178   AC_MSG_RESULT([no])
 179   ;;
 180 esac
 181
 182 dnl --------------------------------------------------------------------------
 183 dnl specific configuration comes in here:
 184 dnl --------------------------------------------------------------------------
 185
 186 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 187
 188 netatalk_cv_admin_group=yes
 189 AC_MSG_CHECKING([for administrative group support])
 190 AC_ARG_WITH(admin-group,
 191         [  --disable-admin-group   disable admin group],[
 192         if test "$enableval" = "no"; then
 193                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 194                 AC_MSG_RESULT([yes])
 195         else
 196                 AC_MSG_RESULT([no])
 197                 netatalk_cv_admin_group=no
 198         fi],[
 199                 AC_MSG_RESULT([yes])
 200         ]
 201 )
 202
 203 NETATALK_AFS_CHECK
 204
 205 NETATALK_CONFIG_DIRS
 206
 207 AC_MSG_CHECKING([for logfile path])
 208 AC_ARG_WITH(logfile,
 209         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 210                           use --without-logfile to disable logger],[
 211         if test x"$withval" = x"no"; then
 212                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 213                 AC_MSG_RESULT([syslog])
 214         elif test "$withval" != "yes"; then
 215                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 216                 AC_MSG_RESULT([$withval])
 217         else
 218                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 219                 AC_MSG_RESULT([/var/log/netatalk.log])
 220         fi],[
 221                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 222                 AC_MSG_RESULT([/var/log/netatalk.log])
 223         ]
 224 )
 225
 226
 227 netatalk_cv_with_cracklib=no
 228 AC_MSG_CHECKING([for cracklib support])
 229 AC_ARG_WITH(cracklib,
 230         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 231         if test "x$withval" != "xno" ; then
 232                 cracklib="$withval"
 233                 AC_CHECK_LIB(crack, main, [
 234                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 235                         LIBS="$LIBS -lcrack"
 236                         AC_MSG_RESULT([yes])
 237                         if test "$cracklib" = "yes"; then
 238                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 239                         fi
 240                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 241                                 [path to cracklib dictionary])
 242                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 243                         netatalk_cv_with_cracklib=yes
 244                         ],[
 245                         AC_MSG_ERROR([cracklib not found!])
 246                         ]
 247                 )
 248         else
 249                 AC_MSG_RESULT([no])
 250         fi
 251         ],[
 252                 AC_MSG_RESULT([no])
 253         ]
 254 )
 255
 256 netatalk_cv_ddp_enabled=yes
 257 AC_MSG_CHECKING([whether to enable DDP])
 258 AC_ARG_ENABLE(ddp,
 259         [  --disable-ddp           disable DDP],[
 260         if test "$enableval" = "no"; then
 261                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 262                 AC_MSG_RESULT([no])
 263                 netatalk_cv_ddp_enabled=no
 264         else
 265                 AC_MSG_RESULT([yes])
 266         fi
 267         ],[
 268                 AC_MSG_RESULT([yes])
 269         ]
 270 )
 271
 272 AC_MSG_CHECKING([whether to enable debug code])
 273 AC_ARG_ENABLE(debug1,
 274         [  --enable-debug1         enable debug code],[
 275         if test "$enableval" != "no"; then
 276                 if test "$enableval" = "yes"; then
 277                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 278                 else
 279                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 280                 fi
 281                 AC_MSG_RESULT([yes])
 282         else
 283                 AC_MSG_RESULT([no])
 284         fi
 285         ],[
 286                 AC_MSG_RESULT([no])
 287         ]
 288 )
 289
 290 AC_MSG_CHECKING([whether to enable verbose debug code])
 291 AC_ARG_ENABLE(debug,
 292         [  --enable-debug          enable verbose debug code],[
 293         if test "$enableval" != "no"; then
 294                 if test "$enableval" = "yes"; then
 295                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 296                 else
 297                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 298                 fi
 299                 AC_MSG_RESULT([yes])
 300         else
 301                 AC_MSG_RESULT([no])
 302         fi
 303         ],[
 304                 AC_MSG_RESULT([no])
 305         ]
 306 )
 307
 308 afp3=no
 309 afp3set=no
 310 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 311 AC_ARG_ENABLE(afp3,
 312         [  --disable-afp3          disable AFP 3.x calls],
 313         [
 314             if test x"$enableval" != x"no"; then
 315                 afp3set=yes
 316                 afp3=yes
 317                 AC_MSG_RESULT([yes])
 318             else
 319                 AC_MSG_RESULT([no])
 320             fi
 321         ],[
 322             AC_MSG_RESULT([yes])
 323             afp3=yes
 324         ]
 325 )
 326
 327 if test x"$afp3" = x"yes"; then
 328         AC_SYS_LARGEFILE([
 329                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 330         ],[
 331                 if test x"$afp3set" = x"yes"; then
 332                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 333                 else
 334                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 335                         afp3=no
 336                 fi
 337         ])
 338 fi
 339
 340 AC_CHECK_ICONV
 341
 342 dnl ----------- A NOTE ABOUT DROPKLUDGE
 343 dnl The trouble with this fix is that if you know what the file is called, it
 344 dnl can be read from the Unix side.  That's okay for most academic institutions
 345 dnl since the students don't have telnet access to the Mac servers.  There is
 346 dnl currently no one working on further development/fixes of DROPKLUDGE.
 347 dnl -----------
 348
 349 netatalk_cv_dropkludge=no
 350 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 351 AC_ARG_ENABLE(dropkludge,
 352         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 353         if test "$enableval" = "yes"; then
 354                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 355                 AC_MSG_RESULT([yes])
 356                 netatalk_cv_dropkludge=yes
 357         else
 358                 AC_MSG_RESULT([no])
 359         fi
 360         ],[
 361                 AC_MSG_RESULT([no])
 362         ]
 363 )
 364
 365 netatalk_cv_force_uidgid=no
 366 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 367 AC_ARG_ENABLE(force-uidgid,
 368         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 369         if test "$enableval" = "yes"; then
 370                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 371                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 372                 AC_MSG_RESULT([yes])
 373                 netatalk_cv_force_uidgid=yes
 374         else
 375                 AC_MSG_RESULT([no])
 376         fi
 377         ],[
 378                 AC_MSG_RESULT([no])
 379         ]
 380 )
 381
 382 dnl Check for CNID database backends
 383 bdb_required=no
 384 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 385
 386 dnl Check for Berkeley DB library
 387 if test "x$bdb_required" = "xyes"; then
 388         AC_PATH_BDB(, [
 389                 AC_MSG_RESULT([])
 390                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 391                 AC_MSG_RESULT([You can download the latest version from http://www.sleepcat.com.])
 392                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 393                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option.])
 394                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 395         ])
 396 fi
 397
 398 dnl Check for quota support
 399 AC_CHECK_QUOTA
 400
 401 dnl Check for optional server location protocol support (used by MacOS X)
 402 NETATALK_SRVLOC
 403
 404 dnl Check for PAM libs
 405 netatalk_cv_use_pam=no
 406 AC_PATH_PAM([
 407         use_pam_so=yes
 408         compile_pam=yes
 409         netatalk_cv_use_pam=yes
 410         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 411 ])
 412
 413 netatalk_cv_use_shadowpw=no
 414 AC_ARG_WITH(shadow,
 415         [  --with-shadow           enable shadow password support [[auto]]],
 416         [netatalk_cv_use_shadowpw="$withval"],
 417         [netatalk_cv_use_shadowpw=auto]
 418 )
 419
 420 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 421     AC_CHECK_HEADER([shadow.h])
 422     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 423         netatalk_cv_use_shadowpw=yes
 424         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 425     else
 426       if test "x$shadowpw" = "xyes"; then
 427         AC_MSG_ERROR([shadow support not available])
 428       else
 429         netatalk_cv_use_shadowpw=no
 430       fi
 431     fi
 432 fi
 433
 434 AC_MSG_CHECKING([whether shadow support should be enabled])
 435 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 436         AC_MSG_RESULT([yes])
 437 else
 438         AC_MSG_RESULT([no])
 439 fi
 440
 441
 442
 443 netatalk_cv_use_shellcheck=yes
 444 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 445 AC_ARG_ENABLE(shell-check,
 446         [  --disable-shell-check   disable checking for a valid shell],[
 447         if test "$enableval" = "no"; then
 448                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 449                 AC_MSG_RESULT([no])
 450                 netatalk_cv_use_shellcheck=no
 451         else
 452                 AC_MSG_RESULT([yes])
 453         fi
 454         ],[
 455                 AC_MSG_RESULT([yes])
 456         ]
 457 )
 458
 459 NETATALK_TCP_WRAPPERS
 460
 461 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 462 AC_ARG_ENABLE(locking,
 463         [  --disable-locking       disable system locking],[
 464                 if test "$enableval" = "no"; then
 465                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 466                         AC_MSG_RESULT([yes])
 467                 else
 468                         AC_MSG_RESULT([no])
 469                 fi
 470
 471         ],[
 472                 AC_MSG_RESULT([no])
 473         ]
 474
 475 )
 476
 477
 478 AC_ARG_ENABLE(redhat,
 479         [  --enable-redhat         use redhat-style sysv configuration ],[
 480         if test "$enableval" = "yes"; then
 481                 sysv_style=redhat
 482         fi
 483         AC_MSG_RESULT([enabling redhat-style sysv support])
 484         ]
 485 )
 486
 487 AC_ARG_ENABLE(suse,
 488         [  --enable-suse           use suse-style sysv configuration ],[
 489         if test "$enableval" = "yes"; then
 490                 sysv_style=suse
 491         fi
 492         AC_MSG_RESULT([enabling suse-style sysv support])
 493         ]
 494 )
 495
 496 AC_ARG_ENABLE(gentoo,
 497         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 498         if test "$enableval" = "yes"; then
 499                 sysv_style=gentoo
 500         fi
 501         AC_MSG_RESULT([enabling gentoo-style sysv support])
 502         ]
 503 )
 504
 505 AC_ARG_ENABLE(cobalt,
 506         [  --enable-cobalt         use cobalt-style sysv configuration ],
 507         if test "$enableval" = "yes"; then
 508                 sysv_style=cobalt
 509         fi
 510         AC_MSG_RESULT([enabling cobalt-style sysv support])
 511 )
 512
 513 AC_ARG_ENABLE(netbsd,
 514         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 515         if test "x$enableval" = "xyes"; then
 516                 sysv_style=netbsd
 517         fi
 518         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 519 )
 520
 521 dnl ----- timelord compilation (disabled by default)
 522 AC_MSG_CHECKING([whether timelord should be compiled])
 523 compile_timelord=no
 524 AC_ARG_ENABLE(timelord,
 525         [  --enable-timelord       enable compilation of timelord server],
 526         [compile_timelord="$enableval"],
 527         [compile_timelord="no"]
 528 )
 529 AC_MSG_RESULT([$compile_timelord])
 530
 531 dnl ----- a2boot compilation (disabled by default)
 532 AC_MSG_CHECKING([whether a2boot should be compiled])
 533 compile_a2boot=no
 534 AC_ARG_ENABLE(a2boot,
 535         [  --enable-a2boot         enable compilation of Apple2 boot server],
 536         [compile_a2boot="$enableval"],
 537         [compile_a2boot="no"]
 538 )
 539 AC_MSG_RESULT([$compile_a2boot])
 540
 541 AC_ARG_WITH(uams-path,
 542         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 543                 uams_path="$withval"
 544         ],[
 545                 uams_path="${PKGCONFDIR}/uams"
 546         ]
 547 )
 548
 549 NETATALK_AC_CUPS
 550
 551 dnl --------------------------------------------------------------------------
 552 dnl FHS stuff has to be done last because it overrides other defaults
 553 dnl --------------------------------------------------------------------------
 554
 555 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 556 AC_ARG_ENABLE(fhs,
 557         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 558         if test "$enableval" = "yes"; then
 559                 uams_path="${libdir}/netatalk"
 560                 sysconfdir="/etc"
 561                 PKGCONFDIR=${sysconfdir}/netatalk
 562                 SERVERTEXT="${PKGCONFDIR}/msg"
 563                 use_pam_so=yes
 564                 mandir="/usr/share/man"
 565                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 566                 AC_MSG_RESULT([yes])
 567         else
 568                 AC_MSG_RESULT([no])
 569         fi
 570         ],[
 571                 AC_MSG_RESULT([no])
 572         ]
 573 )
 574
 575 dnl --------------------------------------------------------------------------
 576 dnl post-FHS substitutions, etc
 577 dnl --------------------------------------------------------------------------
 578
 579 dnl ***** UAMS_PATH
 580 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 581 dnl     [path to UAMs [default=PKGCONF/uams]])
 582 UAMS_PATH="${uams_path}"
 583 AC_SUBST(UAMS_PATH)
 584
 585 dnl --------------------------------------------------------------------------
 586 dnl drop in includes for top level directory structures here...
 587 dnl --------------------------------------------------------------------------
 588
 589 dnl Note: $(top_srcdir)/include should be added before all other includes
 590 dnl       so that includes from that directory a preferred to includes from
 591 dnl       /usr/include or similar places.
 592 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 593 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 594
 595 dnl --------------------------------------------------------------------------
 596 dnl specific configuration comes in here:
 597 dnl --------------------------------------------------------------------------
 598
 599 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 600
 601 dnl --------------------- determine operating system from "target"
 602 case "$host_os" in
 603         *aix*)                          this_os=aix ;;
 604         *freebsd*)                      this_os=freebsd ;;
 605         *hpux11*)                       this_os=hpux11 ;;
 606         *irix*)                         this_os=irix ;;
 607         *linux*)                        this_os=linux ;;
 608         *osx*)                          this_os=macosx ;;
 609         *darwin*)                       this_os=macosx ;;
 610         *netbsd*)                       this_os=netbsd ;;
 611         *openbsd*)                      this_os=openbsd ;;
 612         *osf*)                          this_os=tru64 ;;
 613         *solaris*)                      this_os=solaris ;;
 614 esac
 615
 616 case "$host_cpu" in
 617         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 618         alpha)                                          this_cpu=alpha ;;
 619         mips)                                           this_cpu=mips ;;
 620         powerpc|ppc)                            this_cpu=ppc ;;
 621 esac
 622
 623 dnl --------------------- operating system specific flags (port from sys/*)
 624
 625 dnl ----- AIX specific -----
 626 if test x"$this_os" = "xaix"; then
 627         AC_MSG_RESULT([ * AIX specific configuration])
 628         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 629
 630         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 631         dnl compilation environment.  It's enough to get things defined
 632         dnl right in endian.h provided that long long is supported, though.
 633         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 634 fi
 635
 636 dnl ----- FreeBSD specific -----
 637 if test x"$this_os" = "xfreebsd"; then
 638         AC_MSG_RESULT([ * FreeBSD specific configuration])
 639         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 640         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 641         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 642 fi
 643
 644 dnl ----- HP-UX 11 specific -----
 645 if test x"$this_os" = "xhpux11"; then
 646         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 647
 648         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 649         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 650 fi
 651
 652 dnl ----- IRIX specific -----
 653 if test x"$this_os" = "xirix"; then
 654         AC_MSG_RESULT([ * IRIX specific configuration])
 655
 656         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 657 fi
 658
 659 dnl ----- Linux specific -----
 660 if test x"$this_os" = "xlinux"; then
 661         AC_MSG_RESULT([ * Linux specific configuration])
 662
 663         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 664         AC_MSG_CHECKING([for struct atalk_addr])
 665 dnl     AC_COMPILE_IFELSE([
 666         AC_TRY_COMPILE([
 667 #include <sys/socket.h>
 668 #include <asm/types.h>
 669 #include <linux/atalk.h>
 670 ],
 671 [
 672 int main() {
 673         struct atalk_addr foo;
 674
 675         return 0;
 676 }
 677         ], [
 678                 ac_have_atalk_addr=yes
 679                 AC_MSG_RESULT([yes])
 680         ], [
 681                 AC_MSG_RESULT([no])
 682         ])
 683
 684 if test "x$ac_have_atalk_addr" = "xyes"; then
 685         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 686 fi
 687
 688         dnl ----- check if we need the quotactl wrapper
 689 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 690 #       AC_CHECK_FUNC(quotactl,,
 691 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 692 #               AC_MSG_RESULT([enabling quotactl wrapper])
 693 #       )
 694
 695         # For quotas on Linux XFS filesystems
 696         AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 697         AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)
 698         # For linux > 2.5.56
 699         AC_CHECK_HEADERS(linux/dqblk_xfs.h)
 700
 701
 702         dnl ----- as far as I can tell, dbtob always does the wrong thing
 703         dnl ----- on every single version of linux I've ever played with.
 704         dnl ----- see etc/afpd/quota.c
 705         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 706
 707         netatalk_cv_linux_sendfile=no
 708         AC_ARG_ENABLE(sendfile,
 709             [  --enable-sendfile       use sendfile syscall default (no) ],[
 710                 if test "$enableval" = "yes"; then
 711                         netatalk_cv_linux_sendfile=yes
 712                 fi
 713                 AC_MSG_RESULT([enabling sendfile syscall])
 714             ]
 715         )
 716
 717         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 718             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 719             AC_TRY_LINK([#include <sys/sendfile.h>],
 720 [\
 721 int tofd, fromfd;
 722 off_t offset;
 723 size_t total;
 724 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 725 ],
 726 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 727
 728 # Try and cope with broken Linux sendfile....
 729             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 730             AC_TRY_LINK([\
 731 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 732 #undef _FILE_OFFSET_BITS
 733 #endif
 734 #include <sys/sendfile.h>],
 735 [\
 736 int tofd, fromfd;
 737 off_t offset;
 738 size_t total;
 739 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 740 ],
 741 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 742
 743             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 744                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 745                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 746                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 747             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 748                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 749                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 750                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 751             else
 752                 netatalk_cv_linux_sendfile=no
 753                 AC_MSG_RESULT(no);
 754             fi
 755         fi
 756
 757         dnl ----- Linux/alpha specific -----
 758         if test x"$this_cpu" = "xalpha"; then
 759                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 760                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 761         fi
 762         need_dash_r=no
 763
 764
 765 fi
 766
 767 dnl ----- Mac OSX specific -----
 768 if test x"$this_os" = "xmacosx"; then
 769         AC_MSG_RESULT([ * Mac OSX specific configuration])
 770         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 771         AC_DEFINE(HAVE_BROKEN_CPP, 1, [Define if cpp is broken])
 772         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 773         dnl AC_DEFINE(NO_DLFCN_H)
 774         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 775         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 776         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 777 fi
 778
 779 dnl ----- NetBSD specific -----
 780 if test x"$this_os" = "xnetbsd"; then
 781         AC_MSG_RESULT([ * NetBSD specific configuration])
 782         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 783         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 784         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 785         need_dash_r=yes
 786
 787         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 788         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 789 fi
 790
 791 dnl ----- OpenBSD specific -----
 792 if test x"$this_os" = "xopenbsd"; then
 793         AC_MSG_RESULT([ * OpenBSD specific configuration])
 794         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 795         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 796 fi
 797
 798 dnl ----- Solaris specific -----
 799 if test x"$this_os" = "xsolaris"; then
 800         AC_MSG_RESULT([ * Solaris specific configuration])
 801         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 802         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 803         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 804         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 805         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 806         need_dash_r=yes
 807         sysv_style=solaris
 808
 809         solaris_module=no
 810         AC_MSG_CHECKING([if we can build Solaris kernel module])
 811         if test -x /usr/ccs/bin/ld; then
 812                 solaris_module=yes
 813         fi
 814         AC_MSG_RESULT([$solaris_module])
 815
 816         COMPILE_64BIT_KMODULE=no
 817         KCFLAGS=""
 818         KLDFLAGS=""
 819         COMPILE_KERNEL_GCC=no
 820
 821         if test "$solaris_module" = "yes"; then
 822            dnl Solaris kernel module stuff
 823            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 824
 825            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 826            if test -x /usr/bin/isainfo; then
 827                 # check for 64 bit platform
 828                 if isainfo -kv | grep '^64-bit'; then
 829                         COMPILE_64BIT_KMODULE=yes
 830                 fi
 831            fi
 832
 833            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 834
 835
 836            if test "${GCC}" = yes; then
 837                 COMPILE_KERNEL_GCC=yes
 838                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 839                         # use for 64 bit
 840                         KCFLAGS="-m64"
 841                         #KLDFLAGS="-melf64_sparc"
 842                         KLDFLAGS="-64"
 843                 else
 844                         KCFLAGS=""
 845                         KLDFLAGS=""
 846                 fi
 847                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 848            else
 849                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 850                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 851                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 852                         KLDFLAGS="-64"
 853                 else
 854                         KCFLAGS=""
 855                         KLDFLAGS=""
 856                 fi
 857                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 858            fi
 859
 860            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 861            AC_TRY_LINK([\
 862 #include <sys/stream.h>
 863 #include <sys/ddi.h>],
 864 [\
 865 timeout_id_t dummy;
 866 ],
 867 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 868
 869            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 870         fi
 871
 872         AC_SUBST(COMPILE_KERNEL_GCC)
 873         AC_SUBST(COMPILE_64BIT_KMODULE)
 874         AC_SUBST(KCFLAGS)
 875         AC_SUBST(KLDFLAGS)
 876 fi
 877
 878 dnl ----- Tru64 specific -----
 879 if test x"$this_os" = "xtru64"; then
 880         AC_MSG_RESULT([ * Tru64 specific configuration])
 881         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 882         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 883         dnl AC_DEFINE(USE_MOUNT_H)
 884         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 885         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 886         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 887         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 888         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 889         AC_CHECK_LIB(security,set_auth_parameters)
 890         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 891         need_dash_r=no
 892         sysv_style=tru64
 893 fi
 894
 895 dnl -- look for openssl
 896 AC_PATH_SSL
 897
 898 dnl -- check for crypt
 899 AC_CRYPT
 900
 901 dnl --------------------- check for building PGP UAM module
 902
 903 AC_MSG_CHECKING([whether the PGP UAM should be build])
 904 AC_ARG_ENABLE(pgp-uam,
 905         [  --enable-pgp-uam        enable build of PGP UAM module],[
 906         if test "$enableval" = "yes"; then
 907                 if test "$compile_ssl" = "yes"; then
 908                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 909                         compile_pgp=yes
 910                         AC_MSG_RESULT([yes])
 911                 else
 912                         AC_MSG_RESULT([no])
 913                 fi
 914         fi
 915         ],[
 916                 AC_MSG_RESULT([no])
 917         ]
 918 )
 919
 920 dnl --------------------- check for building Kerberos v4 UAM module
 921
 922 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 923 AC_ARG_ENABLE(krb4-uam,
 924         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 925         if test "$enableval" = "yes"; then
 926                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 927                 compile_kerberos=yes
 928                 AC_MSG_RESULT([yes])
 929         else
 930                 AC_MSG_RESULT([no])
 931         fi
 932         ],[
 933                 AC_MSG_RESULT([no])
 934         ]
 935 )
 936
 937 dnl --------------------- check for building Kerberos V UAM module
 938
 939 netatalk_cv_build_krb5_uam=no
 940 AC_ARG_ENABLE(krbV-uam,
 941         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 942         [
 943                 if test x"$enableval" = x"yes"; then
 944                         NETATALK_GSSAPI_CHECK([
 945                                 netatalk_cv_build_krb5_uam=yes
 946                         ],[
 947                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 948                         ])
 949                 fi
 950         ]
 951
 952 )
 953
 954 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 955 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 956         AC_MSG_RESULT([yes])
 957 else
 958         AC_MSG_RESULT([no])
 959 fi
 960 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 961
 962 dnl --------------------- overwrite the config files . . . or not.
 963
 964 AC_MSG_CHECKING([whether configuration files should be overwritten])
 965 AC_ARG_ENABLE(overwrite,
 966         [  --enable-overwrite      overwrite configuration files during installation],
 967         [OVERWRITE_CONFIG="${enable_overwrite}"],
 968         [OVERWRITE_CONFIG="no"]
 969 )
 970 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 971
 972 dnl --------------------- last minute substitutions
 973
 974 AC_SUBST(LIBS)
 975 AC_SUBST(CFLAGS)
 976 AC_SUBST(OVERWRITE_CONFIG)
 977
 978 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 979 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 980 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
 981 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
 982 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
 983 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
 984 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
 985 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
 986 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
 987 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
 988 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
 989 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
 990 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
 991 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
 992 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
 993 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
 994 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
 995 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
 996
 997 dnl --------------------- generate files
 998
 999 AC_OUTPUT([Makefile
1000         bin/Makefile
1001         bin/adv1tov2/Makefile
1002         bin/aecho/Makefile
1003         bin/afile/Makefile
1004         bin/afppasswd/Makefile
1005         bin/cnid/Makefile
1006         bin/cnid/cnid_maint
1007         bin/cnid/cnid2_create
1008         bin/getzones/Makefile
1009         bin/megatron/Makefile
1010         bin/nbp/Makefile
1011         bin/pap/Makefile
1012         bin/psorder/Makefile
1013         bin/uniconv/Makefile
1014         config/Makefile
1015         contrib/Makefile
1016         contrib/macusers/Makefile
1017         contrib/macusers/macusers
1018         contrib/nu/Makefile
1019         contrib/nu/nu
1020         contrib/printing/Makefile
1021         contrib/shell_utils/Makefile
1022         contrib/shell_utils/afpd-mtab.pl
1023         contrib/shell_utils/apple_cp
1024         contrib/shell_utils/apple_mv
1025         contrib/shell_utils/apple_rm
1026         contrib/shell_utils/cleanappledouble.pl
1027         contrib/shell_utils/netatalkshorternamelinks.pl
1028         contrib/timelord/Makefile
1029         contrib/a2boot/Makefile
1030         distrib/Makefile
1031         distrib/config/Makefile
1032         distrib/config/netatalk-config
1033         distrib/initscripts/Makefile
1034         distrib/m4/Makefile
1035         doc/Makefile
1036         etc/Makefile
1037         etc/afpd/Makefile
1038         etc/atalkd/Makefile
1039         etc/cnid_dbd/Makefile
1040         etc/uams/Makefile
1041         etc/uams/uams_krb4/Makefile
1042         etc/papd/Makefile
1043         etc/psf/Makefile
1044         include/Makefile
1045         include/atalk/Makefile
1046         libatalk/Makefile
1047         libatalk/adouble/Makefile
1048         libatalk/asp/Makefile
1049         libatalk/atp/Makefile
1050         libatalk/cnid/Makefile
1051         libatalk/cnid/db3/Makefile
1052         libatalk/cnid/cdb/Makefile
1053         libatalk/cnid/last/Makefile
1054         libatalk/cnid/mtab/Makefile
1055         libatalk/cnid/dbd/Makefile
1056         libatalk/cnid/hash/Makefile
1057         libatalk/cnid/tdb/Makefile
1058         libatalk/compat/Makefile
1059         libatalk/dsi/Makefile
1060         libatalk/nbp/Makefile
1061         libatalk/netddp/Makefile
1062         libatalk/util/Makefile
1063         libatalk/tdb/Makefile
1064         libatalk/unicode/Makefile
1065         libatalk/unicode/charsets/Makefile
1066         macros/Makefile
1067         man/Makefile
1068         man/man1/Makefile
1069         man/man3/Makefile
1070         man/man4/Makefile
1071         man/man5/Makefile
1072         man/man8/Makefile
1073         sys/Makefile
1074         sys/generic/Makefile
1075         sys/generic/sys/Makefile
1076         sys/netatalk/Makefile
1077         sys/netbsd/Makefile
1078         sys/netbsd/netatalk/Makefile
1079         sys/solaris/Makefile
1080         sys/sunos/Makefile
1081         sys/ultrix/Makefile
1082         ],
1083         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1084 )
1085
1086 AC_NETATALK_LIBS_SUMMARY
1087 AC_NETATALK_CONFIG_SUMMARY
1088