configure.in

   1 dnl $Id: configure.in,v 1.179.2.3.2.37.2.1 2004-10-27 13:31:01 tkaiser Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18 AC_PROG_MAKE_SET
  19 AC_LIBTOOL_DLOPEN
  20 AC_PROG_LIBTOOL
  21 AC_PROG_PERL
  22 AC_PROG_GREP
  23 AC_PROG_PS
  24
  25 dnl *********************************************************************
  26 dnl FIXME! FIXME! These should be selectable properly, and should produce
  27 dnl the proper flags and defines...
  28 dnl *********************************************************************
  29
  30 ############################################
  31 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  32 #AC_SEARCH_LIBS(dlopen, [dl])
  33 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  34
  35 dnl Checks for libraries.
  36 dnl Replace `main' with a function in -labs:
  37 dnl AC_CHECK_LIB(abs, main)
  38 dnl Replace `main' with a function in -laudit:
  39 dnl AC_CHECK_LIB(audit, main)
  40 dnl Replace `main' with a function in -lauth:
  41 dnl AC_CHECK_LIB(auth, main)
  42 dnl Replace `main' with a function in -lcmd:
  43 dnl AC_CHECK_LIB(cmd, main)
  44 dnl Replace `main' with a function in -lcrypt:
  45 dnl AC_CHECK_LIB(crypt, main)
  46 dnl Replace `main' with a function in -ld:
  47 dnl AC_CHECK_LIB(d, main)
  48 dnl Replace `main' with a function in -ldl:
  49 AC_CHECK_LIB(dl, dlopen)
  50 dnl Replace `main' with a function in -lkauth:
  51 dnl AC_CHECK_LIB(kauth, main)
  52 dnl Replace `main' with a function in -lkrb:
  53 dnl AC_CHECK_LIB(krb, main)
  54 dnl Replace `main' with a function in -llwp:
  55 dnl AC_CHECK_LIB(lwp, main)
  56 dnl Replace `main' with a function in -ln:
  57 dnl AC_CHECK_LIB(n, main)
  58 dnl Replace `main' with a function in -lnsl:
  59 AC_CHECK_LIB(nsl, main)
  60 dnl Replace `main' with a function in -lprot:
  61 dnl AC_CHECK_LIB(prot, main)
  62 dnl Replace `main' with a function in -lrx:
  63 dnl AC_CHECK_LIB(rx, main)
  64 dnl Replace `main' with a function in -lrxkad:
  65 dnl AC_CHECK_LIB(rxkad, main)
  66 dnl Replace `main' with a function in -lsocket:
  67 AC_CHECK_LIB(socket, socket)
  68 dnl Replace `main' with a function in -lsys:
  69 dnl AC_CHECK_LIB(sys, main)
  70 dnl Replace `main' with a function in -lubik:
  71 dnl AC_CHECK_LIB(ubik, main)
  72
  73
  74 #
  75 # Check presence of some functions
  76 #
  77 # Check for XPG4 access() function
  78 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  79 # has such a function that works only on AFS filesystems.
  80 AC_CHECK_FUNCS(access)
  81 #
  82 AC_CHECK_FUNCS(pread pwrite)
  83
  84 dnl Checks for header files.
  85 AC_HEADER_DIRENT
  86 AC_HEADER_STDC
  87 AC_HEADER_SYS_WAIT
  88 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  89 AC_CHECK_HEADER(sys/cdefs.h,,
  90         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  91         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  92 )
  93 AC_CHECK_HEADERS([sys/mount.h], , ,
  94 [#ifdef HAVE_SYS_PARAM_H
  95 #include <sys/param.h>
  96 #endif
  97 ])
  98
  99 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 100
 101 dnl Checks for typedefs, structures, and compiler characteristics.
 102 AC_C_CONST
 103 AC_TYPE_UID_T
 104 AC_C_INLINE
 105 AC_TYPE_MODE_T
 106 AC_TYPE_OFF_T
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_STRUCT_ST_RDEV
 110 AC_HEADER_TIME
 111 AC_STRUCT_TM
 112
 113 dnl --------------------------------------------------------------------------
 114 dnl check if dlsym needs to add an underscore, uses libtool macros
 115 dnl --------------------------------------------------------------------------
 116 AC_LTDL_DLLIB
 117 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 118 AC_LTDL_DLSYM_USCORE
 119 if test x"$libltdl_cv_need_uscore" = xyes; then
 120     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 121 fi
 122
 123
 124 dnl Checks for library functions.
 125 AC_TYPE_GETGROUPS
 126 AC_PROG_GCC_TRADITIONAL
 127 AC_FUNC_MEMCMP
 128 AC_HEADER_MAJOR
 129 AC_FUNC_MMAP
 130 AC_TYPE_SIGNAL
 131 AC_FUNC_UTIME_NULL
 132 AC_FUNC_WAIT3
 133 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul strchr memcpy)
 134 AC_CHECK_FUNCS(backtrace_symbols)
 135 AC_CHECK_FUNCS(setlocale nl_langinfo)
 136 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 137 AC_CHECK_FUNCS(strlcpy strlcat)
 138 AC_CHECK_FUNCS(setlinebuf)
 139 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 140 AC_CACHE_SAVE
 141
 142 dnl Checks for (v)snprintf
 143 NETATALK_SNPRINTF_CHECK
 144
 145 dnl --------------------------------------------------------------------------
 146 dnl 64bit platform check
 147 dnl --------------------------------------------------------------------------
 148
 149 AC_MSG_CHECKING([whether to check for 64bit libraries])
 150 dnl Determine libdir name
 151 case $host in
 152 *-*-linux*)
 153   # Test if the compiler is 64bit
 154   echo 'int i;' > conftest.$ac_ext
 155   atalk_cv_cc_64bit_output=no
 156   if AC_TRY_EVAL(ac_compile); then
 157     case `/usr/bin/file conftest.$ac_objext` in
 158     *"ELF 64"*)
 159       atalk_cv_cc_64bit_output=yes
 160       ;;
 161     esac
 162   fi
 163   rm -rf conftest*
 164   ;;
 165 esac
 166
 167 dnl
 168 dnl FIXME: Do we need something like this for Solaris 64bit?
 169 dnl
 170
 171 case $host_cpu:$atalk_cv_cc_64bit_output in
 172 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 173   atalk_libname="lib64"
 174   AC_MSG_RESULT([yes])
 175   ;;
 176 *:*)
 177   atalk_libname="lib"
 178   AC_MSG_RESULT([no])
 179   ;;
 180 esac
 181
 182 dnl --------------------------------------------------------------------------
 183 dnl specific configuration comes in here:
 184 dnl --------------------------------------------------------------------------
 185
 186 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 187
 188 netatalk_cv_admin_group=yes
 189 AC_MSG_CHECKING([for administrative group support])
 190 AC_ARG_WITH(admin-group,
 191         [  --disable-admin-group   disable admin group],[
 192         if test "$enableval" = "no"; then
 193                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 194                 AC_MSG_RESULT([yes])
 195         else
 196                 AC_MSG_RESULT([no])
 197                 netatalk_cv_admin_group=no
 198         fi],[
 199                 AC_MSG_RESULT([yes])
 200         ]
 201 )
 202
 203 NETATALK_AFS_CHECK
 204
 205 NETATALK_CONFIG_DIRS
 206
 207 AC_MSG_CHECKING([for logfile path])
 208 AC_ARG_WITH(logfile,
 209         [  --with-logfile=PATH     path for file used by logger [/var/log/netatalk.log]
 210                           use --without-logfile to disable logger],[
 211         if test x"$withval" = x"no"; then
 212                 AC_DEFINE(DISABLE_LOGGER, 1, [Define if the logger should not be used])
 213                 AC_MSG_RESULT([syslog])
 214         elif test "$withval" != "yes"; then
 215                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "$withval", [Path to the log file])
 216                 AC_MSG_RESULT([$withval])
 217         else
 218                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 219                 AC_MSG_RESULT([/var/log/netatalk.log])
 220         fi],[
 221                 AC_DEFINE_UNQUOTED(LOGFILEPATH, "/var/log/netatalk.log", [Path to the log file])
 222                 AC_MSG_RESULT([/var/log/netatalk.log])
 223         ]
 224 )
 225
 226
 227 netatalk_cv_with_cracklib=no
 228 AC_ARG_WITH(cracklib,
 229         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 230         if test "x$withval" != "xno" ; then
 231                 cracklib="$withval"
 232                 AC_CHECK_LIB(crack, main, [
 233                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 234                         LIBS="$LIBS -lcrack"
 235                         if test "$cracklib" = "yes"; then
 236                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 237                         fi
 238                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 239                                 [path to cracklib dictionary])
 240                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 241                         netatalk_cv_with_cracklib=yes
 242                         ],[
 243                         AC_MSG_ERROR([cracklib not found!])
 244                         ]
 245                 )
 246         fi
 247         ]
 248 )
 249 AC_MSG_CHECKING([for cracklib support])
 250 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 251
 252 netatalk_cv_ddp_enabled=yes
 253 AC_MSG_CHECKING([whether to enable DDP])
 254 AC_ARG_ENABLE(ddp,
 255         [  --disable-ddp           disable DDP],[
 256         if test "$enableval" = "no"; then
 257                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 258                 AC_MSG_RESULT([no])
 259                 netatalk_cv_ddp_enabled=no
 260         else
 261                 AC_MSG_RESULT([yes])
 262         fi
 263         ],[
 264                 AC_MSG_RESULT([yes])
 265         ]
 266 )
 267
 268 AC_MSG_CHECKING([whether to enable debug code])
 269 AC_ARG_ENABLE(debug1,
 270         [  --enable-debug1         enable debug code],[
 271         if test "$enableval" != "no"; then
 272                 if test "$enableval" = "yes"; then
 273                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 274                 else
 275                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 276                 fi
 277                 AC_MSG_RESULT([yes])
 278         else
 279                 AC_MSG_RESULT([no])
 280         fi
 281         ],[
 282                 AC_MSG_RESULT([no])
 283         ]
 284 )
 285
 286 AC_MSG_CHECKING([whether to enable verbose debug code])
 287 AC_ARG_ENABLE(debug,
 288         [  --enable-debug          enable verbose debug code],[
 289         if test "$enableval" != "no"; then
 290                 if test "$enableval" = "yes"; then
 291                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 292                 else
 293                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 294                 fi
 295                 AC_MSG_RESULT([yes])
 296         else
 297                 AC_MSG_RESULT([no])
 298         fi
 299         ],[
 300                 AC_MSG_RESULT([no])
 301         ]
 302 )
 303
 304 afp3=no
 305 afp3set=no
 306 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 307 AC_ARG_ENABLE(afp3,
 308         [  --disable-afp3          disable AFP 3.x calls],
 309         [
 310             if test x"$enableval" != x"no"; then
 311                 afp3set=yes
 312                 afp3=yes
 313                 AC_MSG_RESULT([yes])
 314             else
 315                 AC_MSG_RESULT([no])
 316             fi
 317         ],[
 318             AC_MSG_RESULT([yes])
 319             afp3=yes
 320         ]
 321 )
 322
 323 if test x"$afp3" = x"yes"; then
 324         AC_SYS_LARGEFILE([
 325                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 326         ],[
 327                 if test x"$afp3set" = x"yes"; then
 328                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 329                 else
 330                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 331                         afp3=no
 332                 fi
 333         ])
 334 fi
 335
 336 AC_CHECK_ICONV
 337
 338 dnl ----------- A NOTE ABOUT DROPKLUDGE
 339 dnl The trouble with this fix is that if you know what the file is called, it
 340 dnl can be read from the Unix side.  That's okay for most academic institutions
 341 dnl since the students don't have telnet access to the Mac servers.  There is
 342 dnl currently no one working on further development/fixes of DROPKLUDGE.
 343 dnl -----------
 344
 345 netatalk_cv_dropkludge=no
 346 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 347 AC_ARG_ENABLE(dropkludge,
 348         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 349         if test "$enableval" = "yes"; then
 350                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 351                 AC_MSG_RESULT([yes])
 352                 netatalk_cv_dropkludge=yes
 353         else
 354                 AC_MSG_RESULT([no])
 355         fi
 356         ],[
 357                 AC_MSG_RESULT([no])
 358         ]
 359 )
 360
 361 netatalk_cv_force_uidgid=no
 362 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 363 AC_ARG_ENABLE(force-uidgid,
 364         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 365         if test "$enableval" = "yes"; then
 366                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 367                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 368                 AC_MSG_RESULT([yes])
 369                 netatalk_cv_force_uidgid=yes
 370         else
 371                 AC_MSG_RESULT([no])
 372         fi
 373         ],[
 374                 AC_MSG_RESULT([no])
 375         ]
 376 )
 377
 378 dnl Check for CNID database backends
 379 bdb_required=no
 380 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 381
 382 dnl Check for Berkeley DB library
 383 if test "x$bdb_required" = "xyes"; then
 384         AC_PATH_BDB(, [
 385                 AC_MSG_RESULT([])
 386                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 387                 AC_MSG_RESULT([You can download the latest version from http://www.sleepycat.com.])
 388                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 389                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option and make sure])
 390                 AC_MSG_RESULT([your linker is configured to check for libraries there.])
 391                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 392         ])
 393 fi
 394
 395 dnl Check for quota support
 396 AC_CHECK_QUOTA
 397
 398 dnl Check for optional server location protocol support (used by MacOS X)
 399 NETATALK_SRVLOC
 400
 401 dnl Check for PAM libs
 402 netatalk_cv_use_pam=no
 403 AC_PATH_PAM([
 404         use_pam_so=yes
 405         compile_pam=yes
 406         netatalk_cv_use_pam=yes
 407         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 408 ])
 409
 410 netatalk_cv_use_shadowpw=no
 411 AC_ARG_WITH(shadow,
 412         [  --with-shadow           enable shadow password support [[auto]]],
 413         [netatalk_cv_use_shadowpw="$withval"],
 414         [netatalk_cv_use_shadowpw=auto]
 415 )
 416
 417 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 418     AC_CHECK_HEADER([shadow.h])
 419     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 420         netatalk_cv_use_shadowpw=yes
 421         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 422     else
 423       if test "x$shadowpw" = "xyes"; then
 424         AC_MSG_ERROR([shadow support not available])
 425       else
 426         netatalk_cv_use_shadowpw=no
 427       fi
 428     fi
 429 fi
 430
 431 AC_MSG_CHECKING([whether shadow support should be enabled])
 432 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 433         AC_MSG_RESULT([yes])
 434 else
 435         AC_MSG_RESULT([no])
 436 fi
 437
 438
 439
 440 netatalk_cv_use_shellcheck=yes
 441 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 442 AC_ARG_ENABLE(shell-check,
 443         [  --disable-shell-check   disable checking for a valid shell],[
 444         if test "$enableval" = "no"; then
 445                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 446                 AC_MSG_RESULT([no])
 447                 netatalk_cv_use_shellcheck=no
 448         else
 449                 AC_MSG_RESULT([yes])
 450         fi
 451         ],[
 452                 AC_MSG_RESULT([yes])
 453         ]
 454 )
 455
 456 NETATALK_TCP_WRAPPERS
 457
 458 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 459 AC_ARG_ENABLE(locking,
 460         [  --disable-locking       disable system locking],[
 461                 if test "$enableval" = "no"; then
 462                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 463                         AC_MSG_RESULT([yes])
 464                 else
 465                         AC_MSG_RESULT([no])
 466                 fi
 467
 468         ],[
 469                 AC_MSG_RESULT([no])
 470         ]
 471
 472 )
 473
 474
 475 AC_ARG_ENABLE(redhat,
 476         [  --enable-redhat         use redhat-style sysv configuration ],[
 477         if test "$enableval" = "yes"; then
 478                 sysv_style=redhat
 479         fi
 480         AC_MSG_RESULT([enabling redhat-style sysv support])
 481         ]
 482 )
 483
 484 AC_ARG_ENABLE(suse,
 485         [  --enable-suse           use suse-style sysv configuration ],[
 486         if test "$enableval" = "yes"; then
 487                 sysv_style=suse
 488         fi
 489         AC_MSG_RESULT([enabling suse-style sysv support])
 490         ]
 491 )
 492
 493 AC_ARG_ENABLE(gentoo,
 494         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 495         if test "$enableval" = "yes"; then
 496                 sysv_style=gentoo
 497         fi
 498         AC_MSG_RESULT([enabling gentoo-style sysv support])
 499         ]
 500 )
 501
 502 AC_ARG_ENABLE(cobalt,
 503         [  --enable-cobalt         use cobalt-style sysv configuration ],
 504         if test "$enableval" = "yes"; then
 505                 sysv_style=cobalt
 506         fi
 507         AC_MSG_RESULT([enabling cobalt-style sysv support])
 508 )
 509
 510 AC_ARG_ENABLE(netbsd,
 511         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 512         if test "x$enableval" = "xyes"; then
 513                 sysv_style=netbsd
 514         fi
 515         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 516 )
 517
 518 AC_ARG_ENABLE(debian,
 519         [  --enable-debian         use debian-style sysv configuration ],[
 520         if test "$enableval" = "yes"; then
 521                 sysv_style=debian
 522         fi
 523         AC_MSG_RESULT([enabling debian-style sysv support])
 524         ]
 525 )
 526
 527 dnl ----- timelord compilation (disabled by default)
 528 AC_MSG_CHECKING([whether timelord should be compiled])
 529 compile_timelord=no
 530 AC_ARG_ENABLE(timelord,
 531         [  --enable-timelord       enable compilation of timelord server],
 532         [compile_timelord="$enableval"],
 533         [compile_timelord="no"]
 534 )
 535 AC_MSG_RESULT([$compile_timelord])
 536
 537 dnl ----- a2boot compilation (disabled by default)
 538 AC_MSG_CHECKING([whether a2boot should be compiled])
 539 compile_a2boot=no
 540 AC_ARG_ENABLE(a2boot,
 541         [  --enable-a2boot         enable compilation of Apple2 boot server],
 542         [compile_a2boot="$enableval"],
 543         [compile_a2boot="no"]
 544 )
 545 AC_MSG_RESULT([$compile_a2boot])
 546
 547 AC_ARG_WITH(uams-path,
 548         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 549                 uams_path="$withval"
 550         ],[
 551                 uams_path="${PKGCONFDIR}/uams"
 552         ]
 553 )
 554
 555 NETATALK_AC_CUPS
 556
 557 dnl --------------------------------------------------------------------------
 558 dnl FHS stuff has to be done last because it overrides other defaults
 559 dnl --------------------------------------------------------------------------
 560
 561 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 562 AC_ARG_ENABLE(fhs,
 563         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 564         if test "$enableval" = "yes"; then
 565                 uams_path="${libdir}/netatalk"
 566                 sysconfdir="/etc"
 567                 PKGCONFDIR=${sysconfdir}/netatalk
 568                 SERVERTEXT="${PKGCONFDIR}/msg"
 569                 use_pam_so=yes
 570                 mandir="/usr/share/man"
 571                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 572                 AC_MSG_RESULT([yes])
 573         else
 574                 AC_MSG_RESULT([no])
 575         fi
 576         ],[
 577                 AC_MSG_RESULT([no])
 578         ]
 579 )
 580
 581 dnl --------------------------------------------------------------------------
 582 dnl post-FHS substitutions, etc
 583 dnl --------------------------------------------------------------------------
 584
 585 dnl ***** UAMS_PATH
 586 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 587 dnl     [path to UAMs [default=PKGCONF/uams]])
 588 UAMS_PATH="${uams_path}"
 589 AC_SUBST(UAMS_PATH)
 590
 591 dnl --------------------------------------------------------------------------
 592 dnl drop in includes for top level directory structures here...
 593 dnl --------------------------------------------------------------------------
 594
 595 dnl Note: $(top_srcdir)/include should be added before all other includes
 596 dnl       so that includes from that directory a preferred to includes from
 597 dnl       /usr/include or similar places.
 598 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 599 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 600
 601 dnl --------------------------------------------------------------------------
 602 dnl specific configuration comes in here:
 603 dnl --------------------------------------------------------------------------
 604
 605 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 606
 607 dnl --------------------- determine operating system from "target"
 608 case "$host_os" in
 609         *aix*)                          this_os=aix ;;
 610         *freebsd*)                      this_os=freebsd ;;
 611         *hpux11*)                       this_os=hpux11 ;;
 612         *irix*)                         this_os=irix ;;
 613         *linux*)                        this_os=linux ;;
 614         *osx*)                          this_os=macosx ;;
 615         *darwin*)                       this_os=macosx ;;
 616         *netbsd*)                       this_os=netbsd ;;
 617         *openbsd*)                      this_os=openbsd ;;
 618         *osf*)                          this_os=tru64 ;;
 619         *solaris*)                      this_os=solaris ;;
 620 esac
 621
 622 case "$host_cpu" in
 623         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 624         alpha)                                          this_cpu=alpha ;;
 625         mips)                                           this_cpu=mips ;;
 626         powerpc|ppc)                            this_cpu=ppc ;;
 627 esac
 628
 629 dnl --------------------- operating system specific flags (port from sys/*)
 630
 631 dnl ----- AIX specific -----
 632 if test x"$this_os" = "xaix"; then
 633         AC_MSG_RESULT([ * AIX specific configuration])
 634         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 635
 636         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 637         dnl compilation environment.  It's enough to get things defined
 638         dnl right in endian.h provided that long long is supported, though.
 639         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 640 fi
 641
 642 dnl ----- FreeBSD specific -----
 643 if test x"$this_os" = "xfreebsd"; then
 644         AC_MSG_RESULT([ * FreeBSD specific configuration])
 645         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 646         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 647         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 648 fi
 649
 650 dnl ----- HP-UX 11 specific -----
 651 if test x"$this_os" = "xhpux11"; then
 652         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 653
 654         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 655         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 656 fi
 657
 658 dnl ----- IRIX specific -----
 659 if test x"$this_os" = "xirix"; then
 660         AC_MSG_RESULT([ * IRIX specific configuration])
 661
 662         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 663 fi
 664
 665 dnl ----- Linux specific -----
 666 if test x"$this_os" = "xlinux"; then
 667         AC_MSG_RESULT([ * Linux specific configuration])
 668
 669         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 670         AC_MSG_CHECKING([for struct atalk_addr])
 671 dnl     AC_COMPILE_IFELSE([
 672         AC_TRY_COMPILE([
 673 #include <sys/socket.h>
 674 #include <asm/types.h>
 675 #include <linux/atalk.h>
 676 ],
 677 [
 678 int main() {
 679         struct atalk_addr foo;
 680
 681         return 0;
 682 }
 683         ], [
 684                 ac_have_atalk_addr=yes
 685                 AC_MSG_RESULT([yes])
 686         ], [
 687                 AC_MSG_RESULT([no])
 688         ])
 689
 690 if test "x$ac_have_atalk_addr" = "xyes"; then
 691         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 692 fi
 693
 694         dnl ----- check if we need the quotactl wrapper
 695 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 696 #       AC_CHECK_FUNC(quotactl,,
 697 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 698 #               AC_MSG_RESULT([enabling quotactl wrapper])
 699 #       )
 700
 701         # For quotas on Linux XFS filesystems
 702         AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 703         AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)
 704         # For linux > 2.5.56
 705         AC_CHECK_HEADERS(linux/dqblk_xfs.h)
 706
 707
 708         dnl ----- as far as I can tell, dbtob always does the wrong thing
 709         dnl ----- on every single version of linux I've ever played with.
 710         dnl ----- see etc/afpd/quota.c
 711         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 712
 713         netatalk_cv_linux_sendfile=no
 714 dnl     disable this for now, code doesn't use sendfile anyway
 715 dnl        AC_ARG_ENABLE(sendfile,
 716 dnl         [  --enable-sendfile       use sendfile syscall default (no) ],[
 717 dnl             if test "$enableval" = "yes"; then
 718 dnl                     netatalk_cv_linux_sendfile=yes
 719 dnl             fi
 720 dnl             AC_MSG_RESULT([enabling sendfile syscall])
 721 dnl         ]
 722 dnl       )
 723
 724         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 725             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 726             AC_TRY_LINK([#include <sys/sendfile.h>],
 727 [\
 728 int tofd, fromfd;
 729 off_t offset;
 730 size_t total;
 731 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 732 ],
 733 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 734
 735 # Try and cope with broken Linux sendfile....
 736             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 737             AC_TRY_LINK([\
 738 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 739 #undef _FILE_OFFSET_BITS
 740 #endif
 741 #include <sys/sendfile.h>],
 742 [\
 743 int tofd, fromfd;
 744 off_t offset;
 745 size_t total;
 746 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 747 ],
 748 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 749
 750             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 751                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 752                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 753                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 754             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 755                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 756                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 757                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 758             else
 759                 netatalk_cv_linux_sendfile=no
 760                 AC_MSG_RESULT(no);
 761             fi
 762         fi
 763
 764         dnl ----- Linux/alpha specific -----
 765         if test x"$this_cpu" = "xalpha"; then
 766                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 767                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 768         fi
 769         need_dash_r=no
 770
 771
 772 fi
 773
 774 dnl ----- Mac OSX specific -----
 775 if test x"$this_os" = "xmacosx"; then
 776         AC_MSG_RESULT([ * Mac OSX specific configuration])
 777         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 778         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 779         dnl AC_DEFINE(NO_DLFCN_H)
 780         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 781         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 782         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 783 fi
 784
 785 dnl ----- NetBSD specific -----
 786 if test x"$this_os" = "xnetbsd"; then
 787         AC_MSG_RESULT([ * NetBSD specific configuration])
 788         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 789         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 790         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 791         need_dash_r=yes
 792
 793         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 794         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 795 fi
 796
 797 dnl ----- OpenBSD specific -----
 798 if test x"$this_os" = "xopenbsd"; then
 799         AC_MSG_RESULT([ * OpenBSD specific configuration])
 800         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 801         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 802 fi
 803
 804 dnl ----- Solaris specific -----
 805 if test x"$this_os" = "xsolaris"; then
 806         AC_MSG_RESULT([ * Solaris specific configuration])
 807         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 808         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 809         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 810         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 811         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 812         need_dash_r=yes
 813         sysv_style=solaris
 814
 815         solaris_module=no
 816         AC_MSG_CHECKING([if we can build Solaris kernel module])
 817         if test -x /usr/ccs/bin/ld; then
 818                 solaris_module=yes
 819         fi
 820         AC_MSG_RESULT([$solaris_module])
 821
 822         COMPILE_64BIT_KMODULE=no
 823         KCFLAGS=""
 824         KLDFLAGS=""
 825         COMPILE_KERNEL_GCC=no
 826
 827         if test "$solaris_module" = "yes"; then
 828            dnl Solaris kernel module stuff
 829            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 830
 831            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 832            if test -x /usr/bin/isainfo; then
 833                 # check for 64 bit platform
 834                 if isainfo -kv | grep '^64-bit'; then
 835                         COMPILE_64BIT_KMODULE=yes
 836                 fi
 837            fi
 838
 839            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 840
 841            if test "${GCC}" = yes; then
 842                 COMPILE_KERNEL_GCC=yes
 843                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 844
 845                         AC_MSG_CHECKING([if we can build a 64bit kernel module])
 846
 847                         case `$CC --version 2>/dev/null` in
 848                         [[12]].* | 3.0.*)
 849                                 COMPILE_64BIT_KMODULE=no
 850                                 COMPILE_KERNEL_GCC=no
 851                                 solaris_module=no;;
 852                         *)
 853                                 # use for 64 bit
 854                                 KCFLAGS="-m64"
 855                                 #KLDFLAGS="-melf64_sparc"
 856                                 KLDFLAGS="-64";;
 857                         esac
 858
 859                         AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 860
 861                 else
 862                         KCFLAGS=""
 863                         KLDFLAGS=""
 864                 fi
 865                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 866            else
 867                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 868                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 869                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 870                         KLDFLAGS="-64"
 871                 else
 872                         KCFLAGS=""
 873                         KLDFLAGS=""
 874                 fi
 875                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 876            fi
 877
 878            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 879            AC_TRY_LINK([\
 880 #include <sys/stream.h>
 881 #include <sys/ddi.h>],
 882 [\
 883 timeout_id_t dummy;
 884 ],
 885 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 886
 887            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 888         fi
 889
 890         AC_SUBST(COMPILE_KERNEL_GCC)
 891         AC_SUBST(COMPILE_64BIT_KMODULE)
 892         AC_SUBST(KCFLAGS)
 893         AC_SUBST(KLDFLAGS)
 894 fi
 895
 896 dnl ----- Tru64 specific -----
 897 if test x"$this_os" = "xtru64"; then
 898         AC_MSG_RESULT([ * Tru64 specific configuration])
 899         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 900         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 901         dnl AC_DEFINE(USE_MOUNT_H)
 902         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 903         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 904         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 905         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 906         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 907         AC_CHECK_LIB(security,set_auth_parameters)
 908         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 909         need_dash_r=no
 910         sysv_style=tru64
 911 fi
 912
 913 dnl -- look for openssl
 914 AC_PATH_SSL
 915
 916 dnl -- check for crypt
 917 AC_CRYPT
 918
 919 dnl --------------------- check for building PGP UAM module
 920
 921 AC_MSG_CHECKING([whether the PGP UAM should be build])
 922 AC_ARG_ENABLE(pgp-uam,
 923         [  --enable-pgp-uam        enable build of PGP UAM module],[
 924         if test "$enableval" = "yes"; then
 925                 if test "$compile_ssl" = "yes"; then
 926                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 927                         compile_pgp=yes
 928                         AC_MSG_RESULT([yes])
 929                 else
 930                         AC_MSG_RESULT([no])
 931                 fi
 932         fi
 933         ],[
 934                 AC_MSG_RESULT([no])
 935         ]
 936 )
 937
 938 dnl --------------------- check for building Kerberos v4 UAM module
 939
 940 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 941 AC_ARG_ENABLE(krb4-uam,
 942         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 943         if test "$enableval" = "yes"; then
 944                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 945                 compile_kerberos=yes
 946                 AC_MSG_RESULT([yes])
 947         else
 948                 AC_MSG_RESULT([no])
 949         fi
 950         ],[
 951                 AC_MSG_RESULT([no])
 952         ]
 953 )
 954
 955 dnl --------------------- check for building Kerberos V UAM module
 956
 957 netatalk_cv_build_krb5_uam=no
 958 AC_ARG_ENABLE(krbV-uam,
 959         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 960         [
 961                 if test x"$enableval" = x"yes"; then
 962                         NETATALK_GSSAPI_CHECK([
 963                                 netatalk_cv_build_krb5_uam=yes
 964                         ],[
 965                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 966                         ])
 967                 fi
 968         ]
 969
 970 )
 971
 972 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
 973 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
 974         AC_MSG_RESULT([yes])
 975 else
 976         AC_MSG_RESULT([no])
 977 fi
 978 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
 979
 980 dnl --------------------- overwrite the config files . . . or not.
 981
 982 AC_MSG_CHECKING([whether configuration files should be overwritten])
 983 AC_ARG_ENABLE(overwrite,
 984         [  --enable-overwrite      overwrite configuration files during installation],
 985         [OVERWRITE_CONFIG="${enable_overwrite}"],
 986         [OVERWRITE_CONFIG="no"]
 987 )
 988 AC_MSG_RESULT([$OVERWRITE_CONFIG])
 989
 990 dnl --------------------- last minute substitutions
 991
 992 AC_SUBST(LIBS)
 993 AC_SUBST(CFLAGS)
 994 AC_SUBST(OVERWRITE_CONFIG)
 995
 996 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
 997 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
 998 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
 999 AM_CONDITIONAL(USE_DHX, test x$compile_ssl = xyes)
1000 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
1001 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
1002 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
1003 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
1004 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
1005 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
1006 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
1007 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
1008 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
1009 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
1010 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
1011 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
1012 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
1013 AM_CONDITIONAL(USE_DEBIAN, test x$sysv_style = xdebian)
1014 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
1015
1016 dnl --------------------- generate files
1017
1018 AC_OUTPUT([Makefile
1019         bin/Makefile
1020         bin/adv1tov2/Makefile
1021         bin/aecho/Makefile
1022         bin/afile/Makefile
1023         bin/afppasswd/Makefile
1024         bin/cnid/Makefile
1025         bin/cnid/cnid_maint
1026         bin/cnid/cnid2_create
1027         bin/getzones/Makefile
1028         bin/megatron/Makefile
1029         bin/nbp/Makefile
1030         bin/pap/Makefile
1031         bin/psorder/Makefile
1032         bin/uniconv/Makefile
1033         config/Makefile
1034         contrib/Makefile
1035         contrib/macusers/Makefile
1036         contrib/macusers/macusers
1037         contrib/nu/Makefile
1038         contrib/nu/nu
1039         contrib/printing/Makefile
1040         contrib/shell_utils/Makefile
1041         contrib/shell_utils/afpd-mtab.pl
1042         contrib/shell_utils/apple_cp
1043         contrib/shell_utils/apple_mv
1044         contrib/shell_utils/apple_rm
1045         contrib/shell_utils/asip-status.pl
1046         contrib/shell_utils/cleanappledouble.pl
1047         contrib/shell_utils/netatalkshorternamelinks.pl
1048         contrib/timelord/Makefile
1049         contrib/a2boot/Makefile
1050         distrib/Makefile
1051         distrib/config/Makefile
1052         distrib/config/netatalk-config
1053         distrib/initscripts/Makefile
1054         distrib/m4/Makefile
1055         doc/Makefile
1056         etc/Makefile
1057         etc/afpd/Makefile
1058         etc/atalkd/Makefile
1059         etc/cnid_dbd/Makefile
1060         etc/uams/Makefile
1061         etc/uams/uams_krb4/Makefile
1062         etc/papd/Makefile
1063         etc/psf/Makefile
1064         include/Makefile
1065         include/atalk/Makefile
1066         libatalk/Makefile
1067         libatalk/adouble/Makefile
1068         libatalk/asp/Makefile
1069         libatalk/atp/Makefile
1070         libatalk/cnid/Makefile
1071         libatalk/cnid/db3/Makefile
1072         libatalk/cnid/cdb/Makefile
1073         libatalk/cnid/last/Makefile
1074         libatalk/cnid/mtab/Makefile
1075         libatalk/cnid/dbd/Makefile
1076         libatalk/cnid/hash/Makefile
1077         libatalk/cnid/tdb/Makefile
1078         libatalk/compat/Makefile
1079         libatalk/dsi/Makefile
1080         libatalk/nbp/Makefile
1081         libatalk/netddp/Makefile
1082         libatalk/util/Makefile
1083         libatalk/tdb/Makefile
1084         libatalk/unicode/Makefile
1085         libatalk/unicode/charsets/Makefile
1086         macros/Makefile
1087         man/Makefile
1088         man/man1/Makefile
1089         man/man3/Makefile
1090         man/man4/Makefile
1091         man/man5/Makefile
1092         man/man8/Makefile
1093         sys/Makefile
1094         sys/generic/Makefile
1095         sys/generic/sys/Makefile
1096         sys/netatalk/Makefile
1097         sys/netbsd/Makefile
1098         sys/netbsd/netatalk/Makefile
1099         sys/solaris/Makefile
1100         sys/sunos/Makefile
1101         sys/ultrix/Makefile
1102         ],
1103         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1104 )
1105
1106 AC_NETATALK_LIBS_SUMMARY
1107 AC_NETATALK_CONFIG_SUMMARY
1108