X-Git-Url: https://arthur.barton.de/cgi-bin/gitweb.cgi?p=ngircd-alex.git;a=blobdiff_plain;f=configure.ng;h=0b0a6588d6c1ec3cf8e3ac1949b23e2be57938cd;hp=25654f9cfbdfc78d2ef74de059a64cfeeb8e355f;hb=e73d70ce6fab3acdefe914520a4296acb6d50eac;hpb=192e304b94f239de13b0f10ca01f6694fe6eea40

diff --git a/configure.ng b/configure.ng
index 25654f9c..0b0a6588 100644
--- a/configure.ng
+++ b/configure.ng
@@ -1,6 +1,6 @@
 #
 # ngIRCd -- The Next Generation IRC Daemon
-# Copyright (c)2001-2012 Alexander Barton (alex@barton.de) and Contributors
+# Copyright (c)2001-2014 Alexander Barton (alex@barton.de) and Contributors
 #
 # This program is free software; you can redistribute it and/or modify
 # it under the terms of the GNU General Public License as published by
@@ -9,19 +9,27 @@
 # Please read the file COPYING, README and AUTHORS for more information.
 #
 
-define(VERSION_ID,esyscmd(git describe|sed -e 's/rel-//g'|sed -e 's/-/~/'|tr -d \\n))
+define(VERSION_ID,esyscmd([
+	V=`git describe 2>/dev/null | sed -e 's/rel-//g' | sed -e 's/-/~/'`;
+	[ -z "$V" -a -r configure ] \
+		&& V=`grep "PACKAGE_STRING=" configure | cut -d"'" -f2 | cut -d' ' -f2`
+	( [ -n "$V" ] && echo "$V" || echo "??" ) | tr -d '\n';
+]))
+
+m4_ifdef([AM_SILENT_RULES],
+	[m4_define([ng_color_tests], [color-tests])],
+	[m4_define([ng_color_tests], [])])
 
 # -- Initialisation --
 
