configure.ac

   1 #
   2 # Copyright (C) 2015 Alon Bar-Lev <alon.barlev@gmail.com>
   3 #
   4 AC_PREREQ(2.60)
   5
   6 define([VERSION_MAJOR], [1])
   7 define([VERSION_MINOR], [3])
   8 define([VERSION_FIX], [1])
   9 define([VERSION_NUMBER], VERSION_MAJOR[.]VERSION_MINOR[.]VERSION_FIX)
  10 define([VERSION_SUFFIX], [_master])
  11
  12 dnl Set to "1" for a first RPM release of a new version
  13 PACKAGE_RPM_RELEASE="0.0.$(echo VERSION_SUFFIX | sed s/^_//)"
  14
  15 AC_INIT([netdata], VERSION_NUMBER[]VERSION_SUFFIX)
  16
  17 AM_MAINTAINER_MODE([disable])
  18 if test x"$USE_MAINTAINER_MODE" = xyes; then
  19 AC_MSG_NOTICE(***************** MAINTAINER MODE *****************)
  20 PACKAGE_BUILT_DATE=$(date '+%d %b %Y')
  21 fi
  22
  23 PACKAGE_RPM_VERSION="VERSION_NUMBER"
  24 AC_SUBST([PACKAGE_RPM_VERSION])
  25 AC_SUBST([PACKAGE_RPM_RELEASE])
  26
  27 AC_CONFIG_AUX_DIR([.])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_SRCDIR([src/main.c])
  31 AM_INIT_AUTOMAKE
  32 AC_CANONICAL_HOST
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 PKG_PROG_PKG_CONFIG
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_CHECK_FUNCS_ONCE(accept4)
  38
  39 AC_ARG_ENABLE(
  40         [plugin-nfacct],
  41         [AS_HELP_STRING([--enable-plugin-nfacct], [enable nfacct plugin, requires root])],
  42         ,
  43         [enable_plugin_nfacct="no"]
  44 )
  45 AC_ARG_ENABLE(
  46         [pedantic],
  47         [AS_HELP_STRING([--enable-pedantic], [enable pedantic compiler warnings])],
  48         ,
  49         [enable_pedantic="no"]
  50 )
  51 AC_ARG_WITH(
  52         [webdir],
  53         [AS_HELP_STRING([--with-webdir], [location of webdir @<:@PKGDATADIR/web@:>@])],
  54         [webdir="${withval}"],
  55         [webdir="\$(pkgdatadir)/web"]
  56 )
  57 AC_ARG_WITH(
  58         [zlib],
  59         [AS_HELP_STRING([--with-zlib], [build with zlib])],
  60         ,
  61         [with_zlib="yes"]
  62 )
  63 AC_ARG_WITH(
  64         [math],
  65         [AS_HELP_STRING([--with-math], [build with math])],
  66         ,
  67         [with_math="yes"]
  68 )
  69 AC_ARG_WITH(
  70         [user],
  71         [AS_HELP_STRING([--with-user], [use this user to drop privilege])],
  72         ,
  73         [with_user="nobody"]
  74 )
  75
  76 ACX_PTHREAD(, [AC_MSG_ERROR([Cannot initialize pthread environment])])
  77 LIBS="${PTHREAD_LIBS} ${LIBS}"
  78 CFLAGS="${CFLAGS} ${PTHREAD_CFLAGS}"
  79 CC="${PTHREAD_CC}"
  80
  81 AC_TYPE_UINT8_T
  82 AC_TYPE_UINT16_T
  83 AC_TYPE_UINT32_T
  84 AC_C_INLINE
  85 AC_FUNC_STRERROR_R
  86
  87 # https://lists.gnu.org/archive/html/autoconf-commit/2012-12/msg00004.html
  88 # AC_C__GENERIC
  89 # -------------
  90 # Define HAVE_C__GENERIC if _Generic works, a la C11.
  91 AN_IDENTIFIER([_Generic], [AC_C__GENERIC])
  92 AC_DEFUN([AC_C__GENERIC],
  93 [AC_CACHE_CHECK([for _Generic], ac_cv_c__Generic,
  94 [AC_COMPILE_IFELSE(
  95    [AC_LANG_SOURCE(
  96       [[int
  97         main (int argc, char **argv)
  98         {
  99           int a = _Generic (argc, int: argc = 1);
 100           int *b = &_Generic (argc, default: argc);
 101           char ***c = _Generic (argv, int: argc, default: argv ? &argv : 0);
 102           _Generic (1 ? 0 : b, int: a, default: b) = &argc;
 103           _Generic (a = 1, default: a) = 3;
 104           return a + !b + !c;
 105         }
 106       ]])],
 107    [ac_cv_c__Generic=yes],
 108    [ac_cv_c__Generic=no])])
 109 if test $ac_cv_c__Generic = yes; then
 110   AC_DEFINE([HAVE_C__GENERIC], 1,
 111            [Define to 1 if C11-style _Generic works.])
 112 fi
 113 ])# AC_C__GENERIC
 114
 115 AC_C__GENERIC
 116
 117 # AC_C___ATOMIC
 118 # -------------
 119 # Define HAVE_C___ATOMIC if __atomic works.
 120 AN_IDENTIFIER([__atomic], [AC_C___ATOMIC])
 121 AC_DEFUN([AC_C___ATOMIC],
 122 [AC_CACHE_CHECK([for __atomic], ac_cv_c___atomic,
 123 [AC_COMPILE_IFELSE(
 124    [AC_LANG_SOURCE(
 125       [[int
 126         main (int argc, char **argv)
 127         {
 128           volatile unsigned long ul1 = 1, ul2 = 0, ul3 = 2;
 129           __atomic_compare_exchange(&ul1, &ul2, &ul3, 1, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST);
 130           __atomic_fetch_add(&ul1, 1, __ATOMIC_SEQ_CST);
 131           __atomic_fetch_sub(&ul3, 1, __ATOMIC_SEQ_CST);
 132           volatile unsigned long long ull1 = 1, ull2 = 0, ull3 = 2;
 133           __atomic_compare_exchange(&ull1, &ull2, &ull3, 1, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST);
 134           __atomic_fetch_add(&ull1, 1, __ATOMIC_SEQ_CST);
 135           __atomic_fetch_sub(&ull3, 1, __ATOMIC_SEQ_CST);
 136           return 0;
 137         }
 138       ]])],
 139    [ac_cv_c___atomic=yes],
 140    [ac_cv_c___atomic=no])])
 141 if test $ac_cv_c___atomic = yes; then
 142   AC_DEFINE([HAVE_C___ATOMIC], 1,
 143            [Define to 1 if __atomic operations work.])
 144 fi
 145 ])# AC_C___ATOMIC
 146
 147 AC_C___ATOMIC
 148
 149
 150 AC_ARG_VAR([MATH_CFLAGS], [C compiler flags for math])
 151 AC_ARG_VAR([MATH_LIBS], [linker flags for math])
 152 if test -z "${MATH_LIBS}"; then
 153         AC_CHECK_LIB(
 154                 [m],
 155                 [sin],
 156                 [MATH_LIBS="-lm"]
 157         )
 158 fi
 159
 160 PKG_CHECK_MODULES(
 161         [UUID],
 162         [uuid],
 163 )
 164 test -z "${UUID_LIBS}" && AC_MSG_ERROR([libuuid required but not found. Try installing 'uuid-dev' or 'libuuid-devel'.])
 165 AC_DEFINE([NETDATA_WITH_UUID], [1], [uuid settings])
 166 OPTIONAL_UUID_CLFAGS="${UUID_CFLAGS}"
 167 OPTIONAL_UUID_LIBS="${UUID_LIBS}"
 168
 169 if test "${enable_plugin_nfacct}" = "yes"; then
 170         PKG_CHECK_MODULES(
 171                 [NFACCT],
 172                 [libnetfilter_acct],
 173         )
 174         PKG_CHECK_MODULES(
 175                 [LIBMNL],
 176                 [libmnl],
 177         )
 178         test -z "${NFACCT_LIBS}" && AC_MSG_ERROR([netfilter_acct required but not found])
 179         test -z "${LIBMNL_LIBS}" && AC_MSG_ERROR([libmnl required but not found. Try installing 'libmnl-dev' or 'libmnl-devel'])
 180         AC_DEFINE([INTERNAL_PLUGIN_NFACCT], [1], [nfacct plugin settings])
 181         OPTIONAL_NFACCT_CLFAGS="${NFACCT_CFLAGS} ${LIBMNL_CFLAGS}"
 182         OPTIONAL_NFACCT_LIBS="${NFACCT_LIBS} ${LIBMNL_LIBS}"
 183 fi
 184 if test "${with_zlib}" = "yes"; then
 185         PKG_CHECK_MODULES(
 186                 [ZLIB],
 187                 [zlib],
 188         )
 189         test -z "${ZLIB_LIBS}" && AC_MSG_ERROR([zlib required but not found. Try installing 'zlib1g-dev' or 'zlib-devel'.])
 190         AC_DEFINE([NETDATA_WITH_ZLIB], [1], [zlib settings])
 191         OPTIONAL_ZLIB_CLFAGS="${ZLIB_CFLAGS}"
 192         OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
 193 fi
 194 if test "${with_math}" = "yes"; then
 195         test -z "${MATH_LIBS}" && AC_MSG_ERROR([math required but not found])
 196         AC_DEFINE([STORAGE_WITH_MATH], [1], [math settings])
 197         OPTIONAL_MATH_CFLAGS="${MATH_CFLAGS}"
 198         OPTIONAL_MATH_LIBS="${MATH_LIBS}"
 199 fi
 200
 201 if test "${GCC}" = "yes"; then
 202         AC_DEFINE_UNQUOTED([likely(x)], [__builtin_expect(!!(x), 1)], [gcc branch optimization])
 203         AC_DEFINE_UNQUOTED([unlikely(x)], [__builtin_expect(!!(x), 0)], [gcc branch optimization])
 204 else
 205         AC_DEFINE_UNQUOTED([likely(x)], [(x)], [gcc branch optimization])
 206         AC_DEFINE_UNQUOTED([unlikely(x)], [(x)], [gcc branch optimization])
 207 fi
 208
 209 if test "${enable_pedantic}" = "yes"; then
 210         enable_strict="yes"
 211         CFLAGS="${CFLAGS} -pedantic -Wall -Wextra -Wno-long-long"
 212 fi
 213
 214 AC_DEFINE_UNQUOTED([NETDATA_USER], ["${with_user}"], [use this user to drop privileged])
 215
 216 AC_SUBST([varlibdir], ["\$(localstatedir)/lib/netdata"])
 217 AC_SUBST([registrydir], ["\$(localstatedir)/lib/netdata/registry"])
 218 AC_SUBST([cachedir], ["\$(localstatedir)/cache/netdata"])
 219 AC_SUBST([chartsdir], ["\$(libexecdir)/netdata/charts.d"])
 220 AC_SUBST([nodedir], ["\$(libexecdir)/netdata/node.d"])
 221 AC_SUBST([pythondir], ["\$(libexecdir)/netdata/python.d"])
 222 AC_SUBST([configdir], ["\$(sysconfdir)/netdata"])
 223 AC_SUBST([logdir], ["\$(localstatedir)/log/netdata"])
 224 AC_SUBST([pluginsdir], ["\$(libexecdir)/netdata/plugins.d"])
 225 AC_SUBST([webdir])
 226
 227 AC_SUBST([OPTIONAL_MATH_CLFAGS])
 228 AC_SUBST([OPTIONAL_MATH_LIBS])
 229 AC_SUBST([OPTIONAL_NFACCT_CLFAGS])
 230 AC_SUBST([OPTIONAL_NFACCT_LIBS])
 231 AC_SUBST([OPTIONAL_ZLIB_CLFAGS])
 232 AC_SUBST([OPTIONAL_ZLIB_LIBS])
 233 AC_SUBST([OPTIONAL_UUID_CLFAGS])
 234 AC_SUBST([OPTIONAL_UUID_LIBS])
 235
 236 AC_CONFIG_FILES([
 237         Makefile
 238         charts.d/Makefile
 239         conf.d/Makefile
 240         netdata.spec
 241         python.d/Makefile
 242         node.d/Makefile
 243         plugins.d/Makefile
 244         src/Makefile
 245         system/Makefile
 246         web/Makefile
 247         contrib/Makefile
 248 ])
 249 AC_OUTPUT
 250
 251 test "${with_math}" != "yes" && AC_MSG_WARN([You are building without math. math allows accurate calculations. It should be enabled.]) || :
 252 test "${with_zlib}" != "yes" && AC_MSG_WARN([You are building without zlib. zlib allows netdata to trasnfer a lot less data with web clients. It should be enabled.]) || :