Update NEWS and ChangeLog files
[ngircd-alex.git] / configure.in
1 #
2 # ngIRCd -- The Next Generation IRC Daemon
3 # Copyright (c)2001-2011 Alexander Barton (alex@barton.de) and Contributors
4 #
5 # This program is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 2 of the License, or
8 # (at your option) any later version.
9 # Please read the file COPYING, README and AUTHORS for more information.
10 #
11
12 define(VERSION_ID,esyscmd(git describe|sed -e 's/rel-//g'|sed -e 's/-/~/'|tr -d \\n))
13
14 # -- Initialisation --
15
16 AC_PREREQ(2.50)
17 AC_INIT(ngircd, VERSION_ID)
18 AC_CONFIG_SRCDIR(src/ngircd/ngircd.c)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE(1.6)
21 AM_CONFIG_HEADER(src/config.h)
22
23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
24
25 # -- Templates for config.h --
26
27 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
28 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
29 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
30 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
31 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
32 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
33 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
34 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
35 AH_TEMPLATE([WANT_IPV6], [Define if IPV6 protocol should be enabled])
36 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
37 AH_TEMPLATE([PAM], [Define if PAM should be used])
38 AH_TEMPLATE([HAVE_sockaddr_in_len], [Define if sockaddr_in.sin_len exists])
39
40 AH_TEMPLATE([TARGET_OS], [Target operating system name])
41 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
42 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
43
44 # -- C Compiler --
45
46 AC_PROG_CC
47 AC_PROG_CC_STDC
48 AC_C_PROTOTYPES
49
50 # -- Helper programs --
51
52 AC_PROG_AWK
53 AC_PROG_INSTALL
54 AC_PROG_LN_S
55 AC_PROG_MAKE_SET
56 AC_PROG_RANLIB
57
58 # -- Compiler Features --
59
60 AM_C_PROTOTYPES
61 AC_C_CONST
62 AC_C_INLINE
63
64 # -- Hard coded system and compiler dependencies/features/options ... --
65
66 AC_DEFUN([GCC_STACK_PROTECT_CC],[
67   ssp_cc=yes
68   # we use -fstack-protector-all for the test to enfoce the use of the guard variable 
69   AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
70   ssp_old_cflags="$CFLAGS"
71   CFLAGS="$CFLAGS -fstack-protector-all"
72   AC_TRY_LINK(,,, ssp_cc=no)
73   echo $ssp_cc
74   CFLAGS="$ssp_old_cflags"
75   if test "X$ssp_cc" = "Xyes"; then
76       CFLAGS="$CFLAGS -fstack-protector"
77       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
78   fi
79 ])
80
81 if test "$GCC" = "yes"; then
82         # We are using the GNU C compiler. Good!
83         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
84
85         GCC_STACK_PROTECT_CC
86 fi
87
88 case "$target_os" in
89         hpux*)
90                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
91                 # (tested with HP/UX 11.11)
92                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
93                 ;;
94 esac
95
96 # Add additional CFLAGS, eventually specified on the command line:
97 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
98
99 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
100
101 # -- Headers --
102
103 AC_HEADER_STDC
104 AC_HEADER_TIME
105 AC_HEADER_SYS_WAIT
106
107 AC_CHECK_HEADERS([ \
108         ctype.h errno.h fcntl.h netdb.h netinet/in.h netinet/in_systm.h \
109         stdlib.h string.h strings.h sys/socket.h sys/time.h unistd.h \
110         ],,AC_MSG_ERROR([required C header missing!]))
111
112 AC_CHECK_HEADERS([ \
113         arpa/inet.h ctype.h malloc.h netinet/ip.h stdbool.h stddef.h varargs.h \
114         ],[],[],[[
115         #ifdef HAVE_SYS_TYPES_H
116                 #include <sys/types.h>
117         #endif
118         #ifdef HAVE_SYS_SOCKET_H
119                 #include <sys/socket.h>
120         #endif
121         #ifdef HAVE_NETINET_IN_H
122                 #include <netinet/in.h>
123         #endif
124         ]]
125 )
126
127 # -- Datatypes --
128
129 AC_MSG_CHECKING(whether socklen_t exists)
130 AC_TRY_COMPILE([
131 #include <sys/types.h>
132 #include <sys/socket.h>
133         ],[
134         socklen_t a, b;
135         a = 2; b = 4; a += b;
136         ],[
137         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
138         ],[
139         AC_MSG_RESULT(no)
140 ])
141
142 AC_TYPE_SIGNAL
143 AC_TYPE_SIZE_T
144
145 AC_CHECK_MEMBER([struct sockaddr_in.sin_len], AC_DEFINE(HAVE_sockaddr_in_len),,
146  [#include <arpa/inet.h>])
147
148 # -- Libraries --
149
150 # A/UX needs this.
151 AC_CHECK_LIB(UTIL,memmove)
152 # needed on solaris. GNU libc also has a libnsl, but we do not need it.
153 AC_SEARCH_LIBS(gethostbyname,nsl)
154 AC_CHECK_LIB(socket,bind)
155
156 # -- Functions --
157
158 AC_FUNC_FORK
159 AC_FUNC_STRFTIME
160
161 AC_CHECK_FUNCS([ \
162         bind gethostbyaddr gethostbyname gethostname inet_ntoa \
163         setsid setsockopt socket strcasecmp waitpid],,
164         AC_MSG_ERROR([required function missing!]))
165
166 AC_CHECK_FUNCS([ \
167         gai_strerror getaddrinfo getnameinfo inet_aton sigaction \
168         sigprocmask snprintf vsnprintf strdup strlcpy strlcat strtok_r])
169
170 # -- Configuration options --
171
172 # use syslog?
173
174 x_syslog_on=no
175 AC_ARG_WITH(syslog,
176         [  --without-syslog        disable syslog (autodetected by default)],
177         [       if test "$withval" != "no"; then
178                         if test "$withval" != "yes"; then
179                                 CFLAGS="-I$withval/include $CFLAGS"
180                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
181                                 LDFLAGS="-L$withval/lib $LDFLAGS"
182                         fi
183                         AC_CHECK_LIB(be, syslog)
184                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
185                                 AC_MSG_ERROR([Can't enable syslog!])
186                         )
187                 fi
188         ],
189         [
190                 AC_CHECK_LIB(be, syslog)
191                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
192         ]
193 )
194 if test "$x_syslog_on" = "yes"; then
195         AC_DEFINE(SYSLOG, 1)
196         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
197 fi
198
199 # use zlib compression?
200
201 x_zlib_on=no
202 AC_ARG_WITH(zlib,
203         [  --without-zlib          disable zlib compression (autodetected by default)],
204         [       if test "$withval" != "no"; then
205                         if test "$withval" != "yes"; then
206                                 CFLAGS="-I$withval/include $CFLAGS"
207                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
208                                 LDFLAGS="-L$withval/lib $LDFLAGS"
209                         fi
210                         AC_CHECK_LIB(z, deflate)
211                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
212                                 AC_MSG_ERROR([Can't enable zlib!])
213                         )
214                 fi
215         ],
216         [       AC_CHECK_LIB(z, deflate)
217                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
218         ]
219 )
220 if test "$x_zlib_on" = "yes"; then
221         AC_DEFINE(ZLIB, 1)
222         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
223 fi
224
225 # detect which IO API to use:
226
227 x_io_backend=none
228
229 AC_ARG_WITH(select,
230         [  --without-select        disable select IO support (autodetected by default)],
231         [       if test "$withval" != "no"; then
232                         if test "$withval" != "yes"; then
233                                 CFLAGS="-I$withval/include $CFLAGS"
234                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
235                                 LDFLAGS="-L$withval/lib $LDFLAGS"
236                         fi
237                         AC_CHECK_FUNCS(select, x_io_select=yes,
238                                 AC_MSG_ERROR([Can't enable select IO support!])
239                         )
240                 fi
241         ],
242         [
243                 AC_CHECK_FUNCS(select, x_io_select=yes)
244         ]
245 )
246
247 AC_ARG_WITH(poll,
248         [  --without-poll          disable poll support (autodetected by default)],
249         [       if test "$withval" != "no"; then
250                         if test "$withval" != "yes"; then
251                                 CFLAGS="-I$withval/include $CFLAGS"
252                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
253                                 LDFLAGS="-L$withval/lib $LDFLAGS"
254                         fi
255                         AC_CHECK_FUNCS(poll, [
256                                 AC_CHECK_HEADERS(poll.h,
257                                         x_io_backend=poll\(\),
258                                         AC_MSG_ERROR(
259                                              [Can't enable poll IO support!])
260                                 )
261                         ], [
262                                 AC_MSG_ERROR([Can't enable poll IO support!])
263                         ])
264                 fi
265         ],
266         [
267                 AC_CHECK_FUNCS(poll, [
268                         AC_CHECK_HEADERS(poll.h, x_io_backend=poll\(\))
269                 ])
270         ]
271 )
272
273 AC_ARG_WITH(devpoll,
274         [  --without-devpoll       disable /dev/poll IO support (autodetected by default)],
275         [       if test "$withval" != "no"; then
276                         if test "$withval" != "yes"; then
277                                 CFLAGS="-I$withval/include $CFLAGS"
278                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
279                                 LDFLAGS="-L$withval/lib $LDFLAGS"
280                         fi
281
282                                 AC_CHECK_HEADERS(sys/devpoll.h,,AC_MSG_ERROR([required C header missing!]))
283                 fi
284         ],
285         [
286                 AC_CHECK_HEADERS(sys/devpoll.h, x_io_backend=/dev/poll)
287         ]
288 )
289
290 AC_ARG_WITH(epoll,
291         [  --without-epoll         disable epoll IO support (autodetected by default)],
292         [       if test "$withval" != "no"; then
293                         if test "$withval" != "yes"; then
294                                 CFLAGS="-I$withval/include $CFLAGS"
295                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
296                                 LDFLAGS="-L$withval/lib $LDFLAGS"
297                         fi
298                         AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes,
299                                 AC_MSG_ERROR([Can't enable epoll IO support!])
300                         )
301                 fi
302         ],
303         [
304                 AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes)
305         ]
306 )
307
308 AC_ARG_WITH(kqueue,
309         [  --without-kqueue        disable kqueue IO support (autodetected by default)],
310         [       if test "$withval" != "no"; then
311                         if test "$withval" != "yes"; then
312                                 CFLAGS="-I$withval/include $CFLAGS"
313                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
314                                 LDFLAGS="-L$withval/lib $LDFLAGS"
315                         fi
316                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\),
317                                 AC_MSG_ERROR([Can't enable kqueue IO support!])
318                         )
319                 fi
320         ],
321         [
322                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\))
323         ]
324 )
325
326 if test "$x_io_epoll" = "yes" -a "$x_io_select" = "yes"; then
327         # when epoll() and select() are available, we'll use both!
328         x_io_backend="epoll(), select()"
329 else
330         if test "$x_io_epoll" = "yes"; then
331                 # we prefere epoll() if it is available
332                 x_io_backend="epoll()"
333         else
334                 if test "$x_io_select" = "yes" -a "$x_io_backend" = "none"; then
335                         # we'll use select, when available and no "better"
336                         # interface has been detected ...
337                         x_io_backend="select()"
338                 fi
339         fi
340 fi
341
342 if test "$x_io_backend" = "none"; then
343         AC_MSG_ERROR([No useable IO API activated/found!?])
344 fi
345
346 # use SSL?
347
348 AC_ARG_WITH(openssl,
349         [  --with-openssl          enable SSL support using OpenSSL],
350         [       if test "$withval" != "no"; then
351                         if test "$withval" != "yes"; then
352                                 CFLAGS="-I$withval/include $CFLAGS"
353                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
354                                 LDFLAGS="-L$withval/lib $LDFLAGS"
355                         fi
356                         AC_CHECK_LIB(crypto, BIO_s_mem)
357                         AC_CHECK_LIB(ssl, SSL_library_init)
358                         AC_CHECK_FUNCS(SSL_library_init, x_ssl_openssl=yes,
359                                 AC_MSG_ERROR([Can't enable openssl])
360                         )
361                 fi
362         ]
363 )
364
365 AC_ARG_WITH(gnutls,
366         [  --with-gnutls           enable SSL support using gnutls],
367         [       if test "$withval" != "no"; then
368                         if test "$withval" != "yes"; then
369                                 CFLAGS="-I$withval/include $CFLAGS"
370                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
371                                 LDFLAGS="-L$withval/lib $LDFLAGS"
372                         fi
373                         AC_CHECK_LIB(gnutls, gnutls_global_init)
374                         AC_CHECK_FUNCS(gnutls_global_init, x_ssl_gnutls=yes,
375                                 AC_MSG_ERROR([Can't enable gnutls])
376                         )
377                 fi
378         ]
379 )
380
381 x_ssl_lib="no"
382 if test "$x_ssl_gnutls" = "yes"; then
383         if test "$x_ssl_openssl" = "yes";then
384                 AC_MSG_ERROR([Cannot enable both gnutls and openssl])
385         fi
386         x_ssl_lib=gnutls
387 fi
388 if test "$x_ssl_openssl" = "yes"; then
389         x_ssl_lib=openssl
390 fi
391
392 # use TCP wrappers?
393
394 x_tcpwrap_on=no
395 AC_ARG_WITH(tcp-wrappers,
396         [  --with-tcp-wrappers     enable TCP wrappers support],
397         [       if test "$withval" != "no"; then
398                         if test "$withval" != "yes"; then
399                                 CFLAGS="-I$withval/include $CFLAGS"
400                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
401                                 LDFLAGS="-L$withval/lib $LDFLAGS"
402                         fi
403                         AC_MSG_CHECKING(for hosts_access)
404                         LIBS="-lwrap $LIBS"
405                         AC_TRY_LINK([
406 #include <tcpd.h>
407 int allow_severity = 0;
408 int deny_severity = 0;
409                                 ],[
410                                 tcpd_warn("link test");
411                                 ],[
412                                 AC_MSG_RESULT(yes)
413                                 AC_DEFINE(TCPWRAP, 1)
414                                 x_tcpwrap_on=yes
415                                 ],[
416                                 AC_MSG_RESULT(no)
417                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
418                         ])
419                 fi
420         ]
421 )
422
423 # do IDENT requests using libident?
424
425 x_identauth_on=no
426 AC_ARG_WITH(ident,
427         [  --with-ident            enable "IDENT" ("AUTH") protocol support],
428         [       if test "$withval" != "no"; then
429                         if test "$withval" != "yes"; then
430                                 CFLAGS="-I$withval/include $CFLAGS"
431                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
432                                 LDFLAGS="-L$withval/lib $LDFLAGS"
433                         fi
434                         AC_CHECK_LIB(ident, ident_id)
435                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
436                                 AC_MSG_ERROR([Can't enable IDENT support!])
437                         )
438                 fi
439         ]
440 )
441 if test "$x_identauth_on" = "yes"; then
442         AC_DEFINE(IDENTAUTH, 1)
443         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
444 fi
445
446 # compile in PAM support?
447
448 x_pam_on=no
449 AC_ARG_WITH(pam,
450         [  --with-pam              enable user authentication using PAM],
451         [       if test "$withval" != "no"; then
452                         if test "$withval" != "yes"; then
453                                 CFLAGS="-I$withval/include $CFLAGS"
454                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
455                                 LDFLAGS="-L$withval/lib $LDFLAGS"
456                         fi
457                         AC_CHECK_LIB(pam, pam_authenticate)
458                         AC_CHECK_FUNCS(pam_authenticate, x_pam_on=yes,
459                                 AC_MSG_ERROR([Can't enable PAM support!])
460                         )
461                 fi
462         ]
463 )
464 if test "$x_pam_on" = "yes"; then
465         AC_DEFINE(PAM, 1)
466         AC_CHECK_HEADERS(security/pam_appl.h,pam_ok=yes)
467         if test "$pam_ok" != "yes"; then
468                 AC_CHECK_HEADERS(pam/pam_appl.h,pam_ok=yes,
469                         AC_MSG_ERROR([required C header missing!]))
470         fi
471 fi
472
473 # compile in IRC+ protocol support?
474
475 x_ircplus_on=yes
476 AC_ARG_ENABLE(ircplus,
477         [  --disable-ircplus       disable IRC+ protocol],
478         if test "$enableval" = "no"; then x_ircplus_on=no; fi
479 )
480 if test "$x_ircplus_on" = "yes"; then
481         AC_DEFINE(IRCPLUS, 1)
482 fi
483
484 # enable support for IPv6?
485 x_ipv6_on=no
486 AC_ARG_ENABLE(ipv6,
487         [  --enable-ipv6           enable IPv6 protocol support],
488         if test "$enableval" = "yes"; then x_ipv6_on=yes; fi
489 )
490 if test "$x_ipv6_on" = "yes"; then
491         # getaddrinfo() and getnameinfo() are optional when not compiling
492         # with IPv6 support, but are required for IPv6 to work!
493         AC_CHECK_FUNCS([ \
494                 getaddrinfo getnameinfo \
495                 ],,AC_MSG_ERROR([required function missing for IPv6 support!]))
496         AC_DEFINE(WANT_IPV6, 1)
497 fi
498
499 # compile in IRC "sniffer"?
500
501 x_sniffer_on=no; x_debug_on=no
502 AC_ARG_ENABLE(sniffer,
503         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
504         if test "$enableval" = "yes"; then
505                 AC_DEFINE(SNIFFER, 1)
506                 x_sniffer_on=yes; x_debug_on=yes
507         fi
508 )
509
510 # enable additional debugging code?
511
512 AC_ARG_ENABLE(debug,
513         [  --enable-debug          show additional debug output],
514         if test "$enableval" = "yes"; then x_debug_on=yes; fi
515 )
516 if test "$x_debug_on" = "yes"; then
517         AC_DEFINE(DEBUG, 1)
518         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
519         AC_CHECK_FUNCS(mtrace)
520 fi
521
522 # enable "strict RFC rules"?
523
524 x_strict_rfc_on=no
525 AC_ARG_ENABLE(strict-rfc,
526         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
527         if test "$enableval" = "yes"; then
528                 AC_DEFINE(STRICT_RFC, 1)
529                 x_strict_rfc_on=yes
530         fi
531 )
532
533 # -- Definitions --
534
535 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
536 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
537 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
538
539 # Add additional CFLAGS, eventually specified on the command line, but after
540 # running this configure script. Useful for "-Werror" for example.
541 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
542
543 # -- Generate files --
544
545 AC_OUTPUT([ \
546         Makefile \
547         doc/Makefile \
548         doc/src/Makefile \
549         src/Makefile \
550         src/portab/Makefile \
551         src/ipaddr/Makefile \
552         src/tool/Makefile \
553         src/ngircd/Makefile \
554         src/testsuite/Makefile \
555         man/Makefile \
556         contrib/Makefile \
557         contrib/Anope/Makefile \
558         contrib/Debian/Makefile \
559         contrib/MacOSX/Makefile \
560         contrib/MacOSX/ngIRCd.xcodeproj/Makefile \
561         contrib/MacOSX/ngIRCd.pmdoc/Makefile \
562 ])
563
564 type dpkg >/dev/null 2>&1
565 if test $? -eq 0; then
566         # Generate debian/ link if the dpkg command exists
567         # (read: if we are running on a debian compatible system)
568         echo "creating Debian-specific links ..."
569         test -f debian/rules || ln -s contrib/Debian debian
570 fi
571
572 # -- Result --
573
574 echo
575 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
576 echo
577
578 # Someone please show me a better way :)  [borrowed by OpenSSH]
579 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
580 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
581 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
582 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
583 D=`eval echo ${docdir}` ; D=`eval echo ${D}`
584
585 echo "             Target: ${target}"
586 test "$target" != "$host" && echo "               Host: ${host}"
587 echo "           Compiler: ${CC}"
588 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
589 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
590 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
591 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
592 echo
593 echo "    'ngircd' binary: $S"
594 echo " Configuration file: $C"
595 echo "       Manual pages: $M"
596 echo "      Documentation: $D"
597 echo
598
599 echo $ECHO_N "     Syslog support: $ECHO_C"
600 test "$x_syslog_on" = "yes" \
601         && echo $ECHO_N "yes   $ECHO_C" \
602         || echo $ECHO_N "no    $ECHO_C"
603 echo $ECHO_N "  Enable debug code: $ECHO_C"
604 test "$x_debug_on" = "yes" \
605         && echo "yes" \
606         || echo "no"
607
608 echo $ECHO_N "   zlib compression: $ECHO_C"
609 test "$x_zlib_on" = "yes" \
610         && echo $ECHO_N "yes   $ECHO_C" \
611         || echo $ECHO_N "no    $ECHO_C"
612 echo $ECHO_N "        IRC sniffer: $ECHO_C"
613 test "$x_sniffer_on" = "yes" \
614         && echo "yes" \
615         || echo "no"
616
617 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
618 test "$x_tcpwrap_on" = "yes" \
619         && echo $ECHO_N "yes   $ECHO_C" \
620         || echo $ECHO_N "no    $ECHO_C"
621 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
622 test "$x_strict_rfc_on" = "yes" \
623         && echo "yes" \
624         || echo "no"
625
626 echo $ECHO_N "      IDENT support: $ECHO_C"
627 test "$x_identauth_on" = "yes" \
628         && echo $ECHO_N "yes   $ECHO_C" \
629         || echo $ECHO_N "no    $ECHO_C"
630 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
631 test "$x_ircplus_on" = "yes" \
632         && echo "yes" \
633         || echo "no"
634
635 echo $ECHO_N "      IPv6 protocol: $ECHO_C"
636 test "$x_ipv6_on" = "yes" \
637         && echo $ECHO_N "yes   $ECHO_C" \
638         || echo $ECHO_N "no    $ECHO_C"
639 echo $ECHO_N "        I/O backend: $ECHO_C"
640         echo "\"$x_io_backend\""
641
642 echo $ECHO_N "        PAM support: $ECHO_C"
643 test "$x_pam_on" = "yes" \
644         && echo $ECHO_N "yes   $ECHO_C" \
645         || echo $ECHO_N "no    $ECHO_C"
646 echo $ECHO_N "        SSL support: $ECHO_C"
647 echo "$x_ssl_lib"
648
649 echo
650
651 # -eof-