-AC_PREREQ([2.67])
-AC_INIT([ngIRCd], VERSION_ID,
-	[ngircd-ml@ngircd.barton.de], [ngircd], [http://ngircd.barton.de/])
+AC_PREREQ([2.61])
+AC_INIT([ngIRCd],[VERSION_ID],[ngircd-ml@ngircd.barton.de],[ngircd],[http://ngircd.barton.de/])
 
 AC_CONFIG_SRCDIR([src/ngircd/ngircd.c])
 AC_CONFIG_HEADER([src/config.h])
 AC_CANONICAL_HOST
 
-AM_INIT_AUTOMAKE([1.11])
+AM_INIT_AUTOMAKE([-Wall 1.10 ]ng_color_tests)
 
 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 
@@ -30,6 +38,7 @@ m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
 AH_TEMPLATE([HAVE_sockaddr_in_len], [Define if sockaddr_in.sin_len exists])
 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
+AH_TEMPLATE([ICONV], [Define if libiconv can be used, e.g. for CHARCONV])
 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
 AH_TEMPLATE([PAM], [Define if PAM should be used])
@@ -51,6 +60,8 @@ AC_PROG_CC_STDC
 
 # -- Helper programs --
 
+m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
+
 AC_PROG_AWK
 AC_PROG_INSTALL
 AC_PROG_LN_S
@@ -63,23 +74,57 @@ AC_C_CONST
 AC_C_INLINE
 __ng_PROTOTYPES__
 
-# -- Hard coded system and compiler dependencies/features/options ... --
+# -- Function Definitions --
 
 AC_DEFUN([GCC_STACK_PROTECT_CC],[
-  ssp_cc=yes
-  # we use -fstack-protector-all for the test to enfoce the use of the guard variable 
-  AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
-  ssp_old_cflags="$CFLAGS"
-  CFLAGS="$CFLAGS -fstack-protector-all"
-  AC_TRY_LINK(,,, ssp_cc=no)
-  echo $ssp_cc
-  CFLAGS="$ssp_old_cflags"
-  if test "X$ssp_cc" = "Xyes"; then
-      CFLAGS="$CFLAGS -fstack-protector"
-      AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
-  fi
+	ssp_cc=yes
+	# Use -fstack-protector-all for the test to enfoce the use of the
+	# guard variable
+	AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
+	ssp_old_cflags="$CFLAGS"
+	CFLAGS="$CFLAGS -fstack-protector-all"
+	AC_LINK_IFELSE([AC_LANG_PROGRAM([],[])],[],[ssp_cc=no])
+	echo $ssp_cc
+	CFLAGS="$ssp_old_cflags"
+	if test "X$ssp_cc" = "Xyes"; then
+		CFLAGS="$CFLAGS -fstack-protector"
+		AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
+	fi
+])
+
+AC_DEFUN([WORKING_GETADDRINFO],[
+	AC_CHECK_FUNCS([getaddrinfo],[
+		AC_MSG_CHECKING([whether getaddrinfo() works])
+		AC_RUN_IFELSE([AC_LANG_SOURCE([[
+#include <stdio.h>
+#include <sys/types.h>
+#include <sys/socket.h>
+#include <netdb.h>
+int
+main(int argc, char **argv)
+{
+	struct addrinfo hints, *ai;
+	memset(&hints, 0, sizeof(hints));
+	hints.ai_flags = AI_PASSIVE;
+	hints.ai_socktype = SOCK_STREAM;
+	hints.ai_family = PF_UNSPEC;
+	if(getaddrinfo(NULL, "0", &hints, &ai) != 0)
+		return 1;
+	return 0;
+}
+		]])],[
+		AC_DEFINE([HAVE_WORKING_GETADDRINFO], 1, [getaddrinfo(0)])
+		AC_MSG_RESULT(yes)
+		],[
+		AC_MSG_RESULT(no)
+		],[
+		AC_MSG_RESULT(no)
+		])
+	])
 ])
 
+# -- Hard coded system and compiler dependencies/features/options ... --
+
 if test "$GCC" = "yes"; then
 	# We are using the GNU C compiler. Good!
 	CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
@@ -98,7 +143,7 @@ esac
 # Add additional CFLAGS, eventually specified on the command line:
 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
 
-CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
+CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"' -DDOCDIR='\"\$(docdir)\"'"
 
 # -- Headers --
 
@@ -108,33 +153,32 @@ AC_HEADER_TIME
 
 # Required header files
 AC_CHECK_HEADERS([ \
-	fcntl.h netdb.h netinet/in.h netinet/in_systm.h stdlib.h string.h \
+	fcntl.h netdb.h netinet/in.h stdlib.h string.h \
 	strings.h sys/socket.h sys/time.h unistd.h \
 	],,AC_MSG_ERROR([required C header missing!]))
 
 # Optional header files
 AC_CHECK_HEADERS_ONCE([ \
-	arpa/inet.h inttypes.h malloc.h netinet/ip.h stdbool.h stddef.h \
-	stdint.h varargs.h \
+	arpa/inet.h inttypes.h malloc.h netinet/in_systm.h netinet/ip.h \
+	stdbool.h stddef.h stdint.h varargs.h \
 	])
 
 # -- Datatypes --
 
 AC_MSG_CHECKING(whether socklen_t exists)
-AC_TRY_COMPILE([
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 #include <sys/types.h>
 #include <sys/socket.h>
-	],[
+	]],[[
 	socklen_t a, b;
 	a = 2; b = 4; a += b;
-	],[
+	]])],[
 	AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
 	],[
 	AC_MSG_RESULT(no)
 ])
 
 AC_TYPE_PID_T
-AC_TYPE_SIGNAL
 AC_TYPE_SIZE_T
 AC_TYPE_SSIZE_T
 AC_TYPE_UID_T
@@ -152,11 +196,11 @@ AC_SEARCH_LIBS([memmove], [UTIL], [], [
 	AC_MSG_ERROR([unable to find the memmove() function])
 ])
 # gethostbyname: Solaris libnsl
-AC_SEARCH_LIBS([gethostbyname], [nsl], [], [
+AC_SEARCH_LIBS([gethostbyname], [bind nsl network], [], [
 	AC_MSG_ERROR([unable to find the gethostbyname() function])
 ])
 # bind: SVR4 libsocket
-AC_SEARCH_LIBS([bind], [socket], [], [
+AC_SEARCH_LIBS([bind], [socket network], [], [
 	AC_MSG_ERROR([unable to find the bind() function])
 ])
 
@@ -174,9 +218,12 @@ AC_CHECK_FUNCS([ \
 	AC_MSG_ERROR([required function missing!]))
 
 # Optional functions
-AC_CHECK_FUNCS_ONCE([ \
-	gai_strerror getaddrinfo getnameinfo inet_aton sigaction sigprocmask \
-	snprintf vsnprintf strdup strlcpy strlcat strtok_r waitpid])
+AC_CHECK_FUNCS_ONCE([
+	arc4random arc4random_stir gai_strerror getnameinfo inet_aton \
+	sigaction sigprocmask snprintf vsnprintf strdup strndup strlcpy strlcat \
+	strtok_r unsetenv waitpid])
+
+WORKING_GETADDRINFO
 
 # -- Configuration options --
 
@@ -420,13 +467,13 @@ AC_ARG_WITH(tcp-wrappers,
 			fi
 			AC_MSG_CHECKING(for hosts_access)
 			LIBS="-lwrap $LIBS"
-			AC_TRY_LINK([
+			AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 #include <tcpd.h>
 int allow_severity = 0;
 int deny_severity = 0;
-				],[
+				]],[[
 				tcpd_warn("link test");
-				],[
+				]])],[
 				AC_MSG_RESULT(yes)
 				AC_DEFINE(TCPWRAP, 1)
 				x_tcpwrap_on=yes
@@ -500,6 +547,34 @@ AC_ARG_ENABLE(ircplus,
 )
 if test "$x_ircplus_on" = "yes"; then
 	AC_DEFINE(IRCPLUS, 1)
+
+	# Compile in iconv support?
+	# We only check for it when IRC+ is enabled, because the IRC+ command
+	# CHARCONV is the only function depending on it.
+	x_iconv_on=no
+	AC_ARG_WITH(iconv,
+		AS_HELP_STRING([--with-iconv],
+			       [enable character conversion using libiconv]),
+		[ if test "$withval" != "no"; then
+			if test "$withval" != "yes"; then
+				CFLAGS="-I$withval/include $CFLAGS"
+				CPPFLAGS="-I$withval/include $CPPFLAGS"
+				LDFLAGS="-L$withval/lib $LDFLAGS"
+			fi
+			AC_CHECK_LIB(iconv, iconv_open)
+			AC_CHECK_FUNCS(iconv_open, x_iconv_on=yes)
+			if test "$x_iconv_on" != "yes"; then
+				AC_CHECK_LIB(iconv, libiconv_open)
+				AC_CHECK_FUNCS(libiconv_open, x_iconv_on=yes)
+			fi
+			if test "$x_iconv_on" != "yes"; then
+				AC_MSG_ERROR([Can't enable libiconv support!])
+			fi
+		fi ]
+	)
+	if test "$x_iconv_on" = "yes"; then
+		AC_DEFINE(ICONV, 1)
+	fi
 fi
 
 # enable support for IPv6?
@@ -569,7 +644,6 @@ test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
 
 AC_CONFIG_FILES([ \
 	Makefile \
-	contrib/Anope/Makefile \
 	contrib/Debian/Makefile \
 	contrib/MacOSX/Makefile \
 	contrib/MacOSX/ngIRCd.pmdoc/Makefile \
@@ -663,7 +737,7 @@ test "$x_ipv6_on" = "yes" \
 	&& echo $ECHO_N "yes   $ECHO_C" \
 	|| echo $ECHO_N "no    $ECHO_C"
 echo $ECHO_N "        I/O backend: $ECHO_C"
-	echo "\"$x_io_backend\""
+	echo "$x_io_backend"
 
 echo $ECHO_N "        PAM support: $ECHO_C"
 test "$x_pam_on" = "yes" \
@@ -672,9 +746,13 @@ test "$x_pam_on" = "yes" \
 echo $ECHO_N "        SSL support: $ECHO_C"
 echo "$x_ssl_lib"
 
+echo $ECHO_N "   libiconv support: $ECHO_C"
+	echo "$x_iconv_on"
+
 echo
 
-if ! grep "^AUTOMAKE_OPTIONS = ../portab/ansi2knr" src/ngircd/Makefile.am >/dev/null 2>&1; then
+define(_automake_regex_,[[^AUTOMAKE_OPTIONS = [a-z .\-]*/portab/ansi2knr]])
+if ! grep "_automake_regex_" src/ngircd/Makefile.am >/dev/null 2>&1; then
 	echo "WARNING:"
 	echo "This GNU automake generated build system does not support \"de-ANSI-fication\","
 	echo "therefore don't use it to generate \"official\" distribution archives!"